home *** CD-ROM | disk | FTP | other *** search
/ Amiga ACS 1998 #6 / amigaacscoverdisc1998-061998.iso / games / descent / source / 3d / interp.asm < prev    next >
Assembly Source File  |  1998-06-08  |  21KB  |  999 lines
  1. ;THE COMPUTER CODE CONTAINED HEREIN IS THE SOLE PROPERTY OF PARALLAX
  2. ;SOFTWARE CORPORATION ("PARALLAX").  PARALLAX, IN DISTRIBUTING THE CODE TO
  3. ;END-USERS, AND SUBJECT TO ALL OF THE TERMS AND CONDITIONS HEREIN, GRANTS A
  4. ;ROYALTY-FREE, PERPETUAL LICENSE TO SUCH END-USERS FOR USE BY SUCH END-USERS
  5. ;IN USING, DISPLAYING,  AND CREATING DERIVATIVE WORKS THEREOF, SO LONG AS
  6. ;SUCH USE, DISPLAY OR CREATION IS FOR NON-COMMERCIAL, ROYALTY OR REVENUE
  7. ;FREE PURPOSES.  IN NO EVENT SHALL THE END-USER USE THE COMPUTER CODE
  8. ;CONTAINED HEREIN FOR REVENUE-BEARING PURPOSES.  THE END-USER UNDERSTANDS
  9. ;AND AGREES TO THE TERMS HEREIN AND ACCEPTS THE SAME BY USE OF THIS FILE.  
  10. ;COPYRIGHT 1993-1998 PARALLAX SOFTWARE CORPORATION.  ALL RIGHTS RESERVED.
  11. ;
  12. ; $Source: f:/miner/source/3d/rcs/interp.asm $
  13. ; $Revision: 1.21 $
  14. ; $Author: john $
  15. ; $Date: 1994/10/26 23:57:49 $
  16. ; 
  17. ; Polygon object interpreter
  18. ; 
  19. ; $Log: interp.asm $
  20. ; Revision 1.21  1994/10/26  23:57:49  john
  21. ; Took out gr_inverse_table
  22. ; 
  23. ; Revision 1.20  1994/09/26  14:43:31  matt
  24. ; Put in checks for faces with fewer than 3 vertices
  25. ; 
  26. ; Revision 1.19  1994/09/09  14:24:14  matt
  27. ; Added support for glowing textures, to add engine glow to Descent.
  28. ; 
  29. ; Revision 1.18  1994/08/26  16:42:03  matt
  30. ; Added check for how many textures used in an object
  31. ; 
  32. ; Revision 1.17  1994/07/29  18:29:17  matt
  33. ; Use instance-by-angles code, instead of building matrix here
  34. ; 
  35. ; Revision 1.16  1994/07/25  10:58:28  matt
  36. ; Fixed morph effect for new 3d point handling
  37. ; 
  38. ; Revision 1.15  1994/07/25  00:00:07  matt
  39. ; Made 3d no longer deal with point numbers, but only with pointers.
  40. ; 
  41. ; Revision 1.14  1994/07/22  17:57:59  matt
  42. ; Changed the name of the rod functions, and took out some debugging code
  43. ; 
  44. ; Revision 1.13  1994/06/07  16:49:36  matt
  45. ; Made interpreter take lighting value as parm, rather than in global var
  46. ; 
  47. ; Revision 1.12  1994/05/31  22:11:52  matt
  48. ; Fixed morphing object lighting
  49. ; 
  50. ; Revision 1.11  1994/05/31  18:35:52  matt
  51. ; Added lighting back to polygon objects
  52. ; 
  53. ; Revision 1.10  1994/05/31  16:03:55  matt
  54. ; Made uvls right for triangulated faces in morphing objects
  55. ; 
  56. ; Revision 1.9  1994/05/30  22:48:34  matt
  57. ; Added support for morph effect
  58. ; 
  59. ; Revision 1.8  1994/05/19  23:12:04  matt
  60. ; Support new uvl value ranges
  61. ; 
  62. ; Revision 1.7  1994/04/29  15:39:46  matt
  63. ; Use ebx in one place because the assembler seemed to be using it anyway
  64. ; even though I typed just bx.
  65. ; 
  66. ; Revision 1.6  1994/04/19  17:02:32  matt
  67. ; Made g3d_interp_outline var accessible by C
  68. ; 
  69. ; Revision 1.5  1994/03/30  10:22:40  matt
  70. ; Added outline option for polygon models
  71. ; 
  72. ; Revision 1.4  1994/03/25  18:23:51  matt
  73. ; Fixed a couple of subobject problems, and made g3_draw_polygon_model
  74. ; take a pointer to a list of angvecs for subobj animation.
  75. ; 
  76. ; Revision 1.3  1994/03/18  16:07:57  matt
  77. ; Added subobject and rod bitmap opcodes
  78. ; 
  79. ; Revision 1.2  1994/03/15  21:23:04  matt
  80. ; Added code
  81. ; 
  82. ; Revision 1.1  1994/03/14  21:26:56  matt
  83. ; Initial revision
  84. ; 
  85. ; 
  86.  
  87.  
  88.  
  89. .386
  90.     option    oldstructs
  91.  
  92.     .nolist
  93.     include    types.inc
  94.     include    psmacros.inc
  95.     include    gr.inc
  96.     include    3d.inc
  97.     .list
  98.  
  99.     assume    cs:_TEXT, ds:_DATA
  100.  
  101. _DATA    segment    dword public USE32 'DATA'
  102.  
  103. rcsid    db    "$Id: interp.asm 1.21 1994/10/26 23:57:49 john Exp $"
  104.     align    4
  105.  
  106. ;table with address for each opcode
  107. opcode_table    dd    op_eof    ;0 = eof
  108.     dd    op_defpoints    ;1 = defpoints
  109.     dd    op_flatpoly    ;2 = flat-shaded polygon
  110.     dd    op_tmappoly    ;3 = texture-mapped polygon
  111.     dd    op_sortnorm    ;4 = sort by normal
  112.     dd    op_rodbm    ;5 = rod bitmap
  113.     dd    op_subcall    ;6 = call a subobject
  114.     dd    op_defp_start    ;7 = defpoints with start
  115.     dd    op_glow    ;8 = glow value for next poly
  116. n_opcodes = ($-opcode_table)/4
  117.  
  118. bitmap_ptr    dd    ?
  119. anim_angles    dd    ?    ;pointer to angle data
  120.  
  121. morph_points    dd    ?    ;alternate points for morph
  122.  
  123. ;light value for the next tmap
  124. glow_num    dd    -1    ;-1 means off
  125. glow_values    dd    ?    ;ptr to array of values
  126.  
  127.     public    _highest_texture_num
  128. _highest_texture_num dw    0
  129.  
  130. zero_angles    fixang    0,0,0    ;vms_angvec <0,0,0>    ;for if no angles specified
  131.  
  132. rod_top_p    g3s_point <>
  133. rod_bot_p    g3s_point <>
  134.  
  135.     ifndef    NDEBUG
  136.     public    g3d_interp_outline,_g3d_interp_outline
  137. _g3d_interp_outline label    dword
  138. g3d_interp_outline    dd    0
  139.     endif
  140.  
  141. morph_pointlist    dd    ?,?,?
  142.  
  143. morph_uvls    fix    3 dup (?,?,?)
  144.  
  145. ;the light for the current model
  146. model_light    fix    ?
  147.  
  148. ;ptr to array of points
  149. Interp_point_list    dd    ?
  150.  
  151. MAX_POINTS_PER_POLY = 25
  152.  
  153. point_list    dd    MAX_POINTS_PER_POLY dup (?)
  154.  
  155. _DATA    ends
  156.  
  157.  
  158.  
  159. _TEXT    segment    dword public USE32 'CODE'
  160.  
  161. ;get and jump to next opcode
  162. next    macro
  163.     xor    ebx,ebx
  164.     mov    bx,[ebp]
  165.     ifndef    NDEBUG
  166.      cmp    ebx,n_opcodes
  167.      break_if    ge,'Invalid opcode'
  168.     endif
  169.     mov    ebx,opcode_table[ebx*4]
  170.     jmp    ebx
  171.     endm
  172.  
  173. ;get and call the next opcode
  174. call_next    macro    
  175.     xor    ebx,ebx
  176.     mov    bx,[ebp]
  177.     ifndef    NDEBUG
  178.      cmp    ebx,n_opcodes
  179.      break_if    ge,'Invalid opcode'
  180.     endif
  181.     mov    ebx,opcode_table[ebx*4]
  182.     call    ebx
  183.     endm
  184.  
  185. ;give the interpreter an array of points to use
  186. g3_set_interp_points:
  187.     mov    Interp_point_list,eax
  188.     ret
  189.  
  190. ;interpreter to draw polygon model
  191. ;takes esi=ptr to object, edi=ptr to array of bitmap pointers, 
  192. ;eax=ptr to anim angles, edx=light value, ebx=ptr to array of glow values
  193. g3_draw_polygon_model:
  194.     pushm    eax,ebx,ecx,edx,esi,edi,ebp
  195.  
  196.     mov    ebp,esi    ;ebp = interp ptr
  197.  
  198.     mov    bitmap_ptr,edi    ;save ptr to bitmap array
  199.     mov    anim_angles,eax
  200.     mov    model_light,edx
  201.     mov    glow_values,ebx
  202.  
  203.     mov    glow_num,-1
  204.  
  205. ;;@@ mov depth,0
  206.  
  207.     call_next
  208.  
  209.     popm    eax,ebx,ecx,edx,esi,edi,ebp
  210.     ret
  211.  
  212. ;handlers for opcodes
  213.  
  214. ;end of a model or sub-rountine
  215. op_eof:    ret
  216.  
  217. ;define a list of points
  218. op_defpoints:    xor    ecx,ecx
  219.     mov    cx,2[ebp]    ;num points
  220.     mov    edi,Interp_point_list
  221.     lea    esi,4[ebp]
  222. rotate_loop:    call    g3_rotate_point
  223.     add    edi,size g3s_point
  224.     add    esi,size vms_vector
  225.     dec    ecx
  226.     jnz    rotate_loop
  227.     mov    ebp,esi
  228.     next
  229.  
  230. ;define a list of points, with starting point num specified
  231. op_defp_start:    xor    ecx,ecx
  232.     xor    eax,eax
  233.     mov    ax,w 4[ebp]    ;starting point num
  234.     imulc    eax,size(g3s_point) ;get ofs of point
  235.     ;changed the above line from "size g3s_point" to "size(g3s_point)" to make the compiler happy -KRB
  236.     
  237.     add    eax,Interp_point_list
  238.     mov    edi,eax
  239.     mov    cx,2[ebp]    ;num points
  240.     lea    esi,8[ebp]
  241.     jmp    rotate_loop
  242.     next
  243.  
  244. ;draw a flat-shaded polygon
  245. op_flatpoly:    xor    ecx,ecx
  246.     mov    cx,2[ebp]    ;num verts
  247.     lea    esi,4[ebp]    ;point
  248.     lea    edi,16[ebp]    ;vector
  249.     call    g3_check_normal_facing
  250.     jng    flat_not_facing
  251.  
  252. ;polygon is facing, so draw it
  253.  
  254.     xor    eax,eax
  255.     mov    ax,28[ebp]            ;get color
  256.     call    gr_setcolor_            ;set it
  257.  
  258.     lea    esi,30[ebp]    ;point number list
  259.  
  260.     ;make list of point pointers
  261.  
  262.     ifndef    NDEBUG
  263.      cmp    ecx,MAX_POINTS_PER_POLY
  264.      break_if    ge,'Too many points in interp poly'
  265.     endif
  266.  
  267.     lea    edi,point_list
  268.     xor    ebx,ebx
  269. copy_loop:    xor    eax,eax
  270.     mov    ax,w [esi+ebx*2]    ;get point number
  271.     imulc    eax,size(g3s_point);Modified to add Parentheses -KRB
  272.     add    eax,Interp_point_list
  273.     mov    [edi+ebx*4],eax
  274.     inc    ebx
  275.     cmp    ebx,ecx
  276.     jne    copy_loop
  277.     mov    esi,edi
  278.  
  279.     call    g3_draw_poly
  280.     xor    ecx,ecx
  281.     mov    cx,2[ebp]    ;restore count
  282.  
  283.     ifndef    NDEBUG
  284.     test    g3d_interp_outline,-1
  285.     jz    no_outline
  286.     pushm    ecx,esi
  287.     lea    esi,30[ebp]
  288.     call    draw_outline
  289.     popm    ecx,esi
  290. no_outline:
  291.     endif    
  292.  
  293. ;polygon is not facing (or we've plotted it). jump to next opcode
  294. flat_not_facing:    and    ecx,0fffffffeh
  295.     inc    ecx    ;adjust for pad
  296.     lea    ebp,30[ebp+ecx*2]
  297.     next
  298.  
  299. ;set the glow value for the next tmap
  300. op_glow:    test    glow_values,-1
  301.     jz    skip_glow
  302.     xor    eax,eax
  303.     mov    ax,2[ebp]
  304.     mov    glow_num,eax
  305. skip_glow:    add    ebp,4
  306.     next
  307.  
  308.  
  309. ;draw a texture map
  310. op_tmappoly:    xor    ecx,ecx
  311.     mov    cx,2[ebp]    ;num verts
  312.     lea    esi,4[ebp]    ;point
  313.     lea    edi,16[ebp]    ;normal
  314.     call    g3_check_normal_facing
  315.     jng    tmap_not_facing
  316.  
  317. ;polygon is facing, so draw it
  318.  
  319.     xor    edx,edx
  320.     mov    dx,28[ebp]    ;get bitmap number
  321.     mov    eax,bitmap_ptr
  322.     mov    edx,[eax+edx*4]
  323.  
  324.     lea    esi,30[ebp]    ;point number list
  325.     mov    eax,ecx
  326.     and    eax,0fffffffeh
  327.     inc    eax
  328.     lea    ebx,30[ebp+eax*2]    ;get uvl list
  329.  
  330. ;calculate light from surface normal
  331.     push    esi
  332.  
  333.     test    glow_num,-1    ;glow override?
  334.     js    no_glow
  335. ;special glow lighting, which doesn't care about surface normal
  336.     mov    eax,glow_num
  337.     mov    esi,glow_values
  338.     mov    eax,[esi+eax*4]
  339.     mov    glow_num,-1
  340.     jmp    got_light_value
  341. no_glow:
  342.     lea    esi,View_matrix.fvec
  343.     lea    edi,16[ebp]    ;normal
  344.     call    vm_vec_dotprod
  345.     neg    eax
  346. ;scale light by model light
  347.     push    edx
  348.     mov    edx,eax
  349.     add    eax,eax
  350.     add    eax,edx    ;eax *= 3
  351.     sar    eax,2    ;eax *= 3/4
  352.     add    eax,f1_0/4    ;eax = 1/4 + eax * 3/4
  353.     fixmul    model_light
  354.     pop    edx
  355. ;now poke light into l values
  356. got_light_value:    pushm    ecx,ebx
  357. l_loop:    mov    8[ebx],eax
  358.     add    ebx,12
  359.     dec    ecx
  360.     jnz    l_loop
  361.     popm    ecx,ebx
  362.     pop    esi
  363.  
  364. ;now draw it
  365.     ;make list of point pointers
  366.  
  367.     ifndef    NDEBUG
  368.      cmp    ecx,MAX_POINTS_PER_POLY
  369.      break_if    ge,'Too many points in interp poly'
  370.     endif
  371.  
  372.     push    ebx
  373.     lea    edi,point_list
  374.     xor    ebx,ebx
  375. copy_loop2:    xor    eax,eax
  376.     mov    ax,w [esi+ebx*2]    ;get point number
  377.     imulc    eax,size(g3s_point);;Modified to add Parentheses -KRB
  378.     add    eax,Interp_point_list
  379.     mov    [edi+ebx*4],eax
  380.     inc    ebx
  381.     cmp    ebx,ecx
  382.     jne    copy_loop2
  383.     mov    esi,edi
  384.     pop    ebx
  385.  
  386.     call    g3_draw_tmap
  387.     xor    ecx,ecx
  388.     mov    cx,2[ebp]    ;restore count
  389.  
  390.     ifndef    NDEBUG
  391.     test    g3d_interp_outline,-1
  392.     jz    no_outline2
  393.     pushm    ecx,esi
  394.     lea    esi,30[ebp]
  395.     call    draw_outline
  396.     popm    ecx,esi
  397. no_outline2:
  398.     endif    
  399.  
  400. ;polygon is not facing (or we've plotted it). jump to next opcode
  401. tmap_not_facing:    mov    ebx,ecx
  402.     and    ebx,0fffffffeh
  403.     inc    ebx    ;adjust for pad
  404.     lea    ebp,30[ebp+ebx*2]
  405.  
  406.     mov    eax,ecx
  407.     sal    ecx,1
  408.     add    ecx,eax
  409.     sal    ecx,2    ;ecx=ecx*12
  410.     add    ebp,ecx    ;point past uvls
  411.  
  412.     next
  413.  
  414. ;sort based on surface normal
  415. op_sortnorm:    lea    esi,16[ebp]    ;point
  416.     lea    edi,4[ebp]    ;vector
  417.     call    g3_check_normal_facing
  418.     jng    sortnorm_not_facing
  419.  
  420. ;is facing.  draw back then front
  421.  
  422.     push    ebp
  423.     xor    eax,eax
  424.     mov    ax,30[ebp]    ;get back offset
  425.     add    ebp,eax
  426.     call_next
  427.     mov    ebp,[esp]    ;get ebp
  428.     xor    eax,eax
  429.     mov    ax,28[ebp]    ;get front offset
  430.     add    ebp,eax
  431.     call_next
  432.     pop    ebp
  433.  
  434.     lea    ebp,32[ebp]
  435.     next
  436.  
  437. ;is not facing.  draw front then back
  438.  
  439. sortnorm_not_facing:
  440.     push    ebp
  441.     xor    eax,eax
  442.     mov    ax,28[ebp]    ;get back offset
  443.     add    ebp,eax
  444.     call_next
  445.     mov    ebp,[esp]    ;get ebp
  446.     xor    eax,eax
  447.     mov    ax,30[ebp]    ;get front offset
  448.     add    ebp,eax
  449.     call_next
  450.     pop    ebp
  451.  
  452.     lea    ebp,32[ebp]
  453.     next
  454.  
  455. ;draw a rod bitmap 
  456. op_rodbm:    lea    esi,20[ebp]    ;bot point
  457.     lea    edi,rod_bot_p
  458.     call    g3_rotate_point
  459.  
  460.     lea    esi,4[ebp]    ;top point
  461.     lea    edi,rod_top_p
  462.     call    g3_rotate_point
  463.  
  464.     lea    esi,rod_bot_p    ;esi=bot, edi=top
  465.     mov    eax,16[ebp]    ;bot width
  466.     mov    edx,32[ebp]    ;top width
  467.  
  468.     xor    ebx,ebx
  469.     mov    bx,2[ebp]    ;get bitmap number
  470.     mov    ecx,bitmap_ptr
  471.     mov    ebx,[ecx+ebx*4]
  472.  
  473.     call    g3_draw_rod_tmap
  474.  
  475.     lea    ebp,36[ebp]
  476.     next
  477.  
  478.  
  479. ;draw a subobject
  480. op_subcall:    xor    eax,eax
  481.     mov    ax,2[ebp]    ;get object number
  482.  
  483. ;get ptr to angles
  484.     mov    edi,anim_angles
  485.     or    edi,edi
  486.     jnz    angles_not_null
  487. ;angles not specified.  Use zero angles
  488.     lea    edi,zero_angles
  489.     jmp    got_angles
  490. angles_not_null:
  491.     imulc    eax,size(vms_angvec);Modified to add Parentheses -KRB
  492.     add    edi,eax
  493. got_angles:
  494.     ;angles in edi
  495.  
  496.     lea    esi,4[ebp]    ;get position
  497.     call    g3_start_instance_angles
  498.  
  499.     push    ebp
  500.     xor    eax,eax
  501.     mov    ax,16[ebp]
  502.     add    ebp,eax    ;offset of subobject
  503.     call_next        ;draw the subobject
  504.     pop    ebp
  505.  
  506.     call    g3_done_instance
  507.  
  508.     lea    ebp,20[ebp]
  509.     next
  510.  
  511.  
  512. ;initialize a polygon object
  513. ;translate colors, scale UV values
  514. ;takes esi=ptr to model
  515. g3_init_polygon_model:
  516.     mov    _highest_texture_num,-1
  517.  
  518.     pushm    eax,ebx,ecx,edx,esi,edi
  519.     call    init_loop
  520.     popm    eax,ebx,ecx,edx,esi,edi
  521.     ret
  522.  
  523.  
  524. init_loop:    mov    ax,[esi]    ;get opcode
  525.     cmp    ax,0    ;eof
  526.     jne    not_eof
  527.     ret
  528. not_eof:
  529.  
  530. ;defpoints
  531.     cmp    ax,1    ;defpoints
  532.     jne    not_defpoints
  533.     xor    eax,eax
  534.     mov    ax,2[esi]    ;get count
  535.     sal    eax,1
  536.     add    ax,2[esi]    ;*3
  537.     lea    esi,4[esi+eax*4]
  538.     jmp    init_loop
  539. not_defpoints:
  540.  
  541. ;flat polygon
  542.     cmp    ax,2
  543.     jne    not_flatpoly
  544.     ifndef    NDEBUG
  545.     cmp     w 2[esi],3
  546.     break_if    l,'face must have 3 or more points'
  547.     endif
  548.     ;NO_INVERSE_TABLE xor    ebx,ebx
  549.     ;NO_INVERSE_TABLE mov    bx,28[esi]        ;get color
  550.     ;NO_INVERSE_TABLE xor    eax,eax
  551.     ;NO_INVERSE_TABLE mov    al,gr_inverse_table[ebx]    ;xlate it
  552.     ; The following 3 lines replace the above
  553.     xor    eax, eax
  554.     mov    ax,28[esi]        ;get color
  555.     call    gr_find_closest_color_15bpp_
  556.  
  557.     mov    28[esi],ax        ;store new color
  558.  
  559.     xor    ecx,ecx
  560.     mov    cx,2[esi]    ;get nverts
  561.     and    ecx,0fffffffeh
  562.     inc    ecx    ;adjust for pad
  563.     lea    esi,30[esi+ecx*2]
  564.     jmp    init_loop
  565. not_flatpoly:
  566.  
  567. ;tmap polygon
  568.     cmp    ax,3
  569.     jne    not_tmappoly
  570.     ifndef    NDEBUG
  571.     cmp     w 2[esi],3
  572.     break_if    l,'face must have 3 or more points'
  573.     endif
  574.     mov    ax,28[esi]    ;get bitmap number
  575.     cmp    ax,_highest_texture_num
  576.     jle    not_new
  577.     mov    _highest_texture_num,ax
  578. not_new:    xor    ecx,ecx
  579.     mov    cx,2[esi]    ;get nverts
  580.     mov    ebx,ecx
  581.     and    ebx,0fffffffeh
  582.     inc    ebx    ;adjust for pad
  583.     lea    esi,30[esi+ebx*2]    ;point at uvls
  584.  
  585.     imul    ecx,12    ;size of uvls
  586.     add    esi,ecx    ;skip them
  587.     jmp    init_loop
  588.  
  589. ;;@@init_uv_loop:    mov    eax,[esi]    ;get u
  590. ;;@@    imul    eax,64    ;times bitmap w
  591. ;;@@    mov    [esi],eax
  592. ;;@@    mov    eax,4[esi]    ;get v
  593. ;;@@    imul    eax,64    ;times bitmap h
  594. ;;@@    mov    4[esi],eax
  595. ;;@@    add    esi,12    ;point at next
  596. ;;@@    dec    ecx
  597. ;;@@    jnz    init_uv_loop
  598. ;;@@    jmp    init_loop
  599. not_tmappoly:
  600.  
  601. ;sort
  602.     cmp    ax,4    ;sortnorm
  603.     jne    not_sortnorm
  604.  
  605.     push    esi
  606.     xor    eax,eax
  607.     mov    ax,28[esi]    ;get front offset
  608.     add    esi,eax
  609.     call    init_loop
  610.     mov    esi,[esp]
  611.     xor    eax,eax
  612.     mov    ax,30[esi]    ;get front offset
  613.     add    esi,eax
  614.     call    init_loop
  615.     pop    esi
  616.     lea    esi,32[esi]
  617.  
  618.     jmp    init_loop
  619. not_sortnorm:
  620.     cmp    ax,5
  621.     jne    not_rodbm
  622.  
  623.     add    esi,36
  624.     jmp    init_loop
  625.  
  626. not_rodbm:
  627.     cmp    ax,6
  628.     jne    not_subcall
  629.  
  630.  
  631.     push    esi
  632.     xor    eax,eax
  633.     mov    ax,16[esi]    ;get subobj offset
  634.     add    esi,eax
  635.     call    init_loop
  636.     pop    esi
  637.  
  638.     add    esi,20
  639.     jmp    init_loop
  640. not_subcall:
  641.     cmp    ax,7    ;defpoints
  642.     jne    not_defpoints_st
  643.     xor    eax,eax
  644.     mov    ax,2[esi]    ;get count
  645.     sal    eax,1
  646.     add    ax,2[esi]    ;*3
  647.     lea    esi,8[esi+eax*4]
  648.     jmp    init_loop
  649. not_defpoints_st:
  650.     cmp    ax,8
  651.     jne    not_glow
  652.     add    esi,4
  653.     jmp    init_loop
  654. not_glow:
  655.  
  656.     debug_brk    "Invalid opcode"
  657.  
  658.     jmp    init_loop
  659.  
  660.  
  661. ;takes ecx=count, esi=ptr to point list
  662. draw_outline:    pushm    eax,ebx,ecx,edx,esi,edi
  663.  
  664.     ;NO_INVERSE_TABLE xor    eax,eax
  665.     ;NO_INVERSE_TABLE mov    al,gr_inverse_table[7fffh]    ;white 
  666.     mov    eax, 255    ; bright white
  667.     call    gr_setcolor_
  668.  
  669.     mov    ebx,esi
  670.  
  671.     xor    eax,eax
  672.     mov    ax,[ebx]    ;get first point
  673.     push    eax    ;save it
  674.  
  675. outline_loop:    xor    esi,esi
  676.     xor    edi,edi
  677.     mov    si,[ebx]
  678.     dec    ecx
  679.     jz    done_loop
  680.     mov    di,2[ebx]
  681.     push    ebx
  682.  
  683.     imul    esi,size g3s_point
  684.     add    esi,Interp_point_list
  685.     imul    edi,size g3s_point
  686.     add    edi,Interp_point_list
  687.  
  688.     call    g3_draw_line
  689.     pop    ebx
  690.  
  691.     add    ebx,2
  692.     jmp    outline_loop
  693.  
  694. done_loop:    pop    edi    ;get first point back
  695.  
  696.     imul    esi,size g3s_point
  697.     add    esi,Interp_point_list
  698.     imul    edi,size g3s_point
  699.     add    edi,Interp_point_list
  700.  
  701.     call    g3_draw_line
  702.  
  703.     popm    eax,ebx,ecx,edx,esi,edi
  704.     ret
  705.  
  706. ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  707.  
  708. ;Special code to draw morphing objects
  709.  
  710. ;define a list of points
  711. morph_defpoints:    xor    ecx,ecx
  712.     mov    cx,2[ebp]    ;num points
  713.     mov    edi,Interp_point_list
  714.     lea    esi,4[ebp]
  715. morph_rotate_list:    lea    eax,[ecx*2+ecx]    ;eax=npoint * 3
  716.     lea    esi,[esi+eax*4]    ;point past points
  717.     push    esi
  718.     mov    esi,morph_points    ;get alternate points
  719. morph_rotate_loop:    call    g3_rotate_point
  720.     add    edi,size g3s_point
  721.     add    esi,size vms_vector
  722.     dec    ecx
  723.     jnz    morph_rotate_loop
  724.     pop    esi    ;restore pointer
  725.     mov    ebp,esi
  726.     next
  727.  
  728. ;define a list of points, with starting point num specified
  729. morph_defp_start:    xor    ecx,ecx
  730.     xor    eax,eax
  731.     mov    ax,w 4[ebp]    ;starting point num
  732.     imulc    eax,size(g3s_point);Modified to add Parentheses -KRB ;get ofs of point
  733.     add    eax,Interp_point_list
  734.     mov    edi,eax
  735.     mov    cx,2[ebp]    ;num points
  736.     lea    esi,8[ebp]
  737.     jmp    morph_rotate_list
  738.  
  739. ;draw a flat-shaded polygon
  740. morph_flatpoly:    xor    ecx,ecx
  741.     mov    cx,2[ebp]    ;num verts
  742.     lea    esi,4[ebp]    ;point
  743.     lea    edi,16[ebp]    ;vector
  744.  
  745. ;set color
  746.     xor    eax,eax
  747.     mov    ax,28[ebp]            ;get color
  748.     call    gr_setcolor_            ;set it
  749.  
  750. ;check and draw
  751.     lea    esi,30[ebp]    ;point number list
  752.  
  753.     xor    eax,eax
  754.     lodsw
  755.     imulc    eax,size(g3s_point);Modified to add Parentheses -KRB
  756.     add    eax,Interp_point_list
  757.     mov    morph_pointlist,eax
  758.     xor    eax,eax
  759.     lodsw
  760.     imulc    eax,size(g3s_point);Modified to add Parentheses -KRB
  761.     add    eax,Interp_point_list
  762.     mov    morph_pointlist+4,eax
  763.     xor    eax,eax
  764.     lodsw
  765.     imulc    eax,size(g3s_point);Modified to add Parentheses -KRB
  766.     add    eax,Interp_point_list
  767.     mov    morph_pointlist+8,eax
  768.  
  769.     cmp    ecx,3    ;3 points is good!
  770.     je    flat_got3
  771.     sub    ecx,2    ;tri count
  772.  
  773. flat_tri_loop:    xor    edi,edi    ;no normal, must compute
  774.     pushm    ecx,esi
  775.     mov    ecx,3    ;always draw triangle
  776.     lea    esi,morph_pointlist
  777.     call    g3_check_and_draw_poly
  778.     popm    ecx,esi
  779.  
  780.     mov    eax,morph_pointlist+8
  781.     mov    morph_pointlist+4,eax
  782.     xor    eax,eax
  783.     lodsw
  784.     imulc    eax,size(g3s_point);Modified to add Parentheses -KRB
  785.     add    eax,Interp_point_list
  786.     mov    morph_pointlist+8,eax
  787.  
  788.     dec    ecx
  789.     jnz    flat_tri_loop
  790.     jmp    flat_done_draw
  791.     
  792. flat_got3:
  793.     lea    esi,morph_pointlist
  794.     xor    edi,edi    ;no normal, must compute
  795.     call    g3_check_and_draw_poly
  796.  
  797. flat_done_draw:    xor    ecx,ecx
  798.     mov    cx,2[ebp]    ;restore count
  799.  
  800.     and    ecx,0fffffffeh
  801.     inc    ecx    ;adjust for pad
  802.     lea    ebp,30[ebp+ecx*2]
  803.     next
  804.  
  805. ;draw a texture map
  806. morph_tmappoly:    xor    ecx,ecx
  807.     mov    cx,2[ebp]    ;num verts
  808.     lea    esi,4[ebp]    ;point
  809.     lea    edi,16[ebp]    ;normal
  810.  
  811. ;get bitmap
  812.     xor    edx,edx
  813.     mov    dx,28[ebp]    ;get bitmap number
  814.     mov    eax,bitmap_ptr
  815.     mov    edx,[eax+edx*4]
  816.  
  817.     lea    esi,30[ebp]    ;point number list
  818.     mov    eax,ecx
  819.     and    eax,0fffffffeh
  820.     inc    eax
  821.     lea    ebx,30[ebp+eax*2]    ;get uvl list
  822. ;calculate light from surface normal
  823.     push    esi
  824.     lea    esi,View_matrix.fvec
  825.     lea    edi,16[ebp]    ;normal
  826.     call    vm_vec_dotprod
  827.     neg    eax
  828. ;scale light by model light
  829.     push    edx
  830.     mov    edx,eax
  831.     add    eax,eax
  832.     add    eax,edx    ;eax *= 3
  833.     sar    eax,2    ;eax *= 3/4
  834.     add    eax,f1_0/4    ;eax = 1/4 + eax * 3/4
  835.     fixmul    model_light
  836.  
  837.     or    eax,eax
  838.     jge    not_zero
  839.     xor    eax,eax
  840. not_zero:
  841.     pop    edx
  842.     pop    esi
  843.  
  844. ;now eax=plane light value
  845.  
  846.     mov    morph_uvls+8,eax
  847.     mov    morph_uvls+20,eax
  848.     mov    morph_uvls+32,eax
  849.  
  850.     xor    eax,eax
  851.     lodsw
  852.     imulc    eax,size(g3s_point);Modified to add Parentheses -KRB
  853.     add    eax,Interp_point_list
  854.     mov    morph_pointlist,eax
  855.     xor    eax,eax
  856.     lodsw
  857.     imulc    eax,size(g3s_point);Modified to add Parentheses -KRB
  858.     add    eax,Interp_point_list
  859.     mov    morph_pointlist+4,eax
  860.     xor    eax,eax
  861.     lodsw
  862.     imulc    eax,size(g3s_point);Modified to add Parentheses -KRB
  863.     add    eax,Interp_point_list
  864.     mov    morph_pointlist+8,eax
  865.  
  866.     cmp    ecx,3    ;3 points is good!
  867.     jl    tmap_done_draw    ;something is bad, abort
  868.     je    tmap_got3
  869.     sub    ecx,2    ;tri count
  870.  
  871.     push    edx
  872.  
  873.     mov    edx,[ebx]
  874.     mov    morph_uvls,edx
  875.     mov    edx,4[ebx]
  876.     mov    morph_uvls+4,edx
  877.  
  878.     mov    edx,12[ebx]
  879.     mov    morph_uvls+12,edx
  880.     mov    edx,16[ebx]
  881.     mov    morph_uvls+16,edx
  882.  
  883.     mov    edx,24[ebx]
  884.     mov    morph_uvls+24,edx
  885.     mov    edx,28[ebx]
  886.     mov    morph_uvls+28,edx
  887.  
  888.     add    ebx,3*12
  889.  
  890.     pop    edx
  891.  
  892.  
  893. tmap_tri_loop:    xor    edi,edi    ;no normal, must compute
  894.     pushm    ebx,edx,ecx,esi
  895.     mov    ecx,3    ;always draw triangle
  896.     lea    esi,morph_pointlist
  897.     lea    ebx,morph_uvls
  898.     call    g3_check_and_draw_tmap
  899.     popm    ebx,edx,ecx,esi
  900.  
  901.     mov    eax,morph_pointlist+8
  902.     mov    morph_pointlist+4,eax
  903.     xor    eax,eax
  904.     lodsw
  905.     imulc    eax,size(g3s_point);Modified to add Parentheses -KRB
  906.     add    eax,Interp_point_list
  907.     mov    morph_pointlist+8,eax
  908.  
  909.     push    edx
  910.     mov    edx,morph_uvls+24
  911.     mov    morph_uvls+12,edx
  912.     mov    edx,morph_uvls+28
  913.     mov    morph_uvls+16,edx
  914.  
  915.     mov    edx,[ebx]
  916.     mov    morph_uvls+24,edx
  917.     mov    edx,4[ebx]
  918.     mov    morph_uvls+28,edx
  919.     add    ebx,12
  920.     pop    edx
  921.  
  922.     dec    ecx
  923.     jnz    tmap_tri_loop
  924.     jmp    tmap_done_draw
  925.     
  926. tmap_got3:
  927. ;poke in light values
  928.     pusha
  929. tmap_l_loop:    mov    8[ebx],eax
  930.     add    ebx,12
  931.     dec    ecx
  932.     jnz    tmap_l_loop
  933.     popa
  934.  
  935.     lea    esi,morph_pointlist
  936.  
  937.     xor    edi,edi    ;no normal
  938.     call    g3_check_and_draw_tmap
  939.  
  940. tmap_done_draw:    xor    ecx,ecx
  941.     mov    cx,2[ebp]    ;restore count
  942.  
  943. ;jump to next opcode
  944.     mov    ebx,ecx
  945.     and    ebx,0fffffffeh
  946.     inc    ebx    ;adjust for pad
  947.     lea    ebp,30[ebp+ebx*2]
  948.  
  949.     mov    eax,ecx
  950.     sal    ecx,1
  951.     add    ecx,eax
  952.     sal    ecx,2    ;ecx=ecx*12
  953.     add    ebp,ecx    ;point past uvls
  954.  
  955.     next
  956.  
  957.  
  958. ;interpreter to draw polygon model
  959. ;takes esi=ptr to object, edi=ptr to array of bitmap pointers, 
  960. ;eax=ptr to anim angles, ebx=alternate points, edx=light value
  961.  
  962. g3_draw_morphing_model:
  963.     pushm    eax,ebx,ecx,edx,esi,edi,ebp
  964.  
  965.     mov    bitmap_ptr,edi    ;save ptr to bitmap array
  966.     mov    anim_angles,eax
  967.     mov    morph_points,ebx
  968.     mov    model_light,edx
  969.  
  970.     mov    ebp,esi    ;ebp = interp ptr
  971.  
  972.     ;set alternate opcode pointers
  973.  
  974.     push    opcode_table[1*4]    ;defpoints
  975.     push    opcode_table[2*4]    ;flatpoly
  976.     push    opcode_table[3*4]    ;tmappoly
  977.     push    opcode_table[7*4]    ;defp_start
  978.  
  979.     mov    opcode_table[1*4],offset morph_defpoints
  980.     mov    opcode_table[2*4],offset morph_flatpoly
  981.     mov    opcode_table[3*4],offset morph_tmappoly
  982.     mov    opcode_table[7*4],offset morph_defp_start
  983.  
  984.     call_next
  985.  
  986.     pop    opcode_table[7*4]    ;defp_start
  987.     pop    opcode_table[3*4]    ;tmappoly
  988.     pop    opcode_table[2*4]    ;flatpoly
  989.     pop    opcode_table[1*4]    ;defpoints
  990.  
  991.     popm    eax,ebx,ecx,edx,esi,edi,ebp
  992.     ret
  993.  
  994. _TEXT    ends
  995.  
  996.     end
  997.  
  998. 
  999.