home *** CD-ROM | disk | FTP | other *** search
/ Amiga ACS 1998 #6 / amigaacscoverdisc1998-061998.iso / games / descent / source / 3d / instance.asm < prev    next >
Assembly Source File  |  1998-06-08  |  4KB  |  183 lines
  1. ;THE COMPUTER CODE CONTAINED HEREIN IS THE SOLE PROPERTY OF PARALLAX
  2. ;SOFTWARE CORPORATION ("PARALLAX").  PARALLAX, IN DISTRIBUTING THE CODE TO
  3. ;END-USERS, AND SUBJECT TO ALL OF THE TERMS AND CONDITIONS HEREIN, GRANTS A
  4. ;ROYALTY-FREE, PERPETUAL LICENSE TO SUCH END-USERS FOR USE BY SUCH END-USERS
  5. ;IN USING, DISPLAYING,  AND CREATING DERIVATIVE WORKS THEREOF, SO LONG AS
  6. ;SUCH USE, DISPLAY OR CREATION IS FOR NON-COMMERCIAL, ROYALTY OR REVENUE
  7. ;FREE PURPOSES.  IN NO EVENT SHALL THE END-USER USE THE COMPUTER CODE
  8. ;CONTAINED HEREIN FOR REVENUE-BEARING PURPOSES.  THE END-USER UNDERSTANDS
  9. ;AND AGREES TO THE TERMS HEREIN AND ACCEPTS THE SAME BY USE OF THIS FILE.  
  10. ;COPYRIGHT 1993-1998 PARALLAX SOFTWARE CORPORATION.  ALL RIGHTS RESERVED.
  11. ;
  12. ; $Source: f:/miner/source/3d/rcs/instance.asm $
  13. ; $Revision: 1.8 $
  14. ; $Author: matt $
  15. ; $Date: 1994/07/29 18:16:16 $
  16. ; 
  17. ; Code for handling instanced 3d objects
  18. ; 
  19. ; $Log: instance.asm $
  20. ; Revision 1.8  1994/07/29  18:16:16  matt
  21. ; Added instance by angles, and corrected parms for g3_init()
  22. ; 
  23. ; Revision 1.7  1994/07/25  00:00:02  matt
  24. ; Made 3d no longer deal with point numbers, but only with pointers.
  25. ; 
  26. ; Revision 1.6  1994/06/16  17:52:31  matt
  27. ; If NULL passed for instance matrix, don't rotate (just do offset)
  28. ; 
  29. ; Revision 1.5  1994/06/01  18:10:22  matt
  30. ; Fixed register trash in g3_start_instance_matrix()
  31. ; 
  32. ; Revision 1.4  1994/03/25  17:09:20  matt
  33. ; Increase MAX_INSTANCE_DEPTH to 5 (from 3)
  34. ; 
  35. ; Revision 1.3  1994/02/10  18:00:43  matt
  36. ; Changed 'if DEBUG_ON' to 'ifndef NDEBUG'
  37. ; 
  38. ; Revision 1.2  1994/01/24  14:08:45  matt
  39. ; Added code to this previously dull file
  40. ; 
  41. ; Revision 1.1  1994/01/23  15:22:52  matt
  42. ; Initial revision
  43. ; 
  44. ; 
  45.  
  46.  
  47.  
  48. .386
  49.     option    oldstructs
  50.  
  51.     .nolist
  52.     include    types.inc
  53.     include    psmacros.inc
  54.     include    vecmat.inc
  55.     include    3d.inc
  56.     .list
  57.  
  58.     assume    cs:_TEXT, ds:_DATA
  59.  
  60. _DATA    segment    dword public USE32 'DATA'
  61.  
  62. rcsid    db    "$Id: instance.asm 1.8 1994/07/29 18:16:16 matt Exp $"
  63.     align    4
  64.  
  65. MAX_INSTANCE_DEPTH    equ    5
  66.  
  67. inst_context_size    equ    ((size vms_matrix) + (size vms_vector))
  68.  
  69. instance_stack    db    MAX_INSTANCE_DEPTH*inst_context_size dup (?)
  70.  
  71. instance_depth    dd    0
  72.  
  73. tempv    vms_vector <>
  74. tempm    vms_matrix <>
  75. tempm2    vms_matrix <>
  76.  
  77. instmat    vms_matrix <>
  78.  
  79. _DATA    ends
  80.  
  81.  
  82. _TEXT    segment    dword public USE32 'CODE'
  83.  
  84. ;start instancing, using angles (called vm_angles_2_matrix)
  85. ;takes esi=position, edi=angvec. trashes esi,edi
  86. ;if angles==NULL, don't modify matrix.  This will be like doing an offset
  87. g3_start_instance_angles:
  88.     or    edi,edi
  89.     jz    g3_start_instance_matrix    ;no new matrix
  90.  
  91.     push    esi
  92.     mov    esi,edi
  93.     lea    edi,instmat
  94.     call    vm_angles_2_matrix
  95.     pop    esi
  96.  
  97. ;    fall    g3_start_instance_matrix
  98.  
  99. ;start instancing, using a matrix
  100. ;takes esi=position, edi=matrix. trashes esi,edi
  101. ;if matrix==NULL, don't modify matrix.  This will be like doing an offset   
  102. g3_start_instance_matrix:
  103.     pushm    eax,ebx,ecx
  104.  
  105.     push    edi    ;save matrix
  106.     push    esi    ;save position
  107.  
  108. ;save current context
  109.     mov    eax,instance_depth
  110.     inc    instance_depth
  111.  
  112.     ifndef    NDEBUG
  113.      cmp    eax,MAX_INSTANCE_DEPTH
  114.      break_if    e,'Already at max depth'
  115.     endif
  116.  
  117.     imul    eax,inst_context_size
  118.     lea    edi,instance_stack[eax]
  119.  
  120.     lea    esi,View_position
  121.     mov    ecx,3
  122.     rep    movsd
  123.     lea    esi,View_matrix
  124.     mov    ecx,9
  125.     rep    movsd
  126.  
  127.  
  128. ;step 1: subtract object position from view position
  129.     pop    esi    ;object position
  130.     lea    edi,View_position
  131.     call    vm_vec_sub2
  132.  
  133. ;step 2: rotate view vector through object matrix
  134.  
  135.     pop    edi    ;get object matrix
  136.     or    edi,edi    ;null matrix?
  137.     jz    no_inst_matrix
  138.     lea    esi,View_position
  139.     lea    eax,tempv
  140.     call    vm_vec_rotate
  141.     vm_copy    esi,eax,ebx
  142.  
  143. ;step 3: rotate object matrix through view_matrix (vm = ob * vm)
  144.  
  145.     mov    esi,edi    ;object matrix
  146.  lea edi,tempm2
  147.  call vm_copy_transpose_matrix
  148.  lea esi,tempm2
  149.     lea    edi,View_matrix
  150.     lea    eax,tempm
  151.     call    vm_matrix_x_matrix
  152.     mov    esi,eax
  153.     mov    ecx,9
  154.     rep    movsd
  155.  
  156. no_inst_matrix:
  157.  
  158. ;now we are done! 
  159.     popm    eax,ebx,ecx
  160.     ret
  161.  
  162. ;we are done instancing
  163. g3_done_instance:    pushm    eax,ecx,esi,edi
  164.     dec    instance_depth
  165.     break_if    s,'Instance stack underflow!'
  166.     mov    eax,instance_depth
  167.     imul    eax,inst_context_size
  168.     lea    esi,instance_stack[eax]
  169.     lea    edi,View_position
  170.     mov    ecx,3
  171.     rep    movsd
  172.     lea    edi,View_matrix
  173.     mov    ecx,9
  174.     rep    movsd
  175.     popm    eax,ecx,esi,edi
  176.     ret
  177.  
  178.  
  179. _TEXT    ends
  180.  
  181.     end
  182.  
  183.