home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
DOS/V Power Report 2001 December
/
VPR0112B.ISO
/
OLS
/
JED194V
/
JEDDOC.LZH
/
GAME.MCR
< prev
next >
Wrap
Text File
|
1994-07-10
|
3KB
|
128 lines
;**********************************************************
; JED マクロサンプル
; 'GAME.MCR'
; [テトリス(R)もどきのゲームマクロ]
; Ver 0.10 初版
; 0.20 May 1993 ... JED V0.6e以降に対応
; 0.30 一部変更 ... JED Ver1.40以降
; 0.40 Jly 1994 ... 枠線コード変更
;
; Written by H.Orikawa 1993, 94
; 注)このマクロはVZ付属のサンプルマクロを参考にした。
;
; *VZ は(株)Village Centerの市販エディタです。
;**********************************************************
;
;【遊び方】
; [CTRL]+[\] :開始
;
; [1]<-->[3] :ブロックを左右に移動
; [2] :ブロックを回転
; [SPACE] :ブロックを落下
; [ESC] :ポーズ
; [Q] :中止
;注)1.乱数発生しないので出現パターンは毎起動時同じ。
; 2.&b(n)はnの値に関係なく常に一定。
; 3.桁ゲージは非表示にしておくこと。
rr = 1,
(mi)? #v ;上書きモードだったら挿入モードにする
uu=10, u=20-uu/2, bb=10, f=g=0,
#68 ;auto indent on
&v(0) ;Cursor off
>20
01: (c)?{ &o(c) #s . }
(cd!=' ')?{ e+, &q }
10: e-, &01 (t)>?{ >+1 >+2 >+3 >+4 >+5 >+6 >+7 }
11: #d &01 #e &01 #s &01 #x
12: (d&1)?{ #s &01 #d #d &01 #d &01 #s #s .}
#x &01 #e #e &01 #e &01 #x #x
13: (d&1)?{ #d &01 #s #e &01 #s &01 #x #d .}
#e &01 #d &01 #e &01 #x #s #x
14: (d&1)?{ #d &01 #s #x &01 #s &01 #d #e .}
#e &01 #x #d &01 #x &01 #e #s
15: (d!=0)?{ #d &01 #s } (d!=1)?{ #e &01 #x }
(d!=2)?{ #s &01 #d } (d!=3)?{ #x &01 #e }
16: #d (d&1)?? &01 #e (d==0)? &01 #s (d&1)? &01 #s (d==1)? &01
#x (d&1)?? &01 #x (d==2)? &01 #d (d&1)? &01 #d (d==3)? &01 #e #s
17: #d (d&1)?? &01 #e (d==3)? &01 #s (d&1)? &01 #s (d==0)? &01
#x (d&1)?? &01 #x (d==1)? &01 #d (d&1)? &01 #d (d==2)? &01 #e #s
20: &s #39 #n #n #18
(u*2-2){' '}
'◇' (uu){'-'} '◇' #m
'§' (uu){' '} '§' #m
'◇' (uu){'='} '◇'
&d #e #k #68 #< (wy-5){ #p } #i (mi)?? #v >> ;overwrite
21: vv=100-f/2, (vv<bb)? {vv=bb,}
&m( "Best score %-5u Score %-5u Delay %-5u", h, g, vv ) >>
22: &s x=u+4, &y(y=4) &x(x*2)
rr+=12, t=rr%7, rr+=56, d=rr&3, rr++, ;適当に設定している
(c-)&10 (e)?{ (c='□')&10 >30 } >>
23: v=vv, >>
24: xx=yy=dd=0,
(c='□')&10 &d &s
:A &k k=r,
(k==$1B)?{ &d !92 &s >A }
(v<0)? >>
(v--)??{ &b(1) >> }
(k)?? >A
&f(k,"Qq312 ")
(r)>?{ >40 >40 (xx+) (xx--) (dd+) { v=-1, &b(2) >> } } >+2
>A
25: yy+,>>
26: (v>0)?{ v-=4, (v<1)? (v=1) }
(c=' ')&10
(yy)?{ &y(y+=yy) }
(xx)?{ x+=xx, &x(x*2) }
d=(d+dd)&3,
(c-)&10 (e)??{ (v)? >-2 >-3 }
&y(y-=yy)
x-=xx, &x(x*2)
d=(d-dd)&3,
(yy)?? >-3
(c='■')&10 &d &s
&y(y=2)
:Y &x(u*2) (x=uu)
:X (cd=='■')?{ #d (x--)? >X &x(u*2) (uu){'☆'} }
#x ((y++)<wy-2)? >Y &d
&s ff-, &y(y=2) &x(u*2)
:Z (cd=='☆')?{
#y &y(2) #k #i &y(y) g++,ff+, &d &s
&b(2) &b(2)
}
#x ((y++)<wy-2)? >Z
&d (ff)? (f++) >21
30: (g>h)? (h=g)
f=g=0,
&d
&b(4) &b(16)
!91 (r==(-1))? >>
#39 #x #k #< (wy-3){ #p } &s #40 (wy-3){ #y } &d >21
40: &d #39 #x (wy-2){ #y } #e #y #y
&m(" ")
(mi)? #v
&v(1) ;カーソル表示
/
;メニュー
91: "",22,1
" GAME OVER "
.
92: "",14,1
" PAUSE "
.