home *** CD-ROM | disk | FTP | other *** search
/ Amiga ACS 1998 #6 / amigaacscoverdisc1998-061998.iso / games / descent / source / 3d / draw.asm < prev    next >
Assembly Source File  |  1998-06-08  |  16KB  |  669 lines
  1. ;THE COMPUTER CODE CONTAINED HEREIN IS THE SOLE PROPERTY OF PARALLAX
  2. ;SOFTWARE CORPORATION ("PARALLAX").  PARALLAX, IN DISTRIBUTING THE CODE TO
  3. ;END-USERS, AND SUBJECT TO ALL OF THE TERMS AND CONDITIONS HEREIN, GRANTS A
  4. ;ROYALTY-FREE, PERPETUAL LICENSE TO SUCH END-USERS FOR USE BY SUCH END-USERS
  5. ;IN USING, DISPLAYING,  AND CREATING DERIVATIVE WORKS THEREOF, SO LONG AS
  6. ;SUCH USE, DISPLAY OR CREATION IS FOR NON-COMMERCIAL, ROYALTY OR REVENUE
  7. ;FREE PURPOSES.  IN NO EVENT SHALL THE END-USER USE THE COMPUTER CODE
  8. ;CONTAINED HEREIN FOR REVENUE-BEARING PURPOSES.  THE END-USER UNDERSTANDS
  9. ;AND AGREES TO THE TERMS HEREIN AND ACCEPTS THE SAME BY USE OF THIS FILE.  
  10. ;COPYRIGHT 1993-1998 PARALLAX SOFTWARE CORPORATION.  ALL RIGHTS RESERVED.
  11. ;
  12. ; $Source: f:/miner/source/3d/rcs/draw.asm $
  13. ; $Revision: 1.30 $
  14. ; $Author: matt $
  15. ; $Date: 1995/02/15 02:26:52 $
  16. ;
  17. ; Source for drawing routines
  18. ;
  19. ; $Log: draw.asm $
  20. ; Revision 1.30  1995/02/15  02:26:52  matt
  21. ; Put in added handling for odd clipping error
  22. ; 
  23. ; Revision 1.29  1995/02/10  16:41:41  matt
  24. ; Put in check for bad points after clip
  25. ; 
  26. ; Revision 1.28  1995/02/09  22:00:52  matt
  27. ; Removed dependence on divide overflow handler; we now check for overflow
  28. ; before dividing.  This fixed problems on some TI chips.
  29. ; 
  30. ; Revision 1.27  1994/11/30  00:59:32  mike
  31. ; optimizations.
  32. ; 
  33. ; Revision 1.26  1994/10/03  12:52:04  matt
  34. ; Fixed typo
  35. ; 
  36. ; Revision 1.25  1994/10/03  12:49:56  matt
  37. ; Took out unused routines & data
  38. ; 
  39. ; Revision 1.24  1994/07/24  23:59:34  matt
  40. ; Made 3d no longer deal with point numbers, but only with pointers.
  41. ; 
  42. ; Revision 1.23  1994/05/30  11:36:26  matt
  43. ; Added g3_set_special_render() to allow a user to specify functions to
  44. ; call for 2d draws.
  45. ; 
  46. ; Revision 1.22  1994/05/19  21:46:13  matt
  47. ; Moved texture lighting out of 3d and into the game
  48. ; 
  49. ; Revision 1.21  1994/05/13  17:06:18  matt
  50. ; Finished ripping out intersected side lighting code
  51. ; 
  52. ; Revision 1.20  1994/05/13  17:02:58  matt
  53. ; Took our special side lighting code
  54. ; 
  55. ; Revision 1.19  1994/04/19  18:45:19  matt
  56. ; Now call the clipped disk, which it should have done all along, but
  57. ; John had only implemented the unclipped disk, and it clipped anyway.
  58. ; 
  59. ; Revision 1.18  1994/04/19  18:26:42  matt
  60. ; Added g3_draw_sphere() function.
  61. ; 
  62. ; Revision 1.17  1994/04/19  17:03:40  matt
  63. ; For polygons, call the texture-mapper's flat shader
  64. ; 
  65. ; Revision 1.16  1994/03/18  15:58:37  matt
  66. ; Fixed bug that caused light vals to be screwed up
  67. ; 
  68. ; Revision 1.15  1994/03/14  12:37:31  matt
  69. ; Made draw routines check for rotated points
  70. ; 
  71. ; Revision 1.14  1994/02/10  18:00:39  matt
  72. ; Changed 'if DEBUG_ON' to 'ifndef NDEBUG'
  73. ; 
  74. ; Revision 1.13  1994/02/09  11:48:16  matt
  75. ; Changes return codes for drawing functions
  76. ; 
  77. ; Revision 1.12  1994/02/01  13:23:05  matt
  78. ; Added use_beam var to turn off beam lighting
  79. ; 
  80. ; Revision 1.11  1994/01/26  20:27:18  mike
  81. ; bright light on very near side.
  82. ; 
  83. ; Revision 1.10  1994/01/26  12:49:26  matt
  84. ; Made lighting computation a seperate function, g3_compute_lighting_value.
  85. ; Note the unwieldy function name, courtesy of Mike.
  86. ; 
  87. ; Revision 1.9  1994/01/25  16:38:02  yuan
  88. ; Fixed beam_brightness
  89. ; 
  90. ; Revision 1.8  1994/01/24  11:08:49  matt
  91. ; Added beam_brightness variable
  92. ; 
  93. ; Revision 1.7  1994/01/22  18:22:09  matt
  94. ; New lighting stuff now done in 3d; g3_draw_tmap() takes lighting parm
  95. ; 
  96. ; Revision 1.6  1993/12/05  23:47:14  matt
  97. ; Added function g3_draw_line_ptrs()
  98. ; 
  99. ; Revision 1.5  1993/11/22  10:51:29  matt
  100. ; Changed texture map function comments to reflect uvl (not just uv) struct
  101. ; 
  102. ; Revision 1.4  1993/11/17  10:40:02  matt
  103. ; Added check for zero-length normal in do_facing_check
  104. ; 
  105. ; Revision 1.3  1993/11/04  18:49:14  matt
  106. ; Added system to only rotate points once per frame
  107. ; 
  108. ; Revision 1.2  1993/11/04  12:36:36  mike
  109. ; Add support for static lighting value.
  110. ; 
  111. ; Revision 1.1  1993/10/29  22:20:27  matt
  112. ; Initial revision
  113. ; 
  114. ;
  115. ;
  116.  
  117. DONT_USE_UPOLY = 1
  118.  
  119. .386
  120.     option    oldstructs
  121.  
  122.     .nolist
  123.     include    types.inc
  124.     include    psmacros.inc
  125.     include    gr.inc
  126.     include    3d.inc
  127.     .list
  128.  
  129.     assume    cs:_TEXT, ds:_DATA
  130.  
  131. _DATA    segment    dword public USE32 'DATA'
  132.  
  133. rcsid    db    "$Id: draw.asm 1.30 1995/02/15 02:26:52 matt Exp $"
  134.     align    4
  135.  
  136. tempv    vms_vector <>
  137.  
  138. n_verts    dd    ?
  139. n_verts_4    dd    ?    ; added by mk, 11/29/94, point coding optimization.
  140. bitmap_ptr    dd    ?
  141.  
  142. uvl_list_ptr    dd    ?
  143.  
  144. tmap_drawer_ptr    dd    draw_tmap_
  145. flat_drawer_ptr    dd    gr_upoly_tmap_
  146. line_drawer_ptr    dd    gr_line_
  147.  
  148. _DATA    ends
  149.  
  150.  
  151.  
  152. _TEXT    segment    dword public USE32 'CODE'
  153.  
  154.     extn    gr_upoly_tmap_
  155.     extn    draw_tmap_
  156.  
  157. ;specifies new routines to call to draw polygons
  158. ;takes eax=ptr to tmap routine, edx=ptr to flat routine, ebx=line rtn
  159. g3_set_special_render:
  160.     or    eax,eax
  161.     jnz    got_tmap_ptr
  162.     lea    eax,cs:draw_tmap_
  163. got_tmap_ptr:    mov    tmap_drawer_ptr,eax
  164.  
  165.     or    edx,edx
  166.     jnz    got_flat_ptr
  167.     lea    edx,cs:gr_upoly_tmap_
  168. got_flat_ptr:    mov    flat_drawer_ptr,edx
  169.  
  170.     or    ebx,ebx
  171.     jnz    got_line_ptr
  172.     lea    ebx,cs:gr_line_
  173. got_line_ptr:    mov    line_drawer_ptr,ebx
  174.  
  175.     ret
  176.  
  177.  
  178. ;alternate entry takes pointers to points. esi,edi = point pointers
  179. g3_draw_line:
  180.     ;;ifndef    NDEBUG
  181.     ;; mov    ax,_Frame_count    ;curren frame
  182.     ;; cmp    ax,[esi].p3_frame    ;rotated this frame?
  183.     ;; break_if    ne,'Point not rotated in draw_line'
  184.     ;; cmp    ax,[edi].p3_frame    ;rotated this frame?
  185.     ;; break_if    ne,'Point not rotated in draw_line'
  186.     ;;endif
  187.  
  188.     mov    al,[esi].p3_codes
  189.     mov    ah,[edi].p3_codes
  190.  
  191. ;check codes for reject, clip, or no clip
  192.  
  193.     test    al,ah    ;check codes_and
  194.     jnz    no_draw_line    ;both off same side
  195.  
  196.     or    al,ah    ;al=codes_or
  197.     js    must_clip_line    ;neg z means must clip
  198.     
  199.     test    [esi].p3_flags,PF_PROJECTED
  200.     jnz    p0_projected
  201.     call    g3_project_point
  202. p0_projected:    test    [esi].p3_flags,PF_OVERFLOW
  203.     jnz    must_clip_line
  204.  
  205.     test    [edi].p3_flags,PF_PROJECTED
  206.     jnz    p1_projected
  207.     xchg    esi,edi    ;get point in esi
  208.     call    g3_project_point
  209.     xchg    esi,edi
  210. p1_projected:    test    [edi].p3_flags,PF_OVERFLOW
  211.     jnz    must_clip_line
  212.  
  213.     pushm    ebx,ecx,edx    ;save regs
  214.  
  215.     test    al,al    ;check codes or
  216.  
  217.     mov    eax,[esi].p3_sx
  218.     mov    edx,[esi].p3_sy
  219.  
  220.     mov    ebx,[edi].p3_sx
  221.     mov    ecx,[edi].p3_sy
  222.  
  223.     jz    unclipped_line    ;cc set from test above
  224.  
  225. ;call clipping line drawer
  226. ;;    call    gr_line_    ;takes eax,edx,ebx,ecx
  227.  push esi
  228.  mov esi,line_drawer_ptr
  229.  call esi
  230.  pop esi
  231.     popm    ebx,ecx,edx
  232.     ret    ;return value from gr_line
  233.  
  234. ;we know this one is on screen
  235. unclipped_line:    ;;call    gr_uline_    ;takes eax,edx,ebx,ecx
  236. ;; call gr_line_
  237.  push esi
  238.  mov esi,line_drawer_ptr
  239.  call esi
  240.  pop esi
  241.     popm    ebx,ecx,edx
  242.     mov    al,1    ;definitely drew
  243.     ret
  244.  
  245. ;both points off same side, no do draw
  246. no_draw_line:    xor    al,al    ;not drawn
  247.     ret
  248.  
  249. ;jumped here from out of g3_draw_line. esi,edi=points, al=codes_or
  250. must_clip_line:    call    clip_line    ;do the 3d clip
  251.     call    g3_draw_line    ;try draw again
  252.  
  253. ;free up temp points
  254.     test    [esi].p3_flags,PF_TEMP_POINT
  255.     jz    not_temp_esi
  256.     call    free_temp_point
  257. not_temp_esi:    test    [edi].p3_flags,PF_TEMP_POINT
  258.     jz    not_temp_edi
  259.     xchg    esi,edi
  260.     call    free_temp_point
  261. not_temp_edi:
  262.     ret    ;ret code set from g3_draw_line
  263.  
  264.  
  265. ;returns true if a plane is facing the viewer. takes the unrotated surface 
  266. ;normal of the plane, and a point on it.  The normal need not be normalized
  267. ;takes esi=vector (unrotated point), edi=normal. 
  268. ;returns al=true if facing, cc=g if facing
  269. ;trashes esi,edi
  270. g3_check_normal_facing:
  271.     push    edi    ;save normal
  272.     lea    eax,tempv
  273.     mov    edi,esi
  274.     lea    esi,View_position
  275.     call    vm_vec_sub
  276.  
  277.     mov    esi,eax    ;view vector
  278.     pop    edi    ;normal
  279.     call    vm_vec_dotprod
  280.  
  281.     or    eax,eax    ;check sign
  282.     setg    al    ;true if positive
  283.  
  284.     ret
  285.  
  286. ;see if face is visible and draw if it is.
  287. ;takes ecx=nv, esi=point list, edi=normal, ebx=point.
  288. ;normal can be NULL, which will for compution here (which will be slow).
  289. ;returns al=-1 if not facing, else 0
  290. ;Trashes ecx,esi,edx,edi
  291. g3_check_and_draw_poly:
  292.     call    do_facing_check
  293.     or    al,al
  294.     jnz    g3_draw_poly
  295.     mov    al,-1
  296.     ret
  297.  
  298. g3_check_and_draw_tmap:
  299.     push    ebx
  300.     mov    ebx,eax
  301.     call    do_facing_check
  302.     pop    ebx
  303.     or    al,al
  304.     jnz    g3_draw_tmap
  305.     mov    al,-1
  306.     ret
  307.  
  308.  
  309. ;takes edi=normal or NULL, esi=list of vert nums, ebx=pnt
  310. ;returns al=facing?
  311. do_facing_check:
  312.     test    edi,edi    ;normal passed?
  313.     jz    compute_normal    ;..nope
  314.  
  315. ;for debug, check for NULL normal
  316.     ifndef    NDEBUG
  317.      mov    eax,[edi].x
  318.      or    eax,[edi].y
  319.      or    eax,[edi].z
  320.      break_if    z,'Zero-length normal in do_facing_check'
  321.     endif
  322.  
  323. ;we have the normal. check if facing
  324.     push    esi
  325.     mov    esi,ebx
  326.     call    g3_check_normal_facing    ;edi=normal
  327.     pop    esi
  328.     setg    al    ;set al true if facing
  329.     ret
  330.  
  331. ;normal not specified, so must compute
  332. compute_normal:
  333.     pushm    ebx,ecx,edx,esi
  334.  
  335. ;get three points (rotated) and compute normal
  336.  
  337.     mov    eax,[esi]    ;get point
  338.     mov    edi,8[esi]    ;get point
  339.     mov    esi,4[esi]    ;get point
  340.  
  341.     lea    ebx,tempv
  342.     call    vm_vec_perp    ;get normal
  343.     mov    edi,eax    ;normal in edi
  344.     call    vm_vec_dotprod    ;point in esi
  345.  
  346.     or    eax,eax    ;check result
  347.     popm    ebx,ecx,edx,esi
  348.     sets    al    ;al=true if facing
  349.     ret
  350.  
  351.  
  352. ;draw a flat-shaded face.  returns true if drew
  353. ;takes ecx=nv, esi=list of pointers to points
  354. ;returns al=0 if called 2d, 1 if all points off screen  
  355. ;Trashes ecx,esi,edx
  356. g3_draw_poly:
  357.     pushm    ebx,edi
  358.  
  359.     lea    edi,Vbuf0    ;list of ptrs
  360.     xor    ebx,ebx    ;counter
  361.     mov    dx,0ff00h    ;init codes
  362.  
  363. codes_loop:    mov    eax,[esi+ebx*4]    ;get point number
  364.     mov    [edi+ebx*4],eax    ;store in ptr array
  365.  
  366.     ;;ifndef    NDEBUG
  367.     ;; push    ebx
  368.     ;; mov    bx,_Frame_count    ;curren frame
  369.     ;; cmp    bx,[eax].p3_frame    ;rotated this frame?
  370.     ;; break_if    ne,'Point not rotated in draw_poly'
  371.     ;; pop    ebx
  372.     ;;endif
  373.  
  374.     and    dh,[eax].p3_codes    ;update codes_and
  375.     or    dl,[eax].p3_codes    ;update codes_or
  376.  
  377.     inc    ebx
  378.     cmp    ebx,ecx    ;done?
  379.     jne    codes_loop    ;..nope
  380.  
  381. ;now dx = codes
  382.     test    dh,dh    ;check codes_and
  383.     jnz    face_off_screen    ;not visible at all
  384.  
  385.     test    dl,dl    ;how about codes_or
  386.     js    must_clip_face    ;neg z means must clip
  387.  jnz must_clip_face
  388.  
  389. ;reentry point for jump back from clipper
  390. draw_poly_reentry:
  391.     push    edx    ;save codes_or
  392.  
  393. ;now make list of 2d coords (& check for overflow)
  394.  
  395.     mov    edx,edi    ;edx=Vbuf0
  396.     xor    ebx,ebx
  397.     lea    edi,Vertex_list
  398.  
  399. coords_loop:    mov    esi,[edx+ebx*4]    ;esi = point
  400.     test    [esi].p3_flags,PF_PROJECTED
  401.     jnz    pnt_projected
  402.     call    g3_project_point
  403. pnt_projected:    test    [esi].p3_flags,PF_OVERFLOW
  404.     jnz    must_clip_face2
  405.     mov    eax,[esi].p3_sx
  406.     mov    [edi+ebx*8],eax
  407.     mov    eax,[esi].p3_sy
  408.     mov    4[edi+ebx*8],eax
  409.  
  410.     inc    ebx
  411.     cmp    ebx,ecx
  412.     jne    coords_loop
  413.  
  414.     mov    eax,ecx    ;eax=nverts
  415.     mov    edx,edi    ;edx=vertslist
  416.  
  417. ;check for trivial accept
  418.     pop    ebx    ;get codes_or
  419. ife DONT_USE_UPOLY
  420.     test    bl,bl
  421.     jz    no_clip_face
  422. endif
  423.     ;;call    gr_poly_    ;takes eax,edx
  424. ;;; call gr_upoly_tmap_
  425.  push ecx
  426.  mov ecx,flat_drawer_ptr
  427.  call ecx
  428.  pop ecx
  429.  
  430.     popm    ebx,edi
  431.     xor    al,al    ;say it drew
  432.     ret
  433.  
  434. ;all on screen.  call non-clipping version
  435. no_clip_face:    ;;call    gr_upoly_    ;takes eax,edx
  436. ;; call gr_poly_
  437.  call gr_upoly_tmap_
  438.     popm    ebx,edi
  439.     xor    al,al    ;say it drew
  440.     ret
  441.  
  442. ;all the way off screen. return
  443. face_off_screen:    popm    ebx,edi
  444.     mov    al,1    ;no draw
  445.     ret
  446.  
  447. ;we require a 3d clip
  448. must_clip_face2:    pop    edx    ;get codes back
  449. must_clip_face:    lea    esi,Vbuf0    ;src
  450.     lea    edi,Vbuf1    ;dest
  451.     mov    al,dl    ;codes in al
  452.     call    clip_polygon    ;count in ecx
  453.  
  454.     mov    edi,esi    ;new list in edi
  455.  
  456. ;clipped away?
  457.     jecxz    clipped_away
  458.     or    dh,dh    ;check codes_and
  459.     jnz    clipped_away
  460.  test dl,dl    ;check codes or
  461.  js clipped_away    ;some points still behind eye
  462.  
  463.     push    edi    ;need edi to free temp pnts
  464.     push    offset cs:reentry_return
  465.     pushm    ebx,edi    ;match what draw has pushed
  466.     jmp    draw_poly_reentry
  467.  
  468. reentry_return:
  469.     pop    edi
  470. clipped_away:    
  471.     push    eax    ;save ret codes
  472. ;free temp points
  473.     xor    ebx,ebx
  474. free_loop:    mov    esi,[edi+ebx*4]    ;get point
  475.     test    [esi].p3_flags,PF_TEMP_POINT
  476.     jz    not_temp
  477.     call    free_temp_point
  478. not_temp:    inc    ebx
  479.     cmp    ebx,ecx
  480.     jne    free_loop
  481.  
  482.     pop    eax    ;get ret codes back
  483.  
  484.     popm    ebx,edi
  485.     ret
  486.  
  487.  
  488. ;draw a texture-mapped face.  returns true if drew
  489. ;takes ecx=nv, esi=point list, ebx=uvl_list, edx=bitmap
  490. ;returns al=0 if called 2d, 1 if all points off screen  
  491. ;Trashes ecx,esi,edx
  492. g3_draw_tmap:
  493.     mov    bitmap_ptr,edx    ;save
  494.  
  495.     pushm    ebx,edi
  496.  
  497.     lea    edi,Vbuf0    ;list of ptrs
  498.     push    ebp    ;save ebp
  499.     mov    ebp,ebx    ;ebp=uvl list
  500.  mov uvl_list_ptr, ebx
  501.     mov    n_verts,ecx    ;save in memory
  502.     shl    ecx, 2
  503.  
  504. ;loop to check codes, make list of point ptrs, and copy uvl's into points
  505.     mov    dh, 0ffh    ; init codes (this pipelines nicely)
  506.     mov    n_verts_4, ecx
  507.     xor    ebx, ebx
  508.     xor    dl, dl    ; init codes (this pipelines nicely)
  509.  
  510. t_codes_loop:    mov    eax,[esi+ebx]    ;get point number
  511.     mov    [edi+ebx],eax    ;store in ptr array
  512.  
  513.     and    dh,[eax].p3_codes    ;update codes_and
  514.     or    dl,[eax].p3_codes    ;update codes_or
  515.  
  516.     mov    ecx,[ebp]    ;get u
  517.     add    ebp, 4    ; (this pipelines better ..mk, 11/29/94 ((my 33rd birthday...)))
  518.     mov    [eax].p3_u,ecx
  519.     mov    ecx,[ebp]    ;get v
  520.     add    ebp, 4
  521.     mov    [eax].p3_v,ecx
  522.     mov    ecx,[ebp]    ;get l
  523.     add    ebp, 4
  524.     mov    [eax].p3_l,ecx
  525.     or    [eax].p3_flags,PF_UVS + PF_LVS    ;this point's got em
  526.  
  527.     add    ebx,4
  528.     cmp    ebx, n_verts_4
  529.     jne    t_codes_loop    ;..nope
  530.  
  531.     pop    ebp    ;restore ebp
  532. ;now dx = codes
  533.     test    dh,dh    ;check codes_and
  534.     jnz    t_face_off_screen    ;not visible at all
  535.  
  536.     test    dl,dl    ;how about codes_or
  537.     jnz    t_must_clip_face    ;non-zero means must clip
  538.  
  539. ;reentry point for jump back from clipper
  540. t_draw_poly_reentry:
  541.  
  542. ;make sure all points projected
  543.     mov    edx,edi    ;edx=Vbuf0
  544.     xor    ebx,ebx
  545.  
  546. t_proj_loop:    mov    esi,[edx+ebx*4]    ;esi = point
  547.  
  548.     ;;ifndef    NDEBUG
  549.     ;; mov    ax,_Frame_count    ;curren frame
  550.     ;; cmp    ax,[esi].p3_frame    ;rotated this frame?
  551.     ;; break_if    ne,'Point not rotated in draw_tmap'
  552.     ;;endif
  553.  
  554.     test    [esi].p3_flags,PF_PROJECTED
  555.     jnz    t_pnt_projected
  556.     call    g3_project_point
  557. t_pnt_projected:
  558.     test    [esi].p3_flags,PF_OVERFLOW
  559.     break_if    nz,'Should not overflow after clip'
  560.     jnz    t_face_off_screen
  561.  
  562.     inc    ebx
  563.     cmp    ebx,n_verts
  564.     jne    t_proj_loop
  565.  
  566. ;now call the texture mapper
  567.     mov    eax,bitmap_ptr    ;eax=bitmap ptr
  568.     mov    edx,n_verts    ;edx=count
  569.     mov    ebx,edi    ;ebx=points
  570. ;;;    call    draw_tmap_
  571.  push ecx
  572.  mov ecx,tmap_drawer_ptr
  573.  call ecx
  574.  pop ecx
  575.     popm    ebx,edi
  576.     xor    al,al    ;say it drew
  577.     ret
  578.  
  579. ;all the way off screen. return
  580. t_face_off_screen:    popm    ebx,edi
  581.     mov    al,1    ;no draw
  582.     ret
  583.  
  584. ;we require a 3d clip
  585. t_must_clip_face:    lea    esi,Vbuf0    ;src
  586.     lea    edi,Vbuf1    ;dest
  587.     mov    al,dl    ;codes in al
  588.     mov    ecx,n_verts
  589.     call    clip_polygon    ;count in ecx
  590.     mov    n_verts,ecx
  591.  
  592.     mov    edi,esi    ;new list in edi
  593.  
  594. ;clipped away?
  595.     jecxz    t_clipped_away
  596.     or    dh,dh    ;check codes_and
  597.     jnz    t_clipped_away
  598.  test dl,dl    ;check codes or
  599.  js t_clipped_away    ;some points still behind eye
  600.  
  601.     push    edi    ;need edi to free temp pnts
  602.     push    offset cs:t_reentry_return
  603.     pushm    ebx,edi    ;match what draw has pushed
  604.     jmp    t_draw_poly_reentry
  605.  
  606. t_reentry_return:
  607.     pop    edi
  608. t_clipped_away:    
  609. ; free temp points
  610.     mov    ebx, ecx
  611.     push    eax    ;save ret code
  612.     dec    ebx
  613.     shl    ebx, 2
  614.  
  615. t_free_loop:    mov    esi,[edi+ebx]    ;get point
  616.     test    [esi].p3_flags,PF_TEMP_POINT
  617.     jz    t_not_temp
  618.     call    free_temp_point
  619. t_not_temp:    sub    ebx, 4
  620.     jns    t_free_loop
  621.  
  622.     pop    eax    ;get ret code
  623.  
  624.     popm    ebx,edi
  625.     ret
  626.  
  627.  
  628.  
  629. ;draw a sortof-sphere. takes esi=point, ecx=radius
  630. g3_draw_sphere:    test    [esi].p3_codes,CC_BEHIND
  631.     jnz    reject_sphere
  632.  
  633.     test    [esi].p3_flags,PF_PROJECTED
  634.     jnz    sphere_p_projected
  635.     call    g3_project_point
  636. sphere_p_projected:
  637.     test    [esi].p3_flags,PF_OVERFLOW
  638.     jnz    reject_sphere
  639.  
  640.  
  641. ;calc radius.  since disk doesn't take width & height, let's just
  642. ;say the the radius is the width
  643.  
  644.     pushm    eax,ebx,ecx,edx
  645.  
  646.     mov    eax,ecx
  647.     fixmul    Matrix_scale.x
  648.     imul    Canv_w2
  649. sphere_proj_div:    divcheck    [esi].z,sphere_div_overflow_handler
  650.     idiv    [esi].z
  651.  
  652.     mov    ebx,eax
  653.  
  654.     mov    eax,[esi].p3_sx
  655.     mov    edx,[esi].p3_sy
  656.     call    gr_disk_
  657.  
  658. sphere_div_overflow_handler:
  659.  
  660.     popm    eax,ebx,ecx,edx
  661.  
  662.  
  663. reject_sphere:    ret
  664.  
  665.  
  666. _TEXT    ends
  667.  
  668.     end
  669.