home *** CD-ROM | disk | FTP | other *** search
/ DOS/V Power Report 1997 March / VPR9703A.ISO / VPR_DATA / DOGA / SOURCES / POLYEDIT.LZH / ML / ML.DOC < prev    next >
Text File  |  1994-08-05  |  10KB  |  247 lines
  1. ****************************************************************************
  2. *
  3. *      マクロ言語
  4. *
  5. *    Copyright T.Kobayashi    1994.8.5
  6. *
  7. ****************************************************************************
  8.  
  9. １．はじめに
  10.  
  11.   　'ml'はインタープリンタ形式で実行するマクロ言語である。モデラ( model.exe,
  12.   model.x )のユーザインターフェースの記述に用いられている。
  13.  
  14.  
  15. ２．予約語と定数
  16.  
  17.   　予約語は以下の通り。
  18.     if, else, while, do, for, break, continue, return, var, 
  19.     function, private
  20.  
  21.   　定義済み定数（システム定数）は以下の通り。
  22.     TRUE        真
  23.     FALSE        偽
  24.     ON        ON
  25.     OFF        OFF
  26.     NOASSIGN    値が代入されていない変数
  27.     BOOLEAN        論理型
  28.     INT        整数型
  29.     REAL        実数型
  30.     ARRAY        配列型
  31.     FUNC        関数への参照型
  32.     TYPE        「型を示す」型
  33.     OBJECT        オブジェクト型
  34.  
  35.  
  36. ３．文法定義
  37.  
  38.   　文法の定義に用いる記号を示す。
  39.       ::=        左辺は右辺で定義される
  40.       ( ... )+    カッコ内の1回以上の繰り返し
  41.       ( ... )*    カッコ内の0回以上の繰り返し
  42.       [ ... ]        カッコ内は省略可能
  43.       " ... "        クオートで囲まれた文字列そのもの
  44.       < ... >        文法上の概念
  45.       |        左右のいずれか
  46.  
  47.   　以下に言語の文法定義を示す。
  48.     <プログラム>    ::=    ( <文> )*
  49.     <文>        ::=    <宣言> | <実行文> | <複文>
  50.     <複文>        ::=    "{" <文>* "}"
  51.     <宣言>        ::=    <変数宣言> | <関数宣言>
  52.     <変数宣言>    ::=    var <変数> ( , <変数> )* ;
  53.     <関数宣言>    ::=    function <識別子> "(" [ <変数列> ] ")" <文>
  54.     <変数列>    ::=    <変数> ( , <変数> )*
  55.     <変数>        ::=    <識別子> ( "[" <式> "]" )*
  56.     <実行文>    ::=    <if文> | <while文> | <do文> | <for文>
  57.                 <break文> | <continue文> | <return文> |
  58.                 <代入文> | <インクリメント文> | <手続き文>
  59.     <if文>        ::=    if "(" <式> ")" <文> [ else <文> ]
  60.     <while文>    ::=    while "(" <式> ")" <文>
  61.     <do文>        ::=    do <文> while "(" <式> ")" ;
  62.     <for文>        ::=    for "(" <文> <式> ; <文> ")" <文>
  63.     <break文>    ::=    break ;
  64.     <continue文>    ::=    continue ;
  65.     <return文>    ::=    return [ <式> ] ;
  66.     <代入文>    ::=    <変数> 代入演算子> <式> ;
  67.     <代入演算子>    ::=    = | += | ｰ= | *= | /= | &= | "|="
  68.     <インクリメント文> ::=    <変数> <インクリメント演算子> ;
  69.     <インクリメント演算子> ::= ++ | --
  70.     <手続き文>    ::=    <識別子> "(" [ <引数列> ] ")" ;
  71.     <引数列>    ::=    <式> ( , <式> )*
  72.      <式>        ::=    <論理積式> ( <論理和演算子> <論理積式> )*
  73.      <論理積式>    ::=    <比較式> ( <論理積演算子> <比較式> )*
  74.      <比較式>    ::=    <単純式> ( <比較演算子> <単純式> )*
  75.      <単純式>    ::=    <積和式> ( <シフト演算子> <積和式> )*
  76.      <積和式>    ::=    <項> ( <加法演算子> <項> )*
  77.      <項>        ::=    <因子> ( <乗法演算子> <因子> )*
  78.      <因子>        ::=    <単純因子> ( <参照演算子> <単純因子> )*
  79.      <単純因子>    ::=    [ <単項演算子> ]
  80.                 ( <変数> | <定数> | <関数> | "(" <式> ")" )
  81.      <関数>        ::=    <識別子> "(" [ <引数列> ] ")"
  82.      <定数>        ::=    <数値定数> | <文字列定数> | <システム定数>
  83.     <論理和演算子>    ::=    "|"
  84.     <論理積演算子>    ::=    &
  85.     <比較演算子>    ::=    == | != | < | > | <= | >=
  86.     <シフト演算子>    ::=    "<<" | ">>"
  87.     <加法演算子>    ::=    + | -
  88.     <乗法演算子>    ::=    * | / | %
  89.     <参照演算子>    ::=    . | "->"
  90.  
  91.   （注意）
  92.         <識別子>はアルファベットまたは数字または'_'の文字を組み合わせた文字列
  93.         （ただし、最初の文字は数字以外）である。
  94.         <数値定数>は0～9と'.'を組み合わせた文字列またはシングルクオートで囲ま
  95.         れた文字（その文字のアスキーコードを示す）。
  96.         <文字列定数>はダブルクオート'"'で囲まれた文字列である。
  97.         <システム定数>は前節で定義した。
  98.         <手続き文>と<関数>で参照されている<識別子>は<関数宣言>で宣言した<識別
  99.         子>でなければならない。
  100.         <単純因子>と<代入文>、<インクリメント>文で参照されている<識別子>は<変
  101.         数定義>で宣言した<識別子>でなければならない。
  102.  
  103.  
  104. ４．意味定義
  105.  
  106.   プログラム
  107.     <プログラム>は複数の<文>から構成される。<プログラム>を複数のファイルに分
  108.     割しても良いが、分割は<文>単位でされなければならない。
  109.     実行はファイルの先頭からなされる。分割した場合は別途ファイルの実行順を指
  110.     定する手段が用意される（はずである）。
  111.   文
  112.     <文>はフリーフォーマットである。改行はスペース文字と同様の意味しか持たな
  113.     い。Ｃと同様に{}で囲まれた1個以上の文は1個の文と同じものとみなされる（複
  114.     文）。
  115.   宣言文
  116.     <宣言文>は実行されない。
  117.   関数宣言
  118.     <関数宣言>中の文も宣言時には実行されない。他の<文>から参照された時に実行さ
  119.     れる。宣言は参照の前になされなければならない。<関数宣言>中で<関数宣言>する
  120.     ことはできない。従って、手続きと関数は常に大域である。
  121.   変数宣言
  122.     トップレベルで宣言された<変数>は大域変数となる。<関数宣言>の中で宣言された
  123.     <変数>はローカル変数となる。<変数宣言>は必ずしも<関数宣言>の先頭でする必要
  124.     はないが、使用する前には宣言しなければならない。同様に大域変数もファイルの
  125.     先頭で宣言する必要はないが、使用する前に宣言しなければならない。
  126.   変数と型
  127.     変数には型はない。数値には型がある。従って数値はその値と型を持ち、変数は型
  128.     と値の両方を保持する。型は以下の通り。
  129.     BOOLEAN    論理型
  130.     INT    整数型
  131.     REAL    実数型
  132.     ARRAY    配列型
  133.     FUNC    関数への参照型
  134.     TYPE    「型を示す」型
  135.     OBJECT    オブジェクト型
  136.     組み込み関数typeofで数値からその型を得ることができる。
  137.     BOOLEANは論理演算と一致、不一致比較( ==, != )のみ演算可能。INTは参照演算を
  138.     除くすべての演算が可能。REALは論理演算、シフト演算、参照演算以外のすべての
  139.     演算が可能。ARRAY, FUNC, TYPEは一致、不一致比較のみ演算可能。
  140.     一度も代入されてない変数を参照してはならない。
  141.     OBJECTは拡張型であり、拡張された型をクラスと呼ぶ。
  142.     クラスは応用システムごとに定義される（行列型、ベクトル型、複素型等）。文字
  143.     列型はデフォルトで定義されている。クラスごとに演算子の動作を定義できる。
  144.   配列変数
  145.     配列変数はＣと同様に[]を用いる。多次元配列も使用可能。
  146.     変数に型はないので配列変数の各メンバに別々の型の数値を代入してもよい。
  147.     1次元の配列変数を識別子だけで参照するとARRAY型とみなされる。同様に2次元の
  148.     配列変数を識別子だけまたは1次元配列として参照してもARRAYとみなされる。
  149.   制御文
  150.     if, while, fo, for, break, continue, returnの動作はＣと同様である。
  151.   演算
  152.     演算は単項演算、乗法演算、加法演算、比較演算、論理演算の順に優先される。
  153.     同一演算の中では左から右に演算される。Ｃと違って論理積と論理和の優先順位
  154.     は同じである。
  155.  
  156.  
  157. ５．組み込み手続きと組み込み関数
  158.  
  159. procedure    print( ... )
  160. ----------------------------------------------------------------------------
  161. 引数を表示して、改行する。
  162. 引数はBOOLEAN, INT, REAL, STRINGが有効。
  163. ［例］    print( "hello ", "world" );
  164. ----------------------------------------------------------------------------
  165.  
  166. procedure    printf( fmt, ... );
  167. ----------------------------------------------------------------------------
  168. フォーマットを設定して表示する。
  169. Ｃと同様。
  170. ----------------------------------------------------------------------------
  171.  
  172. procedure    callprocedure( proc, ... )
  173. ----------------------------------------------------------------------------
  174. 手続きを呼び出す。
  175. procはPROC型でなければならない。2番目以降の引数にprocへの引数を設定する。
  176. ［例］    callprocedure( print, "hello ", "world" );
  177. ----------------------------------------------------------------------------
  178.  
  179. function    typeof( arg )
  180. ----------------------------------------------------------------------------
  181. argの型を返す。argはすべての型で有効。
  182. 戻り値はTYPE型。
  183. ----------------------------------------------------------------------------
  184.  
  185. function    sizeof( ary )
  186. ----------------------------------------------------------------------------
  187. 配列のサイズを返す。aryは配列型。
  188. 戻り値はINT型。
  189. ----------------------------------------------------------------------------
  190.  
  191. function    strcat( str1, str2, ... )
  192. ----------------------------------------------------------------------------
  193. 引数の文字列を連結する。引数の数は可変ですべて文字列型。
  194. 戻り値はSTRING型。
  195. ----------------------------------------------------------------------------
  196.  
  197. function    tostring( arg )
  198. ----------------------------------------------------------------------------
  199. argを文字列に変換する。argはBOOLEAN, INT, REAL型のいずれか。
  200. 戻り値はSTRING型。
  201. ［例］    str = tostring( 1.0 );    strに"1.0"が代入される。
  202. ----------------------------------------------------------------------------
  203.  
  204. function    stringto( str )
  205. ----------------------------------------------------------------------------
  206. strをBOOLEAN, INT, REAL型のいずれかに変換する。strはSTRING型。
  207. いずれの型にも変換できなかった場合はstrそのものを返す。
  208. 戻り値はBOOLEAN, INT, REAL, STRING型。
  209. ［例］    a = tostring( "123" );    aに123が代入される。
  210. ----------------------------------------------------------------------------
  211.  
  212. function    strlen( str )
  213. ----------------------------------------------------------------------------
  214. strの長さを得る。strはSTRING型。
  215. 戻り値はINT型。
  216. ----------------------------------------------------------------------------
  217.  
  218. function    substr( str, top, len )
  219. ----------------------------------------------------------------------------
  220. 文字列strのtop文字目からlen文字の長さの文字列を得る。
  221. strはSTRING型、top, lenはINT型。
  222. 戻り値はSTRING型。
  223. ----------------------------------------------------------------------------
  224.  
  225. function    sqrt( arg )
  226. function    sin( arg )
  227. function    cos( arg )
  228. function    tan( arg )
  229. function    log( arg )
  230. function    exp( arg )
  231. ----------------------------------------------------------------------------
  232. 数値関数、引数はREAL型で戻り値もREAL型
  233. ----------------------------------------------------------------------------
  234.  
  235. function    abs( arg )
  236. ----------------------------------------------------------------------------
  237. 引数argの絶対値を求める。argはINTまたはREAL型。
  238. 戻り値はargと同じ型。
  239. ----------------------------------------------------------------------------
  240.  
  241. function    callfunction( func, ... )
  242. ----------------------------------------------------------------------------
  243. 関数を呼び出す。
  244. funcはFUNC型でなければならない。2番目以降の引数にfuncへの引数を設定する。
  245. ［例］    a = callfunction( tostring, "123" );    aに123が代入される。
  246. ----------------------------------------------------------------------------
  247.