home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
OS/2 Shareware BBS: 10 Tools
/
10-Tools.zip
/
armsdk20.zip
/
armsdk.exe
/
INSTALL.BAT
< prev
next >
Wrap
DOS Batch File
|
1998-10-23
|
6KB
|
178 lines
@ECHO OFF
REM **********************************************************************
REM **
REM ** (C) COPYRIGHT IBM CORP. 1996. ALL RIGHTS RESERVED.
REM **
REM ***********************************************************************
REM **
REM **
REM **
REM ***********************************************************************
set prodname="Application Response Measurement Development Toolkit"
set ApiName=ARM
REM set SdkPath=F:
set SdkPath=.
if (%ApiName%)==() goto OutOfEnvSpace
if (%prodname%)==() goto OutOfEnvSpace
if (%SdkPath%)==() goto OutOfEnvSpace
@cls
echo ***************************************************************
echo * *
echo * This command file installs the *
echo %prodname%
echo * In order to successfully perform this installation, *
echo * the following must be true: *
echo * *
echo * 1. The CD root directory must be the *
echo * current directory: *
echo * *
echo ***************************************************************
echo Press any key to start the installation. . .
pause > nul
cls
echo ***************************************************************
echo ***************************************************************
echo ***************************************************************
echo WARNING: If you have installed another application supporting
echo the %prodname% API
echo This command will overwrite any previous installations
echo of the API.
echo If so, cancel %0 now with CNTL-C.
echo ***************************************************************
echo ***************************************************************
echo ***************************************************************
pause
if (%1)==() goto Usage
if not exist %SdkPath%\%ApiName%.LST goto BadPath
set DestPat=%1\ARM_SDK
rem -----------------------------------
rem Create directories
rem and
rem Copy files
rem -----------------------------------
MD %DestPat%
xcopy %SdkPath%\README.PC %DestPat%\
MD %DestPat%\DOC
xcopy %SdkPath%\DOC\*.* %DestPat%\DOC
MD %DestPat%\INCLUDE
xcopy %SdkPath%\INCLUDE\*.* %DestPat%\include /s
MD %DestPat%\LIB
MD %DestPat%\LIB\WIN95_NT
xcopy %SdkPath%\LIB\WIN95_NT\*.DLL %DestPat%\LIB\WIN95_NT\
xcopy %SdkPath%\LIB\WIN95_NT\*.LIB %DestPat%\LIB\WIN95_NT\
MD %DestPat%\LIB\OS2
xcopy %SdkPath%\LIB\OS2\*.DLL %DestPat%\LIB\OS2
xcopy %SdkPath%\LIB\OS2\*.LIB %DestPat%\LIB\OS2\
MD %DestPat%\LIB\LOGAGENT
xcopy %SdkPath%\LIB\LOGAGENT\*.C %DestPat%\LIB\LOGAGENT\
xcopy %SdkPath%\LIB\LOGAGENT\LOGFILE %DestPat%\LIB\LOGAGENT\
MD %DestPat%\SAMPLES
MD %DestPat%\SAMPLES\WIN95_NT
xcopy %SdkPath%\SAMPLES\WIN95_NT\*.* %DestPat%\SAMPLES\WIN95_NT /s
echo @echo off > %DestPat%\SAMPLES\WIN95_NT\C\SETENV.BAT
echo set INCLUDE=%DestPat%\INCLUDE;%INCLUDE% >> %DestPat%\SAMPLES\WIN95_NT\C\SETENV.BAT
echo set LIB=%DestPat%\LIB\WIN95_NT;%LIB% >> %DestPat%\SAMPLES\WIN95_NT\C\SETENV.BAT
MD %DestPat%\SAMPLES\OS2
xcopy %SdkPath%\SAMPLES\OS2\*.* %DestPat%\SAMPLES\OS2 /s
echo @echo off > %DestPat%\SAMPLES\OS2\C\SETENV.CMD
echo set INCLUDE=%DestPat%\INCLUDE;%INCLUDE% >> %DestPat%\SAMPLES\OS2\C\SETENV.CMD
echo set LIB=%DestPat%\LIB\OS2;%LIB% >> %DestPat%\SAMPLES\OS2\C\SETENV.CMD
goto DoneCompleted
:OutOfEnvSpace
rem -----------------------------------
rem Display Out of Env. Space Message
rem -----------------------------------
echo:
echo: Error: Out of Environment Space !!
echo:
echo: Increase the size of your environment using the
echo: '/e' switch on COMMAND.COM.
echo:
echo: Example CONFIG.SYS:
echo:
echo: SHELL=C:\COMMAND.COM /e:512
echo:
goto DoneAborted
:BadPath
rem -----------------------------------
rem Display Bad Source Path Message
rem -----------------------------------
echo:
echo: Error: Bad Source Path !!
echo:
echo: The current working directory is not the CD-ROM drive
echo: with the %prodname% CD in the drive.
echo: Please make sure the correct CD is in the drive and
echo: the current directory is the parent directory of CD.
echo:
echo:
goto DoneAborted
:Usage
rem ---------------------------
rem Display INSTALL.BAT Usage
rem ---------------------------
echo:
echo: Usage:
echo: %0 {drive}
echo:
echo: where {drive} = destination drive
echo:
echo: example:
echo: %0 c:
echo:
goto DoneAborted
:MissSdkPath
rem -----------------------------
rem Display Set SdkPath Message
rem -----------------------------
echo:
echo: Error: Bad SDK DRIVE !!
echo:
echo: %SdkPath%
echo:
echo: Set the 'SdkPath' environment variable in
echo: %0.BAT to your CD drive or change directory
echo: to <your CD drive>:\
echo:
goto DoneAborted
:DoneAborted
echo: Installation failed
goto Done
:DoneCompleted
echo:
echo: -----------------------------------
echo: Installation completed
echo: -----------------------------------
echo:
echo: %prodname% installed in
echo:
echo: %DestPat%
echo:
goto Done
:Done
set prodname=
set SdkPath=
set ApiName=