home *** CD-ROM | disk | FTP | other *** search
/ Amiga ACS 1998 #6 / amigaacscoverdisc1998-061998.iso / games / descent / source / 3d / clipper.asm < prev    next >
Assembly Source File  |  1998-06-08  |  9KB  |  383 lines
  1. ;THE COMPUTER CODE CONTAINED HEREIN IS THE SOLE PROPERTY OF PARALLAX
  2. ;SOFTWARE CORPORATION ("PARALLAX").  PARALLAX, IN DISTRIBUTING THE CODE TO
  3. ;END-USERS, AND SUBJECT TO ALL OF THE TERMS AND CONDITIONS HEREIN, GRANTS A
  4. ;ROYALTY-FREE, PERPETUAL LICENSE TO SUCH END-USERS FOR USE BY SUCH END-USERS
  5. ;IN USING, DISPLAYING,  AND CREATING DERIVATIVE WORKS THEREOF, SO LONG AS
  6. ;SUCH USE, DISPLAY OR CREATION IS FOR NON-COMMERCIAL, ROYALTY OR REVENUE
  7. ;FREE PURPOSES.  IN NO EVENT SHALL THE END-USER USE THE COMPUTER CODE
  8. ;CONTAINED HEREIN FOR REVENUE-BEARING PURPOSES.  THE END-USER UNDERSTANDS
  9. ;AND AGREES TO THE TERMS HEREIN AND ACCEPTS THE SAME BY USE OF THIS FILE.  
  10. ;COPYRIGHT 1993-1998 PARALLAX SOFTWARE CORPORATION.  ALL RIGHTS RESERVED.
  11. ;
  12. ; $Source: f:/miner/source/3d/rcs/clipper.asm $
  13. ; $Revision: 1.6 $
  14. ; $Author: matt $
  15. ; $Date: 1994/07/25 00:00:02 $
  16. ;
  17. ; Source for clipper
  18. ;
  19. ; $Log: clipper.asm $
  20. ; Revision 1.6  1994/07/25  00:00:02  matt
  21. ; Made 3d no longer deal with point numbers, but only with pointers.
  22. ; 
  23. ; Revision 1.5  1994/02/10  18:00:38  matt
  24. ; Changed 'if DEBUG_ON' to 'ifndef NDEBUG'
  25. ; 
  26. ; Revision 1.4  1994/01/13  15:39:09  mike
  27. ; Change usage of Frame_count to _Frame_count
  28. ; 
  29. ; Revision 1.3  1993/11/04  18:48:39  matt
  30. ; Added system to only rotate points once per frame
  31. ; 
  32. ; Revision 1.2  1993/11/04  12:36:25  mike
  33. ; Add clipping for lighting value.
  34. ; 
  35. ; Revision 1.1  1993/10/29  22:20:27  matt
  36. ; Initial revision
  37. ; 
  38. ;
  39. ;
  40.  
  41. .386
  42.     option    oldstructs
  43.  
  44.     .nolist
  45.     include    types.inc
  46.     include    psmacros.inc
  47.     include    gr.inc
  48.     include    3d.inc
  49.     .list
  50.  
  51.     assume    cs:_TEXT, ds:_DATA
  52.  
  53. _DATA    segment    dword public USE32 'DATA'
  54.  
  55. rcsid    db    "$Id: clipper.asm 1.6 1994/07/25 00:00:02 matt Exp $"
  56.     align    4
  57.  
  58.  public free_point_num
  59.  
  60. ;buffer of temp points for when clipping creates a new point
  61. temp_points    db    MAX_POINTS_IN_POLY * size g3s_point dup (?)
  62.  
  63. free_points    label    dword
  64. p = temp_points
  65.     rept    MAX_POINTS_IN_POLY
  66.      dd    p
  67.      p = p+size g3s_point
  68.     endm
  69.  
  70. free_point_num    dd    0
  71.     
  72. ;Vars for polygon clipper
  73.  
  74. nverts    dd    ?    ;number of verts in poly
  75. nv_cnt    dd    ?    ;loop variable
  76.  
  77. plane    db    ?
  78.  
  79. _DATA    ends
  80.  
  81.  
  82.  
  83. _TEXT    segment    dword public USE32 'CODE'
  84.  
  85. ;get a temporary point. returns ebp=point.
  86. get_temp_point:    mov    ebp,free_point_num
  87.     mov    ebp,free_points[ebp*4]
  88.     inc    free_point_num
  89.     mov    [ebp].p3_flags,PF_TEMP_POINT    ;clear proj,set temp
  90.     ifndef    NDEBUG
  91.      cmp    free_point_num,MAX_POINTS_IN_POLY
  92.      break_if    e,"temp_point buf empty!"
  93.     endif
  94.     ret
  95.  
  96. ;free a temporary point. takes esi=point
  97. free_temp_point:    push    eax
  98.     dec    free_point_num
  99.     mov    eax,free_point_num
  100.     mov    free_points[eax*4],esi
  101.     pop    eax
  102.     ret
  103.  
  104. ;clip a particular value (eg. x, y, u). 
  105. ;assumes esi,edi=start,end points, ebp=dest point, and ebx/ecx=fraction
  106. ;stores new value and returns it in eax
  107. clip_value    macro    ofs
  108.     mov    eax,[edi].ofs    ;end
  109.     sub    eax,[esi].ofs    ;-start
  110.     imul    ebx
  111.     idiv    ecx
  112.     add    eax,[esi].ofs    ;+start
  113.     mov    [ebp].ofs,eax
  114.     endm
  115.  
  116. ;clips an edge against one plane. 
  117. ;takes esi (on) ,edi (off)=points, cl=plane flag (1,2,4,8 = left,right,bot,top)
  118. ;returns esi,edi=clipped points (edi new), bl=codes
  119. ;trashes eax,edx,ebp
  120. clip_edge:
  121.  
  122. ;compute clipping value k = (xs-zs) / (xs-xe-zs+ze)
  123. ;use x or y as appropriate, and negate x/y value as appropriate
  124.  
  125.     mov    ebx,[esi].x    ;eax = xs
  126.     mov    edx,[edi].x    ;ebx = xe
  127.  
  128.     test    cl,CC_OFF_TOP+CC_OFF_BOT    ;top or bot (y)?
  129.     jz    not_y
  130.     mov    ebx,[esi].y    ;eax = ys
  131.     mov    edx,[edi].y    ;ebx = ye
  132. not_y:
  133.     test    cl,CC_OFF_LEFT+CC_OFF_BOT ;right or top (neg)?
  134.     jz    not_neg
  135.     neg    ebx
  136.     neg    edx
  137. not_neg:
  138.     mov    plane,cl    ;store
  139.     push    ecx    ;save plane
  140.  
  141.     sub    ebx,[esi].z    ;ebx = xs-zs
  142.     mov    ecx,ebx    ;ecx = xs-zs
  143.     sub    ecx,edx    ;edx = xs-xe-zs
  144.     add    ecx,[edi].z    ;edx = xs-xe+zs+ze
  145.  
  146. ;now frac=ebx/ecx
  147.  
  148.     call    get_temp_point    ;ret ebp=point
  149.     ;;mov    ax,_Frame_count
  150.     ;;mov    [ebp].p3_frame,ax    ;this point valid 
  151.  
  152.     clip_value x
  153.     mov    [ebp].z,eax    ;assume z=x
  154.  
  155.     clip_value y
  156.  
  157.     test    plane,CC_OFF_TOP+CC_OFF_BOT    ;top or bot (y)?
  158.     jz    not_y2
  159.     mov    [ebp].z,eax    ;z=y
  160. not_y2:
  161.  
  162. ;check if uv values present, and clip if so
  163.     test    [esi].p3_flags,PF_UVS    ;uv values here?
  164.     jz    no_clip_uv    ;..nope
  165.  
  166.     clip_value p3_u
  167.     clip_value p3_v
  168.     or    [ebp].p3_flags,PF_UVS    ;new point has uv set
  169. no_clip_uv:
  170.  
  171. ;check if lv values present, and clip if so
  172.     test    [esi].p3_flags,PF_LVS    ;lv values here?
  173.     jz    no_clip_lv    ;..nope
  174.  
  175.     clip_value p3_l
  176.     or    [ebp].p3_flags,PF_LVS    ;new point has lv set
  177. no_clip_lv:
  178.     pop    ecx    ;get plane back
  179.  
  180. ;negate z if clipping against left or bot
  181.     test    cl,CC_OFF_LEFT+CC_OFF_BOT ;right or top (neg)?
  182.     jz    not_neg2
  183.     neg    [ebp].z    ;z=-x (or -y)
  184. not_neg2:
  185.  
  186. ;see if discarded point is temp point, and free it if so
  187.  
  188.     mov    edi,ebp    ;return correct point
  189.     mov    eax,edi
  190.     jmp    code_point    ;returns bl=codes
  191.  
  192.  
  193. ;clips a line to the viewing pyramid.
  194. ;takes esi,edi=points (pointers), al=codes_or
  195. ;return esi,edi=clipped points, one or both new
  196. clip_line:    pushm    ebx,ecx,edx,ebp
  197.  
  198.     mov    ecx,1    ;plane flag
  199.  
  200. l_plane_loop:    test    al,cl    ;off this plane?
  201.     jz    l_not_this_plane
  202.  
  203.     test    [esi].p3_codes,cl    ;this one on?
  204.     jz    order_ok    ;..yep
  205.     xchg    esi,edi    ;..nope
  206. order_ok:
  207.     push    edi    ;save old off-screen point
  208.     call    clip_edge    ;esi=on, edi=off
  209.             ;returns bl=new edi codes
  210.  
  211.     pop    eax    ;get discarded point
  212. ;see if must free rejected point
  213.     test    [eax].p3_flags,PF_TEMP_POINT
  214.     jz    not_temp_eax
  215.     xchg    esi,eax
  216.     call    free_temp_point
  217.     mov    esi,eax
  218. not_temp_eax:
  219.  
  220.     mov    al,[esi].p3_codes    ;get esi codes
  221.     test    al,bl    ;clipped away?
  222.     jnz    l_clipped_away    ;..yep
  223.     or    al,bl    ;get new codes_or
  224. l_not_this_plane:
  225.     add    ecx,ecx    ;next plane
  226.     cmp    ecx,16    ;done?
  227.     jne    l_plane_loop    ;..nope
  228.  
  229. l_clipped_away:    popm    ebx,ecx,edx,ebp
  230.     ret
  231.  
  232.  
  233. ;TEMPORARY - inline this code when working
  234. ;takes esi,edi=lists
  235. ;returns edi=end of new list, dx=new codes. trashes eax,ebx,edx,ebp,esi
  236. clip_plane:
  237.     mov    ebx,nverts
  238.  
  239. ;copy first two verts to end
  240.     mov    eax,[esi]
  241.     mov    [esi+ebx*4],eax
  242.     mov    eax,4[esi]
  243.     mov    4[esi+ebx*4],eax
  244.  
  245.     mov    nv_cnt,ebx    ;loop variable
  246.  
  247.     add    esi,4    ;point at second
  248.  
  249.     mov    edx,0ff00h    ;initialize codes
  250.  
  251. point_loop:    mov    eax,[esi]    ;get current point
  252.     add    esi,4
  253.  
  254. ;go though list of points. 
  255.  
  256.     test    [eax].p3_codes,cl    ;cur point off?
  257.     jz    cur_not_off    ;..nope
  258.  
  259. ;cur point is off. check prev and next
  260.  
  261.     mov    ebx,[esi-8]    ;get prev
  262.     test    [ebx].p3_codes,cl    ;prev off?
  263.     jnz    prev_off    ;..yup, so nothing to clip
  264.  
  265.     push    eax    ;save current point
  266.  
  267. ;must clip cur (off screen) to prev (on screen)
  268.     pushm    edx,esi,edi    ;save codes,list pointers
  269.  
  270.     mov    esi,ebx    ;esi=on screen
  271.     mov    edi,eax    ;edi=off screen
  272.     call    clip_edge
  273.     mov    eax,edi    ;save new point
  274.  
  275.     popm    edx,esi,edi    ;get codes,list pointers
  276.  
  277.     mov    [edi],eax    ;store in dest list
  278.     add    edi,4
  279.     or    dl,bl    ;update codes_or
  280.     and    dh,bl    ;update codes_and
  281.  
  282.     pop    eax    ;restore current point
  283. prev_off:
  284.     mov    ebx,[esi]    ;get next
  285.     test    [ebx].p3_codes,cl    ;next off?
  286.     jnz    next_off    ;..yes
  287.  
  288.     push    eax    ;save current point
  289.  
  290. ;must clip cur (off screen) to next (on screen)
  291.     pushm    edx,esi,edi    ;save codes,list pointers
  292.  
  293.     mov    esi,ebx    ;esi=on screen
  294.     mov    edi,eax    ;edi=off screen
  295.     call    clip_edge
  296.     mov    eax,edi    ;save new point
  297.  
  298.     popm    edx,esi,edi    ;get codes,list pointers
  299.  
  300.     mov    [edi],eax    ;store in dest list
  301.     add    edi,4
  302.     or    dl,bl    ;update codes_or
  303.     and    dh,bl    ;update codes_and
  304.  
  305.     pop    eax    ;get current back
  306. next_off:
  307.  
  308. ;see if must free discarded point
  309.     test    [eax].p3_flags,PF_TEMP_POINT
  310.     jz    not_temp
  311.     xchg    esi,eax
  312.     call    free_temp_point
  313.     mov    esi,eax
  314. not_temp:
  315.  
  316.     jmp    do_next_point
  317.  
  318. cur_not_off:    mov    [edi],eax    ;store cur in dest buffer
  319.     add    edi,4
  320.     or    dl,[eax].p3_codes    ;update codes_or
  321.     and    dh,[eax].p3_codes    ;update codes_and
  322.  
  323. do_next_point:    dec    nv_cnt
  324.     jnz    point_loop
  325.  
  326.     ret
  327.  
  328.  
  329. ;3d clip a polygon.  
  330. ;takes esi=src list, edi=dest list, ecx=nverts, al=codes_or
  331. ;returns esi=list of clipped points, some of them new, ecx=new nverts, dx=codes
  332. ;esi at exit will be either of esi,edi at entry
  333. clip_polygon:    push    ebp
  334.  
  335.     mov    nverts,ecx    ;save
  336.  
  337. ;now loop through each plane, a-clipping as we go
  338.  
  339.     mov    ecx,1    ;plane flag
  340.  
  341.     mov    dl,al    ;dl = codes_or 
  342.  
  343. ;clipping from [esi] -> [edi]
  344. p_plane_loop:    test    dl,cl    ;off this plane?
  345.     jz    p_not_this_plane
  346.  
  347.     push    esi    ;save src ptr
  348.     push    edi    ;save dest ptr
  349.  
  350. ;clip against this plane
  351.     call    clip_plane    ;when working, inline this code
  352.  
  353. ;done clip for this plane
  354.     mov    eax,edi    ;end of dest loop
  355.     pop    esi    ;get start of dest buffer
  356.  
  357.     sub    eax,esi    ;get delta
  358.     sar    eax,2    ;get new vert count
  359.     mov    nverts,eax    ;save new value
  360.  
  361.     pop    edi    ;new dest = old scr
  362.  
  363.     test    dh,dh    ;check new codes_and
  364.     jnz    p_clipped_away    ;polygon all off screen
  365.  
  366. p_not_this_plane:    add    ecx,ecx    ;next plane
  367.     cmp    ecx,16    ;done?
  368.     jne    p_plane_loop    ;..nope
  369.  
  370. p_clipped_away:    pop    ebp
  371.     mov    ecx,nverts    ;new value
  372.     ret
  373.  
  374.  
  375. _TEXT    ends
  376.  
  377.  
  378.  
  379. ;should I write a combined clipper/projector?
  380.  
  381.     end
  382.  
  383.