home *** CD-ROM | disk | FTP | other *** search
/ Enigma Amiga Life 113 / EnigmaAmiga113CD.iso / software / utilities / viewer / source / viewerv4.4-le-ß.asm < prev   
Encoding:
Assembly Source File  |  1999-11-19  |  251.8 KB  |  10,722 lines
  1. ****************************************************************************
  2. *
  3. * RAM-based Console-Device text- and binary file viewer.
  4. * RAM-based virtual screen picture/image viewer.
  5. *
  6. ** THIS IS THE SPEICIAL VERSION, 4.4-LE - REAL "LINE EDIT" IMPLEMENTED!!!!!
  7. *
  8. *
  9. * Copyright 1992 - 1999 Jörg van de Loo
  10. *            Hövel 15
  11. *            47559 Kranenburg
  12. *            Germany
  13. *
  14. * No e-mail address ( - released to the public!).
  15. *
  16. * -13.06.1992, 22:58:59- V1.0 - Text viewer (PowerPacker (© Nico François) support)
  17. * -14.06.1992  23:55:43- V2.0 - Text and picture viewer (thanks to Holger Gzella for picture decoding)
  18. * -24.09.1992, 14:47:32- V3.0 - Text, picture and binary files viewer
  19. *  ...
  20. * -04.04.1993, 23:07:01- V3.6 - Rewritten for OS 3 (mainly, console handling...)
  21. * -18.06.1994, 21:05:22- V3.7 - Up from this version 100% OS 3 compatible, also brush support
  22. *                (complete re-work of picture decoding)
  23. * -24.06.1994, 15:33:28- V3.8
  24. * -26.06.1994, 01:54:47- V3.9
  25. * -28.06.1994, 14:42:19- V3.A
  26. * -30.06.1994, 00:23:00- V3.B  - Bug fixed version
  27. * -08.01.1995, 22:04:00- V3.BA - better Monitor handling plus ACBM files viewer -
  28. *                 pure sentimental - want to see old Amiga Basic used
  29. *                 pictures.
  30. *                 Now Viewer supports also a masking plane ....
  31. * -15.05.1996, 12:45:47- V3.C1 - FinalCopy-II and IFF-Text ASCII extracting support
  32. * -25.05.1996, 16:03:25- V3.D3 - Pweeh, string search routine implemented....
  33. *                 I crashed my system totally with lost of the source
  34. *                 because I forgot to give DisplayBeep() a parameter (NULL).
  35. *                 With MasterSekaV1.71 I recovered the lost source.
  36. * -23.08.1997, 21:22:54- V3.D38 - Viewer can now display 8bit images 100% correctly on a CyberGrafX (41.2+) screen
  37. * -28.12.1997, 23:03:31- V3.D39 - After heavy request AutoRequester now supports keys (AMIGA-V, AMIGA-B)
  38. * -19.02.1998, 09:53:16- V3.D3A - Viewer is now compatible (97%) to the Picasso96 software package
  39. *                  and to other alien gfx-board software packages (I hope so).
  40. * -18.10.1998, 21:44:21- V3.D3B - Viewer is now able to display 24 bit images on my gfx-card (CyberVision3D)
  41. * -09.04.1999, 22:26:29- V3.E00 - Conversion from HAM8 to 24 bit added (Picasso96 now 100% compatible to Viewer!!!)
  42. * -23.04.1999, 20:04:31- V3.ED0 - HAM6 to 24 bit tune-up implemented (removed code for HAM6 to 16 bit - too less brillance)
  43. * -01.05.1999, 23:31:48- V3.EDE - Removed bug that caused machine to crash upon displaying non-super bitmap images
  44. *                  on native AMIGAs and which was introduced with the code to display HAM8 images on
  45. *                  a 24 bit screen (set two `bne´ to wrong labels where one lead to an invalid stack)
  46. * -12.08.1999, 19:47:20- V4.0 - Added function to play either compressed or uncompressed 8SVX mono sound files from
  47. *                fast memory.
  48. * -19.11.1999, 15:32:17- V4.4 - Added support for 9 to 16 bitplane images (versions 4.1 - 4.3 extremly faulty)
  49. *
  50. *
  51. *
  52. *
  53. * Simple Text-, Binary- and Image-file viewer for the Amiga Operation System.
  54. *
  55. * This material is released "as it", no warranties are made!
  56. *
  57. * The program-code is position independent and resident capable.
  58. * It  requires  kickstart  1.2  or  higher and an Amiga Custom-Chip-Set (due
  59. * some  code  which  can be easily rewritten for non based Amiga Custom Chip
  60. * Set computers). AA- (AGA) resolution support added for pic-viewer of V3.7.
  61. *
  62. * Tested  successfully  under  SegTracker,  Enforcer, Mungwall, IOTorture in 
  63. * many circumstances.
  64. *
  65. * The  executeable  based  on this source may freely distributed so long the
  66. * copyright notice is unmodified - known as FreeWare.
  67. *
  68. * The  source-code  may improved by anyone who wants to do it - in this case
  69. * please read the "PRG-ShouldRead" file first - for the agreements.
  70. *
  71. * This  source-code  may  enclosed  to  _ANY_  assembler  package  (also  in
  72. * modified  form)  for  an example "how to code in 680x0 assembler", but the
  73. * copyright notice must be at least unaltered.
  74. *
  75. *
  76. * Noone can say: Copyright "Whose name" - I'm (J.v.d.Loo) the copyright holder!
  77. *
  78. *
  79. * This  program  was  written  using  HiSoft's  Devpac  Amiga  3 assembler -
  80. * without its special advantages.
  81. *
  82. *
  83. * If  anyone  takes  money  for  this  source-code,  object-file or enclosed |
  84. * documentation  and  someone  tells me - the fellow who took the money will |
  85. * meet  me  - more than 6 foots tall, more than 200 pounds - and what's very |
  86. * dangerous  -  carrier of the stinking sock - but my Master told me to take |
  87. * off  my  shoes only in an emergency - the smell is not the worst - he said |
  88. * - but the burning eyes...                             |
  89. *
  90. *
  91. * NOTES:
  92. * This source file can be assembled unmodified at least with:
  93. *    HiSoft's Devpac Amiga Assembler 3   (commercial) [fast assembler]
  94. *    Samu Noujua's SNMA Assembler 1.99   (freeware)   [fast assembler]
  95. *    Frank Wille's PhxAss Assembler 4.18 (shareware)  [medium assembler/ fast linker]
  96. *
  97. * For  the  Macro-System's Draco computer you have to remove all lines which
  98. * are accessing the hardware directly.
  99. *
  100. * List of what to do...
  101. *     Printer  status should be tested via parallel/and or serial devices,
  102. *     using QUERY-command.
  103. *    Picture  display  routine must first open the screen, then a window.
  104. *    'Blit' the image to the window rastport instead of screen's bitmap.
  105. *    May  replace code for scrolling SuperBitMaps through 'Blits' because
  106. *    the  most 3rd graphic board software doesn't support changes of View
  107. *    dx/dy,  or  they  don't  support  custom  bitmaps and then the image
  108. *    screen's bitmap is only as tall as the standard monitor resolution.
  109. *    Status  of  left-  and  right mousebuttons can be easily checked via
  110. *    IDCMPs of the (added) image window.
  111. *    The other code is system-conform (I hope...).
  112.  
  113.  
  114.     IFD    __G2
  115.  
  116.     OUTPUT    RAM:Viewer        ; Child's name when using Devpac
  117.  
  118.     MACHINE    MC68000            ; Processor selection
  119.  
  120.     ENDC
  121.  
  122. *    OPT    D+
  123.  
  124.     include    exec/types.i
  125.     include    exec/memory.i
  126.     include    exec/ports.i
  127.     include    exec/lists.i
  128.     include    exec/devices.i
  129.     include    exec/execbase.i
  130.  
  131.     include    graphics/gfx.i
  132.     include    graphics/text.i
  133.     include    graphics/rastport.i
  134.     include    graphics/gfxbase.i
  135.     include    graphics/graphics_lib.i
  136.  
  137.     include    intuition/intuition.i
  138.     include    intuition/screens.i
  139.     include    intuition/intuitionbase.i
  140.     include    intuition/intuition_lib.i
  141.  
  142.     include    dos/dos.i
  143.  
  144.     include    devices/audio.i
  145.  
  146.  
  147. ***********************************
  148. *
  149. * Define needed constants and arrays
  150. *
  151.     STRUCTURE    _Table,68        ; Begin at offset 68 (end of table used by startup-code)
  152.  
  153.     ULONG    _dummy000        ; Only to make "FIB" staying on a through eight
  154. *                      divisible address - you may use "ALIGNLONG"
  155. *                      MACRO instead...
  156.  
  157.     STRUCT    _FIB,272        ; FileInfoBlock
  158.  
  159.     STRUCT    _NewScreen,ens_SIZEOF    ; Screen's structure
  160.     STRUCT    _StdTags,56        ; Screen's taglist (up from OS 2.0)
  161.  
  162.     STRUCT    _WindowRecord,nw_SIZEOF    ; Window's structure
  163.     STRUCT    _ErrWindowStruc,nw_SIZEOF ; Ditto
  164.  
  165.     STRUCT    _Gad1,gg_SIZEOF
  166.     STRUCT    _Gad2,gg_SIZEOF
  167.     STRUCT    _GTxt1,it_SIZEOF
  168.     STRUCT    _GTxt2,it_SIZEOF
  169.  
  170.     STRUCT    _Gad3,gg_SIZEOF        ; Audio Hit Gadget, no text
  171.  
  172.     STRUCT    _ArpReqStruc,32        ; Only 26 bytes are needed
  173.     STRUCT    _UserFontStruc,8    ; Font-record
  174.  
  175.     ALIGNLONG
  176.  
  177.     ULONG    _RealIWidth        ; No boundary
  178.     ULONG    _ImageWidth        ; 16 bit boundary
  179.  
  180. * BMHD-settings follow..... - used for picture
  181.     UWORD    _Width            ; May be taller than displayable... (64 bit boundary)
  182.     UWORD    _Height            ; ditto
  183.     UWORD    _XPos
  184.     UWORD    _YPos
  185.     UBYTE    _Depth
  186.     UBYTE    _Masking
  187.     UBYTE    _Compresstyp
  188.     UBYTE    _BMHDFlags        ; Was before ks 3.0 unused (bmhd_pad)
  189.     UWORD    _TransColour
  190.     UBYTE    _XAspect
  191.     UBYTE    _YAspect
  192.     UWORD    _PlaneWidth        ; Visible size
  193.     UWORD    _PlaneHeight        ; ditto
  194.     UWORD    _Dummy            ; Strictly for longword adjustment
  195.     ULONG    _ViewPortMod
  196.     STRUCT    _Colourmap,1024        ; Max. room for 256 colours
  197.  
  198.     ULONG    _TypeOfMem        ; Which memory type used for bitmap allocation? (~0 = CHIP, 0 = ANY)
  199.     LONG    _ViewPortShare        ; Can we change through RasInfo the visible part of an image ( 0=yes,1=yes,-1=no)
  200.     ULONG    _HAMSet            ; Depth of image in case image is HAM encoded
  201.  
  202.     UWORD    _OldY            ; Used only for ks lower than v36
  203.     UWORD    _OldX            ; Used only for ks lower than v36
  204.  
  205.     UWORD    _BgPen            ; Colour-index for background of window's title
  206.  
  207.     STRUCT    _DisplayInfo,dis_SIZEOF    ; Buffer for DisplayInfoData
  208.  
  209.     ALIGNLONG            ; <- EXEC/EXEC_TYPES.I
  210.  
  211.     APTR    _GfxBase
  212.     APTR    _IntuitionBase
  213.     APTR    _ReqToolsBase
  214.     APTR    _ArpBase
  215.     APTR    _CyberGfxBase
  216.     APTR    _ScreenPtr
  217.  
  218.     APTR    _ReqPtr            ; ReqTools requester record
  219.  
  220.     ULONG    _argError        ; Not zero upon argument error
  221.     ULONG    _LinesInFile        ; Number of lines in file
  222.     ULONG    _UPFSize        ; Uncompressed file size
  223.     ULONG    _IncSize        ; Increased uncompressed file size
  224.     ULONG    _Line            ; Current line where cursor stays
  225.     ULONG    _PageWidth
  226.     UWORD    _StdPageSize        ; Std. scrollwidth for console in lines
  227.  
  228.     ALIGNLONG
  229.  
  230.     APTR    _ErrWindowPtr        ; Intuition window record
  231.     APTR    _DecrunchAddr        ; Address decrunched file
  232.     APTR    _StdprWindowPtr        ; Old pointer for system requesters
  233.     APTR    _PtrToWTitle        ; Pointer to window's title text
  234.     APTR    _UserProject        ; Info-file (for icon.library)
  235.     APTR    _WindowPtr        ; Intuition window record
  236.     APTR    _IAddr            ; Window's object that raised message
  237.  
  238.     STRUCT    _WindowTitle,148    ; Room for window's title (title is
  239. *                      changed each time a new file is loaded)
  240.  
  241.     LABEL    _WriteIo        ; Startaddress for console-write message
  242.     STRUCT    _Msg,20            ; Message length, 20 byte
  243.     STRUCT    _Io,12            ; Console-write IO, 12 bytes
  244.     STRUCT    _WriteReq,16        ; Console-write request, 16 bytes
  245.     STRUCT    _WriteReply,34        ; ReplyPort for Console-write
  246.  
  247.     STRUCT    _ReadIo,48        ; Console-read message including IO and REQ
  248.     STRUCT    _ReadReply,34        ; Console-read reply port
  249.  
  250.     ALIGNLONG
  251.  
  252.     APTR    _TextPtr        ; Address file in memory
  253.     APTR    _BufferSize        ; Allocated size
  254.     LONG    _FileSize        ; File's real size
  255.  
  256.     BPTR    _LockSave        ; Key to file (closed)
  257.     BPTR    _FileHandle        ; Handle (closed)
  258.  
  259.     APTR    _UserFontPtr        ; Font record (perhaps opened)
  260.     APTR    _OldFontPtr        ; System's default font
  261.  
  262.     APTR    _SearchStrPtr        ; Pointer to search address (from where to continue)
  263.     ULONG    _SearchStrLen        ; Length of search string
  264.     ULONG    _CharBuffer        ; Read char of IO-request to build complete search string
  265.     STRUCT    _IOReqString,256    ; Buffer which contains search string
  266.  
  267.     STRUCT    _IOInlineBuf,64        ; Buffer for converting IO-status report to ascii
  268.  
  269.  
  270.     APTR    arg_1            ; Shell arguments....
  271.     APTR    arg_2
  272.     APTR    arg_3
  273.  
  274.     STRUCT    WB_arg_1,60        ; WBench arguments (tooltypes) (max.: 14!!!)
  275.  
  276.     BPTR    lock_1            ; Overgiven files (Workbench, -the trick
  277.     APTR    file_1            ;  with the shift...)
  278. *    BPTR    lock_2
  279. *    APTR    file_2
  280. *    BPTR    lock_3
  281. *    APTR    file_3
  282.  
  283.  
  284.     STRUCT    _Drive,256        ; Buffer for volume's/directory's name
  285.     STRUCT    _File,108        ; The filename itself
  286.     STRUCT    _FileName,364        ; Merged name in dos-convention
  287.  
  288.     STRUCT    _UserFontBuf,108    ; Into this buffer the name of the font
  289. *                      the user want to use is copied from the
  290. *                      tooltypes - so that we can modify it
  291.  
  292.     STRUCT    _ConBuffer,256        ; Buffer for console commands
  293.  
  294.     APTR    _SourceFileSize        ; Same as FileSize (used by picture)
  295.     APTR    _SourceFilePtr        ; Same as TextPtr + 2 (used by picture)
  296.  
  297.     APTR    _RGB24Ptr
  298.     ULONG    _RGB24Size
  299.  
  300.     APTR    _Bitplane        ; Address decompressed ILBM file (chip mem)
  301.     ULONG    _AllPlaneSize        ; Size of all planes (connected bitplanes)
  302.  
  303.     STRUCT    _BitmapStruc,bm_SIZEOF+(4*16)    ; Screen's or image's bitmap (for safety, 24 bit depth)
  304.  
  305.     ULONG    _CMapNumEntries        ; Colourmap entries (max. 256)
  306.  
  307.     APTR    _RGB32Values        ; Pointer to 32Bit colours of ILBM-file
  308.     STRUCT    _RGB32Colours,((256*3)+2)*4    ; Room for 256 32Bit colours (see LoadRGB32())
  309.  
  310.     UWORD    _RMB            ; State of right mouse button
  311.     UWORD    _Max            ; Local used (haven't got enough unused registers)
  312.  
  313.     UWORD    _MouseID        ; Saved mouse event
  314.  
  315.     UWORD    _PageSize        ; Number of lines of one page
  316.     UWORD    _XOffset        ; X and Y offset for console window,
  317.     UWORD    _YOffset        ; specified in ToolType
  318.  
  319.  
  320.     UBYTE    _NoLineFlag        ; Flag, if it is non-zero, the lines are
  321. *                      not counted, e.g. when restoring window
  322. *                      contents
  323.     UBYTE    _NoWarnFlag        ; When this flag is set, displaying
  324. *                      warnings is supressed
  325.     UBYTE    _NoCheckPrtFlag        ; When this is set, the printer is not checked
  326.     UBYTE    _WrapFlag        ; When this is set, make a word wrap when
  327. *                      the contents of one line do not fit in window
  328.     UBYTE    _PageSizeFlag        ; When this flag is set, the user has got defined the
  329. *                      scrollwidth
  330.     UBYTE    _ReqFlag        ; Indicates which requester is used,
  331. *                      0 == no requester opened till now
  332. *                      1 == ReqTools
  333. *                      2 == Arp
  334. *                     -1 == bad luck, ReqTools nor Arp could be opened
  335.     UBYTE    _LoadFlag        ; Indicates loading or saving, 0 == saving
  336.  
  337.     UBYTE    _BlitFlag        ; Local used, means blit image to screen
  338.     UBYTE    _SuperBitMap        ; Local used, means screen uses a superbitmap
  339.     UBYTE    _RIChanged        ; Local used, RasInfo is changed, so call
  340. *                      MakeScreen() and RetinkDisplay()
  341.  
  342.     ALIGNLONG
  343.  
  344.     APTR    _AudioBuffer        ; Address audio datas in Chip-Mem
  345.     ULONG    _AudioBufferSize    ; How tall is that buffer?
  346.     ULONG    _AudioPeriod        ; How many samples per second?
  347.     APTR    _VHDRPtr
  348.     APTR    _BODYPtr
  349.     ULONG    _BODYSize
  350.     APTR    _IOAudio
  351.     UBYTE    _AudGadget
  352.  
  353.     LABEL    _TableSize        ; Pweeh, size of the defined constants and
  354. *                      arrays, is automatically allocated when
  355. *                      this program is started (done by startup-code)
  356.  
  357.  
  358. *
  359. ** Include the startup-code
  360. *
  361.     include    RAD:include/startup.easy    ; Simple but effective startup-code
  362. *                          - perhaps you should change directory...
  363.  
  364. *
  365. ** RAW-key equates....
  366. *
  367. CRSR_UP        equ    $4C            ; Page Up
  368. CRSR_DN        equ    $4D            ; Page down
  369. CRSR_BK        equ    $4E            ; one line back
  370. CRSR_FD        equ    $4F            ; one line further
  371. L_Key        equ    $28            ; load new
  372. E_Key        equ    $12            ; enlarge window
  373. H_Key        equ    $25            ; help page
  374. I_Key        equ    $17            ; info
  375. A_Key        equ    $20            ; about page
  376. T_Key        equ    $14            ; top of file
  377. B_Key        equ    $35            ; bottom of file
  378. W_Key        equ    $11            ; window contents to prt
  379. P_Key        equ    $19            ; print file to prt
  380. F_Key        equ    $23            ; print file to file
  381. C_Key        equ    $33            ; window contents to file 
  382. PG_UP        equ    $3F            ; page up
  383. PG_DN        equ    $1F            ; page down
  384. RETURN        equ    $44            ; one line down
  385. ENTER        equ    $43            ; one line down
  386. HOME        equ    $3D            ; top of file
  387. END        equ    $1D            ; button of file
  388. R_SHIFT        equ    $61            ; one line back (step)
  389. R_Key        equ    $13            ; refresh Window
  390. S_Key        equ    $21            ; Search (find)
  391. N_Key        equ    $36            ; Next search (find)
  392. PrtSc        equ    $5D            ; print screen to prt
  393. HELP_Key    equ    $5F            ; Display title
  394.  
  395.  
  396. * - ReqTools
  397.     IFND    _LVOrtAllocRequestA
  398. _LVOrtAllocRequestA    EQU    -30
  399.     ENDC
  400.  
  401.     IFND    _LVOrtFreeRequestA
  402. _LVOrtFreeRequestA    EQU    -36
  403.     ENDC
  404.  
  405.     IFND    _LVOrtChangeReqAttrA
  406. _LVOrtChangeReqAttrA    EQU    -48
  407.     ENDC
  408.  
  409.     IFND    _LVOrtFileRequestA
  410. _LVOrtFileRequestA    EQU    -54
  411.     ENDC
  412.  
  413. * - Arp
  414.     IFND    _LVOArpFileRequest
  415. _LVOArpFileRequest    EQU    -294
  416.     ENDC
  417.  
  418. * - DiskFont
  419.     IFND    _LVOOpenDiskFont
  420. _LVOOpenDiskFont    EQU    -30
  421.     ENDC
  422.  
  423. * - CyberGraphics
  424.     IFND    _LVOWritePixelArray
  425. _LVOWritePixelArray    EQU    -126
  426.     ENDC
  427.  
  428.     IFND    RECTFMT_RGB
  429. RECTFMT_RGB    EQU    0
  430.     ENDC
  431.  
  432. *************************************************************
  433. *
  434. * This subroutine parses the Shell arguments.
  435. * Inputs: none (routine uses global constants).
  436. * Result: ErrorCode placed in "_argError", see "EQU's" below.
  437. *
  438. * Remarks: Only three arguments are parsed (if available).
  439. *
  440.  
  441. ed_QuoteNotAllowed    EQU    1    ; Possible errorcodes
  442. ed_MissingEndQuote    EQU    10    ; stored in "_argError"
  443.  
  444. _getArg
  445.     movea.l    _argv(A5),A0
  446.     lea    arg_1(A5),A1
  447.     moveq    #0,D2
  448.     bra.s    _getArg1.1
  449. _getArg.1
  450.     addq.b    #4,D2
  451.     cmpi.b    #12,D2            ; 3 args * à 4 bytes = 12
  452.     beq.s    _argEnd
  453.     cmpi.b    #' ',(A0)
  454.     beq.s    _skipUnused
  455. _getArg1.1
  456.     cmpi.b    #10,(A0)
  457.     beq.s    _argEnd
  458. _getArg.2
  459.     cmpi.b    #'"',(A0)
  460.     beq.s    _inQuotes
  461. _noQuotes
  462.     move.l    A0,(A1,D2.w)
  463. _stdLoop
  464.     cmpi.b    #'"',(A0)
  465.     beq.s    _argError.1
  466.     cmpi.b    #10,(A0)
  467.     beq.s    _noMoreArg
  468.     cmpi.b    #' ',(A0)
  469.     beq.s    _nextArgument
  470.     addq.l    #1,A0
  471.     bra.s    _stdLoop
  472. _nextArgument
  473.     clr.b    (A0)+
  474.     bra.s    _getArg.1
  475. _inQuotes
  476.     addq.l    #1,A0
  477.     move.l    A0,(A1,D2.w)
  478. _quoteLoop
  479.     cmpi.b    #10,(A0)
  480.     beq.s    _argError.2
  481.     cmpi.b    #'"',(A0)
  482.     beq.s    _nextArgument
  483.     addq.l    #1,A0
  484.     bra.s    _quoteLoop
  485. _noMoreArg
  486.     clr.b    (A0)
  487. 1$
  488.     addq.b    #4,D2
  489.     cmpi.b    #12,D2            ; max: 3 arguments
  490.     beq.s    _argEnd
  491.     clr.l    (A1,D2.w)
  492.     bra.s    1$
  493. _argEnd
  494.     rts                ; back
  495. _skipUnused
  496.     addq.l    #1,A0
  497.     cmpi.b    #' ',(A0)
  498.     beq.s    _skipUnused
  499.     bra.s    _getArg1.1
  500. _argError.1
  501.     moveq    #ed_QuoteNotAllowed,D0
  502.     bsr.s    _setArgError
  503.     subq.b    #4,D2
  504.     bra.s    _noMoreArg
  505. _argError.2
  506.     moveq    #ed_MissingEndQuote,D0
  507.     bsr.s    _setArgError
  508.     subq.b    #4,D2
  509.     bra.s    _noMoreArg
  510. _setArgError
  511.     move.l    D0,_argError(A5)
  512.     rts
  513.  
  514. ******************************************************************************
  515. *
  516. * Routine to parse from Workbench overgiven files.
  517. * Inpts: D0 - how many arguments (files) allowed to store
  518. *        D1 - how many arguments are there?,
  519. *     A0 - pointer to sm_ArgList (global - startup-code -> WBench-message),
  520. *     A1 - address array for lock of file and filename, -
  521. *          - array must look like this:
  522. *        BPTR Lock
  523. *        APTR File (string pointer)
  524. *        BPTR Lock
  525. *        APTR File (string pointer)
  526. *        ... and so on
  527. * Results: none
  528. *
  529.  
  530. _GetWBFiles
  531.     subq.l    #1,D1
  532.     beq.s    3$
  533.     bcs.s    3$
  534.     addq.l    #4,A0
  535.     bra.s    2$
  536. 1$
  537.     addq.l    #4,A0
  538.     move.l    (A0),(A1)+        ; Lock
  539.     addq.l    #4,A0
  540.     move.l    (A0),(A1)+        ; Filename
  541.     subq.l    #1,D1            ; argc -1
  542.     beq.s    3$
  543. 2$
  544.     dbf    D0,1$
  545. 3$
  546.     rts
  547.  
  548. ****************************************************
  549. *
  550. * Subroutine to set the returncode for this program,
  551. * use Shell-command why to investigate the error.
  552. *
  553. * Inputs: D0 - errorcode
  554. * Results: none
  555. *
  556.  
  557. _SetError
  558.     move.l    D0,_errno(A5)
  559. _setError4Task
  560.     movea.l    _SysBase(A5),A0
  561.     movea.l    276(A0),A0        ; ThisTask
  562.     move.l    D0,pr_Result2(A0)
  563.     rts
  564.  
  565. ******************************************
  566. *
  567. * Entry point, called out of startup-code.
  568. *
  569.  
  570. _main    ; Startup-Code enters here...
  571.     bsr.w    _InitStandard        ; Init windows
  572.  
  573.     tst.l    _WBenchMsg(A5)
  574.     bne.s    .GetWBArgs        ; If we are started from workbench
  575.     bsr.w    _getArg            ; otherwise parse Shell arguments
  576.     bra.s    .argsOk
  577. .GetWBArgs
  578.     tst.l    _argc(A5)        ; Any file given (from WB)?
  579.     beq.s    0$
  580.  
  581.     moveq    #1,D0            ; Max. allowed number of arguments!
  582.     move.l    _argc(A5),D1        ; Number of arguments stored (WB)
  583.     movea.l    _argv(A5),A0        ; sm_ArgList pointer
  584.     lea    lock_1(A5),A1        ; Address buffer
  585.     bsr.s    _GetWBFiles        ; Call subroutine to parse files
  586.  
  587. 0$
  588.     moveq    #13,D0            ; 14 Entries
  589.     tst.l    _ToolTypesArray(A5)
  590.     beq.s    .argsOk
  591.  
  592.     movea.l    _ToolTypesArray(A5),A0    ; Pointer to ToolTypeArray
  593.     lea    WB_arg_1(A5),A1        ; Address first WB-Text
  594. 1$
  595.     tst.l    (A0)
  596.     beq.s    .argsOk            ; If no more texts are set...
  597.     move.l    (A0)+,(A1)+        ; WB-Arg-Text -> Arg[1..] a.s.o.
  598.     dbf    D0,1$
  599.  
  600. .argsOk        
  601.     move.l    #20,_errno(A5)
  602.     bsr.w    _SetPrefs        ; See there
  603.     bsr.w    _OpenROMLibs        ; Open libraries
  604.     tst.l    _WBenchMsg(A5)        ; WB-start?
  605.     beq.s    4$            ; No? - then it was a Shell-start
  606.     bsr.w    _SetDirection        ; Get user datas
  607.     bsr.w    _CheckWarning
  608.     bsr.w    _CheckExecute        ; Execute (if a specification) a command
  609. 4$
  610.     bsr.w    _SetWindow        ; Set window limits
  611.     bsr.w    _CheckWrap        ; Check Word-Wrap (ToolTypes)
  612.     move.l    #100,_errno(A5)
  613.     bsr.w    _OpenWindow
  614.     tst.l    D0
  615.     beq.w    _Out_02            ; Don't bomb
  616.  
  617. **********************************************
  618. *
  619. * Open console device for reading and writing.
  620. *
  621.  
  622.     move.l    #80,_errno(A5)
  623.     movea.l    _SysBase(A5),A6        ; Make ReadReplyPort
  624.     lea    _ReadReply(A5),A0
  625.     move.l    _OwnTask(A5),MP_SIGTASK(A0)    ; Task to be signalled
  626.     lea    MP_MSGLIST(A0),A0        ; Console-read reply port
  627.     NEWLIST    A0
  628.  
  629.     lea    _WriteReply(A5),A0    ; Make WriteReplyPort
  630.     lea    MP_MSGLIST(A0),A0    ; Console-read reply port
  631.     NEWLIST    A0
  632.  
  633.     lea     _ReadIo(A5),A1
  634.     move.l    _WindowPtr(A5),IO_DATA(A1)
  635.     move.l    #wd_SIZEOF,IO_LENGTH(A1)
  636.     moveq    #0,D0            ; Unit
  637.     moveq    #0,D1            ; Flags
  638.     lea    _DeviceName(pc),A0
  639.     jsr    _LVOOpenDevice(A6)    ; Open console device
  640.     tst.l    D0
  641.     beq.s    .ConsoleIsOpen
  642.     lea    _ErrorOpenDevTxt(pc),A0    ; else...
  643.     bsr.w    _DisplayError
  644.     bra.w    _Out_01
  645.  
  646. .ConsoleIsOpen
  647.     lea    _ReadIo(A5),A0        ; ReadIo<->WriteIo 
  648.     lea    _WriteIo(A5),A1
  649.     move.l    IO_DEVICE(A0),IO_DEVICE(A1)    ; Device
  650.     move.l    IO_UNIT(A0),IO_UNIT(A1)        ; Unit
  651.  
  652.     lea    _ReadReply(A5),A2
  653.     move.l    A2,MN_REPLYPORT(A0)
  654.  
  655.     lea    _WriteReply(A5),A2
  656.     move.l    A2,MN_REPLYPORT(A1)
  657.  
  658.     clr.l    _errno(A5)
  659.  
  660. ***********************
  661. *
  662. * Some useful stuff....
  663. *
  664.  
  665.     bsr.w    _CursorOff        ; Cursor invisible
  666.     bsr.w    _SetPtr4Req        ; Twist pointer for system-requesters
  667.     bsr.w    _SetScrollWidth        ; Seek and set scrollwidth
  668.     bsr.w    _SetPageWidthAndLen    ; Seek and set page sizes
  669.  
  670.     lea    _ConBuffer(A5),A0    ; Address buffer
  671.     move.w    #$9B48,(A0)        ; Cursor Home
  672.     moveq    #2,D0            ; 2 chars for output
  673.     bsr.w    _ConOut_Rel        ; Write down to console...
  674.  
  675.     tst.l    arg_1(A5)        ; Any file placed?
  676.     bne.w    _CLILoad        ; Yes..
  677.     tst.l    file_1(A5)        ; Or is there a file?
  678.     bne.w    _WBLoad            ; Yes...
  679. *                      Otherwise....
  680. _InitRequester
  681.     bsr.w    OpenReq            ; Open for requests needed libraries
  682.     tst.b    _ReqFlag(A5)        ; ReqTools or Arp opened?
  683.     bmi.w    _End_1            ; No, bad luck
  684. _NextTry
  685.     st.b    _LoadFlag(A5)        ; We want to load...
  686.     bsr.w    _GetFile        ; Build request and get file
  687.     cmpi.l    #-1,D0            ; Hard error?
  688.     beq.w    _End_1            ; Ok, finish immediately
  689.     tst.l    D0            ; No file?
  690.     beq.s    _NoFileChosen        ; Too bad
  691.     
  692.     bsr.w    _ReadFile        ; Read that file
  693.     tst.l    D0            ; Any error?
  694.     beq.s    _Loop            ; Yes...
  695.  
  696. *
  697. ** Now we check the file. If it returns to this point all went ok.
  698. ** We check for ascii files, binary files, PP20 files, ILBM files.
  699. *
  700.     bsr.w    _CheckFile
  701.  
  702.     bsr.w    _IgnoreSettings        ; ANSI-Filter
  703.  
  704.     bsr.w    _SetViewerPrefs        ; Preferences
  705.  
  706.     bra.w    _FirstPage        ; Display first page
  707.  
  708. _NoFileChosen
  709.     lea    _NoFileMsg(pc),A0
  710.     bsr.w    _DisplayError
  711.     tst.l    D0            ; User said: "Cancle" loading
  712.     beq.w    _End            ; If so, terminate...
  713.  
  714. ***********************************************
  715. *
  716. * Main routine, is waiting until an event occurs.
  717. *
  718.  
  719. _Loop
  720.     clr.b    _NoLineFlag(A5)        ; Allow line counting
  721.     bsr.w    _ComLine        ; Make window-title
  722.  
  723. .noComLine
  724.     bsr.w    _SetActionWait        ; Allow intuition to send us RAW-key messages
  725.  
  726.     tst.l    _TextPtr(A5)        ; Any text to display?
  727.     beq.s    .NoNextTxt        ; If not
  728.  
  729.     tst.b    _AudGadget(A5)
  730.     bne.s    .NoNextTxt
  731.  
  732.     tst.w    _MouseID(A5)        ; This inidicates if a mousebutton
  733. *                      was already touched, if it was touched,
  734.     bne.w    .MouseWasTouched    ; we have to jump to an other routine...
  735.  
  736. .NoNextTxt
  737.     move.l    A2,-(sp)
  738.     movea.l    _WindowPtr(A5),A2
  739.     movea.l    wd_UserPort(A2),A2
  740.     movea.l    A2,A0
  741.     movea.l    _SysBase(A5),A6
  742.     jsr    _LVOWaitPort(A6)    ; Wait until a message has reached us
  743.  
  744.     movea.l    A2,A0
  745.     jsr    _LVOGetMsg(A6)
  746.     movea.l    D0,A1
  747.     movea.l    D0,A2
  748.     jsr    _LVOReplyMsg(A6)
  749.  
  750.     move.l    20(A2),D0        ; im_Class
  751.     move.w    24(A2),D1        ; im_Code
  752.     move.l    28(A2),_IAddr(A5)
  753.     movea.l    (sp)+,A2
  754. *
  755. ** Some notes at this point: normally you should remember the received things i.e.
  756. ** im_Class, im_Code, im_IAddress and so on into private constants and _THEN_
  757. ** reply the message to avoid conflicts with intuition. Because intuition does
  758. ** only send us (at most) each 1/10 second a message - and this is assembler -
  759. ** _AND_ we awoke yet (running task) it's not too critical to save the message
  760. ** things not - _BUT_ - if intuition is rewritten for (may be) Kickstart 41/42
  761. ** and it's then a lot faster, the replying without saving will cause BIG trouble.
  762. *
  763.     cmpi.l    #$8,D0            ; MouseButtons?
  764.     beq.s    4$            ; Startup for mouse-buttons!!!!
  765.  
  766.     cmpi.l    #$40,D0
  767.     beq.s    3$
  768.  
  769.     bsr.w    _SetNILWait        ; Tell intuition we don't want to have message
  770. *                      for now, do it via a PA_IGNORE flag which
  771. *                      blocks messages for our window
  772.  
  773.     clr.w    _MouseID(A5)        ; Erase ID
  774.  
  775.     movem.l    D0-D1,-(sp)
  776. 1$
  777.     movea.l    _WindowPtr(A5),A0
  778.     movea.l    wd_UserPort(A0),A0
  779.     jsr    _LVOGetMsg(A6)        ; Ignore following messages until
  780.     tst.l    D0            ; flag is active...
  781.     beq.s    2$
  782.  
  783.     movea.l    D0,A1
  784.     jsr    _LVOReplyMsg(A6)    ; Free message
  785.     bra.s    1$
  786. 2$
  787.     movem.l    (sp)+,D0-D1
  788.  
  789.     cmpi.l    #$200,D0        ; CLOSEWINDOW ?
  790.     beq.w    _End            ; If so...
  791.  
  792.     cmpi.l    #$400,D0        ; RAWKEY?
  793.     beq.w    _RawKey            ; If so...
  794.  
  795. 3$
  796.     cmpi.l    #$40,D0            ; Gadget up ?
  797.     bne.w    _Loop
  798.     movea.l    _IAddr(A5),A0
  799.     cmpi.w    #3,gg_GadgetID(A0)    ; Gadget id = 3?
  800.     bne.w    _Loop
  801.     bra.w    _AudioHit
  802.  
  803. *
  804. ** If the first time a mousebutton was clicked, we are at this point.
  805. *
  806. 4$
  807.     tst.b    _AudGadget(A5)
  808.     bne.w    _Loop
  809.  
  810.     move.w    D1,_MouseID(A5)
  811.  
  812.     cmpi.w    #$69,D1            ; Right one?
  813.     bne.s    .LeftOne
  814.     move.w    D1,_MouseID(A5)
  815. .RO1
  816.     move.w    #CRSR_FD,D1
  817.     bra.s    _RawKey
  818.  
  819. .LeftOne
  820.     cmpi.w    #$68,D1            ; Left one?
  821.     bne.s    .NotValid        ; Not a valid message...
  822.     move.w    D1,_MouseID(A5)
  823. .LO1
  824.     move.w    #CRSR_BK,D1
  825.     bra.s    _RawKey
  826. .NotValid
  827.     clr.w    _MouseID(A5)
  828.     bra.w    _Loop
  829.  
  830. *
  831. ** A mouse-button was clicked a while ago, we have now to check if the mousebutton
  832. ** was released.
  833. *
  834. .MouseWasTouched
  835.     move.l    A2,-(sp)
  836.     movea.l    _WindowPtr(A5),A0
  837.     movea.l    wd_UserPort(A0),A0
  838.     movea.l    _SysBase(A5),A6
  839.     jsr    _LVOGetMsg(A6)        ; Do we have a message?
  840.     tst.l    D0
  841.     beq.s    .further        ; No, just do it like a mousebutton was clicked
  842.     movea.l    D0,A1
  843.     movea.l    D0,A2
  844.     jsr    _LVOReplyMsg(A6)
  845.     cmpi.l    #$8,im_Class(A2)    ; MouseButtons?        | SEE NOTES ABOUT
  846.     bne.s    .further        ; see above        | MESSAGES A PIECE
  847.     cmpi.w    #$68+$80,im_Code(A2)    ; Left one released?    | FURTHER ABOVE....
  848.     beq.s    .EndMouse
  849.     cmpi.w    #$69+$80,im_Code(A2)    ; or right one released?
  850.     bne.s    .further
  851. .EndMouse
  852.     movea.l    (sp)+,A2
  853.     clr.w    _MouseID(A5)        ; Clear ID (code), indicates that no mouse-
  854.     bra.w    _Loop            ; button is held down
  855.  
  856. .further
  857.     movea.l    (sp)+,A2
  858.     cmpi.w    #$68,_MouseID(A5)    ; Left mousebutton?
  859.     beq.s    .LO1
  860.     bra.s    .RO1            ; else it was the right one!
  861. *
  862. ** Startup for console action
  863. *
  864. _RawKey
  865.     lea    _ConBuffer(A5),A0    ; Buffer
  866.     move.w    D1,(A0)            ; Store there the raw-key
  867.     bra.w    _ConsoleEvent        ; just go ahead
  868.  
  869.  
  870. **********************
  871. *
  872. * Our end has come....
  873. *
  874.  
  875. _End_1
  876.     lea    _NoReqTxt(pc),A0    ; Fail with message (couldn't open file-
  877.     bsr.w    _DisplayError        ; requester)
  878. _End
  879.     movea.l    4.w,A6
  880.     suba.l    A1,A1
  881.     jsr    _LVOFindTask(A6)
  882.     movea.l    D0,A0
  883.     movea.l    pr_ReturnAddr(A0),A0    ; Program's exit address
  884.     subq.l    #8,A0
  885.     movea.l    (A0),A5            ; Restore basetable pointer
  886.  
  887.     movea.l    _OwnTask(A5),A0        ; Restore pointer for system-requesters
  888.     move.l    _StdprWindowPtr(A5),184(A0)
  889.  
  890.     tst.l    _UserProject(A5)    ; .info-file there?
  891.     beq.s    0$
  892.     movea.l    _IconBase(A5),A6
  893.     movea.l    _UserProject(A5),A0
  894.     jsr    _LVOFreeDiskObject(A6)    ; Free the info-file resources
  895. 0$
  896.     movea.l    _SysBase(A5),A6
  897.     lea    _ReqToolsBase(A5),A2    ; ReqTools-library open?
  898.     tst.l    (A2)
  899.     beq.s    1$            ; No
  900.     movea.l    A6,A4            ; Save Exec
  901.     movea.l    (A2),A6            ; ReqTools-Base
  902.     movea.l    _ReqPtr(A5),A1        ; File-requester-record
  903.     jsr    _LVOrtFreeRequestA(A6)    ; Free it
  904.     movea.l    A6,A1            ; ReqTools-Base A1
  905.     movea.l    A4,A6            ; Exec
  906.     jsr    _LVOCloseLibrary(A6)
  907. 1$
  908.     tst.l    _ArpBase(A5)        ; Arp-Library open?
  909.     beq.s    2$            ; No
  910.     movea.l    _ArpBase(A5),A1
  911.     jsr    _LVOCloseLibrary(A6)
  912. 2$
  913.     tst.l    _CyberGfxBase(A5)
  914.     beq.s    3$
  915.     movea.l    _CyberGfxBase(A5),A1
  916.     jsr    _LVOCloseLibrary(A6)
  917. 3$
  918.     move.l    _BufferSize(A5),D0    ; Something allocated?
  919.     beq.s    4$            ; No
  920.     movea.l    _TextPtr(A5),A1        ; Else
  921.     jsr    _LVOFreeMem(A6)        ; free it
  922. 4$
  923.     bsr.w    _FreeAudio
  924.  
  925.     movea.l    _SysBase(A5),A6
  926.     lea    _ReadIo(A5),A1
  927.     jsr    _LVOCloseDevice(A6)    ; Close console-device
  928. _Out_01
  929.     bsr.w    _CloseWindow        ; Close main-window
  930. _Out_02
  931.     bsr.w    _CloseROMLibs        ; Close 'em
  932.  
  933.     rts                ; Back into startup-code
  934.  
  935. ********************************************
  936. *
  937. * One routine with a few entries to call....
  938. *
  939. * It will write down to the console-window
  940. * the overgiven text.
  941. *
  942.  
  943. _ConOut        ; Write down 1 char, the char is in the "_ConBuffer"
  944.     movea.l    _SysBase(A5),A6
  945.     lea    _WriteIo(A5),A1        ; Io-structure for writing
  946.     move.l    #1,IO_LENGTH(A1)    ; 1 char for output
  947.  
  948. _ContConOut    ; Write down x-chars, the chars are in the "_ConBuffer"
  949.     move.w    #CMD_WRITE,IO_COMMAND(A1)    ; Command = Write
  950.     lea    _ConBuffer(A5),A0    ; Address char
  951.  
  952. _ContConOut_01    ; Check first for tab-width (take 1 tab as 8 blanks)
  953.     bsr.s    _CheckTAB
  954. _ContConOut_02    ; Just do it (writing)
  955.     move.l    A0,IO_DATA(A1)        ; Address string
  956.     movea.l    _SysBase(A5),A6
  957.     jsr    _LVODoIO(A6)        ; Do it, but wait until done
  958.     lea    _ConBuffer(A5),A0
  959.     rts
  960.  
  961. _ConOut_Rel    ; Relative length, rigid address (number of chars in D0)
  962.     lea    _WriteIo(A5),A1
  963.     move.l    D0,IO_LENGTH(A1)
  964.     bra.s    _ContConOut
  965.  
  966. _ConOut_Reloc    ; Relative length, relative address (number of chars in D0,
  967. *                             address string in A0)
  968.     movea.l    _SysBase(A5),A6
  969.     lea    _WriteIo(A5),A1
  970.     move.l    D0,IO_LENGTH(A1)
  971.     move.w    #CMD_WRITE,IO_COMMAND(A1)    ; Command = Write
  972.     bra.s    _ContConOut_01
  973.  
  974. *****************************************************
  975. *
  976. * Compute length for one line, take 1 tab as 8 blanks.
  977. *
  978.  
  979. _CheckTAB
  980.     tst.b    _WrapFlag(A5)        ; Word Warp allowed?
  981.     bne.w    .CT_End            ; If so...
  982.  
  983.     tst.l    _PageWidth(A5)
  984.     beq.w    .CT_End
  985.  
  986.     movem.l    D0-D3/A0-A2,-(sp)
  987.     move.l    _PageWidth(A5),D3    ; Number of Displayable columns
  988.     addq.w    #1,D3
  989.     move.l    D0,D2            ; Number of chars to print down
  990.     movea.l    A0,A2            ; Address string
  991. .CT_Next
  992.     movea.l    A2,A0            ; Current string
  993.     moveq    #0,D0            ; Number of Chars
  994.     moveq    #0,D1            ; Number of columns
  995. .CT_Search
  996.     addq.w    #1,D0            ; Number of chars plus 1
  997.     addq.w    #1,D1            ; Number of columns plus 1
  998.     cmp.l    D1,D3            ; Compare width maximum of possible
  999. *                      displayable columns
  1000.     bls.s    .CT_Store
  1001.  
  1002.     cmpi.b    #10,(A2)        ; LineFeed
  1003.     beq.s    .CT_Store
  1004.     cmpi.b    #9,(A2)            ; TAB
  1005.     beq.s    .CT_AddTAB
  1006.     cmpi.b    #27,(A2)        ; ESC
  1007.     beq.s    .CT_IgnoreESC
  1008.  
  1009.     addq.l    #1,A2
  1010.     subq.w    #1,D2            ; Number of chars minus 1
  1011.     beq.s    .CT_Store
  1012.     bra.s    .CT_Search
  1013.  
  1014. .CT_Store
  1015.     lea    _WriteIo(A5),A1        ; Io-structure for writing
  1016.     move.w    #CMD_WRITE,IO_COMMAND(A1)    ; Command = Write
  1017.     move.l    D0,IO_LENGTH(A1)    ; Chars for output
  1018.     move.l    A0,IO_DATA(A1)        ; Address string
  1019.     movea.l    _SysBase(A5),A6
  1020.     jsr    _LVODoIO(A6)        ; Do it, but wait until done
  1021.  
  1022.     tst.w    D2
  1023.     beq.s    .CT_End_1
  1024.  
  1025.     moveq    #-1,D0
  1026. 1$
  1027.     subq.w    #1,D2
  1028.     beq.s    .CT_End_1
  1029.     cmpi.b    #10,(A2)+        ; LineFeed
  1030.     dbeq    D0,1$
  1031.  
  1032.     bra.s    .CT_Next
  1033.  
  1034. .CT_AddTAB
  1035.     addq.w    #7,D1
  1036.     andi.w    #-8,D1
  1037.     addq.l    #1,A2
  1038.     subq.w    #1,D2
  1039.     beq.s    .CT_Store
  1040.     bra.s    .CT_Search
  1041.  
  1042. .CT_IgnoreESC
  1043.     subq.w    #1,D1
  1044.     addq.l    #4,A2            ; Ignore 4 chars (currently no real length
  1045.     addq.w    #3,D0            ; checking (Sequencer) is done...)
  1046.     subq.w    #4,D2
  1047.     beq.s    .CT_Store
  1048.     bcs.s    2$
  1049.     bra.s    .CT_Search
  1050. 2$
  1051.     subq.l    #1,A2
  1052.     subq.w    #1,D0
  1053.     addq.w    #1,D2
  1054.     bcs.s    2$
  1055.     bra.s    .CT_Store
  1056.  
  1057. .CT_End_1
  1058.     movem.l    (sp)+,D0-D3/A0-A2
  1059. .CT_End
  1060.     rts
  1061.  
  1062. ***********************************************
  1063. *
  1064. * Read from console-window - but don't wait for
  1065. * the result.
  1066. *
  1067. * Inputs: D0 - number of chars to read
  1068. * Results: Chars in gloabal "_ConBuffer"
  1069. *
  1070.  
  1071. _QueueRead
  1072.     lea    _ReadIo(A5),A1
  1073.     move.l    D0,IO_LENGTH(A1)    ; Number of chars to read
  1074.     move.l    A0,IO_DATA(A1)
  1075.     move.w    #CMD_READ,IO_COMMAND(A1) ; Command READ
  1076.     movea.l    _SysBase(A5),A6
  1077.     jmp    _LVOSendIO(A6)        ; Send command
  1078.  
  1079. _GetConMsg
  1080.     moveq    #20,D0
  1081.     lea    _ConBuffer(A5),A0
  1082.     bsr.s    _QueueRead        ; Get the message
  1083.     movea.l    _SysBase(A5),A6
  1084.     lea    _ReadReply(A5),A0
  1085.     jmp    _LVOGetMsg(A6)
  1086.  
  1087.  
  1088. ************************************************************
  1089. *
  1090. * Open graphic and intuition libraries,
  1091. * required version is 33 (ks 1.2).
  1092. *
  1093. * Inputs: None
  1094. * Result: GfxBase and IntuitionBase
  1095. *      (NULL not possible!!! - noone works with a ks. lower 33!!!)
  1096. * At the moment I know only one person who got a ks. lower than 33, 32,
  1097. * OS1.1 PAL - Amiga 1000, the machine with the WOM; no, he doesn't sells it...
  1098. *
  1099.  
  1100. _OpenROMLibs
  1101.     movea.l    _SysBase(A5),A6
  1102.     lea    _IntuitionName(pc),A1
  1103.     moveq    #33,D0
  1104.     jsr    _LVOOpenLibrary(A6)
  1105.     move.l    D0,_IntuitionBase(A5)
  1106.     moveq    #33,D0
  1107.     lea    _GfxName(pc),A1
  1108.     jsr    _LVOOpenLibrary(A6)
  1109.     move.l    D0,_GfxBase(A5)
  1110.     rts
  1111.  
  1112. ****************************************
  1113. *
  1114. * Close graphic and intuition libraries.
  1115. *
  1116. * Inputs: None
  1117. * Results: None
  1118. *
  1119.  
  1120. _CloseROMLibs
  1121.     movea.l    _SysBase(A5),A6
  1122.     movea.l    _IntuitionBase(A5),A1
  1123.     jsr    _LVOCloseLibrary(A6)
  1124.     movea.l    _GfxBase(A5),A1
  1125.     jmp    _LVOCloseLibrary(A6)
  1126.  
  1127.  
  1128. *******************************************
  1129. *
  1130. * Open main window which is used as console
  1131. * window.
  1132. *
  1133. * We take from the tooltypes (if wb-start)
  1134. * the specified X- and Y-offset for our
  1135. * window and of course the font the user
  1136. * specified (in tooltypes) for this window.
  1137. *
  1138. * Inputs: None
  1139. * Results: _UserFontPtr (may be NULL)
  1140. *       _WindowPtr (may be NULL)
  1141. *
  1142.  
  1143. _OpenWindow
  1144.     lea    WB_arg_1(A5),A0
  1145. .NextTType
  1146.     tst.l    (A0)            ; Argument there?
  1147.     beq.s    _NoOffsetDeclared    ; No
  1148.     movea.l    (A0)+,A1        ; Address overgiven string
  1149.     lea    _OffsetSpecName(pc),A2    ; Address string to compare
  1150.     moveq    #12,D0            ; 13 chars to compare
  1151. .CheckTType
  1152.     cmpm.b    (A1)+,(A2)+        ; Compare strings
  1153.     bne.s    .NextTType        ; "WINDOWOFFSET="
  1154.     dbf    D0,.CheckTType
  1155.     movea.l    A1,A0            ; Pointer to following string
  1156.  
  1157.     moveq    #0,D0
  1158.     move.b    (A0),D0
  1159.     lsl.w    #8,D0
  1160.     move.b    1(A0),D0
  1161.     lsl.l    #8,D0
  1162.     move.b    2(A0),D0
  1163.     lsl.l    #8,D0
  1164.     move.b    3(A0),D0
  1165.     cmpi.l    #'AUTO',D0        ; Auto adjustment?
  1166.     bne.s    .Value    
  1167.     tst.b    4(A0)
  1168.     bne.s    .Value
  1169.  
  1170.     movea.l    _IntuitionBase(A5),A1
  1171.     movea.l    ib_ActiveScreen(A1),A1
  1172.     moveq    #0,D0
  1173.     move.b    sc_BarHeight(A1),D0
  1174.     addq.w    #1,D0
  1175.     move.w    D0,_YOffset(A5)
  1176.     bra.s    _NoOffsetDeclared    ; ...altough it is...
  1177. .Value
  1178.     moveq    #0,D0            ; No mask
  1179.     bsr.w    _StrToLong
  1180.     tst.l    D1
  1181.     bmi.s    _NoOffsetDeclared    ; Upon error
  1182. .XOffsetGot
  1183.     move.w    D0,_XOffset(A5)        ; Save X-Offset
  1184.  
  1185.     moveq    #0,D0            ; No mask
  1186.     bsr.w    _StrToLong
  1187.     tst.l    D1
  1188.     bmi.s    _NoOffsetDeclared    ; Upon error
  1189. .YOffsetGot
  1190.     move.w    D0,_YOffset(A5)        ; Save Y-Offset
  1191.  
  1192. *
  1193. ** Look for the font...
  1194. *
  1195. _NoOffsetDeclared
  1196.     lea    WB_arg_1(A5),A0
  1197. .NextTType
  1198.     tst.l    (A0)            ; Argument there?
  1199.     beq.w    _NoFontDeclared        ; No
  1200.     movea.l    (A0)+,A1        ; Address overgiven string
  1201.     lea    _FontSpecName(pc),A2    ; Address string to compare
  1202.     moveq    #4,D0            ; 5 chars to compare
  1203. .CheckTType
  1204.     cmpm.b    (A1)+,(A2)+        ; Compare strings
  1205.     bne.s    .NextTType        ; "FONT="
  1206.     dbf    D0,.CheckTType
  1207.     movea.l    A1,A0            ; Pointer to following string
  1208.  
  1209.     lea    _UserFontBuf(A5),A1    ; Our private buffer
  1210.     tst.b    (A0)            ; End of user's string?
  1211.     beq.w    _NoFontDeclared
  1212. 1$
  1213.     move.b    (A0)+,(A1)+        ; Copy font's name
  1214.     beq.w    _NoFontDeclared        ; If an interrupted end...
  1215.     cmpi.b    #',',(A0)        ; Comma = number follows!
  1216.     bne.s    1$
  1217.  
  1218.     move.b    #'.',(A1)+        ; Add string ".font" to font's name
  1219.     move.b    #'f',(A1)+
  1220.     move.b    #'o',(A1)+
  1221.     move.b    #'n',(A1)+
  1222.     move.b    #'t',(A1)+
  1223.     clr.b    (A1)
  1224.  
  1225.     moveq    #0,D0            ; No mask
  1226.     bsr.w    _StrToLong
  1227.     cmpi.l    #-1,D1
  1228.     beq.s    _NoFontDeclared
  1229.  
  1230. _OpenUserFont
  1231.     lea    _UserFontStruc(A5),A0    ; FontAttr-record
  1232.     move.w    D0,4(A0)        ; Save height of font
  1233.     move.b    #$40|1,7(A0)        ; Designed and ROM-Font (on first try)
  1234.     lea    _UserFontBuf(A5),A1    ; Buffer with font's name
  1235.     move.l    A1,(A0)            ; Set name in FontAttr-record
  1236.     movea.l    _GfxBase(A5),A6
  1237.     jsr    _LVOOpenFont(A6)    ; Try to open the font
  1238.     tst.l    D0            ; Font opened?
  1239.     beq.s    .OpenDiskFont        ; If not...
  1240.     movea.l    D0,A1            ; TextFont
  1241.     lea    _UserFontStruc(A5),A0    ; FontAttr-record
  1242.     move.w    4(A0),D1        ; Get height of font
  1243.     cmp.w    20(A1),D1        ; Height of opened font same as...
  1244.     beq.s    _GotFont        ; Of course...
  1245.  
  1246.     movea.l    _GfxBase(A5),A6        ; Otherwise close
  1247.     jsr    _LVOCloseFont(A6)    ; opened font (got not the right height)
  1248.  
  1249. .OpenDiskFont
  1250.     lea    _DiskFontName(pc),A1    ; "diskfont.library"
  1251.     moveq    #33,D0
  1252.     movea.l    _SysBase(A5),A6
  1253.     jsr    _LVOOpenLibrary(A6)    ; Open the library
  1254.     tst.l    D0
  1255.     beq.s    _NoFontDeclared        ; Damned!
  1256.  
  1257.     movea.l    D0,A6            ; DiskfontBase
  1258.     lea    _UserFontStruc(A5),A0    ; Addr. FontAttr-record
  1259.     move.b    #$40|2,7(A0)        ; Designed and DISK-Font!
  1260.     jsr    _LVOOpenDiskFont(A6)    ; Load the disk-resident-font
  1261.     tst.l    D0            ; Got font?
  1262.     beq.s    1$            ; No...
  1263.     move.l    D0,D2            ; Save font-pointer
  1264.     movea.l    A6,A1            ; DiskFontBase
  1265.     movea.l    _SysBase(A5),A6
  1266.     jsr    _LVOCloseLibrary(A6)    ; Close "diskfont.library"
  1267.     move.l    D2,D0            ; Font-pointer
  1268.     bra.s    _GotFont
  1269. 1$
  1270.     movea.l    A6,A1            ; DiskfontBase
  1271.     movea.l    _SysBase(A5),A6
  1272.     jsr    _LVOCloseLibrary(A6)
  1273.     bra.s    _NoFontDeclared        ; Error exit
  1274. _GotFont
  1275.     move.l    D0,_UserFontPtr(A5)    ; Save font-pointer
  1276.  
  1277. *
  1278. ** Attempt to open the window with (if) overgiven X- and Y-Offsets
  1279. ** and (if) user specified font.
  1280. *
  1281. _NoFontDeclared
  1282.     movea.l    _SysBase(A5),A6
  1283.     jsr    _LVOForbid(A6)
  1284.  
  1285.     movea.l    _IntuitionBase(A5),A6
  1286.     move.l    ib_ActiveScreen(A6),_ScreenPtr(A5)    ; Get active screen
  1287.  
  1288.     lea    _WindowRecord(A5),A0    ; Window-record
  1289.     move.l    _ScreenPtr(A5),nw_Screen(A0) ; On this screen our window should appear
  1290.     movea.l    _ScreenPtr(A5),A1    ; Address screen-record
  1291.  
  1292.     move.w    _XOffset(A5),D0
  1293.     beq.s    0$
  1294.     add.w    D0,(A0)            ; Set left edge of window
  1295. 0$
  1296.     move.w    _YOffset(A5),D0
  1297.     beq.s    1$
  1298.     add.w    D0,nw_TopEdge(A0)    ; Set top edge of window
  1299. 1$
  1300.     tst.w    nw_Width(A0)
  1301.     bne.s    2$
  1302.     move.w    sc_Width(A1),nw_Width(A0)
  1303. 2$
  1304.     tst.w    nw_Height(A0)
  1305.     bne.s    3$
  1306.     move.w    sc_Height(A1),nw_Height(A0)
  1307. 3$
  1308.     move.w    _XOffset(A5),D0
  1309.     beq.s    4$
  1310.     sub.w    D0,nw_Width(A0)
  1311. 4$
  1312.     move.w    _YOffset(A5),D0
  1313.     beq.s    5$
  1314.     sub.w    D0,nw_Height(A0)
  1315. 5$
  1316.     jsr    _LVOOpenWindow(A6)    ; Open the window
  1317.     move.l    D0,-(sp)
  1318.     movea.l    _SysBase(A5),A6
  1319.     jsr    _LVOPermit(A6)
  1320.     move.l    (sp)+,D0
  1321.     move.l    D0,_WindowPtr(A5)    ; Save window pointer
  1322.     beq.w    7$
  1323.  
  1324.     movem.l    D0/A2-A3,-(sp)
  1325.     movea.l    D0,A3            ; Window
  1326.     movea.l    wd_BorderRPort(A3),A2    ; RastPort of titlebar
  1327.  
  1328.     movea.l    _IntuitionBase(A5),A6
  1329.     cmpi.w    #35,LIB_VERSION(A6)    ; Kickstart 2.x or higher?
  1330.     bls.s    .Read            ; No...
  1331.     movea.l    wd_WScreen(A3),A0    ; Window's screen
  1332.     jsr    _LVOGetScreenDrawInfo(A6)    ; Get drawing infos
  1333.     tst.l    D0
  1334.     beq.s    .Read
  1335.     movea.l    D0,A1            ; DrawInfos
  1336.     movea.l    dri_Pens(A1),A0        ; Pointer to pen-array
  1337.     move.w    5*2(A0),D0        ; Get fillpen (aktive window's bar background)
  1338.     move.l    D0,-(sp)
  1339.     movea.l    wd_WScreen(A3),A0    ; Window's screen
  1340.     jsr    _LVOFreeScreenDrawInfo(A6)
  1341.     move.l    (sp)+,D0
  1342.     movea.l    _GfxBase(A5),A6        ; Restore Base
  1343.     bra.s    .SavePen
  1344. .Read
  1345.     movea.l    A2,A1
  1346.     moveq    #28,D0            ; X
  1347.     moveq    #1,D1            ; Y (room of first vertical pixel)
  1348.     movea.l    _GfxBase(A5),A6
  1349.     jsr    _LVOReadPixel(A6)    ; Get title bar's background colour
  1350. .SavePen
  1351.     move.w    D0,_BgPen(A5)        ; Save colour
  1352. *
  1353. ** Now we have to set the font for the title bar, it's the same like the screen's
  1354. ** default font!
  1355. *
  1356.     movea.l    wd_WScreen(A3),A0    ; The window our screen appears on
  1357.     lea    sc_RastPort(A0),A0    ; Screen's rastport
  1358.     movea.l    rp_Font(A0),A0        ; Default font
  1359.     movea.l    A2,A1            ; Window's title bar rastport
  1360.     jsr    _LVOSetFont(A6)        ; Set font (there isn't one - til now!)
  1361.     movem.l    (sp)+,D0/A2-A3
  1362.  
  1363.     tst.l    _UserFontPtr(A5)    ; Font opened?
  1364.     beq.s    6$
  1365.     move.l    D0,-(sp)
  1366.     movea.l    _WindowPtr(A5),A1
  1367.     movea.l    wd_RPort(A1),A1        ; RastPort
  1368.     move.l    rp_Font(A1),_OldFontPtr(A5)    ; Save old font for later
  1369.     movea.l    _UserFontPtr(A5),A0
  1370.     jsr    _LVOSetFont(A6)        ; Set font the user want
  1371.  
  1372.     move.l    (sp)+,D0
  1373. 6$
  1374.     movea.l    _WindowPtr(A5),A1
  1375.     movea.l    wd_RPort(A1),A1        ; RastPort
  1376.     cmpi.b    #1,rp_Mask(A1)        ; Only one bitplane?
  1377.     beq.s    .okBP            ; Yes...
  1378.     move.b    #%11,rp_Mask(A1)    ; Max. 2 bitplanes for Gfx-output!
  1379. * At the moment (ks 3.0) it's not supported, may be ks 3.1 will support it.
  1380. * If this cause trouble with your 3rd party graphic board, remove the lines.
  1381.  
  1382. .okBP
  1383.     rts
  1384.  
  1385. 7$
  1386.     tst.l    _UserFontPtr(A5)
  1387.     beq.s    8$
  1388.     movea.l    _UserFontPtr(A5),A1
  1389.     movea.l    _GfxBase(A5),A6
  1390.     jsr    _LVOCloseFont(A6)
  1391. 8$
  1392.     moveq    #0,D0
  1393.     lea    _WindowRecord(A5),A0
  1394.     move.w    nw_Height(A0),D0
  1395.     move.l    D0,-(sp)
  1396.     move.w    nw_Width(A0),D0
  1397.     move.l    D0,-(sp)
  1398.     move.w    nw_TopEdge(A0),D0
  1399.     move.l    D0,-(sp)
  1400.     move.w    (A0),D0            ; LeftEdge
  1401.     move.l    D0,-(sp)
  1402.     pea    _ErrorOpenWindowTxt(pc)
  1403.     bsr.w    _FmtDisplay
  1404.     lea    20(sp),sp        ; Restore stack
  1405.     moveq    #0,D0
  1406.     rts
  1407.  
  1408. *******************************************
  1409. *
  1410. * Close the main window.
  1411. * If a font was opened for this window,
  1412. * the system-default font is first set
  1413. * to the window (restored), then the opened
  1414. * font is closed and after that, the window
  1415. * is closed.
  1416. *
  1417. * Inputs: None
  1418. * Results: None
  1419. *
  1420.  
  1421. _CloseWindow
  1422.     tst.l    _UserFontPtr(A5)
  1423.     beq.s    1$
  1424.     movea.l    _GfxBase(A5),A6
  1425.  
  1426.     movea.l    _WindowPtr(A5),A1
  1427.     move.l    wd_RPort(A1),A1
  1428.     movea.l    _OldFontPtr(A5),A0
  1429.     jsr    _LVOSetFont(A6)
  1430.  
  1431.     movea.l    _UserFontPtr(A5),A1
  1432.     jsr    _LVOCloseFont(A6)
  1433.  
  1434. 1$
  1435.     movea.l    _IntuitionBase(A5),A6
  1436.     movea.l    _WindowPtr(A5),A0
  1437.     jmp    _LVOCloseWindow(A6)
  1438.  
  1439. *************************************
  1440. *
  1441. * Short subroutine to set window's name
  1442. * pc-relative.
  1443. *
  1444. * Inputs: None
  1445. * Results: None
  1446. *
  1447.  
  1448. _SetPrefs
  1449.     lea    _WindowRecord(A5),A0
  1450.     lea    _WindowName(pc),A1
  1451.     move.l    A1,nw_Title(A0)
  1452.     rts
  1453.  
  1454. *****************************************
  1455. *
  1456. * Main routine calls this one.
  1457. * This one will jump to the routine which
  1458. * belongs to the key.
  1459. *
  1460. * Inputs: A0 - "_ConBuffer"
  1461. *              Key in "_ConBuffer"
  1462. * Results: None
  1463. * Notes: Never call it via "bsr" or "jsr"!
  1464. *
  1465.  
  1466. _ConsoleEvent
  1467.     cmpi.w    #L_Key,(A0)
  1468.     beq.w    _LoadNew
  1469.     cmpi.w    #E_Key,(A0)
  1470.     beq.w    _EnlargeWindow
  1471.     cmpi.w    #H_Key,(A0)
  1472.     beq.w    _DisplayHelp
  1473.     cmpi.w    #I_Key,(A0)
  1474.     beq.w    _Info
  1475.     cmpi.w    #A_Key,(A0)
  1476.     beq.w    _About
  1477.     tst.l    _TextPtr(A5)
  1478.     beq.w    _Loop
  1479.     move.w    (A0),D0
  1480.     cmpi.b    #CRSR_UP,D0
  1481.     beq.w    _PageUp
  1482.     cmpi.b    #CRSR_DN,D0
  1483.     beq.w    _PageDown
  1484.     cmpi.b    #CRSR_FD,D0
  1485.     beq.w    _OneLineUp
  1486.     cmpi.b    #CRSR_BK,D0
  1487.     beq.w    _OneLineDown
  1488.     cmpi.b    #T_Key,D0
  1489.     beq.w    _Top
  1490.     cmpi.b    #B_Key,D0
  1491.     beq.w    _Bottom
  1492.     cmpi.b    #RETURN,D0
  1493.     beq.w    _OneLineDown
  1494.     cmpi.b    #ENTER,D0
  1495.     beq.w    _OneLineDown
  1496.     cmpi.b    #HOME,D0
  1497.     beq.w    _Top
  1498.     cmpi.b    #END,D0
  1499.     beq.w    _Bottom
  1500.     cmpi.b    #PG_UP,D0
  1501.     beq.w    _PageUp_01
  1502.     cmpi.b    #PG_DN,D0
  1503.     beq.w    _PageDown_01
  1504.     cmpi.b    #R_SHIFT,D0
  1505.     beq.w    _OneLineUp
  1506.     cmpi.b    #W_Key,D0
  1507.     beq.w    _WindowContentsPrt
  1508.     cmpi.b    #PrtSc,D0
  1509.     beq.w    _WindowContentsPrt
  1510.     cmpi.b    #C_Key,D0
  1511.     beq.w    _WindowContensFile
  1512.     cmpi.b    #P_Key,D0
  1513.     beq.w    _Print2Prt
  1514.     cmpi.b    #F_Key,D0
  1515.     beq.s    _Print2File
  1516.     cmpi.b    #R_Key,D0
  1517.     beq.w    _RestorePage
  1518.     cmpi.w    #S_Key,D0
  1519.     beq.w    _SearchSequence
  1520.     cmpi.w    #N_Key,D0
  1521.     beq.w    _ContinueSearch
  1522.     cmpi.b    #HELP_Key,D0
  1523.     bsr.s    _DisplayTitle
  1524.     bra.w    _Loop
  1525.  
  1526. **************************************************
  1527. *
  1528. * Allow counting lines and create new window-title.
  1529. *
  1530. * Inputs: none
  1531. * Results: none
  1532. *
  1533.  
  1534. _DisplayTitle
  1535.     clr.b    _NoLineFlag(A5)        ; Allow to count lines
  1536.     bsr.w    _ComLine        ; Create (modify) window-title
  1537.     rts
  1538.  
  1539. **************************************
  1540. *
  1541. * Set prefs to display the ascii-text,
  1542. * set up registers.
  1543. *
  1544. * Inputs: none
  1545. * Results: A3 - textstart, A2 - textend
  1546. *
  1547.  
  1548. _SetViewerPrefs
  1549.     movea.l    _TextPtr(A5),A4        ; Current text-position
  1550.     addq.l    #2,A4            ; Overread #$200A
  1551.     movea.l    A4,A3            ; Textstart A3
  1552.     movea.l    A4,A2            ;     ^        A2
  1553.     move.l    _FileSize(A5),D0    ; Length file
  1554.     add.l    D0,A2            ; = textend
  1555.     addq.l    #3,A2            ; + #$0200A + 1 byte behind source
  1556.     move.b    #10,(A2)        ; = textend
  1557.     move.l    A3,D5
  1558.     move.l    A3,D6
  1559.     rts
  1560.  
  1561. *************************************
  1562. *
  1563. * Print that ascii-text-file to file.
  1564. *
  1565. * Inputs: none
  1566. * Reslts: none
  1567. *
  1568.  
  1569. _Print2File
  1570.     clr.b    _LoadFlag(A5)        ; Set save-flag
  1571.     tst.b    _ReqFlag(A5)
  1572.     bne.s    1$            ; Requester already opened?
  1573.     bsr.w    OpenReq            ; No...
  1574. 1$
  1575.     bsr.w    _GetFile        ; Get filename
  1576.     cmpi.l    #-1,D0            ; Hard error?
  1577.     beq.w    _CantPrint        ; If so...
  1578.     tst.l    D0            ; No file?
  1579.     bne.s    _PrintFileTO        ; If so...
  1580.     bra.w    _Loop            ; ...and back
  1581.  
  1582. *
  1583. ** Ok, do further...
  1584. *
  1585. _PrintFileTO
  1586.     lea    _PrintFileTxt(pc),A0
  1587.     bsr.w    _DisplayError
  1588.     tst.l    D0            ; User cancelled?
  1589.     beq.s    _DoNotPrint        ; ..then do not write down the file
  1590.  
  1591.     lea    _FileName(A5),A0
  1592.     movea.l    A3,A1            ; Textstart
  1593.     move.l    _FileSize(A5),D0    ; Length file
  1594.     bsr.w    _PrintFile        ; Write down the file
  1595.     bra.w    _Loop            ; ...and end
  1596.  
  1597. ***************************************
  1598. *
  1599. * Write down window contents to a file.
  1600. *
  1601. * Inputs: none
  1602. * Reslts: none
  1603. *
  1604.  
  1605. _WindowContensFile
  1606.     clr.b    _LoadFlag(A5)        ; Indicate loading
  1607.     tst.b    _ReqFlag(A5)
  1608.     bne.s    1$            ; Requester already opened?
  1609.     bsr.w    OpenReq            ; No...
  1610. 1$
  1611.     bsr.w    _GetFile        ; Get filename
  1612.     cmpi.l    #-1,D0            ; Hard error?
  1613.     beq.s    _CantPrint        ; If so...
  1614.     tst.l    D0            ; No file?
  1615.     bne.s    _PrintFileTO_01        ; If so...
  1616.     bra.w    _Loop
  1617.  
  1618. *
  1619. ** Further....
  1620. *
  1621. _PrintFileTO_01
  1622.     lea    _PrintContentsTxt(pc),A0
  1623.     bsr.w    _DisplayError
  1624.     tst.l    D0            ; Right mosebutton?
  1625.     beq.s    _DoNotPrint        ; Then do not write
  1626.     movea.l    D6,A1            ; Current address (current line D6)
  1627.     movea.l    A1,A0
  1628.     move.w    _PageSize(A5),D1    ; Number of lines of one page
  1629.     addq.w    #2,D1            ; plus one line and one for linefeed
  1630.     moveq    #0,D0            ; Counter
  1631. 1$
  1632.     cmpa.l    A2,A0            ; Textend == current textposition?
  1633.     bge.s    2$            ; If so, error
  1634.     addq.w    #1,D0
  1635.     cmpi.b    #10,(A0)+        ; Search for linefeed
  1636.     bne.s    1$
  1637.     dbf    D1,1$            ; Lines of one page
  1638. 2$
  1639.     lea    _FileName(A5),A0    ; The filename
  1640.     bsr.w    _PrintFile        ; Write down file
  1641.     bra.w    _Loop            ; back to main
  1642.  
  1643. *******************************
  1644. *
  1645. * Print window contents to PRT:
  1646. *
  1647. * Inputs: none
  1648. * Reslts: none
  1649. *
  1650.  
  1651. _WindowContentsPrt
  1652.     lea    _FileName(A5),A0
  1653.     move.l    #'PRT:',(A0)+
  1654.     clr.b    (A0)
  1655.     bsr.s    _CheckPrinter        ; Check if printer is turned off or so...
  1656.     bra.s    _PrintFileTO_01
  1657.  
  1658. *
  1659. ** Error handling....
  1660. *
  1661. _DoNotPrint
  1662.     lea    _PrintCancelTxt(pc),A0
  1663.     bsr.w    _DisplayError
  1664.     bra.w    _Loop
  1665. _CantPrint
  1666.     bra.w    _End    
  1667.  
  1668. **************************
  1669. *
  1670. * Print whole file to PRT:
  1671. *
  1672. * Inputs: none
  1673. * Reslts: none
  1674. *
  1675.  
  1676. _Print2Prt
  1677.     lea    _FileName(A5),A0
  1678.     move.l    #'PRT:',(A0)+
  1679.     clr.b    (A0)
  1680.     bsr.s    _CheckPrinter
  1681.     bra.w    _PrintFileTO    
  1682.  
  1683. ****************************************
  1684. *
  1685. * Check printer: uses direct CIA-access.
  1686. * Works only 100% correctly with Epson-
  1687. * printers.
  1688. *
  1689. * Inputs: none
  1690. * Reslts: none
  1691. * Notes: Checking can be disabled
  1692. *
  1693.  
  1694. _CheckPrinter
  1695.     tst.b    _NoCheckPrtFlag(A5)    ; Allowed to check?
  1696.     bne.s    1$
  1697.     move.b    $BFD000,D0        ; CIA PRA
  1698.     cmpi.b    #255,D0
  1699.     beq.s    .PrinterOFF
  1700.     cmpi.b    #253,D0
  1701.     beq.s    .NotOneLine
  1702.     cmpi.b    #255,D0
  1703.     bne.s    .PrinterOFF
  1704. 1$
  1705.     rts
  1706. .PrinterOFF
  1707.     lea    _PrinterOFFTxt(pc),A0
  1708.     bsr.w    _DisplayError
  1709.     addq.l    #4,sp
  1710.     bra.w    _Loop
  1711. .NotOneLine
  1712.     lea    _NotOnelineTxt(pc),A0
  1713.     bsr.w    _DisplayError
  1714.     addq.l    #4,sp
  1715.     bra.w    _Loop
  1716.  
  1717. *********************
  1718. *
  1719. * How to explain....?
  1720. *
  1721.  
  1722. _PageUp
  1723.     move.w    _PageSize(A5),D7    ; ditto
  1724.     bra.w    _LinesUp
  1725. _PageUp_01
  1726.     move.w    _StdPageSize(A5),D7    ; Set scrollwidth
  1727.     addq.w    #1,D7            ; We can display one line more
  1728.     bra.w    _OnePageUp
  1729. _PageDown
  1730.     move.w    _PageSize(A5),D7    ; see above
  1731.     bra.w    _LinesDown
  1732. _PageDown_01
  1733.     move.w    _StdPageSize(A5),D7    ; see above
  1734.     addq.w    #1,D7            ; We can display one line more
  1735.     bra.w    _OnePageDown
  1736. _OneLineUp
  1737.     moveq    #0,D7            ; 1 line!
  1738.     bra.w    _LinesUp
  1739. _OneLineDown
  1740.     moveq    #0,D7            ; ditto
  1741.     bra.w    _LinesDown
  1742. _RestorePage
  1743.     bsr.w    _SetPageWidthAndLen
  1744. _RestorePage_1
  1745.     bsr.w    _RestoreCurrentPage
  1746.     bra.w    _Loop
  1747.  
  1748. ****************************************************
  1749. *
  1750. * Load from Shell overgiven file and set scrollwidth.
  1751. *
  1752. * Inputs: none
  1753. * Reslts: none
  1754. *
  1755.  
  1756. _CLILoad
  1757.     tst.l    arg_2(A5)        ; 2. argument empty?
  1758.     beq.s    1$            ; If so...
  1759.     movea.l    arg_2(A5),A0
  1760.  
  1761. *
  1762. ** Convert chars of second argument to uppercase.
  1763. ** 2. argument should look like this: 1> viewer <textfile> scrollwidth=11
  1764. **                               ¯¯¯¯¯¯¯¯¯¯¯¯¯¯
  1765. *
  1766. 2$
  1767.     tst.b    (A0)
  1768.     beq.s    4$
  1769.     cmpi.b    #'@',(A0)
  1770.     bls.s    3$
  1771.     cmpi.b    #'z',(A0)
  1772.     bhi.s    3$
  1773.     bclr    #5,(A0)
  1774. 3$
  1775.     addq.l    #1,A0
  1776.     bra.s    2$
  1777. 4$
  1778.     lea    arg_2(A5),A0
  1779.     clr.l    4(A0)            ; Clear next argument
  1780.     bsr.w    _SetScrollWidth_01    ; Get scrollwidth
  1781. 1$
  1782.     movea.l    arg_1(A5),A0        ; Address 1. argument (filename)
  1783.     lea    _FileName(A5),A1    ; Address buffer for filename
  1784. _StoreArgName
  1785.     move.b    (A0)+,(A1)+        ; Copy argument
  1786.     tst.b    -1(A0)
  1787.     bne.s    _StoreArgName    
  1788.     bra.s    _ReadIn
  1789.  
  1790. *******************************************
  1791. *
  1792. * Startup to load workbench overgiven file.
  1793. *
  1794. * Inputs: none
  1795. * Results: none
  1796. *
  1797.  
  1798. _WBLoad
  1799.     tst.l    lock_1(A5)        ; Lock to dir?
  1800.     beq.s    1$            ; No...
  1801.     move.l    lock_1(A5),D1
  1802.     movea.l    _DOSBase(A5),A6
  1803.     jsr    _LVOCurrentDir(A6)    ; else set as current directory
  1804. 1$
  1805.     tst.l    file_1(A5)
  1806.     beq.w    _InitRequester
  1807.  
  1808.     movea.l    file_1(A5),A0        ; Address name from file
  1809.     lea    _FileName(A5),A1
  1810.     bra.s    _StoreArgName
  1811.  
  1812. *****************************************
  1813. *
  1814. * Build requester, check file, read file.
  1815. *
  1816. * Inputs: none
  1817. * Results: none
  1818. *
  1819.  
  1820. _LoadNew
  1821.     st.b    _LoadFlag(A5)        ; Flag == load
  1822.     tst.b    _ReqFlag(A5)
  1823.     bne.s    1$            ; Requester already opened?
  1824.     bsr.w    OpenReq            ; No...
  1825. 1$
  1826.     bsr.w    _GetFile        ; Get filename
  1827.     tst.l    D0
  1828.     bmi.w    _End_1            ; Hard error?
  1829.     tst.l    D0
  1830.     beq.w    _Loop            ; No file?
  1831. _ReadIn
  1832.     bsr.w    _FreeAudio
  1833.  
  1834.     bsr.w    _ReadFile        ; Read file in
  1835.     tst.l    D0            ; Error?
  1836.     beq.w    _Loop            ; If so...
  1837.  
  1838.     bsr.w    _ClearWindow        ; Erase window contents
  1839.  
  1840.     bsr.w    _CheckFile        ; Check if ASCII, PP-crunched or IFF-screen
  1841.  
  1842.     bsr.w    _IgnoreSettings        ; ANSI-filter
  1843.  
  1844. *    bsr.w    _SetViewerPrefs        ; Set up ascii-file to display
  1845.  
  1846.     bra.w    _FirstPage        ; Display first page
  1847.  
  1848. *********************************************
  1849. *
  1850. * Display first page of ascii-text in window.
  1851. *
  1852. * Inputs: none
  1853. * Results: none
  1854. *
  1855.  
  1856. _Top
  1857.     bra.w    _FirstPage        ; Display first page
  1858.  
  1859. *********************************************
  1860. *
  1861. * Display last page of ascii-text in window.
  1862. *
  1863. * Inputs: none
  1864. * Results: none
  1865. *
  1866.  
  1867. _Bottom
  1868.     bra.w    _LastPage
  1869.  
  1870. **********************************************
  1871. *
  1872. * Page up - clear window and write down string
  1873. *
  1874. * Inputs: D5 == Address of last char in window (or NULL)
  1875. *         D6 == Address of 1. char in window
  1876. *         D7 == Number of lines to scroll (display)
  1877. *         A2 == Address last char of text
  1878. *         A3 == Address first char of text
  1879. *         A4 == used
  1880. * Results:
  1881. *      D5 == Address of last char in window
  1882. *         D6 == Address of 1. char in window
  1883. *
  1884.  
  1885. _OnePageUp
  1886.     movea.l    D6,A4
  1887.     movea.l    A4,A0
  1888.     subq.l    #4,A0            ; Any chars to display?
  1889.     cmpa.l    A3,A0
  1890.     bls.w    _Loop            ; If not...
  1891.  
  1892.     bsr.w    _ClearWindow
  1893.  
  1894.     moveq    #0,D2            ; Number of chars!
  1895. 0$
  1896.     cmpa.l    A3,A4            ; A3 == lowest address, A4 == current address, does it fit?
  1897.     bls.s    6$            ; If not...
  1898.  
  1899. 1$
  1900.     moveq    #0,D0            ; Counter for number of chars
  1901. 2$
  1902.     addq.w    #1,D0            ; Else counter for number of chars plus 1
  1903.     subq.l    #1,A4
  1904.     cmpi.b    #10,(A4)        ; Next line?
  1905.     bne.s    2$
  1906.     add.w    D0,D2
  1907. 3$    
  1908.     tst.b    _NoLineFlag(A5)        ; Counting lines allowed?
  1909.     bne.s    4$            ; No...
  1910.     subq.l    #1,_Line(A5)
  1911. 4$
  1912.     move.l    A4,D6            ; Remember startaddress of string in D6 as next pointer
  1913. *                      for LinesUp-routine
  1914.     movea.l    D5,A0            ; Address last char in window
  1915. 5$
  1916.     cmpi.b    #10,-(A0)        ; Find LineFeed
  1917.     bne.s    5$
  1918.     move.l    A0,D5            ; New address last char in window
  1919.  
  1920.     dbf    D7,0$
  1921.  
  1922.     move.l    D2,-(sp)
  1923.     lea    _ConBuffer(A5),A0    ; Address buffer
  1924.     move.w    #$9B48,(A0)        ; Cursor Home
  1925.     moveq    #2,D0            ; 2 chars for output
  1926.     bsr.w    _ConOut_Rel        ; Output
  1927.     move.l    (sp)+,D0
  1928.  
  1929.     movea.l    A4,A0
  1930.     addq.l    #1,A0
  1931.     subq.w    #1,D0
  1932.     bsr.w    _ConOut_Reloc        ; Print down those lines
  1933.  
  1934.     bra.w    _Loop
  1935.  
  1936. 6$
  1937.     bsr.w    _RestoreCurrentPage
  1938.     bra.w    _Loop
  1939.  
  1940. ***********************************************
  1941. *
  1942. * Number of lines to scroll up....
  1943. *
  1944. * Inputs: D5 == Address of last char in window (or NULL)
  1945. *         D6 == Address of 1. char in window
  1946. *         D7 == Number of lines to scroll (display)
  1947. *         A2 == Address last char of text
  1948. *         A3 == Address first char of text
  1949. *         A4 == used
  1950. * Results:
  1951. *      D5 == Address of last char in window
  1952. *         D6 == Address of 1. char in window
  1953. *
  1954.  
  1955. _LinesUp
  1956.     movea.l    D6,A4            ; Last address from LinesDown as current address for us
  1957. 0$
  1958.     cmpa.l    A3,A4            ; A3 == lowest address, A4 == current address, does it fit?
  1959.     bls.w    _Loop            ; If not...
  1960.  
  1961.     lea    _ConBuffer(A5),A0    ; Address buffer
  1962.     move.w    #$9B48,(A0)+        ; Cursor Home
  1963.     move.l    #$9B314100,(A0)        ; Scroll 1 line up
  1964.     moveq    #5,D0            ; 5 chars for output
  1965.     bsr.w    _ConOut_Rel        ; Output
  1966. 1$
  1967.     moveq    #0,D0            ; Counter for number of chars
  1968. 2$
  1969.     addq.w    #1,D0            ; Else counter for number of chars plus 1
  1970.     subq.l    #1,A4
  1971.     cmpi.b    #10,(A4)
  1972.     bne.s    2$
  1973. 3$    
  1974.     tst.b    _NoLineFlag(A5)        ; Counting lines allowed?
  1975.     bne.s    4$            ; No...
  1976.     subq.l    #1,_Line(A5)
  1977. 4$
  1978.     movea.l    A4,A0
  1979.     addq.l    #1,A0
  1980.     subq.w    #1,D0
  1981.     bsr.w    _ConOut_Reloc        ; Print down the line
  1982.  
  1983.     move.l    A4,D6            ; Remember startaddress of string in D6 as next pointer
  1984. *                      for LinesUp-routine
  1985.     movea.l    D5,A0            ; Address last char in window
  1986. 5$
  1987.     cmpi.b    #10,-(A0)        ; Find LineFeed
  1988.     bne.s    5$
  1989.     move.l    A0,D5            ; New address last char in window
  1990.  
  1991.     dbf    D7,0$
  1992.  
  1993.     bra.w    _Loop
  1994.  
  1995. *******************************************************************
  1996. *
  1997. * Scroll down one complete page an write to freed room the strings.
  1998. *
  1999. * Inputs: D5 == Address of last char in window (or NULL)
  2000. *         D6 == Address of 1. char in window
  2001. *         D7 == Number of lines to scroll (display)
  2002. *         A2 == Address last char of text
  2003. *         A3 == Address first char of text
  2004. *         A4 == used
  2005. * Results:
  2006. *      D5 == Address of last char in window
  2007. *         D6 == Address of 1. char in window
  2008. *
  2009.  
  2010. _OnePageDown
  2011.     movea.l    D5,A4            ; Last address char in window
  2012.     movea.l    A4,A0
  2013.     addq.l    #2,A0            ; At least a few bytes to display?
  2014.     cmpa.l    A2,A0            ; Does it fit?
  2015.     bge.w    _Loop
  2016.  
  2017.     bsr.w    _ClearWindow
  2018.     addq.l    #1,A4            ; Ignore introducing LineFeed
  2019.  
  2020.     lea    _ConBuffer(A5),A0
  2021.     move.w    #$9B48,(A0)
  2022.     moveq    #2,D0
  2023.     bsr.w    _ConOut_Rel
  2024.  
  2025.     bra.s    _Lines_Down
  2026.  
  2027. **************************************************************
  2028. *
  2029. * Scroll down and print contents, number of lines: ScrollWidth.
  2030. *
  2031. * Inputs: D5 == Address of last char in window (or NULL)
  2032. *         D6 == Address of 1. char in window
  2033. *         D7 == Number of lines to scroll (display)
  2034. *         A2 == Address last char of text
  2035. *         A3 == Address first char of text
  2036. *         A4 == used
  2037. * Results:
  2038. *      D5 == Address of last char in window
  2039. *         D6 == Address of 1. char in window
  2040. *
  2041.  
  2042. _LinesDown
  2043.     movea.l    D5,A4            ; Last address char in window
  2044.     cmpa.l    A2,A4            ; Does it fit?
  2045.     bge.w    _Loop
  2046.  
  2047.     lea    _ConBuffer(A5),A0
  2048.     move.l    #$9B393939,(A0)+    ; Cursor End of Display
  2049.     move.b    #$48,(A0)        ; <CSI>999H
  2050.     moveq    #5,D0
  2051.     bsr.w    _ConOut_Rel
  2052.  
  2053. _Lines_Down
  2054.     movea.l    A4,A0
  2055.     moveq    #0,D0            ; Counter for number of chars
  2056. 1$
  2057.     cmpa.l    A2,A4            ; A2 == highest address, A4 == current
  2058.     bge.w    _Loop
  2059.  
  2060.     addq.w    #1,D0            ; Counter for chars plus 1
  2061.     addq.l    #1,A4
  2062.     cmpi.b    #10,(A4)        ; LineFeed?
  2063.     bne.s    1$            ; If not, do it further
  2064.     bsr.w    _ConOut_Reloc        ; Print down one line
  2065.  
  2066.     move.l    A4,D5            ; Last char address in window
  2067.     movea.l    D6,A0            ; First char in window
  2068. 2$
  2069.     addq.l    #1,A0
  2070.     cmpi.b    #10,(A0)        ; LineFeed (next line)?
  2071.     bne.s    2$
  2072.     move.l    A0,D6            ; New address (first char in window)
  2073.  
  2074.     tst.b    _NoLineFlag(A5)        ; Allowed to count lines?
  2075.     bne.s    3$            ; No...
  2076.     addq.l    #1,_Line(A5)
  2077. 3$
  2078.     dbf    D7,_Lines_Down        ; Number of lines
  2079.  
  2080.     bra.w    _Loop    
  2081.  
  2082. *********************************
  2083. *
  2084. * Restore current window contents
  2085. *
  2086. * Inputs: D5 == Address of last char in window (or NULL)
  2087. *         D6 == Address of 1. char in window
  2088. *         A2 == Address last char of text
  2089. *         A3 == Address first char of text
  2090. *         A4 == used
  2091. * Results:
  2092. *      D5 == Address of last char in window
  2093. *         D6 == Address of 1. char in window
  2094. *
  2095.  
  2096. _RestoreCurrentPage
  2097.     tst.l    _BufferSize(A5)        ; Any datas to display out there?
  2098.     beq.s    2$            ; If not...
  2099.  
  2100.     move.l    D6,D5            ; Last address == current
  2101.     addq.l    #1,D5            ; Ignore introducing linefeed
  2102.  
  2103.     move.w    _StdPageSize(A5),D7
  2104.     addq.w    #1,D7
  2105.  
  2106.     movea.l    D5,A4            ; Last address char in window
  2107.     cmpa.l    A2,A4            ; Does it fit?
  2108.     bge.s    2$
  2109.  
  2110.     lea    _ConBuffer(A5),A0    ; Address buffer
  2111.     move.l    #$1B5B306D,(A0)+    ; Reset display
  2112.     move.l    #$9B639B48,(A0)+    ; Reset console and Cursor Home
  2113.     move.l    #$9B4A9B48,(A0)        ; Erase to end of display Cursor Home
  2114.     moveq    #12,D0            ; 12 chars for output
  2115.     bsr.w    _ConOut_Rel        ; Output
  2116.  
  2117. 0$
  2118.     movea.l    A4,A0
  2119.     moveq    #0,D0            ; Counter for number of chars
  2120. 1$
  2121.     cmpa.l    A2,A4            ; A2 == highest address, A4 == current
  2122.     bge.s    2$
  2123.  
  2124.     addq.w    #1,D0            ; Counter for chars plus 1
  2125.     addq.l    #1,A4
  2126.     cmpi.b    #10,(A4)        ; LineFeed?
  2127.     bne.s    1$            ; If not, do it further
  2128.     bsr.w    _ConOut_Reloc        ; Print down one line
  2129.  
  2130.     move.l    A4,D5            ; Last char address in window
  2131.     dbf    D7,0$            ; Number of lines
  2132. 2$
  2133.     rts
  2134.  
  2135. ***************************************
  2136. *
  2137. * Display first page of ascii-text-file
  2138. *
  2139. * Inputs: D5 == Address of last char in window (or NULL)
  2140. *         D6 == Address of 1. char in window
  2141. *         A2 == Address last char of text
  2142. *         A3 == Address first char of text
  2143. *         A4 == used
  2144. * Results:
  2145. *      D5 == Address of last char in window
  2146. *         D6 == Address of 1. char in window
  2147. *
  2148.  
  2149. _FirstPage
  2150.     bsr.w    _SetViewerPrefs        ; Prefs == as on start!
  2151.  
  2152.     moveq    #0,D7
  2153.     move.w    _StdPageSize(A5),D7
  2154.     addq.w    #1,D7
  2155.     move.l    D7,_Line(A5)        ; == number of lines that "are" displayed"!?"
  2156.  
  2157.     movea.l    D5,A4            ; Last address char in window
  2158.     cmpa.l    A2,A4            ; Does it fit?
  2159.     bge.w    _Loop
  2160.  
  2161.     lea    _ConBuffer(A5),A0    ; Address buffer
  2162.     move.l    #$1B5B306D,(A0)+    ; Reset display
  2163.     move.l    #$9B639B48,(A0)+    ; Reset and Cursor Home
  2164.     move.l    #$9B4A9B48,(A0)        ; Erase to end of display + Cursor Home
  2165.     moveq    #12,D0            ; 12 chars for output
  2166.     bsr.w    _ConOut_Rel        ; Output
  2167. 0$
  2168.     movea.l    A4,A0
  2169.     moveq    #0,D0            ; Counter for number of chars
  2170. 1$
  2171.     cmpa.l    A2,A4            ; A2 == highest address, A4 == current
  2172.     bge.w    _Loop
  2173.  
  2174.     addq.w    #1,D0            ; Counter for chars plus 1
  2175.     addq.l    #1,A4
  2176.     cmpi.b    #10,(A4)        ; LineFeed?
  2177.     bne.s    1$            ; If not, do it further
  2178.     bsr.w    _ConOut_Reloc        ; Print down one line
  2179.  
  2180.     move.l    A4,D5            ; Last char's address in window
  2181.     dbf    D7,0$            ; Number of lines
  2182.  
  2183.     bra.w    _Loop    
  2184.  
  2185. **************************************
  2186. *
  2187. * Display last page of ascii-text-file
  2188. *
  2189. * Inputs: D5 == Address of last char in window (or NULL)
  2190. *         D6 == Address of 1. char in window
  2191. *         A2 == Address last char of text
  2192. *         A3 == Address first char of text
  2193. *         A4 == used
  2194. * Results:
  2195. *      D5 == Address of last char in window
  2196. *         D6 == Address of 1. char in window
  2197. *
  2198.  
  2199. _LastPage
  2200.     move.l    A2,D5            ; Highest address as current for LinesDown
  2201.     move.l    D5,D6            ; Highest address as current for us!
  2202.  
  2203.     lea    _ConBuffer(A5),A0    ; Address buffer
  2204.     move.l    #$1B5B306D,(A0)+    ; Reset display
  2205.     move.l    #$9B639B48,(A0)+    ; Reset console and Cursor Home
  2206.     move.w    #$9B4A,(A0)        ; Erase to end of display + Cursor Home
  2207.     moveq    #10,D0            ; 10 chars for output
  2208.     bsr.w    _ConOut_Rel        ; Output
  2209.  
  2210.     move.w    _StdPageSize(A5),D7    ; Number of scrolls
  2211.     addq.w    #1,D7            ; Plus 1
  2212.  
  2213.     movea.l    D6,A4
  2214. 0$
  2215.     cmpa.l    A3,A4            ; A3 == lowest address, A4 == current address, does it fit?
  2216.     bls.w    _Loop            ; If not...
  2217.  
  2218.     lea    _ConBuffer(A5),A0    ; Address buffer
  2219.     move.w    #$9B48,(A0)+        ; Cursor Home
  2220.     move.l    #$9B314100,(A0)        ; Scroll 1 line up
  2221.     moveq    #5,D0            ; 5 chars for output
  2222.     bsr.w    _ConOut_Rel        ; Output
  2223. 1$
  2224.     moveq    #0,D0            ; Counter for number of chars
  2225. 2$
  2226.     addq.w    #1,D0            ; Counter for number of chars plus 1
  2227.     subq.l    #1,A4            ; Next char
  2228.     cmpi.b    #10,(A4)        ; Next line?
  2229.     bne.s    2$
  2230.  
  2231.     movea.l    A4,A0
  2232.     addq.l    #1,A0
  2233.     subq.w    #1,D0
  2234.     bsr.w    _ConOut_Reloc        ; Print down the line
  2235.  
  2236.     move.l    A4,D6            ; Remember startaddress of string in D6 as next pointer
  2237. *                      for LinesUp-routine
  2238.     dbf    D7,0$
  2239.  
  2240.     move.l    _LinesInFile(A5),D0    ; How many lines in file?
  2241.     addq.l    #1,D0
  2242.     move.l    D0,_Line(A5)        ; = lines
  2243.  
  2244.     bra.w    _Loop
  2245.  
  2246. ************************
  2247. *
  2248. * Make cursor invisible.
  2249. *
  2250. * Inputs: none
  2251. * Results: none
  2252. *
  2253.  
  2254. _CursorOff
  2255.     clr.l    -(sp)
  2256.     movea.l    sp,A0
  2257.     move.b    #$9B,(A0)
  2258.     move.b    #'0',1(A0)
  2259.     move.b    #' ',2(A0)
  2260.     move.b    #'p',3(A0)
  2261.     moveq    #4,D0
  2262.     bsr.w    _ConOut_Reloc        ; Output
  2263.     addq.l    #4,sp
  2264.     rts
  2265.  
  2266. _CursorOn
  2267.     clr.l    -(sp)
  2268.     movea.l    sp,A0
  2269.     move.b    #$9B,(A0)
  2270.     move.b    #' ',1(A0)
  2271.     move.b    #'p',2(A0)
  2272.     moveq    #3,D0
  2273.     bsr.w    _ConOut_Reloc        ; Output
  2274.     addq.l    #4,sp
  2275.     rts
  2276.  
  2277. ****************************************************************
  2278. *
  2279. * Twist pointer for system-requester so that system-requesters
  2280. * which mean us, will appear on our window; must be done because
  2281. * any other screen as the Workbench's one can be used by Viewer.
  2282. *
  2283. * Inputs: none
  2284. * Results: none
  2285. *
  2286.  
  2287. _SetPtr4Req
  2288.     movea.l    _OwnTask(A5),A0
  2289.     move.l    pr_WindowPtr(A0),_StdprWindowPtr(A5)    ; Save default pointer
  2290.     move.l    _WindowPtr(A5),pr_WindowPtr(A0)        ; Twist
  2291.     rts
  2292.  
  2293. ***********************************************
  2294. *
  2295. * Find in tooltypes a string which tells us to make a
  2296. * word warp when the contents of one line do not fit
  2297. * in one line (window limits)
  2298. *
  2299. * Inputs: none
  2300. * Results: none
  2301. *
  2302.  
  2303. _CheckWrap
  2304.     lea    WB_arg_1(A5),A0
  2305. 1$
  2306.     tst.l    (A0)            ; Any argument?
  2307.     beq.s    4$
  2308.  
  2309.     movea.l    (A0)+,A1
  2310.     lea    _WrapDef(pc),A2        ; String to compare
  2311.     moveq    #7,D0
  2312. 2$
  2313.     cmpm.b    (A1)+,(A2)+
  2314.     bne.s    1$
  2315.     dbf    D0,2$
  2316.     st.b    _WrapFlag(A5)        ; Set flag
  2317. 4$
  2318.     rts
  2319.  
  2320. *************************************************
  2321. *
  2322. * Get window limits out of tooltypes,
  2323. * (EXTENTWINDOW=<width>,<height>)
  2324. *
  2325. * Inputs: (GetNextArg() - pointer to string in A0
  2326. * Results: none
  2327. *
  2328.  
  2329. _SetWindow                ; Only if WB-start!!!
  2330.     lea    WB_arg_1(A5),A0
  2331. _GetNextArg                ; this one for the Shell
  2332. 1$
  2333.     tst.l    (A0)            ; Argument there?
  2334.     beq.s    .EndSetWindow        ; No
  2335.     movea.l    (A0)+,A1        ; Address overgiven string
  2336.     lea    _WindowDef(pc),A2    ; Address string to compare
  2337.     moveq    #12,D0            ; 13 chars to compare
  2338. 3$
  2339.     cmpm.b    (A1)+,(A2)+        ; Compare strings
  2340.     bne.s    1$            ; "EXTENTWINDOW="
  2341.     dbf    D0,3$
  2342.  
  2343.     moveq    #0,D0            ; Fill up (no mask)
  2344.     movea.l    A1,A0            ; A0 string (contains value)
  2345.     bsr.w    _StrToLong
  2346.     tst.l    D1            ; Error?
  2347.     bmi.s    .EndSetWindow
  2348.  
  2349. .SetWidth
  2350.     lea    _WindowRecord(A5),A3    ; Address window-record
  2351.     move.w    D0,nw_Width(A3)        ; Set width
  2352.  
  2353.     moveq    #0,D0            ; No mask
  2354. * String to convert already in A0
  2355.     bsr.w    _StrToLong
  2356.     tst.l    D1
  2357.     bmi.s    .EndSetWindow
  2358.  
  2359. .SetHeight
  2360.     lea    _WindowRecord(A5),A3    ; Window-record
  2361.     move.w    D0,nw_Height(A3)    ; Set height
  2362.  
  2363. .EndSetWindow
  2364.     rts
  2365.  
  2366. *********************************************************
  2367. *
  2368. * Set scrollwidth, user has to specify it on his own,
  2369. * tooltyes or Shell.
  2370. *
  2371. * Inputs: (SetScrollWidth_01() - only Shell: A0 - string)
  2372. * Results: none
  2373. *
  2374.  
  2375. _SetScrollWidth                ; Only available from Workbench
  2376.     lea    WB_arg_1(A5),A0        ; Address constant of 1. argument
  2377. _SetScrollWidth_01            ; Jumpmark for Shell use
  2378.     tst.l    (A0)            ; Address 1. argument there?
  2379.     beq.s    1$
  2380.  
  2381.     movea.l    (A0)+,A1        ; Out of it address 1. argument
  2382.     lea    _PageDef(pc),A2
  2383.     moveq    #11,D0            ; 12 loops
  2384. 2$
  2385.     cmpm.b    (A1)+,(A2)+        ; Compare char for char
  2386.     bne.s    _SetScrollWidth_01    ; "SCROLLWIDTH="
  2387.     dbf    D0,2$
  2388.  
  2389.     moveq    #0,D0            ; No mask
  2390.     movea.l    A1,A0            ; Text into A0    
  2391.     bsr.w    _StrToLong        ; Get value
  2392.     cmpi.l    #-1,D1            ; On error
  2393.     beq.s    1$
  2394.     subq.w    #1,D0            ; Because scrolling can be done once more!
  2395.     move.w    D0,_PageSize(A5)    ; Set length to scroll
  2396.     st.b    _PageSizeFlag(A5)    ; Set flag
  2397. 1$
  2398.     rts
  2399.  
  2400. ****************************************************
  2401. *
  2402. * Get from and only! from Workbench overgiven file,
  2403. * may be specified in the defaulttool of the project-
  2404. * icon of a file.
  2405. *
  2406. * Inputs: none
  2407. * Results: none
  2408. *
  2409.  
  2410. _SetDirection
  2411.     tst.l    _argc(A5)        ; Any argument?
  2412.     beq.s    2$            ; If not...
  2413.  
  2414.     move.l    lock_1(A5),D1        ; Get the lock to the file
  2415.     beq.s    3$
  2416.     movea.l    _DOSBase(A5),A6
  2417.     jsr    _LVOCurrentDir(A6)    ; Change current directory to project's one
  2418. 3$
  2419.     tst.l    file_1(A5)        ; No file?
  2420.     beq.s    2$
  2421.  
  2422.     movea.l    file_1(A5),A0        ; Name of file
  2423.     tst.l    _IconBase(A5)
  2424.     beq.s    2$
  2425.     movea.l    _IconBase(A5),A6
  2426.     jsr    _LVOGetDiskObject(A6)    ; Load ".info"-file
  2427.     move.l    D0,_UserProject(A5)    ; Save its handle
  2428.     movea.l    D0,A0            ; Pointer to entries A0
  2429.     tst.l    D0
  2430.     beq.s    2$            ; Upon error
  2431.  
  2432.     movea.l    do_ToolTypes(A0),A0    ; Get those tooltype-pointer
  2433.     move.l    A0,_ToolTypesArray(A5)
  2434.  
  2435.     moveq    #14,D0            ; Allow 15 entries to be stored
  2436.     lea    WB_arg_1(A5),A1        ; Address for 1. argument
  2437. 1$
  2438.     move.l    (A0)+,(A1)+        ; Save these pointers
  2439.     beq.s    2$            ; Last pointer?
  2440.     dbf    D0,1$            ; No...
  2441. 2$
  2442.     rts
  2443.  
  2444. *************************************************
  2445. *
  2446. * Get page width and length in lines. Do it via a
  2447. * console status report.
  2448. *
  2449. * Maximums for now:
  2450. * 999 lines and 999 columns.
  2451. * The console will report if we set the limits to
  2452. * 999 the maximum which is displayable, e.g.
  2453. * <CSI>20;78R - mean 20 lines and 78 columns.
  2454. *
  2455. * Inputs: none
  2456. * Results: none
  2457. *
  2458.  
  2459. _SetPageWidthAndLen
  2460.     movem.l    D0-D7/A0-A6,-(sp)
  2461. .GetConReport
  2462.     lea    _ConBuffer(A5),A0
  2463.     move.l    #$9B39393B,(A0)+    ; Move Cursor <CSI>99; [ NOTEZ-BIEN: We cannot use 999
  2464. *                      here - due to the below menitioned bug! ]
  2465.     move.l    #$39393948,(A0)+    ; 999H - here it works...
  2466.     moveq    #8,D0
  2467.     bsr.w    _ConOut_Rel
  2468.  
  2469.     lea    _ConBuffer(A5),A0
  2470.     move.l    #$9B393939,(A0)+    ; Because of a bug in the con-routines
  2471.     move.b    #'B',(A0)        ; we have to set the cursor as single CSI
  2472.     moveq    #5,D0            ; to end of the display (<CSI>999B
  2473.     bsr.w    _ConOut_Rel
  2474.  
  2475.     lea    _ConBuffer(A5),A0
  2476.     move.l    #$9B366E00,(A0)+    ; Console Device Status Report
  2477. *                      <CSI>6n
  2478.     moveq    #3,D0            ; 3 chars
  2479.     bsr.w    _ConOut_Rel        ; Output
  2480.     lea    _ConBuffer(A5),A0
  2481.     moveq    #20,D0
  2482. .ClearIt
  2483.     clr.b    (A0)+
  2484.     dbf    D0,.ClearIt
  2485. 1$
  2486.     bsr.w    _GetConMsg        ; Get the message from the console-device
  2487.     tst.l    D0            ; Message?
  2488.     beq.s    1$
  2489.     movea.l    D0,A1
  2490.     jsr    _LVOReplyMsg(A6)
  2491.  
  2492.     lea    _ConBuffer(A5),A0
  2493.     addq.l    #1,A0
  2494.     move.l    A0,D2
  2495.     move.l    _stdout(A5),D1
  2496.     beq.s    8$
  2497.     moveq    #7,D3
  2498.     movea.l    _DOSBase(A5),A6        ; Print message to Shell-window
  2499.     jsr    _LVOWrite(A6)
  2500. 8$
  2501.  
  2502.     lea    _ConBuffer(A5),A0
  2503.     addq.l    #1,A0            ; Overread CSI
  2504.  
  2505.     moveq    #0,D0            ; No mask
  2506.     bsr.w    _StrToLong        ; Get value
  2507.     cmpi.l    #-1,D1            ; Error ?
  2508.     bne.s    2$
  2509.     cmpi.b    #';',-1(A0)        ; Last char the semicolon?
  2510.     beq.s    2$            ; If so, it is ok
  2511.     bra.w    .GetConReport        ; Upon error
  2512. 2$
  2513.     subq.w    #2,D0            ; Minus 2 = scrollwidth
  2514.     move.w    D0,_StdPageSize(A5)    ; Standard scrollwidth
  2515.     tst.b    _PageSizeFlag(A5)    ; Already defined (ToolTypes)?
  2516.     bne.s    3$            ; If so...
  2517.     move.w    D0,_PageSize(A5)    ; Else save it
  2518. 3$
  2519. *
  2520. ** Get count which stays after the semicolon
  2521. ** (returned by the status-report)
  2522. *
  2523.     moveq    #0,D0            ; No mask
  2524.     bsr.w    _StrToLong        ; Get value
  2525.     cmpi.l    #-1,D1            ; Error ?
  2526.     bne.s    4$
  2527.     cmpi.b    #'R',-1(A0)        ; Last char the 'R'?
  2528.     beq.s    4$            ; If so, it is ok
  2529.     bra.w    .GetConReport        ; Else get new
  2530. 4$
  2531.     subq.w    #1,D0
  2532.     move.l    D0,_PageWidth(A5)    ; Set max. length
  2533.  
  2534.     lea    _IOInlineBuf(A5),A0
  2535.     move.b    #10,(A0)+
  2536.     move.l    _PageWidth(A5),D0    
  2537.     bsr.w    _comdec
  2538.     move.b    #10,(A0)+
  2539.     clr.b    (A0)
  2540.     lea    _IOInlineBuf(A5),A0
  2541.     move.l    _stdout(A5),D1
  2542.     beq.s    6$
  2543.     move.l    A0,D2
  2544.     moveq    #-1,D3
  2545. 7$
  2546.     tst.b    (A0)+
  2547.     dbeq    D3,7$
  2548.     not.l    D3
  2549.     movea.l    _DOSBase(A5),A6
  2550.     jsr    _LVOWrite(A6)        ; Print down settings to Shell-window
  2551. 6$
  2552.     movem.l    (sp)+,D0-D7/A0-A6
  2553. 5$
  2554.     rts
  2555.  
  2556. ********************************************************************
  2557. *
  2558. * Open and init a filerequester, only Arp and ReqTools supported yet.
  2559. *
  2560. *
  2561. * Inputs: none
  2562. * Results: Gloabal Flag ("_ReqFlag), indicates which requester is used,
  2563. *                  1 ReqTools
  2564. *                  2 Arp
  2565. *                 -1 failed to open (hard error)
  2566. *
  2567.  
  2568. OpenReq
  2569.     tst.l    _ReqPtr(A5)
  2570.     bne.s    1$
  2571.     movea.l    _SysBase(A5),A6
  2572.     moveq    #37,D0
  2573.     lea    _ReqToolsName(pc),A1
  2574.     jsr    _LVOOpenLibrary(A6)
  2575.     move.l    D0,_ReqToolsBase(A5)
  2576.     beq.s    _ArpReq            ; If it failed...
  2577.     movea.l    _ReqToolsBase(A5),A6    ; else
  2578.     moveq    #0,D0            ; Must be NULL for the moment
  2579.     suba.l    A0,A0            ; (Tags) ditto
  2580.     jsr    _LVOrtAllocRequestA(A6)    ; Allocate structure
  2581.     move.l    D0,_ReqPtr(A5)
  2582.     beq.s    .noReqToolsReq        ; Upon error
  2583. 1$
  2584.     move.b    #1,_ReqFlag(A5)        ; Say: ok reqtools
  2585.     rts
  2586. .noReqToolsReq
  2587.     movea.l    A6,A1
  2588.     movea.l    _SysBase(A5),A6
  2589.     jsr    _LVOCloseLibrary(A6)
  2590.     clr.l    _ReqToolsBase(A5)    ; Important!!!
  2591.  
  2592. _ArpReq
  2593.     tst.l    _ArpBase(A5)
  2594.     bne.s    2$
  2595.     movea.l    _SysBase(A5),A6
  2596.     moveq    #39,D0
  2597.     lea    _ArpName(pc),A1
  2598.     jsr    _LVOOpenLibrary(A6)
  2599.     move.l    D0,_ArpBase(A5)
  2600.     beq.s    .NoArp            ; Hard error, failed to open any requester!
  2601.     bsr.s    _InitReq        ; Init Arp-structure
  2602. 2$
  2603.     move.b    #2,_ReqFlag(A5)        ; Flag for Ok Arp
  2604.     rts
  2605.  
  2606. .NoArp
  2607.     move.b    #-1,_ReqFlag(A5)    ; Say: damned, failed to open
  2608.     rts
  2609.  
  2610. **********************************
  2611. *
  2612. * Display ReqTools file-requester.
  2613. *
  2614. * Inputs: none
  2615. * Results: none
  2616. *
  2617.  
  2618. _ReqLoad
  2619.     movem.l    A2-A3,-(sp)
  2620.     suba.l    A0,A0            ; TAG-list
  2621.     movea.l    _ReqPtr(A5),A1        ; ReqTools-structure
  2622.     lea    _File(A5),A2        ; Buffer for filename
  2623.     tst.b    _LoadFlag(A5)        ; Shall we load?
  2624.     bne.s    3$            ; No, save!
  2625.     lea    _SaveTitle(pc),A3    ; Save-string (title-text)
  2626.     bra.s    2$
  2627. 3$
  2628.     lea    _AWTitle(pc),A3        ; Window-title == load
  2629. 2$
  2630.     movea.l    _ReqToolsBase(A5),A6
  2631.     jsr    _LVOrtFileRequestA(A6)
  2632.     tst.l    D0
  2633.     beq.s    4$            ; No file was chosen!
  2634.     lea    _Drive(A5),A1        ; Address buffer for directory
  2635.     movea.l    _ReqPtr(A5),A0        ; Address Requester-structure
  2636.     movea.l    16(A0),A0        ; rtfi_Dir(A0),A0! - pointer to directory
  2637. 1$
  2638.     move.b    (A0)+,(A1)+        ; Copy drive-name
  2639.     tst.b    -1(A0)            ; Copy also NULL-byte
  2640.     bne.s    1$
  2641.     moveq    #1,D0            ; Signal ok
  2642. 4$
  2643.     movem.l    (sp)+,A2-A3
  2644.     rts
  2645.  
  2646. ************************************
  2647. *
  2648. * Initialize Arp-requester structure.
  2649. *
  2650. * Inputs: none
  2651. * Results: none
  2652. *
  2653.  
  2654. _InitReq
  2655.     lea    _ArpReqStruc(A5),A0    ; Address structure
  2656.     lea    _AWTitle(pc),A1        ; Address title for requester
  2657.     move.l    A1,(A0)
  2658.     lea    _File(A5),A1        ; Address buffer for name
  2659.     move.l    A1,4(A0)
  2660.     lea    _Drive(A5),A1        ; Address buffer for directory
  2661.     move.l    A1,8(A0)
  2662.     move.b    #':',_Drive(A5)        ; Say current directory
  2663.     rts
  2664.  
  2665. *****************************
  2666. *
  2667. * Display Arp-file-requester.
  2668. *
  2669. * Inputs: none
  2670. * Results: none
  2671. *
  2672.  
  2673. _ArpLoad
  2674.     movem.l    D2-D7/A2-A6,-(sp)    ; <-I don't trust Arp
  2675.     lea    _ArpReqStruc(A5),A0    ; Address structure
  2676.     tst.b    _LoadFlag(A5)        ; Shall we load a file?
  2677.     bne.s    1$            ; Yes...
  2678.     lea    _SaveTitle(pc),A1    ; Otherwise set saving-title
  2679.     move.l    A1,(A0)
  2680.     bra.s    2$
  2681. 1$
  2682.     lea    _AWTitle(pc),A1        ; Title (Load)
  2683.     move.l    A1,(A0)
  2684. 2$
  2685.     movea.l    _ArpBase(A5),A6
  2686.     lea    _ArpReqStruc(A5),A0    ; Structure of requester
  2687.     jsr    _LVOArpFileRequest(A6)
  2688.     movem.l    (sp)+,D2-D7/A2-A6
  2689.     rts
  2690.  
  2691. ***************************************************
  2692. *
  2693. * Merge volume's/directory's name with file's name.
  2694. *
  2695. * Inputs: none
  2696. * Results: none
  2697. *
  2698.  
  2699. _GetFileName
  2700.     move.l    A2,-(sp)
  2701.     lea    _Drive(A5),A0
  2702.     lea    _File(A5),A1
  2703.     lea    _FileName(A5),A2
  2704. 1$
  2705.     tst.b    (A0)
  2706.     beq.s    2$
  2707.     move.b    (A0)+,(A2)+
  2708.     bra.s    1$
  2709. 2$
  2710.     tst.b    -1(A0)
  2711.     beq.s    3$
  2712.     cmpi.b    #':',-1(A0)
  2713.     beq.s    3$
  2714.     cmpi.b    #'/',-1(A0)
  2715.     beq.s    3$
  2716.     move.b    #'/',(A2)+
  2717. 3$
  2718.     move.b    (A1)+,(A2)+
  2719.     tst.b    -1(A1)
  2720.     bne.s    3$
  2721.     movea.l    (sp)+,A2
  2722.     rts
  2723.  
  2724. ***********************************
  2725. *
  2726. * Startup to display filerequester.
  2727. *
  2728. * Inputs: none
  2729. * Results: D0 == NULL upon error
  2730. *
  2731.  
  2732. *------------------------------------------------------
  2733. _GetFile
  2734.     cmpi.b    #-1,_ReqFlag(A5)    ; No requester at all?
  2735.     beq.s    .NoReqAtAll
  2736.     cmpi.b    #1,_ReqFlag(A5)        ; ReqTools-Load-routine?
  2737.     bne.s    .ArpMustLoad        ; No, Arp
  2738.     bsr.w    _ReqLoad        ; else ReqTools-file-requester
  2739.     tst.l    D0            ; Ok?
  2740.     beq.s    .NoFileGet        ; No, no file selected!
  2741.     bsr.s    _GetFileName        ; Combinate filename in dos-convention
  2742.     moveq    #$11,D0            ; Return ok
  2743.     rts
  2744.  
  2745. .ArpMustLoad
  2746.     bsr.w    _ArpLoad        ; Arp-file-requester
  2747.     tst.l    D0            ; No file?
  2748.     beq.s    .NoFileGet
  2749.     bsr.s    _GetFileName        ; Combinate filename in dos-convention
  2750.     moveq    #$11,D0            ; Return ok.
  2751.     rts
  2752. .NoReqAtAll
  2753.     moveq    #-1,D0            ; Damned, no requester at all!
  2754.     rts
  2755. .NoFileGet                ; No file was selected
  2756.     rts
  2757.  
  2758. ***************************************************************
  2759. *
  2760. * Complex routine which loads a file, sets up needed parameters.
  2761. *
  2762. * Inputs: none
  2763. * Results: D0 - NULL upon error
  2764. *
  2765.  
  2766. _ReadFile
  2767.     movea.l    _SysBase(A5),A6
  2768.     movea.l    _TextPtr(A5),A1
  2769.     move.l    _BufferSize(A5),D0
  2770.     beq.s    1$
  2771.     jsr    _LVOFreeMem(A6)        ; Free last pointed text
  2772.     clr.l    _BufferSize(A5)
  2773.     clr.l    _TextPtr(A5)
  2774.     clr.l    _Line(A5)
  2775.     clr.l    _SearchStrPtr(A5)    ; Don't access what isn't valid....
  2776.     clr.l    _SearchStrLen(A5)
  2777. 1$
  2778.     movea.l    _DOSBase(A5),A6
  2779.     lea    _FileName(A5),A0
  2780.     move.l    A0,D1
  2781.     moveq    #ACCESS_READ,D2        ; Mode: READ
  2782.     jsr    _LVOLock(A6)
  2783.     move.l    D0,_LockSave(A5)    ; Save lock of file
  2784.     beq.w    .LockErr
  2785.     move.l    _LockSave(A5),D1    ; The key to the file
  2786.     lea    _FIB(A5),A0        ; Address FileInfoBlock
  2787.     move.l    A0,D2            ; into D2
  2788.     jsr    _LVOExamine(A6)        ; Get file's status
  2789.     lea    _FIB(A5),A0        ; Address FileInfoBlock
  2790.     tst.l    (A0)            ; Was function Examine successful?
  2791.     beq.w    .ExamineErr        ; No, oh boy
  2792.     move.l    _LockSave(A5),D1    ; Key to D1
  2793.     jsr    _LVOUnLock(A6)        ; Free key
  2794.     lea    _FIB(A5),A0        ; Address FileInfoBlock
  2795.     tst.l    4(A0)            ; Dir or file?
  2796.     bpl.w    .ItsADir        ; Too bad, it's a dir
  2797.     move.l    124(A0),_FileSize(A5)    ; Get size in bytes of file
  2798.     move.l    124(A0),D0        ; also into D0
  2799.     beq.w    .FileEmpty        ; If the file is empty
  2800.     addq.l    #8,D0            ; else filelength plus 8 bytes
  2801.     bsr.w    _MakeCountEven        ; Align count
  2802.  
  2803.     move.l    D0,_BufferSize(A5)    ; Save extended count
  2804.  
  2805.     movea.l    _SysBase(A5),A6
  2806.     move.l    #MEMF_PUBLIC|MEMF_CLEAR,D1
  2807.     jsr    _LVOAllocMem(A6)    ; Mem demand
  2808.     move.l    D0,_TextPtr(A5)        ; Save address allocated memory
  2809.     beq.w    .AllocError        ; Upon error...
  2810.  
  2811.     movea.l    _DOSBase(A5),A6
  2812.     lea    _FileName(A5),A0    ; Address string (file's name)
  2813.     move.l    A0,D1            ; into D1
  2814.     move.l    #MODE_OLDFILE,D2    ; Mode = OLD
  2815.     jsr    _LVOOpen(A6)        ; Open file
  2816.     move.l    D0,_FileHandle(A5)    ; Save handle
  2817.     beq.s    .FileOpenErr        ; Upon error
  2818.     move.l    _FileHandle(A5),D1
  2819.     movea.l    _TextPtr(A5),A0        ; Address buffer for file to read in
  2820.     move.w    #$200A,(A0)+        ; Write first a Blank and a LineFeed
  2821.     move.l    A0,D2            ; Current address into D2
  2822.     move.l    _FileSize(A5),D3    ; Length file        
  2823.     jsr    _LVORead(A6)        ; Read file into buffer
  2824.     tst.l    D0
  2825.     bmi.s    .ReadError        ; Upon error
  2826.     bsr.s    .CloseFile        ; Close file
  2827.     movea.l    _TextPtr(A5),A0
  2828.     move.l    _FileSize(A5),D0
  2829.     cmpi.b    #10,1(A0,D0.l)
  2830.     beq.s    .ok
  2831.     move.b    #10,2(A0,D0.l)        ; LineFeed (end)
  2832. .ok
  2833.     moveq    #$11,D0            ; Say ok
  2834.     rts                ; and back
  2835.  
  2836. .ReadError
  2837.     movea.l    _DOSBase(A5),A6        ; - Because of bug in DOS v39
  2838. *                      we have to restore DOSBase....
  2839.     jsr    _LVOIoErr(A6)        ; Get the error
  2840.     bsr.w    _SetError        ; Set the error
  2841.     bsr.s    .CloseFile        ; Close file
  2842.     bsr.w    _FreeFile        ; Free allocated memory
  2843.     lea    _ReadErrTxt(pc),A0    ; Errorstring
  2844.     bsr.w    _DisplayError        ; Tell user...
  2845.     moveq    #0,D0
  2846.     rts
  2847.  
  2848. .CloseFile
  2849.     move.l    A6,-(sp)
  2850.     movea.l    _DOSBase(A5),A6
  2851.     move.l    _FileHandle(A5),D1
  2852.     jsr    _LVOClose(A6)
  2853.     movea.l    (sp)+,A6
  2854.     rts
  2855.  
  2856. .FileOpenErr
  2857.     jsr    _LVOIoErr(A6)        ; Get the error
  2858.     bsr.w    _SetError        ; and set it
  2859.     bsr.w    _FreeFile        ; Free memory
  2860.     lea    _OpenFileErrTxt(pc),A0    ; Errorstring
  2861.     bsr.w    _DisplayError        ; Tell user...
  2862.     moveq    #0,D0
  2863.     rts
  2864.  
  2865. .AllocError
  2866.     movea.l    _DOSBase(A5),A6        ; Get errorcode (103)
  2867.     jsr    _LVOIoErr(A6)
  2868.     bsr.w    _SetError        ; Set the errorcode
  2869.     lea    _AllocErrTxt(pc),A0    ; Errorstring
  2870.     bsr.w    _DisplayError        ; Tell user...
  2871.     moveq    #0,D0
  2872.     rts
  2873.  
  2874. .FileEmpty
  2875.     lea    _EmptyTxt(pc),A0    ; Errorstring
  2876.     bsr.w    _DisplayError        ; Tell user...
  2877.     moveq    #0,D0
  2878.     rts
  2879.  
  2880. .ItsADir
  2881.     lea    _DirTxt(pc),A0        ; Errorstring
  2882.     bsr.w    _DisplayError        ; Tell user...
  2883.     tst.l    D0
  2884.     beq.s    3$            ; If user said abort...
  2885.  
  2886.     bsr.w    OpenReq            ; Initialize requester (Arp or Reqtools)
  2887.     cmpi.b    #-1,_ReqFlag(A5)    ; No requester at all?
  2888.     beq.s    3$            ; If so...
  2889.  
  2890.     lea    _FileName(A5),A0    ; Name of directory
  2891.     move.l    A0,D1
  2892.     moveq    #ACCESS_READ,D2        ; Mode: Read
  2893.     movea.l    _DOSBase(A5),A6
  2894.     jsr    _LVOLock(A6)        ; Lock Directory
  2895.     move.l    D0,D2            ; Lock into D2
  2896.     beq.s    3$            ; If we can't get lock
  2897.  
  2898. *    move.l    D0,D0            ; Lock
  2899.     lea    _Drive(A5),A0        ; Buffer for name from Lock
  2900.     lea    _FIB(A5),A1        ; FileInfoBlock
  2901.     bsr.w    _GetNameFromLock    ; Get complete name of Lock, e.g. "DF0:pics/brushes/"
  2902.  
  2903.     move.l    D2,D1            ; Lock
  2904.     movea.l    _DOSBase(A5),A6
  2905.     jsr    _LVOUnLock(A6)        ; Free Lock
  2906.  
  2907.     cmpi.b    #1,_ReqFlag(A5)        ; Reqtools-requester?
  2908.     bne.s    2$            ; If not, it must be arp (for now)
  2909.     clr.l    -(sp)            ; Local TagItems....
  2910.     clr.l    -(sp)            ;   TAG_DONE
  2911.     clr.l    -(sp)            ;   ti_DATA (pointer to directory string)
  2912.     clr.l    -(sp)            ;   ti_TAG (RTFI_Dir)
  2913.     movea.l    sp,A0            ; As TagList...
  2914.     move.l    #$80000000+50,(A0)    ; Tell: change directory (RTFI_Dir)
  2915.     lea    _Drive(A5),A1        ; Address new directory string
  2916.     move.l    A1,4(A0)        ;  as pointer for ReqTools
  2917.     movea.l    _ReqPtr(A5),A1        ; Reqtools-Requester-Record
  2918.     movea.l    _ReqToolsBase(A5),A6
  2919.     jsr    _LVOrtChangeReqAttrA(A6) ; Change directory to overgiven one
  2920.     lea    16(sp),sp        ; Correct stack
  2921. 2$
  2922.     st.b    _LoadFlag(A5)        ; Tell: we're going to "load" a file
  2923.     bsr.w    _GetFile        ; Get filename (display requester)
  2924.     tst.l    D0            ; Nothing picked?
  2925.     beq.s    3$            ; Hard error not possible, only "no file chosen"
  2926.     bra.w    _ReadFile        ; Again, try to load the file...
  2927. 3$
  2928.     moveq    #0,D0            ; Tell, didn't fit to read file
  2929.     rts
  2930.  
  2931. .ExamineErr                ; Should never occur
  2932.     jsr    _LVOIoErr(A6)
  2933.     bsr.w    _SetError
  2934.     move.l    _LockSave(A5),D1    ; Key
  2935.     jsr    _LVOUnLock(A6)        ; We allow other people to modify that file...
  2936.     lea    _ExamineErrTxt(pc),A0
  2937.     bsr.w    _DisplayError
  2938.     moveq    #0,D0
  2939.     rts
  2940.  
  2941. .LockErr
  2942.     jsr    _LVOIoErr(A6)
  2943.     bsr.w    _SetError
  2944.     lea    _LockErrTxt(pc),A0
  2945.     bsr.w    _DisplayError
  2946. *
  2947. ** Now we do something smart....
  2948. *
  2949. ** When the user calls us directly from CLI/Shell with the path and file and
  2950. ** the file he/she wants to displayed can't be locked because he/she entered
  2951. ** an invalid path or filename, we search as long as the path is valid, example:
  2952. *
  2953. **   1> viewer hd2:dtp/pictures/btush/aga/lamp.bsh   <- incorrect
  2954. ** was chosen by the user, but the valid name is:
  2955. **   1> viewer hd2:dtp/pictures/brush/aga/lamp.bsh   <- correct
  2956. *
  2957. ** The only thing we now have to do is to search backward if the string is valid, i.e.
  2958. ** if the directory can be locked:
  2959. *
  2960. ** (--------) "hd2:dtp/pictures/btush/aga/lamp.bsh" - caused the lock-error
  2961. ** (1st loop) "hd2:dtp/pictures/btush/aga/"        - isn't still valid
  2962. ** (2nd loop) "hd2:dtp/pictures/btush/"            - isn't still valid
  2963. ** (3rd loop) "hd2:dtp/pictures/"            - valid!!!
  2964. *
  2965. ** Now we copy this valid string into the buffer for the "_Drive" and depending
  2966. ** of the requester-modules (ReqTools/Arp) we setup the necessary things.
  2967. ** That's all!
  2968. *
  2969.  
  2970. * Let's say the the volume isn't available (e.g. "DF7:"), then it makes no sense
  2971. * to execute the following routine (if we can't access the disk, we can't access
  2972. * the directories...).
  2973.     move.l    _errno(A5),D0        ; Get current IoErr-errornumber
  2974.     cmpi.l    #ERROR_DEVICE_NOT_MOUNTED,D0
  2975.     beq.w    .NotFound
  2976.     cmpi.l    #ERROR_NOT_A_DOS_DISK,D0
  2977.     beq.w    .NotFound
  2978.     cmpi.l    #ERROR_NO_DISK,D0
  2979.     beq.w    .NotFound
  2980.     cmpi.l    #ERROR_OBJECT_IN_USE,D0 ; Does somebody format the drive?
  2981.     beq.w    .NotFound
  2982.  
  2983. .FindValidDir
  2984.     lea    _FileName(A5),A0    ; Address string of filename
  2985.     movea.l    A0,A1            ; Startaddress of string also in A1
  2986.     moveq    #-1,D0            ; Dummy-counter
  2987. .FindStrEnd
  2988.     tst.b    (A0)+            ; Find string end
  2989.     dbeq    D0,.FindStrEnd
  2990.     subq.l    #1,A0            ; Pointer to NULL-byte (terminator) of string
  2991.  
  2992. .Find
  2993.     cmpa.l    A0,A1            ; Original same as decreased address?, i.e.
  2994.     beq.w    .NotFound        ; stringstart found - then no trailing was found
  2995.     cmpi.b    #':',(A0)        ; Else...
  2996.     beq.s    .Found
  2997.     cmpi.b    #'/',(A0)
  2998.     beq.s    .Found
  2999.     subq.l    #1,A0
  3000.     dbf    D0,.Find        ; So long not found...
  3001.  
  3002. .Found
  3003.     move.b    (A0),D1            ; Remember last valid char
  3004.     clr.b    (A0)            ; Last valid char is the ":" or the "/", so
  3005. *                      terminate string (_FileName), i.e. replace ":"
  3006. *                      or "/" through NULL-byte - otherwise at next loop
  3007. *                      we found the same char (never ending loop)
  3008. *                      "Viewer Hang Up"
  3009.     move.l    A2,-(sp)
  3010.     lea    _Drive(A5),A2        ; Stringbuffer for volume/directory
  3011. .Cpy
  3012.     cmpa.l    A1,A0            ; Copy all chars until we reach the right address
  3013.     beq.s    .Done
  3014.     move.b    (A1)+,(A2)+
  3015.     dbf    D0,.Cpy
  3016.  
  3017. .Done
  3018.     move.b    D1,(A2)+        ; Copy also remembered trailing
  3019.     clr.b    (A2)            ; Terminate new string
  3020.     movea.l    (sp)+,A2
  3021.  
  3022.     lea    _Drive(A5),A0
  3023.     move.l    A0,D1
  3024.     moveq    #ACCESS_READ,D2
  3025.     movea.l    _DOSBase(A5),A6
  3026.     jsr    _LVOLock(A6)        ; Can we lock the directory (or volume)
  3027.     move.l    D0,D1
  3028.     beq.s    .FindValidDir        ; If not, try again...
  3029.     jsr    _LVOUnLock(A6)        ; Else give back not more needed lock
  3030.  
  3031.     bsr.w    OpenReq            ; Initialize requester (Arp or Reqtools)
  3032.     cmpi.b    #-1,_ReqFlag(A5)    ; No requester at all?
  3033.     beq.s    .NotFound        ; If so...
  3034.  
  3035.     cmpi.b    #1,_ReqFlag(A5)        ; Reqtools-requester?
  3036.     bne.s    .NotFound        ; If not, it must be arp (for now)
  3037.     clr.l    -(sp)            ; Local TagItems....
  3038.     clr.l    -(sp)            ;   TAG_DONE
  3039.     clr.l    -(sp)            ;   ti_DATA (pointer to directory string)
  3040.     clr.l    -(sp)            ;   ti_TAG (RTFI_Dir)
  3041.     movea.l    sp,A0            ; As TagList...
  3042.     move.l    #$80000000+50,(A0)    ; Tell: change directory (RTFI_Dir)
  3043.     lea    _Drive(A5),A1        ; Address new directory string
  3044.     move.l    A1,4(A0)        ;  as pointer for ReqTools
  3045.     movea.l    _ReqPtr(A5),A1        ; Reqtools-Requester-Record
  3046.     movea.l    _ReqToolsBase(A5),A6
  3047.     jsr    _LVOrtChangeReqAttrA(A6) ; Change directory to overgiven one
  3048.     lea    16(sp),sp        ; Correct stack
  3049.  
  3050. .NotFound
  3051.     moveq    #0,D0            ; Indicates no file was loaded...
  3052.     rts
  3053.  
  3054. ***************************************************************
  3055. *
  3056. *
  3057. * Inputs: D0 - Lock of directory
  3058. *      A0 - buffer for name of merged volume/directory name
  3059. *      A1 - buffer for FileInfoBlock (272 byte here)
  3060. *
  3061.  
  3062. _GetNameFromLock
  3063.     movem.l    D2/D6-D7/A3-A4,-(sp)
  3064.  
  3065.     movea.l    _DOSBase(A5),A6
  3066.  
  3067.     move.l    D0,D6            ; Lock
  3068.     beq.s    .ErrorEnd
  3069.  
  3070.     move.l    A0,A3            ; Buffer
  3071.     move.l    A1,A4            ; FIB
  3072.  
  3073.     moveq    #1,D7            ; Counter
  3074.     move.l    D6,-(sp)        ; Lock onto stack
  3075.  
  3076. .Parent
  3077.     move.l    D6,D1            ; Lock
  3078.     jsr    _LVOParentDir(A6)
  3079.     tst.l    D0            ; Previous dir
  3080.     beq.s    .Volume            ; Home-directory e.g. DF0
  3081.     move.l    D0,-(sp)        ; Lock passed onto stack
  3082.     addq.l    #1,D7            ; 1 more Lock
  3083.     move.l    D0,D6            ; Save this Lock
  3084.     bra.s    .Parent            ; So long home-directory not found...
  3085. .Volume
  3086.     move.l    (sp)+,D1        ; Lock
  3087.     bsr.s    .ExamineDir        ; Get those infos
  3088.     bsr.s    .CopyName        ; Copy volume's name
  3089.     move.b    #':',-1(A3)        ; Set colon
  3090.     subq.l    #1,D7            ; 1 less argument
  3091.     beq.s    .FoundThem        ; If all...
  3092. .Drawer
  3093.     move.l    (sp)+,D1        ; Lock
  3094.     bsr.s    .ExamineDir        ; Get the infos
  3095.     bsr.s    .CopyName        ; Copy drawer's name
  3096.     move.b    #'/',-1(A3)        ; Set trailing
  3097.     subq.l    #1,D7            ; 1 less argument
  3098.     beq.s    .FoundThem
  3099.     bra.s    .Drawer
  3100.  
  3101. .FoundThem
  3102.     clr.b    (A3)
  3103.     moveq    #0,D0            ; Indicates no error
  3104. .end
  3105.     movem.l    (sp)+,D2/D6-D7/A3-A4
  3106.     rts
  3107.  
  3108. .ErrorEnd
  3109.     moveq    #-1,D0
  3110.     bra.s    .end
  3111.  
  3112.  
  3113. .ExamineDir
  3114.     move.l    A4,D2        ; FIB
  3115.     jmp    _LVOExamine(A6)
  3116.  
  3117. .CopyName
  3118.     move.l    A4,A0        ; FIB
  3119.     addq.l    #8,A0        ; Lock
  3120. .CopyIt
  3121.     move.b    (A0)+,(A3)+
  3122.     bne.s    .CopyIt
  3123.     rts
  3124.  
  3125. ************************
  3126. *
  3127. * Free allocated data...
  3128. *
  3129. * Inputs: none
  3130. * Results: none
  3131.  
  3132. _FreeFile
  3133.     move.l    A6,-(sp)
  3134.     movea.l    _SysBase(A5),A6
  3135.     movea.l    _TextPtr(A5),A1
  3136.     move.l    _BufferSize(A5),D0
  3137.     jsr    _LVOFreeMem(A6)
  3138.     clr.l    _BufferSize(A5)        ; Important!!!
  3139.     clr.l    _TextPtr(A5)        ; Important!!!
  3140.     clr.l    _SearchStrPtr(A5)
  3141.     clr.l    _SearchStrLen(A5)
  3142.     movea.l    (sp)+,A6
  3143.     rts
  3144.  
  3145. ******************************************
  3146. *
  3147. * File is an object module or a binary file.
  3148. * Called out of "CheckFile()
  3149. *
  3150. * Inputs: none
  3151. * Results: none
  3152. *
  3153.  
  3154. *------------------------------------------------------
  3155. _WrongFileType
  3156.     tst.b    _NoWarnFlag(A5)
  3157.     bne.s    1$
  3158.     bsr.w    _GetConvertedSize
  3159.     move.l    D0,-(sp)
  3160.     pea    _ObjectFileTxt(pc)    ; Display the error
  3161.     bsr.w    _FmtDisplay
  3162.     addq.l    #8,sp
  3163.     tst.l    D0            ; Right mouse button?
  3164.     beq.s    0$            ; Yes
  3165. 1$
  3166.     bra.w    _ConvertBinary
  3167. 0$
  3168.     addq.l    #4,sp            ; Remove "bsr"
  3169.     bsr.s    _FreeFile
  3170.     bra.w    _Loop
  3171.  
  3172. _BinaryFile
  3173.     tst.b    _NoWarnFlag(A5)
  3174.     bne.s    1$
  3175.     bsr.w    _GetConvertedSize
  3176.     move.l    D0,-(sp)
  3177.     pea    _BinaryFileTxt(pc)
  3178.     bsr.w    _FmtDisplay
  3179.     addq.l    #8,sp
  3180.     tst.l    D0            ; Right mouse button?
  3181.     beq.s    0$            ; Yes
  3182. 1$
  3183.     bra.w    _ConvertBinary
  3184. 0$
  3185.     addq.l    #4,sp            ; Remove "bsr"
  3186.     bsr.s    _FreeFile
  3187.     bra.w    _Loop
  3188.  
  3189. **********************************************
  3190. *
  3191. * Check if the file is an ascii-text file,
  3192. *  a powerpacker.library packed ascii-textfile,
  3193. *  a picture,
  3194. *  a powerpacker.library packed picture or -what is
  3195. * not truely displayable
  3196. *  an object file,
  3197. *  a binary file (like ANIMs).
  3198. *
  3199. * Inputs: none
  3200. * Results: none
  3201. *
  3202.  
  3203. _CheckFile
  3204.     movea.l    _TextPtr(A5),A0        ; Source in memory
  3205.     addq.l    #2,A0            ; Overread #$200A
  3206.     cmpi.l    #'PP20',(A0)        ; PowerPacker.library packed?
  3207.     beq.w    _Decrunch
  3208.     cmpi.l    #$000003F3,(A0)        ; Hunk header?
  3209.     beq.s    _WrongFileType        ; If so ...
  3210.     cmpi.l    #'CAT ',(A0)
  3211.     beq.w    _LoadFCFile
  3212.     cmpi.l    #'LIST',(A0)
  3213.     beq.w    _LoadFCFile
  3214.     cmpi.l    #'FORM',(A0)        ; IFF-file?
  3215.     bne.s    _CheckFile_1        ; If not...
  3216.     cmpi.l    #'ILBM',8(A0)        ; Picture?
  3217.     beq.w    _LoadScreen        ; If so...
  3218.     cmpi.l    #'ACBM',8(A0)        ; Picture?
  3219.     beq.w    _LoadScreen        ; If so...
  3220.     cmpi.l    #'SWRT',8(A0)        ; FinalCopy document?
  3221.     beq.w    _LoadFCFile
  3222.     cmpi.l    #'FTXT',8(A0)        ; IFF-text document?
  3223.     beq.w    _LoadFCFile
  3224.     cmpi.l    #'WOWO',8(A0)        ; WordWoorth text document?
  3225.     beq.w    _LoadFCFile
  3226.     cmpi.l    #'8SVX',8(A0)        ; Audio file?
  3227.     beq.w    _LoadAudio
  3228.  
  3229. *
  3230. ** Test if file contains binary datas...
  3231. *
  3232. _CheckFile_1
  3233.     move.l    #255,D0            ; Counter
  3234.     move.l    _FileSize(A5),D1    ; Old filelength
  3235.     cmp.l    D0,D1            ; Compare
  3236.     ble.s    SetLittleFileSize    ; Smaller than 256!
  3237.     bra.s    Test_If_Binary        ; Else test 256 bytes
  3238. SetLittleFileSize:
  3239.     move.b    D1,D0            ; As much bytes file is large (smaller than 256)
  3240.     subq.b    #1,D0            ; Minus 1 - because of DBF
  3241.  
  3242. Test_If_Binary
  3243.     move.b    (A0),D1
  3244.     cmpi.b    #$9B,D1
  3245.     beq.s    .Ok
  3246.     cmpi.b    #127,D1
  3247.     bls.s    .Ok1
  3248.     cmpi.b    #159,D1
  3249.     bls.w    _BinaryFile
  3250.     bra.s    .Ok
  3251. .Ok1
  3252.     cmpi.b    #31,D1
  3253.     bhi.s    .Ok
  3254.     cmpi.b    #6,D1
  3255.     bls.w    _BinaryFile
  3256. .Ok2
  3257.     cmpi.b    #15,D1
  3258.     beq.w    .Ok
  3259.     cmpi.b    #16,D1
  3260.     beq.w    .Ok
  3261.     cmpi.b    #27,D1
  3262.     beq.s    .Ok
  3263.     bhi.w    _BinaryFile
  3264.     cmpi.b    #15,D1
  3265.     bhi.w    _BinaryFile
  3266. .Ok
  3267.     addq.l    #1,A0            ; One char further
  3268.     dbf    D0,Test_If_Binary    ; All bytes tested?
  3269.     rts
  3270.  
  3271. *******************************************
  3272. *
  3273. * Decrunch startup for PP20 crunched files.
  3274. *
  3275. * Inputs: none
  3276. * Results: none
  3277. *
  3278.  
  3279. _Decrunch
  3280.     movea.l    _TextPtr(A5),A0        ; Source
  3281.     addq.l    #2,A0            ; Overread #$200A
  3282.     move.l    _FileSize(A5),D0    ; Length file
  3283.     lea    -4(A0,D0.l),A0        ; Pointer to last longword of crunched file
  3284.  
  3285.     move.l    (A0),D0            ; Only upper 24 bits are intresting
  3286.     lsr.l    #8,D0            ; Skip crunch-info
  3287.     move.l    D0,_UPFSize(A5)        ; UnPackedFileSize
  3288.     addi.l    #12,D0            ; Plus 8 bytes :-) Nico François
  3289. *                      plus 4 :-) Jörg van de Loo
  3290.     bsr.w    _MakeCountEven        ; Align size
  3291.     move.l    D0,_IncSize(A5)        ; Increased file size
  3292.  
  3293.     tst.b    _NoWarnFlag(A5)        ; Allowed to display warning?
  3294.     bne.s    1$
  3295.     move.l    _UPFSize(A5),D0        ; Length file
  3296.     move.l    D0,-(sp)
  3297.     pea    _PPCrunchTxt(pc)    ; Tell user
  3298.     bsr.w    _FmtDisplay
  3299.     addq.l    #8,sp
  3300.     tst.l    D0            ; Right mousebtton?
  3301.     beq.w    _BinaryFile        ; If so...
  3302. 1$
  3303.     move.l    _IncSize(A5),D0
  3304.     move.l    #MEMF_PUBLIC|MEMF_CLEAR,D1
  3305.     movea.l    _SysBase(A5),A6
  3306.     jsr    _LVOAllocMem(A6)
  3307.     move.l    D0,_DecrunchAddr(A5)    ; Buffer for decrunched datas
  3308.     beq.s    .DecrunchError
  3309.  
  3310.     movea.l    _TextPtr(A5),A0        ; = Decrunch address
  3311.     addq.l    #2,A0            ; Overread #$200A
  3312.     move.l    _FileSize(A5),D0    ; Length crunched file
  3313.     movea.l    _DecrunchAddr(A5),A1    ; Address for uncrunched file
  3314.     move.w    #$200A,(A1)+        ; (but write down Blank and LineFeed as first
  3315. *                      entries, important for the ascii-text-viewer).
  3316.  
  3317.     bsr.s    _PPDecrunch        ; Decrunch datas
  3318.  
  3319.     movea.l    _DecrunchAddr(A5),A0
  3320.     move.l    _UPFSize(A5),D0
  3321.     cmpi.b    #10,1(A0,D0.l)
  3322.     beq.s    .CrunchOk
  3323.     move.b    #10,2(A0,D0.l)        ; Write LineFeed at end of uncrunched file
  3324. .CrunchOk
  3325.     bsr.w    _FreeFile        ; Free not needed thing
  3326.  
  3327.     move.l    _DecrunchAddr(A5),_TextPtr(A5)    ; Copy pointer
  3328.     move.l    _IncSize(A5),_BufferSize(A5)    ; Copy size
  3329.     move.l    _UPFSize(A5),_FileSize(A5)    ; Copy size
  3330.  
  3331.     bra.w    _CheckFile        ; Check unpacked file
  3332.  
  3333. .DecrunchError
  3334.     lea    _DecrunchErrTxt(pc),A0
  3335.     bsr.w    _DisplayError
  3336.     bsr.w    _FreeFile        ; see above
  3337.     addq.l    #4,sp            ; Remove "bsr" CheckFile
  3338.     bra.w    _Loop
  3339.  
  3340.  
  3341. ***********************************
  3342. *
  3343. * Copyright Nico François
  3344. *
  3345.  
  3346. _PPDecrunch
  3347.     movem.l    D1-D3/D5-D7/A2-A3,-(sp)
  3348.     bsr.s    .PowerPackerDecruncher
  3349.     movem.l    (sp)+,D1-D3/D5-D7/A2-A3
  3350.     rts
  3351. .PowerPackerDecruncher
  3352.     lea    4(A0),A3
  3353.     lea    0(A0,D0.l),A0
  3354.     movea.l    A1,A2
  3355.     moveq    #3,D6
  3356.     moveq    #7,D7
  3357.     moveq    #1,D5
  3358.     movea.l    A2,A1
  3359.     move.l    -(A0),D1
  3360.     tst.b    D1
  3361.     beq.s    1$
  3362.     bsr.s    5$
  3363.     subq.b    #1,D1
  3364.     lsr.l    D1,D5
  3365. 1$
  3366.     lsr.l    #8,D1
  3367.     add.l    D1,A2
  3368. 2$
  3369.  
  3370.     bsr.s    5$
  3371.     bcs.s    12$
  3372.     moveq    #0,D2
  3373. 3$
  3374.     moveq    #1,D0
  3375.     bsr.s    8$
  3376.     add.w    D1,D2
  3377.     cmp.w    D6,D1
  3378.     beq.s    3$
  3379. 4$
  3380.     moveq    #7,D0
  3381.     bsr.s    8$
  3382.     move.b    D1,-(A2)
  3383.     dbf    D2,4$
  3384.     cmp.l    A2,A1
  3385.     bcs.s    12$
  3386.     rts
  3387. 5$
  3388.     lsr.l    #1,D5
  3389.     beq.s    6$
  3390.     rts
  3391. 6$
  3392.     move.l    -(A0),D5
  3393.     roxr.l    #1,D5
  3394.     rts
  3395. 7$
  3396.     subq.w    #1,D0
  3397. 8$
  3398.     moveq    #0,D1
  3399. 9$
  3400.     lsr.l    #1,D5
  3401.     beq.s    11$
  3402. 10$
  3403.     roxl.l    #1,D1
  3404.     dbf    D0,9$
  3405.     rts
  3406. 11$
  3407.     move.l    -(A0),D5
  3408.     roxr.l    #1,D5
  3409.     bra.s    10$
  3410. 12$
  3411.     moveq    #1,D0
  3412.     bsr.s    8$
  3413.     moveq    #0,D0
  3414.     move.b    0(A3,D1.w),D0
  3415.     move.w    D1,D2
  3416.     cmp.w    D6,D2
  3417.     bne.s    15$
  3418.     bsr.s    5$
  3419.     bcs.s    13$
  3420.     moveq    #7,D0
  3421. 13$
  3422.     bsr.s    7$
  3423.     move.w    D1,D3
  3424. 14$
  3425.     moveq    #2,D0
  3426.     bsr.s    8$
  3427.     add.w    D1,D2
  3428.     cmp.w    D7,D1
  3429.     beq.s    14$
  3430.     bra.s    16$
  3431. 15$
  3432.     bsr.s    7$
  3433.     move.w    D1,D3
  3434. 16$
  3435.     addq.w    #1,D2
  3436. 17$
  3437.     move.b    0(A2,D3.w),-(A2)
  3438.     dbf    D2,17$
  3439.     cmpa.l    A2,A1
  3440.     bcs.s    2$
  3441.     rts
  3442.  
  3443. ***********************************************
  3444. *
  3445. * Attempt to find a display ID which does match
  3446. * with the settings of the computed image.
  3447. *
  3448. * Needed for the Picasso96 software package.
  3449. *
  3450. * Should also works with other by me unknown
  3451. * 3rd party software packages.
  3452. *
  3453.  
  3454. _GetMode
  3455.     movem.l    D2-D3/D5-D7/A2,-(sp)
  3456.  
  3457.     moveq    #0,D5
  3458.     move.b    D0,D5
  3459.  
  3460.     cmpi.w    #1360,_Width(A5)    ; Maximum widtn for a 24 bit display (CV3D)
  3461.     bls.s    1$
  3462.     cmpi.b    #16,D5            ; If not 24 bitplanes deep
  3463.     bls.s    1$
  3464.     moveq    #16,D5            ; Else, force screen from 24 to 16 bitplanes
  3465. 1$
  3466.     moveq    #0,D7            ; Error code or Monitor ID
  3467.  
  3468.     movea.l    _SysBase(A5),A6
  3469.     move.l    #128,D0            ; Buffer for DimensionInfo (di)
  3470.     move.l    #MEMF_CLEAR,D1
  3471.     jsr    _LVOAllocMem(A6)
  3472.     tst.l    D0
  3473.     beq.w    .end
  3474.     movea.l    D0,A2            ; DimensionInfo
  3475.  
  3476.     movea.l    _GfxBase(A5),A6
  3477.     moveq    #INVALID_ID,D6        ; Get really first ID!
  3478.  
  3479.     cmpi.b    #7,D5
  3480.     bhi.s    .loop
  3481.     moveq    #8,D5            ; Less than 8 bitplanes -> now 8 bitplanes!
  3482.  
  3483. .loop
  3484.     move.l    D6,D0            ; Last monitor ID
  3485.     jsr    _LVONextDisplayInfo(A6)
  3486.     cmpi.l    #INVALID_ID,D0        ; End of monitor ID list?
  3487.     beq.s    .notfound
  3488.  
  3489.     move.l    D0,D6            ; Monitor ID
  3490.     andi.l    #$FFF00000,D0        ; Only non native AMIGA modes allowed!
  3491.     beq.s    .loop
  3492.     cmpi.l    #$FFF00000,D0        ; Test monitor? - ignore!
  3493.     beq.s    .loop
  3494.  
  3495.     suba.l    A0,A0            ; handle = 0
  3496.     movea.l    A2,A1            ; di
  3497.     move.l    #128,D0            ; size of buffer
  3498.     move.l    #DTAG_DIMS,D1        ; TAG
  3499.     move.l    D6,D2            ; Monitor ID
  3500.     jsr    _LVOGetDisplayInfoData(A6)
  3501.     tst.l    D0
  3502.     beq.s    .loop            ; If it failed...
  3503.  
  3504. *    cmpi.w    #15,dim_MaxDepth(A2)    ; Ignore 15bit modes!
  3505. *    beq.s    .loop
  3506.  
  3507.     cmp.w    #16,D5            ; More than 16 bitplanes?
  3508.     bls.s    .normalDepthCheck    ; If not, a normal depth check
  3509.  
  3510.     cmp.w    #23,dim_MaxDepth(A2)    ; Can we display 24 bitplanes at a time with this monitor?
  3511.     bls.s    .loop            ; No...
  3512.  
  3513.     bra.s    .dimCheck        ; Yes...
  3514.  
  3515. .normalDepthCheck
  3516.     cmp.w    dim_MaxDepth(A2),D5    ; Right depth?
  3517.     bne.s    .loop            ; If not...
  3518.  
  3519. .dimCheck
  3520.     lea    dim_Nominal(A2),A0    ; Get dimension of monitor
  3521.     move.w    ra_MaxX(A0),D0        ; Last X-position of monitor (e.g. 639)
  3522.     move.w    ra_MaxY(A0),D1        ; Last Y-position of monitor (e.g. 479)
  3523.     addq.w    #1,D0            ; e.g. == 640
  3524.     addq.w    #1,D1            ; e.g. == 480
  3525.  
  3526.     move.w    _PlaneWidth(A5),D2    ; e.g. 640
  3527.     move.w    _PlaneHeight(A5),D3    ; e.g. 480
  3528.  
  3529.     cmp.w    D0,D2
  3530.     bne.s    .loop
  3531.     cmp.w    D1,D3
  3532.     bne.s    .loop
  3533.  
  3534.     move.l    D6,D7            ; Found ID!
  3535.  
  3536. * Now figure out if this monitor supports changes of RasInfo,
  3537. * set ViewPortShare by default to no (#-1)!
  3538.  
  3539. * Completey removed because Picasso96 1.4x supports now changing of View^dx/dy
  3540.     moveq    #0,D0            ; Must be set to minus 1 if the check should work!!!
  3541.     move.l    D0,_ViewPortShare(A5)
  3542.  
  3543. *    suba.l    A0,A0            ; handle = 0
  3544. *    movea.l    A2,A1            ; Now MonitorInfo!!!
  3545. *    move.l    #128,D0            ; size of buffer
  3546. *    move.l    #DTAG_MNTR,D1        ; TAG
  3547. *    move.l    D6,D2            ; Monitor ID
  3548. *    jsr    _LVOGetDisplayInfoData(A6)
  3549. *    tst.l    D0
  3550. *    beq.s    .freeDI
  3551.  
  3552. *    move.l    mtr_Compatibility(A2),_ViewPortShare(A5)
  3553. *    bra.s    .freeDI
  3554.  
  3555. .notfound
  3556. *    moveq    #0,D7            ; No ID!
  3557. *    move.l    D7,_ViewPortShare(A5)    ; Reset
  3558.  
  3559. .freeDI
  3560.     movea.l    _SysBase(A5),A6
  3561.     movea.l    A2,A1
  3562.     move.l    #128,D0
  3563.     jsr    _LVOFreeMem(A6)
  3564. .end
  3565.     move.l    D7,D0
  3566.     movem.l    (sp)+,D2-D3/D5-D7/A2
  3567.     rts                ; Return ID in D0 or zero for not found
  3568. *                      (only foreign modes will be returned)
  3569.  
  3570. ************************************************
  3571. *
  3572. * Display picture or image...
  3573. *
  3574. * Inputs: none
  3575. * Results: none
  3576. *
  3577.  
  3578. _LoadScreen
  3579.     tst.b    _NoWarnFlag(A5)
  3580.     bne.s    0$
  3581.  
  3582.     cmpi.l    #'ACBM',8(A0)        ; ACBM-file?
  3583.     bne.s    .IFF_ILBM        ; if not, must be ILBM-file
  3584.  
  3585.     lea    _ACBMTxt(pc),A0
  3586.     bsr.w    _DisplayError
  3587.     tst.l    D0            ; User cancelled?
  3588.     beq.w    _BinaryFile        ; If so, don't display
  3589.     bra.s    0$
  3590.  
  3591. .IFF_ILBM
  3592.     lea    _ILBMTxt(pc),A0
  3593.     bsr.w    _DisplayError
  3594.     tst.l    D0            ; User cancelled?
  3595.     beq.w    _BinaryFile        ; If so, don't display
  3596. 0$
  3597.     movea.l    _TextPtr(A5),A0        ; Source in memory
  3598.     addq.l    #2,A0            ; Overread #$200A
  3599.  
  3600.     move.l    A0,_SourceFilePtr(A5)    ; Copy pointer and size
  3601.     move.l    _FileSize(A5),_SourceFileSize(A5)
  3602.  
  3603.     bsr.w    _Convert        ; Decrunch image
  3604.     move.l    D0,-(sp)        ; Save returncode
  3605.  
  3606.     movea.l    _SysBase(A5),A6
  3607.     movea.l    _TextPtr(A5),A1
  3608.     move.l    _BufferSize(A5),D0    ; Free old datas
  3609.     jsr    _LVOFreeMem(A6)
  3610.     clr.l    _TextPtr(A5)        ; Important!!!
  3611.     clr.l    _BufferSize(A5)
  3612.     clr.l    _SearchStrPtr(A5)
  3613.     clr.l    _SearchStrLen(A5)
  3614.  
  3615.     move.l    (sp)+,D0        ; Get return code
  3616.     cmpi.l    #1,D0            ; 1 means all ok.
  3617.     bne.w    2$
  3618.  
  3619.  
  3620.     moveq    #0,D0
  3621.     move.b    _Depth(A5),D0
  3622.     move.l    _ViewPortMod(A5),D1
  3623.     andi.l    #HAM_KEY,D1        ; HAM6 or HAM8?
  3624.     beq.s    .noham            ; If not...
  3625.  
  3626. .ham
  3627.     moveq    #0,D1
  3628.     move.b    _Depth(A5),D1
  3629.     move.l    D1,_HAMSet(A5)
  3630.     move.b    #24,_Depth(A5)        ; Always use a 24 bit depth screen for HAM modes
  3631.  
  3632.     moveq    #1,D1            ; Initial val
  3633.     subq.b    #2,D0            ; 8 to 6 or 6 to 4
  3634.     lsl.w    D0,D1            ; HAM8: 1 << 6 = 64 or HAM6: 1 << 4 = 16
  3635.     lsl.l    D0,D1            ; Perform 64 * 64 * 64 or
  3636.     lsl.l    D0,D1            ; 16 * 16 * 16
  3637.     bra.s    .giveMsg        ; Done for HAM
  3638.  
  3639. .noham
  3640.     clr.l    _HAMSet(A5)
  3641.     moveq    #1,D1
  3642.     lsl.l    D0,D1            ; 1 << x = number of colours used
  3643.  
  3644. .giveMsg
  3645.     tst.b    _NoWarnFlag(A5)
  3646.     bne.s    .DontWrite
  3647.  
  3648.     move.l    _AllPlaneSize(A5),D0    ; Allocated size (in bytes)
  3649.     move.l    D0,-(sp)
  3650.     move.l    D1,-(sp)        ; Number of colours
  3651.     move.w    _Height(A5),D0        ; Height of image
  3652.     move.l    D0,-(sp)
  3653.     move.l    _RealIWidth(A5),D0    ; Width of image (no boundary)
  3654.     move.l    D0,-(sp)
  3655.     move.w    _Height(A5),D0        ; Number of rows used by bitmap
  3656.     move.l    D0,-(sp)
  3657.     move.w    _Width(A5),D0        ; Width in pixels of bitmap
  3658.     move.l    D0,-(sp)
  3659.     move.w    _PlaneHeight(A5),D0    ; Original screen's height
  3660.     move.l    D0,-(sp)
  3661.     move.w    _PlaneWidth(A5),D0    ; Original screen's width
  3662.     move.l    D0,-(sp)
  3663.     pea    _ImageInfoTxt(pc)
  3664.     bsr.w    _FmtDisplay
  3665.     lea    9*4(sp),sp
  3666.     tst.l    D0
  3667.     beq.w    2$
  3668.  
  3669. .DontWrite
  3670.     clr.b    _BlitFlag(A5)        ; Reset flags, important!!!
  3671.     clr.b    _SuperBitMap(A5)
  3672.     moveq    #0,D0
  3673.     move.l    D0,_ViewPortShare(A5)
  3674.  
  3675. *
  3676. ** If we're in OS3(+) we ask the system for the proberty ViewPort ModeID!
  3677. *
  3678.     movea.l    _GfxBase(A5),A6
  3679.     cmpi.w    #38,LIB_VERSION(A6)
  3680.     bls.w    .stdcheck
  3681.  
  3682.     tst.l    _TypeOfMem(A5)        ; TypeOfMem set up by routine _Convert(), if it is zero
  3683. *                      the bitplanes for the image where forces to public (FAST)
  3684. *                      memory, since an alien gfx board software created the window's bitmap
  3685.     bne.w    .stdcheck
  3686.  
  3687.     bsr.w    _CheckEHB
  3688.  
  3689.     clr.l    -(sp)            ; Assumption: 3rd party GFX device
  3690.     clr.l    -(sp)
  3691.     clr.l    -(sp)
  3692.     clr.l    -(sp)
  3693.     clr.l    -(sp)
  3694.     clr.l    -(sp)
  3695.     clr.l    -(sp)
  3696.     movea.l    sp,A0
  3697.  
  3698.     moveq    #0,D1
  3699.     move.l    D1,D2
  3700.     move.w    _PlaneHeight(A5),D1    ; Screen's dimension (not bitmap !!!)
  3701.     move.w    _PlaneWidth(A5),D2
  3702.  
  3703. *
  3704. ** Make a 4 to 3 aspect ratio so that any 3rd party device can handle it...
  3705. *    
  3706.     lsl.l    #2,D1            ; * 4
  3707.     divu.w    #3,D1            ; / 3
  3708.  
  3709.     cmp.w    D1,D2            ; Range check...
  3710.     bhi.s    .align0
  3711.  
  3712.     andi.l    #$FFFF,D1 
  3713.     move.w    D1,D2            ; New Width
  3714.  
  3715. .align0
  3716.     cmpi.w    #360,D2            ; Following are resolutions which can be used
  3717.     bhi.s    .align1            ; for 8 bitplane images, the other do only
  3718.     move.w    #320,D2            ; support 15/16 and 24/32 bit resolutions...
  3719.     move.w    #240,D1
  3720.     bra.s    .dimset
  3721. .align1
  3722.     cmpi.w    #768,D2
  3723.     bhi.s    .align2
  3724.     move.w    #640,D2
  3725.     move.w    #480,D1
  3726.     bra.s    .dimset
  3727. .align2
  3728.     cmpi.w    #896,D2
  3729.     bhi.s    .align3
  3730.     move.w    #800,D2
  3731.     move.w    #600,D1
  3732.     bra.s    .dimset
  3733. .align3
  3734.     move.w    #1024,D2        ; Default...
  3735.     move.w    #768,D1
  3736. .dimset
  3737.     move.w    D2,_PlaneWidth(A5)
  3738.     move.w    D1,_PlaneHeight(A5)
  3739.  
  3740.     moveq    #0,D0
  3741.     move.b    _Depth(A5),D0
  3742.     cmpi.b    #14,D0            ; Force a 9-14 bitplane display to 15 bit
  3743.     bhi.s    .depthok
  3744.     cmpi.b    #8,D0
  3745.     bls.s    .depthok
  3746.     moveq    #15,D0
  3747.     bra.s    .startscan
  3748.  
  3749. .depthok
  3750.     cmpi.b    #16,D0
  3751.     bls.s    .startscan
  3752.  
  3753.     cmpi.w    #1360,_Width(A5)
  3754.     bls.s    .startscan
  3755.     moveq    #16,D0
  3756.  
  3757. .startscan
  3758.     movem.l    D0-D2,-(sp)
  3759.  
  3760.     move.l    #BIDTAG_NominalWidth,(A0)
  3761.     move.w    D2,4(A0)
  3762.     move.l    #BIDTAG_NominalHeight,6(A0)
  3763.     move.w    D1,10(A0)
  3764.     move.l    #BIDTAG_Depth,12(A0)
  3765.     move.b    D0,14(A0)
  3766.     clr.l    16(A0)            ; TAG_Done
  3767.     movea.l    _GfxBase(A5),A6
  3768.     jsr    _LVOBestModeIDA(A6)
  3769.     move.l    D0,_ViewPortMod(A5)    ; Save 3rd party GFX device View Mode ID (only CyberGraphX)
  3770.  
  3771.     andi.l    #$FFF00000,D0        ; Only foreign modes!
  3772.     beq.s    .getModeID
  3773.     cmpi.l    #$FFF00000,D0        ; Do not use a test monitor!
  3774.     bne.s    .modeok
  3775.  
  3776. .getModeID
  3777.     move.l    (sp),D0            ; Depth
  3778.     bsr.w    _GetMode        ; Find monitor id that suits...
  3779.     move.l    D0,_ViewPortMod(A5)
  3780.     bne.s    .modeok            ; If found
  3781.     movem.l    (sp)+,D0-D2
  3782.     cmpi.b    #15,D0            ; 15 bit?
  3783.     bne.s    .wrongMode        ; No
  3784.     moveq    #16,D0            ; Try 16 bit instead of 15
  3785.     bra.s    .startscan
  3786.  
  3787. .wrongMode
  3788.     lea    _ErrorInvalidIDTxt(pc),A0
  3789.     bsr.w    _DisplayError
  3790.     lea    7*4(sp),sp
  3791.     bra.w    2$
  3792.  
  3793. .modeok
  3794.     movem.l    (sp)+,D0-D2
  3795.     lea    7*4(sp),sp
  3796.     bsr.w    _BrightenColours    ; Adjust the colours, e.g.: native AA = 8 bits per pen, 3rd party e.g. only 6
  3797.     bra.s    .ViewModeSet
  3798.  
  3799. .stdcheck
  3800.     move.l    _ViewPortMod(A5),D0    ; ViewModes
  3801.     movea.l    _SysBase(A5),A6
  3802.     cmpi.w    #35,LIB_VERSION(A6)
  3803.     bls.s    .StdChipSet
  3804.     movea.l    _GfxBase(A5),A6
  3805.     jsr    _LVOModeNotAvailable(A6)
  3806.     tst.l    D0
  3807.     beq.s    .ViewModeSet
  3808.  
  3809.     move.l    _ViewPortMod(A5),D0    ; Take as std-chip-set because Monitor isn't installed
  3810.  
  3811. .StdChipSet
  3812.     andi.l    #$FFFF,D0        ; Clear upper 16 bits because
  3813.     move.l    D0,_ViewPortMod(A5)    ; OS 1.x doesn't cares about Monitors!
  3814.     bsr.w    _DefaultMonitor        ; Choose screen-mode depending on video system...
  3815.  
  3816. .ViewModeSet
  3817.     lea    _NewScreen(A5),A0    ; Init screen-record
  3818.     clr.l    (A0)+
  3819.     move.w    _PlaneWidth(A5),(A0)+
  3820.     move.w    _PlaneHeight(A5),(A0)+
  3821.     moveq    #0,D0
  3822.     move.b    _Depth(A5),D0
  3823.     tst.l    _TypeOfMem(A5)
  3824.     bne.s    .storeDepth
  3825.     cmpi.b    #16,D0
  3826.     bls.s    .storeDepth
  3827.     cmp.w    #1360,_Width(A5)
  3828.     bls.s    .storeDepth
  3829.     moveq    #16,D0            ; Reduce 24 bit to 16
  3830. .storeDepth
  3831.     move.w    D0,(A0)+
  3832.     move.b    #-1,(A0)+
  3833.     move.b    #-1,(A0)+
  3834.     move.l    _ViewPortMod(A5),D0
  3835.     move.w    D0,(A0)+
  3836.     move.w    #NS_EXTENDED|CUSTOMSCREEN|CUSTOMBITMAP|SCREENQUIET,D1
  3837.     move.w    D1,(A0)+
  3838.     clr.l    (A0)+            ; Font
  3839.     lea    _ScreenName(pc),A1
  3840.     move.l    A1,(A0)+
  3841.     clr.l    (A0)+            ; Gadgets
  3842.     lea    _BitmapStruc(A5),A1    ; Set bitmap as screen's bitmap
  3843.     move.l    A1,(A0)+
  3844.     lea    _StdTags(A5),A1        ; Init tag-list for screen
  3845.     move.l    A1,(A0)+
  3846.     move.l    #SA_DisplayID,(A1)+
  3847.  
  3848.     move.l    _ViewPortMod(A5),D0
  3849.     tst.l    _TypeOfMem(A5)        ; Check if bitplanes forced to FAST-RAM - then
  3850. *                      the monitor ID isn't (shouldn't be) a normal AMIGA view mode
  3851.     beq.s    .Set
  3852.  
  3853.     btst.l    #12,D0            ; An ECS or AA monitor?
  3854.     bne.s    .ECS_AA            ; if so...
  3855.  
  3856.     andi.l    #$FFFF,D0        ; else mask out unused bytes
  3857.     bra.s    .Set
  3858.  
  3859. .ECS_AA
  3860.     cmpi.l    #$5FFFF,D0        ; Highest possible OS1 and! OS2 monitor ID
  3861.     bhi.s    .NewAAMode        ; We do have an AA display mode - so
  3862. *                      check if we have the "AA-chip-set"
  3863.     bra.s    .Set            ; We have only to open a standard or ECS display
  3864.  
  3865. *
  3866. ** AA monitor used for displaying, do we have the right chip-set?
  3867. ** NOTE: I check here the hardware but for the sakeness of completeness the info-data-
  3868. ** base of the monitor itselfs must be examined.
  3869. *
  3870. .NewAAMode
  3871.     movea.l    _SysBase(A5),A6
  3872.     cmpi.w    #38,LIB_VERSION(A6)    ; OS3.x or greater?
  3873.     bls.s    .MustEraseDbl        ; If not...
  3874.     movea.l    _GfxBase(A5),A6
  3875.     move.b    gb_ChipRevBits0(A6),D1    ; AA custom chip-set enabled?
  3876.     andi.b    #GFXF_AA_ALICE|GFXF_AA_LISA,D1
  3877.     bne.s    .Set            ; If enabled...
  3878.  
  3879. .MustEraseDbl
  3880.     andi.l    #$FFFF,D0        ; else take as default monitor
  3881.  
  3882. .Set
  3883.     tst.l    D0
  3884.     bne.s    .gotMID
  3885.     bsr.w    _DefaultMonitor
  3886. .gotMID
  3887.     move.l    D0,(A1)+        ; Set DisplayID
  3888.     clr.l    (A1)
  3889.  
  3890.     clr.b    _BlitFlag(A5)        ; Erase flag
  3891.  
  3892.     move.w    _Height(A5),D0
  3893.     move.w    _PlaneHeight(A5),D1
  3894.     cmp.w    D0,D1
  3895.     slt.b    _SuperBitMap(A5)    ; Bitmap taller than screen? - see there
  3896.     shi.b    _BlitFlag(A5)        ; Displaying a brush?
  3897.  
  3898.     move.w    _Width(A5),D0
  3899.     move.w    _PlaneWidth(A5),D1
  3900.     tst.l    _TypeOfMem(A5)        ; Foreign display HW used to display image?
  3901.     beq.s    .widthSetOk        ; If so,
  3902.  
  3903.     addi.w    #63,D1            ;  otherwise care about the BURST-Fetch-mode
  3904.     andi.w    #-64,D1            ;  so we have to correct this value
  3905. .widthSetOk
  3906.     tst.b    _SuperBitMap(A5)    ; Already dimension for a superbitmap?
  3907.     bne.s    1$            ; If so, skip next
  3908.  
  3909.     cmp.w    D0,D1            ; Check for superbitmap
  3910.     slt.b    _SuperBitMap(A5)    ; Set flag when encountered
  3911.  
  3912. 1$
  3913.     tst.b    _BlitFlag(A5)        ; Already a brush encountered?
  3914.     bne.s    .MustSet        ; If so...
  3915.  
  3916.     cmp.w    D0,D1
  3917.     shi.b    _BlitFlag(A5)        ; Encountered now
  3918.  
  3919.     tst.b    _BlitFlag(A5)        ; Do we display a brush?
  3920.     bne.s    .MustSet        ; If so...
  3921.  
  3922.     bra.s    .CheckDevice        ; Normal fullscreen image either with a superbitmap or without
  3923.  
  3924. .MustSet
  3925.     lea    _NewScreen(A5),A0
  3926.     move.w    #NS_EXTENDED|CUSTOMSCREEN|SCREENQUIET,ns_Type(A0) ; No custom bitmap used when displaying brushes!
  3927.  
  3928. .CheckDevice
  3929.     tst.l    _TypeOfMem(A5)        ; If the bitplanes have been forced to public memory
  3930. *                      I assume that a 3rd party GFX software driver is installed,
  3931. *                      this means we cannot use the system function to set the view
  3932. *                      since AMIGA 3rd party GFX boards are originally from the PC 
  3933. *                      and PCs don't support overscan!!!
  3934.     beq.s    .3rdParty
  3935.     bsr.w    _SetView        ; See there... (only for real AMIGA monitors/screens)
  3936.     bra.s    .ScreenSet
  3937.  
  3938. .3rdParty
  3939.     lea    _NewScreen(A5),A0
  3940.     move.w    #NS_EXTENDED|CUSTOMSCREEN|SCREENQUIET,ns_Type(A0) ; No custom bitmap!
  3941.     clr.l    ns_CustomBitMap(A0)
  3942.  
  3943.     tst.b    _SuperBitMap(A5)    ; Do we have a super bitmap?
  3944.     beq.s    .ScreenSet
  3945.  
  3946.     lea    _StdTags(A5),A0        ; Taglist for screen, SA_DisplayID already set
  3947.     move.l    #SA_AutoScroll,8(A0)
  3948.     move.l    #0,12(A0)        ; FALSE
  3949.     move.l    #SA_Type,16(A0)
  3950.     move.l    #CUSTOMSCREEN,20(A0)
  3951.     move.l    #SA_Width,24(A0)
  3952.     move.l    _ImageWidth(A5),28(A0)    ; How tall must be the screen's bitmap (without alignments)
  3953.     move.l    #SA_Height,32(A0)
  3954.     clr.w    36(A0)            ; Clear upper word of longword
  3955.     move.w    _Height(A5),38(A0)
  3956.     clr.l    40(A0)            ; TAG_DONE
  3957.  
  3958. .ScreenSet
  3959.     lea    _NewScreen(A5),A0
  3960.     movea.l    _IntuitionBase(A5),A6
  3961.     jsr    _LVOOpenScreen(A6)
  3962.     tst.l    D0
  3963.     bne.s    .OkScreen        ; Screen is open...
  3964.  
  3965.     lea    _ErrorOpeningScreen(pc),A0
  3966.     bsr.w    _DisplayError
  3967.     bra.w    2$
  3968.  
  3969. .OkScreen
  3970.     move.l    D0,D2            ; ScreenPtr
  3971.     movea.l    D0,A0
  3972.     lea    sc_ViewPort(A0),A0    ; Get screen's viewport
  3973.     lea    _Colourmap(A5),A1    ; Get screen's colourmap
  3974.     move.l    _CMapNumEntries(A5),D0    ; Number of colours (max 256)
  3975.     movea.l    _GfxBase(A5),A6
  3976.     cmpi.w    #38,LIB_VERSION(A6)
  3977.     bhi.s    .set32Bit        ; Running an AGA machine!
  3978.     jsr    _LVOLoadRGB4(A6)    ; Else use old colour-set function
  3979.     bra.s    .ColoursSet
  3980.  
  3981. .set32Bit
  3982.     tst.l    _TypeOfMem(A5)
  3983.     bne.s    .modifyCM32
  3984.  
  3985. *
  3986. ** Following only for displays with more than 8 bitplanes
  3987. *
  3988.     cmpi.b    #8,_Depth(A5)
  3989.     bls.s    .modifyCM32
  3990.  
  3991.     move.l    D2,-(sp)
  3992.     movea.l    D2,A2
  3993.  
  3994.     lea    sc_ViewPort(A2),A0
  3995.     moveq    #0,D0
  3996.     move.l    D0,D1
  3997.     move.l    D0,D2
  3998.     move.l    D0,D3
  3999.     jsr    _LVOSetRGB32(A6)    ; Colour zero of ViewPort to black
  4000.  
  4001.     lea    sc_RastPort(A2),A1
  4002.     moveq    #0,D0
  4003.     jsr    _LVOSetAPen(A6)        ; Use Rastport's pen zero
  4004.  
  4005.     lea    sc_RastPort(A2),A1
  4006.     moveq    #0,D0
  4007.     moveq    #0,D1
  4008.     move.w    sc_Width(A2),D2
  4009.     subq.w    #1,D2
  4010.     move.w    sc_Height(A2),D3
  4011.     subq.w    #1,D3
  4012.     jsr    _LVORectFill(A6)    ; Flood Screen with pen zero (black background)
  4013.  
  4014.     move.l    (sp)+,D2
  4015.     bra.s    .ColoursSet
  4016.  
  4017. .modifyCM32
  4018.     lea    _RGB32Colours(A5),A1    ; RGB32 Colourtable
  4019.     jsr    _LVOLoadRGB32(A6)    ; Load them
  4020.  
  4021. .ColoursSet
  4022.     tst.l    _TypeOfMem(A5)        ; Since the most 3rd party GFX board drivers don't support
  4023.     beq.s    .blit            ; custom BitMaps we have to copy the bitplanes manually...
  4024.  
  4025.     tst.b    _BlitFlag(A5)        ; Do we have to blit an image to the screen?
  4026.     beq.w    .noneedblit        ; No...
  4027.  
  4028. .blit
  4029.     movem.l    D2-D7/A2,-(sp)
  4030.  
  4031. .loop
  4032.     movea.l    _IntuitionBase(A5),A6
  4033.     move.l    ib_FirstScreen(A6),D0
  4034.     cmp.l    D2,D0
  4035.     beq.s    .startblit
  4036.  
  4037.     movea.l    _DOSBase(A5),A6
  4038.     moveq    #1,D1
  4039.     jsr    _LVODelay(A6)
  4040.     bra.s    .loop
  4041.  
  4042. .startblit
  4043.     tst.l    _HAMSet(A5)
  4044.     bne.s    .convertHAM
  4045.  
  4046.     lea    _BitmapStruc(A5),A0    ; Image's bitmap
  4047.     cmpi.b    #24,bm_Depth(A0)
  4048.     bne.s    .check16bit
  4049.     movea.l    D2,A1            ; Screen A1
  4050.     lea    sc_RastPort(A1),A1
  4051.     bsr.w    _PlanarBMtoRGB24
  4052.     tst.l    D0
  4053.     bne.w    .none
  4054.     bra.s    .realstartblit
  4055.  
  4056. .convertHAM
  4057.     tst.l    _TypeOfMem(A5)        ; HAM and no gfx-board?
  4058.     bne.s    .realstartblit
  4059.  
  4060.     lea    _BitmapStruc(A5),A0    ; Image's bitmap
  4061.     movea.l    D2,A1            ; Screen A1
  4062.     lea    sc_RastPort(A1),A1
  4063.     bsr.w    _HAMtoRGB24
  4064.     tst.l    D0
  4065.     bne.w    .none
  4066.  
  4067. .check16bit
  4068.     cmpi.b    #8,bm_Depth(A0)
  4069.     bls.s    .realstartblit
  4070.     cmpi.b    #16,bm_Depth(A0)
  4071.     bhi.s    .realstartblit
  4072.     movea.l    D2,A1            ; Screen A1
  4073.     lea    sc_RastPort(A1),A1
  4074.     bsr.w    _CLUTtoRGB16
  4075.     tst.l    D0
  4076.     bne.w    .none
  4077.     
  4078. .realstartblit
  4079.     lea    _BitmapStruc(A5),A0    ; Image's bitmap
  4080.     movea.l    D2,A1            ; Screen A1
  4081.     movea.l    A1,A2
  4082.     lea    sc_RastPort(A1),A1    ; Screen's RastPort
  4083.     movea.l    rp_BitMap(A1),A1
  4084.     moveq    #0,D0
  4085.     move.l    D0,D1
  4086.     moveq    #0,D2
  4087.     move.w    sc_Width(A2),D2        ; Screen's dimensions
  4088.     lsr.w    #1,D2            ; Half
  4089.     moveq    #0,D7
  4090.     move.l    _RealIWidth(A5),D7    ; Image's width
  4091.     lsr.w    #1,D7            ; Half
  4092.     sub.w    D7,D2            ; == X-Offset for image
  4093.  
  4094.     move.w    sc_Height(A2),D3
  4095.     lsr.w    #1,D3            ; Half
  4096.     move.w    _Height(A5),D7
  4097.     lsr.w    #1,D7            ; Half
  4098.     sub.w    D7,D3            ; Y-Offset for image
  4099.  
  4100.     move.l    _RealIWidth(A5),D4    ; Image's width
  4101.     move.w    _Height(A5),D5        ; Image's height
  4102.  
  4103. *
  4104. ** Because a blit must be friendly, we now check the bounds
  4105. *
  4106.     tst.w    D2
  4107.     bpl.s    .XOk
  4108.     moveq    #0,D2
  4109. .XOk
  4110.     tst.w    D3
  4111.     bpl.s    .YOk
  4112.     moveq    #0,D3
  4113. .YOk
  4114.     move.w    D4,D7
  4115.     add.w    D2,D7
  4116.     cmp.w    sc_Width(A2),D7
  4117.     bls.s    .WOk
  4118.     move.w    sc_Width(A2),D7
  4119.     addq.w    #1,D7
  4120.  
  4121.     move.w    D4,D6
  4122.     add.w    D2,D6
  4123.     sub.w    D7,D6
  4124.  
  4125.     sub.w    D6,D4
  4126. .WOk
  4127.     move.w    D5,D7
  4128.     add.w    D3,D7
  4129.     cmp.w    sc_Height(A2),D7
  4130.     bls.s    .doblit
  4131.     move.w    sc_Height(A2),D7
  4132.     addq.w    #1,D7
  4133.  
  4134.     move.w    D5,D6            ; e.g. 832
  4135.     add.w    D3,D6            ; e.g. 0
  4136.     sub.w    D7,D6            ; 800 from 832 = 32
  4137.  
  4138.     sub.w    D6,D5            ; 832 - 32 = 800
  4139.  
  4140. .doblit
  4141.     move.b    #$C0,D6            ; Minterm == blit all
  4142.     move.l    #$FF,D7            ; Only byte treated...
  4143.     suba.l    A2,A2
  4144.  
  4145.     movem.l    D0-D1/A0-A1,-(sp)
  4146.     movea.l    _GfxBase(A5),A6
  4147.     jsr    _LVOWaitBlit(A6)
  4148.     movem.l    (sp)+,D0-D1/A0-A1
  4149.     jsr    _LVOBltBitMap(A6)     ; Blit the image to the display (only first 8 bitplanes... shit...)
  4150.  
  4151. .none
  4152.     movem.l    (sp)+,D2-D7/A2
  4153.  
  4154. .noneedblit
  4155.     movem.l    D2-D7/A2-A4,-(sp)
  4156.     movea.l    D2,A4            ; Screen
  4157.     lea    sc_ViewPort(A4),A3    ; Screen's ViewPort
  4158.     movea.l    vp_RasInfo(A3),A3    ; Screen's RasInfo
  4159.     move.w    _PlaneWidth(A5),D2    ; Visible size (screen)
  4160.     move.w    _PlaneHeight(A5),D3    ; Visible size (screen)
  4161.     move.l    _RealIWidth(A5),D4    ; Whole size (bitmap)
  4162.     move.w    _Height(A5),D5        ; Whole size (bitmap)
  4163.     move.w    D2,D6            ; Current Width
  4164.     move.w    D3,D7            ; Current Height
  4165.  
  4166. .Wait
  4167.     clr.b    _RIChanged(A5)        ; Important
  4168.  
  4169.     tst.b    _SuperBitMap(A5)    ; Do we have a superbitmap?
  4170.     beq.w    .PureWait        ; No, wait only
  4171.  
  4172.     move.w    sc_MouseX(A4),D0    ; Mouse-x-position on screen
  4173.     move.w    sc_MouseY(A4),D1    ; Mouse-y-position on screen
  4174.     move.w    $DFF016.l,_RMB(A5)    ; Right mouse button state
  4175.     addq.w    #1,D0            ; Important!
  4176.     addq.w    #1,D1            ; Important!
  4177.  
  4178. *
  4179. ** When the mouse hits the limits of the screen, we scroll the bitmap
  4180. ** to the direction where the mouse hits the screen limits, so we display
  4181. ** the normally invisible parts.
  4182. *
  4183. .ScrollRight
  4184.     cmp.w    D0,D2            ; MouseX + 1 same as screenwidth (not bitmap!)
  4185.     bhi.s    .ScrollDown        ; If not, mouse not at border...
  4186.  
  4187.     cmp.w    D4,D6            ; Right border reached ? (max == current ?)
  4188.     bge.s    .ScrollDown        ; - then not at the border of the bitmap...
  4189.  
  4190.     st.b    _RIChanged(A5)        ; Else indicate: Must "Rethink Display" after this action
  4191.  
  4192.     btst    #2,_RMB(A5)        ; Right mouse button?
  4193.     beq.s    .SR16            ; - then move faster...
  4194. .SR1
  4195.     addq.w    #1,D6            ; One more pixel (right side) + 1 to display
  4196.     addq.w    #1,ri_RxOffset(A3)    ; Change offset so the hidden pixel can be displayed
  4197.     bra.s    .ScrollDown        ; Check for down scrolling
  4198. .SR16    
  4199.     move.w    D6,_Max(A5)        ; RMB - maximum visible  (_Max(A5) is only a dummy -
  4200. *                      haven't got enought registers....
  4201.     addi.w    #16,_Max(A5)        ; plus 16 pixels
  4202.     cmp.w    _Max(A5),D4        ; In range? - does it fit?
  4203.     blt.s    .SR1            ; If not...
  4204.     addi.w    #16,D6            ; Else 16 pixels more to display
  4205.     addi.w    #16,ri_RxOffset(A3)    ; Change offset (X) so those hidden 16 pixels can
  4206. *                    ; be displayed    
  4207. .ScrollDown
  4208.     cmp.w    D1,D3            ; MouseY + 1 same as bottom of screen (not bitmap!)
  4209.     bhi.s    .ScrollLeft        ; If not, screen border not touched...
  4210.  
  4211.     cmp.w    D5,D7            ; max == current ?
  4212.     bge.s    .ScrollLeft
  4213.  
  4214.     st.b    _RIChanged(A5)
  4215.  
  4216.     btst    #2,_RMB(A5)
  4217.     beq.s    .SD16
  4218. .SD1
  4219.     addq.w    #1,D7
  4220.     addq.w    #1,ri_RyOffset(A3)
  4221.     bra.s    .ScrollLeft
  4222. .SD16
  4223.     move.w    D7,_Max(A5)
  4224.     addi.w    #16,_Max(A5)
  4225.     cmp.w    _Max(A5),D5
  4226.     blt.s    .SD1
  4227.  
  4228.     addi.w    #16,D7
  4229.     addi.w    #16,ri_RyOffset(A3)
  4230.  
  4231. .ScrollLeft
  4232.     tst.w    sc_MouseX(A4)        ; Top of screen touched with mouse?
  4233.     bne.s    .ScrollUp
  4234.  
  4235.     cmp.w    D2,D6            ; std == current ?
  4236.     bls.s    .ScrollUp
  4237.  
  4238.     st.b    _RIChanged(A5)
  4239.  
  4240.     btst    #2,_RMB(A5)
  4241.     beq.s    .SL16
  4242. .SL1
  4243.     subq.w    #1,D6
  4244.     subq.w    #1,ri_RxOffset(A3)
  4245.     bra.s    .ScrollUp
  4246. .SL16
  4247.     move.w    D6,_Max(A5)
  4248.     subi.w    #16,_Max(A5)
  4249.     cmp.w    _Max(A5),D2
  4250.     bhi.s    .SL1
  4251.  
  4252.     subi.w    #16,D6
  4253.     subi.w    #16,ri_RxOffset(A3)
  4254.  
  4255. .ScrollUp
  4256.     tst.w    sc_MouseY(A4)        ; Left border touched with mouse?
  4257.     bne.s    .Check
  4258.  
  4259.     cmp.w    D3,D7            ; std == current ?
  4260.     bls.s    .Check
  4261.  
  4262.     st.b    _RIChanged(A5)
  4263.  
  4264.     btst    #2,_RMB(A5)
  4265.     beq.s    .SU16
  4266. .SU1
  4267.     subq.w    #1,D7
  4268.     subq.w    #1,ri_RyOffset(A3)
  4269.     bra.s    .Check
  4270. .SU16
  4271.     move.w    D7,_Max(A5)
  4272.     subi.w    #16,_Max(A5)
  4273.     cmp.w    _Max(A5),D3
  4274.     bhi.s    .SU1
  4275.  
  4276.     subi.w    #16,D7
  4277.     subi.w    #16,ri_RyOffset(A3)
  4278.  
  4279. .Check
  4280.     tst.b    _RIChanged(A5)        ; RasInfo changed?
  4281.     beq.s    .PureWait        ; No, wait only
  4282.  
  4283.     tst.l    _ViewPortShare(A5)    ; Assumption: If we can share the ViewPort we
  4284.     bmi.s    .mustblit        ; can also change the RasInfo-offsets!
  4285.  
  4286. * Called under OS1.x, 2.x and OS3.x when a native Amiga monitor is available.
  4287. * CyberGraphX will also end here...
  4288.     movea.l    _IntuitionBase(A5),A6
  4289.     movea.l    A4,A0            ; Screen
  4290.     jsr    _LVOMakeScreen(A6)    ; Move screen contents
  4291.     jsr    _LVORethinkDisplay(A6)    ; and make them visible
  4292.     bra.s    .CheckLMB
  4293.  
  4294. .mustblit    ; This is only for alien gfx-board software packages... (Picasso96)
  4295.     movem.l    D2-D7/A2,-(sp)        ; » We have to blit the non visible part
  4296. *                        into the display
  4297.  
  4298.     lea    _BitmapStruc(A5),A0    ; Image's bitmap
  4299.     lea    sc_RastPort(A4),A1    ; Screen's RastPort
  4300.     movea.l    rp_BitMap(A1),A1    ; Screen's BitMap
  4301.     suba.l    A2,A2            ; No Temp
  4302.     move.w    D6,D0            ; Last displayable pixel X
  4303.     move.w    D7,D1            ; Last displayable pixel Y
  4304.     moveq    #0,D2            ; DestX
  4305.     moveq    #0,D3            ; DestY
  4306.     move.w    _PlaneWidth(A5),D4    ; Width
  4307.     move.w    _PlaneHeight(A5),D5    ; Height
  4308.     sub.w    D4,D0            ; = SrcX
  4309.     sub.w    D5,D1            ; = SrcY
  4310.     move.b    #$C0,D6            ; Cooky cut
  4311.     move.b    #$FF,D7            ; All planes
  4312.  
  4313.     movem.l    D0-D1/A0-A1,-(sp)
  4314.     movea.l    _GfxBase(A5),A6
  4315.     jsr    _LVOWaitBlit(A6)
  4316.     movem.l    (sp)+,D0-D1/A0-A1
  4317.  
  4318.     jsr    _LVOBltBitMap(A6)
  4319.     jsr    _LVOWaitBlit(A6)
  4320.  
  4321.     movem.l    (sp)+,D2-D7/A2
  4322.     bra.s    .CheckLMB
  4323.  
  4324. .PureWait
  4325.     moveq    #4,D1            ; Wait 4/50 or 4/60 seconds
  4326.     movea.l    _DOSBase(A5),A6
  4327.     jsr    _LVODelay(A6)
  4328.  
  4329. .CheckLMB
  4330.     btst    #6,$BFE001        ; Left mouse button?
  4331.     bne.w    .Wait
  4332.  
  4333.     movem.l    (sp)+,D2-D7/A2-A4
  4334.  
  4335.     movea.l    D2,A0            ; Screen
  4336.     movea.l    _IntuitionBase(A5),A6
  4337.     jsr    _LVOCloseScreen(A6)
  4338.     bsr.w    _RestoreView        ; See there
  4339. 2$
  4340.     tst.l    _Bitplane(A5)        ; Bitplane allocated?
  4341.     beq.s    3$
  4342.     movea.l    _Bitplane(A5),A1
  4343.     move.l    _AllPlaneSize(A5),D0
  4344.     clr.l    _AllPlaneSize(A5)
  4345.     clr.l    _Bitplane(A5)
  4346.     movea.l    _SysBase(A5),A6
  4347.     jsr    _LVOFreeMem(A6)        ; Free bitplanes
  4348. 3$
  4349.     movea.l    _IntuitionBase(A5),A6
  4350.     movea.l    _WindowPtr(A5),A0
  4351.     jsr    _LVOActivateWindow(A6)    ; Activate our window
  4352.  
  4353.     addq.l    #4,sp
  4354.     bra.w    _LoadNew        ; Display requester
  4355.  
  4356. ************************************************************************
  4357. *
  4358. ** Subroutines to set correct view for overscan pictures of ks lower v36.
  4359. *
  4360.  
  4361. _SetView
  4362.     movem.l    D0-D1/A0-A1/A6,-(sp)
  4363.     movea.l    _IntuitionBase(A5),A6
  4364.     cmpi.w    #35,LIB_VERSION(A6)    ; Lower V36?
  4365.     bhi.s    .OSOScanSet
  4366.  
  4367.     jsr    _LVOViewAddress(A6)    ; Get view
  4368.     movea.l    D0,A0
  4369.     move.w    v_DyOffset(A0),_OldY(A5) ; Save old offset
  4370.     move.w    v_DxOffset(A0),_OldX(A5)
  4371.  
  4372.     cmpi.w    #320,_PlaneWidth(A5)    ; Lower than 320?
  4373.     bls.s    1$            ; No overscan!
  4374.     cmpi.w    #352,_PlaneWidth(A5)    ; If it fits, we have
  4375.     bls.s    2$            ; an overscan-screen
  4376.  
  4377.     cmpi.w    #640,_PlaneWidth(A5)    ; Lower than 640?
  4378.     bls.s    1$            ; No overscan!
  4379.  
  4380.     bra.s    2$            ; Else we have an overscan-screen
  4381.  
  4382. 1$
  4383.     cmpi.w    #256,_PlaneHeight(A5)    ; Lower than 256?
  4384.     bls.s    .NoOScan        ; No overscan!
  4385.     cmpi.w    #290,_PlaneHeight(A5)    ; If it fits, we have
  4386.     bls.s    2$            ; an overscan-screen
  4387.  
  4388.     cmpi.w    #512,_PlaneHeight(A5)    ; Lower than 512?
  4389.     bls.s    .NoOScan        ; No overscan!
  4390.  
  4391. 2$    ; We have an overscan screen!
  4392.     move.w    #30,v_DyOffset(A0)    ; Change dyOffset
  4393.     move.w    #112,v_DxOffset(A0)    ; Change dxOffset
  4394.     jsr    _LVORethinkDisplay(A6)    ; Make display
  4395.  
  4396. .NoOScan
  4397.     movem.l    (sp)+,D0-D1/A0-A1/A6
  4398.     rts
  4399.  
  4400. * Let the system do the work (up from OS2.0)...
  4401. .OSOScanSet
  4402.     lea    _StdTags(A5),A0
  4403.     movea.l    4(A0),A0        ; MonitorID
  4404.     clr.l    -(sp)            ; Make room for rectangle - see gfx.i
  4405.     clr.l    -(sp)
  4406.     movea.l    sp,A1            ; Rectangle
  4407.     moveq    #OSCAN_STANDARD,D0    ; The simply - may improve on your own...
  4408.     jsr    _LVOQueryOverscan(A6)    ; Give me informations...
  4409.     tst.l    D0            ; Failed?
  4410.     beq.s    .NoOScan
  4411.     movea.l    sp,A0            ; Rectangle
  4412.     lea    _NewScreen(A5),A1
  4413.     move.w    (A0),(A1)        ; ( ra_MinX(A0),ns_LeftEdge(A1) )
  4414.     move.w    ra_MinY(A0),ns_TopEdge(A1)
  4415.     addq.l    #8,sp
  4416.     bra.s    .NoOScan        ; Set...
  4417.  
  4418. _RestoreView
  4419.     movem.l    D0-D1/A0-A1/A6,-(sp)
  4420.     movea.l    _IntuitionBase(A5),A6
  4421.     cmpi.w    #35,LIB_VERSION(A6)    ; Ks 1.3 including Headly-Monitor?
  4422.     bhi.s    .NotNeeded        ; At least Kickstart 2.0 ßeta...
  4423.  
  4424.     jsr    _LVOViewAddress(A6)    ; Get old offsets
  4425.     movea.l    D0,A0
  4426.     move.w    _OldY(A5),v_DyOffset(A0); Restore them
  4427.     move.w    _OldX(A5),v_DxOffset(A0)
  4428.     jsr    _LVORethinkDisplay(A6)
  4429. .NotNeeded
  4430.     movem.l    (sp)+,D0-D1/A0-A1/A6
  4431.     rts
  4432.  
  4433. ************************************************************************
  4434. *
  4435. ** Running OS 1.x or the required mode is not available (up from OS 2.x)
  4436. *
  4437. * Video Overscan taken as limit to check against...
  4438. *
  4439.  
  4440. _DefaultMonitor
  4441.     moveq    #0,D0
  4442.     cmpi.w    #362,_PlaneWidth(A5)    ; Los-Res maximum?
  4443.     bhi.s    .MinMedRes        ; If taller, at least Med-Res
  4444.     bra.s    .CheckILace
  4445. .MinMedRes
  4446.     ori.w    #V_HIRES,D0        ; Set Hires key
  4447.  
  4448. .CheckILace
  4449.     cmpi.w    #283,_PlaneHeight(A5)    ; Maximum for PAL non-interlace
  4450.     bhi.s    .ItsInterlace        ; else we have to set interlace-bit
  4451.     bra.s    .CheckNTSC
  4452. .ItsInterlace
  4453.     ori.w    #V_LACE,D0        ; Set LACE-key
  4454.  
  4455. .CheckNTSC
  4456.     movea.l    _GfxBase(A5),A6
  4457.     move.w    gb_DisplayFlags(A6),D1
  4458.     btst    #2,D1            ; PAL or NTSC ($4 means PAL)?
  4459.     bne.s    .VMSet            ; was PAL
  4460.  
  4461.     btst    #2,D0            ; else NTSC - check for interlace ($4 means V_LACE)
  4462.     bne.s    .VMSet            ; Since already set
  4463.  
  4464.     cmpi.w    #241,_PlaneHeight(A5)    ; Maximum for NTSC non-lace
  4465.     bls.s    .VMSet
  4466.     ori.w    #V_LACE,D0
  4467.  
  4468. .VMSet
  4469.     move.l    _ViewPortMod(A5),D1
  4470.     btst    #11,D1            ; HAM-Key? (HAM or HAM8?)
  4471.     beq.s    .SetDim            ; No HAM, else
  4472.     ori.w    #V_HAM,D0        ; set HAM-Key
  4473.  
  4474. .SetDim
  4475.     move.l    D0,_ViewPortMod(A5)    ; Save new ViewModes
  4476.  
  4477.     move.w    gb_DisplayFlags(A6),D1
  4478.     andi.w    #V_HIRES,D0
  4479.     bne.s    .Hires
  4480.  
  4481.     cmpi.w    #362,_PlaneWidth(A5)    ; We have a Lores display
  4482.     bls.s    .checkDimHeight
  4483.     move.w    #362,_PlaneWidth(A5)
  4484.     bra.s    .checkDimHeight
  4485.  
  4486. .Hires
  4487.     cmpi.w    #724,_PlaneWidth(A5)    ; We have a Medres or Hires display
  4488.     bls.s    .checkDimHeight
  4489.     move.w    #724,_PlaneWidth(A5)
  4490.  
  4491. .checkDimHeight
  4492.     move.l    _ViewPortMod(A5),D0
  4493.     andi.w    #V_LACE,D0        ; Check for interlace
  4494.     bne.s    .Interlace
  4495.  
  4496.     btst    #2,D1            ; Check display against NTSC / PAL
  4497.     bne.s    .noILacePAL
  4498.  
  4499.     cmpi.w    #241,_PlaneHeight(A5)    ; Non interlace NTSC display
  4500.     bls.s    .done
  4501.     move.w    #241,_PlaneHeight(A5)
  4502.     bra.s    .done
  4503.  
  4504. .noILacePAL
  4505.     cmpi.w    #283,_PlaneHeight(A5)    ; Non interlace PAL display
  4506.     bls.s    .done
  4507.     move.w    #283,_PlaneHeight(A5)
  4508.     bra.s    .done
  4509.  
  4510. .Interlace
  4511.     btst    #2,D1            ; Check Display against NTSC / PAL
  4512.     bne.s    .ILacePAL
  4513.  
  4514.     cmpi.w    #482,_PlaneHeight(A5)    ; Interlace NTSC display
  4515.     bls.s    .done
  4516.     move.w    #482,_PlaneHeight(A5)
  4517.     bra.s    .done
  4518.  
  4519. .ILacePAL
  4520.     cmpi.w    #566,_PlaneHeight(A5)    ; Interlace PAL display
  4521.     bls.s    .done
  4522.     move.w    #566,_PlaneHeight(A5)
  4523. .done
  4524.     rts
  4525.  
  4526. *************************************************************************
  4527. *
  4528. ** Convert a AMIGA BitMap-Structure with 24 bitplanes to the RGB values a
  4529. ** 3rd party gfx-board support.
  4530. ** This routines needs a 68020 CPU.
  4531. ** This routine has been designed as a hack (late after midnight) and so
  4532. ** it looks really dirty. Sorry for that.
  4533. *
  4534.  
  4535.     OPT    P=68020
  4536.  
  4537. _PlanarBMtoRGB24
  4538. *    A0 - bitmap, A1 Rastport
  4539.  
  4540.     movem.l    D2-D7/A2-A6,-(sp)
  4541.  
  4542.     movea.l    A0,A3            ; Bitmap
  4543.     movea.l    A1,A2            ; RastPort
  4544.  
  4545.     tst.l    _CyberGfxBase(A5)
  4546.     bne.s    .start
  4547.     movea.l    _SysBase(A5),A6
  4548.     lea    _CyberGfxName(pc),A1
  4549.     moveq    #40,D0
  4550.     jsr    _LVOOpenLibrary(A6)
  4551.     move.l    D0,_CyberGfxBase(A5)
  4552.     beq.w    .endall
  4553. .start
  4554.     OPT    OW-
  4555.     move.w    bm_BytesPerRow(A3),D0
  4556.     mulu.w    #24,D0
  4557.     move.l    D0,D3
  4558.     move.l    D0,_RGB24Size(A5)
  4559.     move.l    #MEMF_PUBLIC|MEMF_CLEAR,D1
  4560.     movea.l    _SysBase(A5),A6
  4561.     jsr    _LVOAllocMem(A6)
  4562.     move.l    D0,_RGB24Ptr(A5)
  4563.     beq.w    .endall
  4564.     OPT    OW+
  4565.  
  4566.     move.l    _CyberGfxBase(A5),D1
  4567.     move.l    _ImageWidth(A5),D2
  4568.  
  4569.     move.l    A5,-(sp)
  4570.     lea    -48(sp),sp        ; Mixed buffer
  4571.     movea.l    sp,A5
  4572.  
  4573.     move.l    D0,24(A5)        ; Data buffer
  4574.     move.l    D1,28(A5)        ; CyberGfxBase
  4575.     move.l    D2,32(A5)        ; ImageWidth
  4576.     move.l    A2,36(A5)        ; RastPort
  4577.     move.l    D3,44(A5)        ; Size of one 24 bit RGB row
  4578.     
  4579.     movea.l    D0,A4            ; RGB24
  4580.  
  4581.     OPT    OW-
  4582.     moveq    #0,D3            ; Line
  4583.     moveq    #0,D4            ; Bytes per row
  4584.     move.w    bm_BytesPerRow(A3),D4    ; As it tells
  4585.     moveq    #0,D7            ; Offset (X) in planar bitmap
  4586.     moveq    #0,D6            ; Pixel per line
  4587.     OPT    OW+
  4588.  
  4589. .nextpixel                ; Read eight pixel (one byte) of each bitplane
  4590. *    moveq    #23,D0            ; For 24 bit-planes
  4591. *    lea    8(A3),A0        ; 1st plane ptr
  4592. *    movea.l    A5,A2            ; Mixed buffer
  4593.  
  4594. *.getB
  4595. *    movea.l    (A0)+,A1
  4596. *    move.b    0(A1,D7.l),(A2)+    ; Read eight pixel (one byte) of each bitplane
  4597. *    subq.w    #1,D0
  4598. *    bcc.s    .getB            ; For 24 bitplanes
  4599.  
  4600. *    movem.l    D3-D4/D6-D7/A3-A5,-(sp)
  4601.  
  4602. *    movea.l    A5,A0
  4603. *    movem.l    (A0)+,D1-D6
  4604.  
  4605. *
  4606. ** Replaces above, consider yourself what's faster. Read eight pixel (one byte) of each bitplane
  4607. *
  4608.     movem.l    D3-D4/D6-D7/A3-A5,-(sp)    ; Replacement start
  4609.     OPT    OW-
  4610.  
  4611.     lea    bm_Planes(A3),A0    ; 1st plane ptr
  4612.     moveq    #8,D0
  4613.  
  4614.     move.b    ([0,A0],D7.l),D1    ; Read 8 pixel of bit-plane 0
  4615.     lsl.w    D0,D1
  4616.     move.b    ([4,A0],D7.l),D1    ; Read 8 pixel of bit-plane 1
  4617.     lsl.l    D0,D1
  4618.     move.b    ([8,A0],D7.l),D1    ; Read 8 pixel of bit-plane 2
  4619.     lsl.l    D0,D1
  4620.     move.b    ([12,A0],D7.l),D1    ; Read 8 pixel of bit-plane 3
  4621.  
  4622.     move.b    ([16,A0],D7.l),D2    ; Read 8 pixel of bit-plane 4
  4623.     lsl.w    D0,D2
  4624.     move.b    ([20,A0],D7.l),D2    ; Read 8 pixel of bit-plane 5
  4625.     lsl.l    D0,D2
  4626.     move.b    ([24,A0],D7.l),D2    ; Read 8 pixel of bit-plane 6
  4627.     lsl.l    D0,D2
  4628.     move.b    ([28,A0],D7.l),D2    ; Read 8 pixel of bit-plane 7
  4629.  
  4630.     move.b    ([32,A0],D7.l),D3    ; Read 8 pixel of bit-plane 8
  4631.     lsl.w    D0,D3
  4632.     move.b    ([36,A0],D7.l),D3    ; Read 8 pixel of bit-plane 9
  4633.     lsl.l    D0,D3
  4634.     move.b    ([40,A0],D7.l),D3    ; Read 8 pixel of bit-plane 10
  4635.     lsl.l    D0,D3
  4636.     move.b    ([44,A0],D7.l),D3    ; Read 8 pixel of bit-plane 11
  4637.  
  4638.     move.b    ([48,A0],D7.l),D4    ; Read 8 pixel of bit-plane 12
  4639.     lsl.w    D0,D4
  4640.     move.b    ([52,A0],D7.l),D4    ; Read 8 pixel of bit-plane 13
  4641.     lsl.l    D0,D4
  4642.     move.b    ([56,A0],D7.l),D4    ; Read 8 pixel of bit-plane 14
  4643.     lsl.l    D0,D4
  4644.     move.b    ([60,A0],D7.l),D4    ; Read 8 pixel of bit-plane 15
  4645.  
  4646.      move.b    ([64,A0],D7.l),D5    ; Read 8 pixel of bit-plane 16
  4647.     lsl.w    D0,D5
  4648.     move.b    ([68,A0],D7.l),D5    ; Read 8 pixel of bit-plane 17
  4649.     lsl.l    D0,D5
  4650.     move.b    ([72,A0],D7.l),D5    ; Read 8 pixel of bit-plane 18
  4651.     lsl.l    D0,D5
  4652.     move.b    ([76,A0],D7.l),D5    ; Read 8 pixel of bit-plane 19
  4653.  
  4654.     move.b    ([80,A0],D7.l),D6    ; Read 8 pixel of bit-plane 20
  4655.     lsl.w    D0,D6
  4656.     move.b    ([84,A0],D7.l),D6    ; Read 8 pixel of bit-plane 21
  4657.     lsl.l    D0,D6
  4658.     move.b    ([88,A0],D7.l),D6    ; Read 8 pixel of bit-plane 22
  4659.     lsl.l    D0,D6
  4660.     move.b    ([92,A0],D7.l),D6    ; Read 8 pixel of bit-plane 23
  4661.  
  4662.     OPT    OW+            ; Replacement end
  4663.  
  4664. *
  4665. ** Registers (D1-D6) filled with 24 bytes each holding 8 pixel
  4666. *
  4667. .getColour
  4668.     movea.l    A4,A0            ; RGB24 buffer
  4669.  
  4670.     move.l    D1,A1
  4671.     move.l    D2,A2
  4672.     move.l    D3,A3
  4673.     move.l    D4,A4
  4674.     move.l    D5,A5
  4675.     move.l    D6,A6
  4676.  
  4677.     move.l    #$80808080,D0
  4678.     and.l    D0,D1            ; bit 0 of plane 0,1,2,3
  4679.     and.l    D0,D2            ; bit 0 of plane 4,5,6,7
  4680.     and.l    D0,D3            ; bit 0 of plane 8,9,10,11
  4681.     and.l    D0,D4            ; bit 0 of plane 12,13,14,15
  4682.     and.l    D0,D5            ; bit 0 of plane 16,17,18,19
  4683.     and.l    D0,D6            ; bit 0 of plane 20,21,22,23
  4684.  
  4685.     moveq    #-34,D0            ; See 'Counting ...' below for explain
  4686.     move.l    D0,-(sp)
  4687.  
  4688. .GetPixelColour
  4689.  
  4690. * Get the red bits (8 per gun) (24 bit)
  4691.  
  4692. * Original R0 pixel 0 bit 31 , R1 pixel 0 bit 23 , R2 pixel 0 bit 15, R3 pixel 0 bit 0 in D1.L
  4693.  
  4694.     move.b    D1,D0            ; R3 pixel 0 in D0.b
  4695.     lsr.w    #8,D1            ; Get R2 pixel 0 on byte position in D1.b
  4696.     lsr.b    #4,D0            ; R3 pixel 0 on position 3
  4697.     lsr.b    #5,D1            ; R2 pixel 0 on position 2
  4698.     or.b    D0,D1
  4699.     move.b    D1,D7            ; Half lower nibble in D7 (bits 3 and 2)    
  4700.  
  4701.     swap.w    D1            ; Original R0 pixel 0, R1 pixel 0, R2 pixel 0, R3 pixel 0 in D1.L
  4702. *                      R0 pixel 0 and R1 pixel 0 in D1.w
  4703.  
  4704.     move.b    D1,D0            ; R1 pixel 0 in D0
  4705.     lsr.w    #8,D1            ; Get R0 pixel 0 on byte position
  4706.     lsr.b    #6,D0            ; R1 pixel 0 on position 1
  4707.     lsr.b    #7,D1            ; R0 pixel 0 on position 0
  4708.     or.b    D0,D1
  4709.     or.b    D1,D7            ; R3 R2 R1 R0
  4710.  
  4711. * --------------------
  4712.  
  4713. * Original R4 pixel 0 bit 31 , R5 pixel 0 bit 23 , R6 pixel 0 bit 15, R7 pixel 0 bit 0 in D2.L
  4714.  
  4715.     move.b    D2,D0            ; R7 pixel 0 in D0
  4716.     lsr.w    #8,D2            ; Get R6 pixel 0 on byte position
  4717. *    lsr.b    #0,D0            ; R7 pixel 0 on position 7
  4718.     lsr.b    #1,D2            ; R6 pixel 0 on position 6
  4719.     or.b    D0,D2
  4720.     or.b    D2,D7            ; R7 R6 nn nn R3, R2, R1, R0
  4721.  
  4722.     swap.w    D2            ; Original R4 pixel 0, R5 pixel 0 in D2.L
  4723. *                      R4 pixel 0, R5 pixel 0 in D2.w
  4724.  
  4725.     move.b    D2,D0            ; R5 pixel 0 in D0
  4726.     lsr.w    #8,D2            ; Get R4 pixel 0 on byte position
  4727.     lsr.b    #2,D0            ; R5 pixel 0 on position 5
  4728.     lsr.b    #3,D2            ; R4 pixel 0 on position 4
  4729.     or.b    D0,D2
  4730.     or.b    D2,D7            ; R0, R1, R2, R3, R4, R1 nn nn
  4731.  
  4732.     move.b    D7,(A0)+        ; Store red value
  4733.  
  4734. * -------------------------------------------------------------------
  4735.  
  4736. * Get the green bits (8 ber gun) (24 bit)
  4737.  
  4738.     move.b    D3,D0            ; G3 pixel 0 in D0
  4739.     lsr.w    #8,D3            ; Get G2 pixel 0 on byte position
  4740.     lsr.b    #4,D0            ; G3 pixel 0 on position 3
  4741.     lsr.b    #5,D3            ; G2 pixel 0 on position 2
  4742.     or.b    D0,D3
  4743.     move.b    D3,D7            ; nn nn nn nn G3 G2 nn nn    
  4744.  
  4745.     swap.w    D3            ; Original G0 pixel 0, G1 pixel 0, G2 pixel 0, G3 pixel 0
  4746. *                      now G0 pixel 0, G1 pixel 0 in D3.w
  4747.  
  4748.     move.b    D3,D0            ; G1 pixel 0 in D0
  4749.     lsr.w    #8,D3            ; Get G0 pixel 0 on byte position
  4750.     lsr.b    #6,D0            ; G1 pixel 0 on position 1
  4751.     lsr.b    #7,D3            ; G0 pixel 0 on position 0
  4752.     or.b    D0,D3
  4753.     or.b    D3,D7            ; nn nn nn nn G3 G2 G1 G0
  4754.  
  4755. * -------------------
  4756.  
  4757.     move.b    D4,D0            ; G7 pixel 0 in D0
  4758.     lsr.w    #8,D4            ; Get G6 pixel 0 on byte position
  4759. *    lsr.b    #0,D0            ; G7 pixel 0 on position 7
  4760.     lsr.b    #1,D4            ; G6 pixel 0 on position 6
  4761.     or.b    D0,D4
  4762.     or.b    D4,D7            ; G7 G6 nn nn G3 G2 G1 G0    
  4763.  
  4764.     swap.w    D4            ; Original G4 pixel 0, G5 pixel 0, G6 pixel 0, G7 pixel 0
  4765. *                      now G4 pixel 0, G5 pixel 0 in D4.w
  4766.  
  4767.     move.b    D4,D0            ; G5 pixel 0 in D0
  4768.     lsr.w    #8,D4            ; Get G4 pixel 0 on byte position
  4769.     lsr.b    #2,D0            ; G5 pixel 0 on position 5
  4770.     lsr.b    #3,D4            ; G4 pixel 0 on position 4
  4771.     or.b    D0,D4
  4772.     or.b    D4,D7            ; G7 G6 G5 G4 G3 G2 G1 G0
  4773.  
  4774.     move.b    D7,(A0)+        ; Store green value
  4775. * -------------------------------------------------------------------
  4776.  
  4777. * Get the blue bits (8 ber gun) (24 bit)
  4778.  
  4779.     move.b    D5,D0            ; B3 pixel 0 in D0
  4780.     lsr.w    #8,D5            ; Get B2 pixel 0 on byte position
  4781.     lsr.b    #4,D0            ; B3 pixel 0 on position 3
  4782.     lsr.b    #5,D5            ; B2 pixel 0 on position 2
  4783.     or.b    D0,D5
  4784.     move.b    D5,D7            ; nn nn nn nn B3 B2 nn nn    
  4785.  
  4786.     swap.w    D5            ; Original B0 pixel 0, B1 pixel 0, B2 pixel 0, B3 pixel 0
  4787. *                      now B0 pixel 0, B1 pixel 0 in D5.w
  4788.  
  4789.     move.b    D5,D0            ; B1 pixel 0 in D0
  4790.     lsr.w    #8,D5            ; Get B0 pixel 0 on byte position
  4791.     lsr.b    #6,D0            ; B1 pixel 0 on position 1
  4792.     lsr.b    #7,D5            ; B0 pixel 0 on position 0
  4793.     or.b    D0,D5
  4794.     or.b    D5,D7            ; nn nn nn nn B3 B2 B1 B0
  4795.  
  4796. * -------------------
  4797.  
  4798.     move.b    D6,D0            ; B7 pixel 0 in D0
  4799.     lsr.w    #8,D6            ; Get B6 pixel 0 on byte position
  4800. *    lsr.b    #0,D0            ; B7 pixel 0 on position 7
  4801.     lsr.b    #1,D6            ; B6 pixel 0 on position 6
  4802.     or.b    D0,D6
  4803.     or.b    D6,D7            ; B7 B6 nn nn B3 B2 B1 B0    
  4804.  
  4805.     swap.w    D6            ; Original B4 pixel 0, B5 pixel 0, B6 pixel 0, B7 pixel 0
  4806. *                      now B4 pixel 0, B5 pixel 0 in D6.w
  4807.  
  4808.     move.b    D6,D0            ; B5 pixel 0 in D0
  4809.     lsr.w    #8,D6            ; Get B4 pixel 0 on byte position
  4810.     lsr.b    #2,D0            ; B5 pixel 0 on position 5
  4811.     lsr.b    #3,D6            ; B4 pixel 0 on position 4
  4812.     or.b    D0,D6
  4813.     or.b    D6,D7            ; B7 B6 B5 B4 B3 B2 B1 B0
  4814.  
  4815.     move.b    D7,(A0)+        ; Store blue value
  4816. * -------------------------------------------------------------------
  4817.  
  4818. * Repeat GetPixelColour until a complete byte (8 pixel) is worked out...
  4819.  
  4820.     move.l    (sp)+,D0
  4821.  
  4822.     move.l    A1,D1
  4823.     move.l    A2,D2
  4824.     move.l    A3,D3
  4825.     move.l    A4,D4
  4826.     move.l    A5,D5
  4827.     move.l    A6,D6
  4828.  
  4829. .thejump
  4830.     addi.l    #36,D0
  4831.     move.l    D0,-(sp)
  4832.  
  4833.     jmp    (pc,D0.w)        ; An opcode for 32 bit CPUs only
  4834.  
  4835. .mask1                    ; Counting 2 :: (-34) = (+2 - +36 = -34) -> 1st offset to PC to reach this (.mask1)
  4836.     move.l    #$40404040,D0        ; -- Each mask has got 15 instruction surrounded by 36 bytes code
  4837.     and.l    D0,D1            ; bit 1 of plane 0,1,2,3
  4838.     and.l    D0,D2            ; bit 1 of plane 4,5,6,7
  4839.     and.l    D0,D3            ; bit 1 of plane 8,9,10,11
  4840.     and.l    D0,D4            ; bit 1 of plane 12,13,14,15
  4841.     and.l    D0,D5            ; bit 1 of plane 16,17,18,19
  4842.     and.l    D0,D6            ; bit 1 of plane 20,21,22,23
  4843.     moveq    #1,D0
  4844.     lsl.l    D0,D1
  4845.     lsl.l    D0,D2
  4846.     lsl.l    D0,D3
  4847.     lsl.l    D0,D4
  4848.     lsl.l    D0,D5
  4849.     lsl.l    D0,D6
  4850.     bra.w    .GetPixelColour
  4851.  
  4852. .mask2
  4853.     move.l    #$20202020,D0
  4854.     and.l    D0,D1            ; bit 2 of plane 0,1,2,3
  4855.     and.l    D0,D2            ; bit 2 of plane 4,5,6,7
  4856.     and.l    D0,D3            ; bit 2 of plane 8,9,10,11
  4857.     and.l    D0,D4            ; bit 2 of plane 12,13,14,15
  4858.     and.l    D0,D5            ; bit 2 of plane 16,17,18,19
  4859.     and.l    D0,D6            ; bit 2 of plane 20,21,22,23
  4860.     moveq    #2,D0
  4861.     lsl.l    D0,D1
  4862.     lsl.l    D0,D2
  4863.     lsl.l    D0,D3
  4864.     lsl.l    D0,D4
  4865.     lsl.l    D0,D5
  4866.     lsl.l    D0,D6
  4867.     bra.w    .GetPixelColour
  4868.  
  4869. .mask3
  4870.     move.l    #$10101010,D0
  4871.     and.l    D0,D1            ; bit 3 of plane 0,1,2,3
  4872.     and.l    D0,D2            ; bit 3 of plane 4,5,6,7
  4873.     and.l    D0,D3            ; bit 3 of plane 8,9,10,11
  4874.     and.l    D0,D4            ; bit 3 of plane 12,13,14,15
  4875.     and.l    D0,D5            ; bit 3 of plane 16,17,18,19
  4876.     and.l    D0,D6            ; bit 3 of plane 20,21,22,23
  4877.     moveq    #3,D0
  4878.     lsl.l    D0,D1
  4879.     lsl.l    D0,D2
  4880.     lsl.l    D0,D3
  4881.     lsl.l    D0,D4
  4882.     lsl.l    D0,D5
  4883.     lsl.l    D0,D6
  4884.     bra.w    .GetPixelColour
  4885.  
  4886. .mask4
  4887.     move.l    #$08080808,D0
  4888.     and.l    D0,D1            ; bit 4 of plane 0,1,2,3
  4889.     and.l    D0,D2            ; bit 4 of plane 4,5,6,7
  4890.     and.l    D0,D3            ; bit 4 of plane 8,9,10,11
  4891.     and.l    D0,D4            ; bit 4 of plane 12,13,14,15
  4892.     and.l    D0,D5            ; bit 4 of plane 16,17,18,19
  4893.     and.l    D0,D6            ; bit 4 of plane 20,21,22,23
  4894.     moveq    #4,D0
  4895.     lsl.l    D0,D1
  4896.     lsl.l    D0,D2
  4897.     lsl.l    D0,D3
  4898.     lsl.l    D0,D4
  4899.     lsl.l    D0,D5
  4900.     lsl.l    D0,D6
  4901.     bra.w    .GetPixelColour
  4902.  
  4903. .mask5
  4904.     move.l    #$04040404,D0
  4905.     and.l    D0,D1            ; bit 5 of plane 0,1,2,3
  4906.     and.l    D0,D2            ; bit 5 of plane 4,5,6,7
  4907.     and.l    D0,D3            ; bit 5 of plane 8,9,10,11
  4908.     and.l    D0,D4            ; bit 5 of plane 12,13,14,15
  4909.     and.l    D0,D5            ; bit 5 of plane 16,17,18,19
  4910.     and.l    D0,D6            ; bit 5 of plane 20,21,22,23
  4911.     moveq    #5,D0
  4912.     lsl.l    D0,D1
  4913.     lsl.l    D0,D2
  4914.     lsl.l    D0,D3
  4915.     lsl.l    D0,D4
  4916.     lsl.l    D0,D5
  4917.     lsl.l    D0,D6
  4918.     bra.w    .GetPixelColour
  4919.  
  4920. .mask6
  4921.     move.l    #$02020202,D0
  4922.     and.l    D0,D1            ; bit 6 of plane 0,1,2,3
  4923.     and.l    D0,D2            ; bit 6 of plane 4,5,6,7
  4924.     and.l    D0,D3            ; bit 6 of plane 8,9,10,11
  4925.     and.l    D0,D4            ; bit 6 of plane 12,13,14,15
  4926.     and.l    D0,D5            ; bit 6 of plane 16,17,18,19
  4927.     and.l    D0,D6            ; bit 6 of plane 20,21,22,23
  4928.     moveq    #6,D0
  4929.     lsl.l    D0,D1
  4930.     lsl.l    D0,D2
  4931.     lsl.l    D0,D3
  4932.     lsl.l    D0,D4
  4933.     lsl.l    D0,D5
  4934.     lsl.l    D0,D6
  4935.     bra.w    .GetPixelColour
  4936.  
  4937. .mask7
  4938.     move.l    #$01010101,D0
  4939.     and.l    D0,D1            ; bit 7 of plane 0,1,2,3
  4940.     and.l    D0,D2            ; bit 7 of plane 4,5,6,7
  4941.     and.l    D0,D3            ; bit 7 of plane 8,9,10,11
  4942.     and.l    D0,D4            ; bit 7 of plane 12,13,14,15
  4943.     and.l    D0,D5            ; bit 7 of plane 16,17,18,19
  4944.     and.l    D0,D6            ; bit 7 of plane 20,21,22,23
  4945.     moveq    #7,D0
  4946.     lsl.l    D0,D1
  4947.     lsl.l    D0,D2
  4948.     lsl.l    D0,D3
  4949.     lsl.l    D0,D4
  4950.     lsl.l    D0,D5
  4951.     lsl.l    D0,D6
  4952.     bra.w    .GetPixelColour
  4953.  
  4954. .mask8                    ; Does not exist!!!
  4955.     move.l    (sp)+,D0        ; - so, continue...
  4956.  
  4957.     movem.l    (sp)+,D3-D4/D6-D7/A3-A5
  4958.  
  4959.     addq.l    #1,D7            ; Worked out 8 pixel
  4960.     lea    24(A4),A4        ; Increase RGB24 buffer
  4961.  
  4962.     addq.w    #1,D6            ; New byte (8 pixel)
  4963.     cmp.w    D6,D4            ; End of line?
  4964.     bne.w    .nextpixel        ; If no new line
  4965.  
  4966.     movem.l    D3-D4/D7,-(sp)
  4967.  
  4968. * WritePixelArray( SrcRect [pointer to src datas A0]
  4969. *           SrcX    X position D0
  4970. *           SrcY    Y position D1
  4971. *           SrcMod bytes per row in source rectangle D2
  4972. *           RastPort A1
  4973. *           DestX  D3
  4974. *           DestY  D4
  4975. *           SizeX  D5
  4976. *           SizeY  D6
  4977. *           SrcFmt RECTFMT_RGB )
  4978.  
  4979.     OPT    OW-
  4980.     movea.l    24(A5),A0        ; Datas
  4981.     moveq    #0,D0
  4982.     moveq    #0,D1
  4983.     moveq    #0,D2
  4984.     move.l    44(A5),D2
  4985.     movea.l    36(A5),A1        ; RastPort
  4986.     move.l    D3,D4            ; DestY
  4987.     moveq    #0,D3            ; DestX
  4988.     move.l    32(A5),D5        ; Width
  4989.     move.w    #1,D6            ; Height
  4990.     moveq    #RECTFMT_RGB,D7
  4991.     movea.l    28(A5),A6
  4992.     jsr    _LVOWritePixelArray(A6)
  4993.     OPT    OW+
  4994.  
  4995.     movem.l    (sp)+,D3-D4/D7
  4996.  
  4997.     move.l    24(A5),A4        ; RGB24 buffer
  4998.  
  4999.     moveq    #0,D6            ; New X position (starting at zero)
  5000.     addq.w    #1,D3            ; Increase line number
  5001.  
  5002.     cmp.w    bm_Rows(A3),D3        ; Already done for all lines?
  5003.     bne.w    .nextpixel
  5004.  
  5005.     lea    48(sp),sp
  5006.     movea.l    (sp)+,A5
  5007.  
  5008.     move.l    _RGB24Ptr(A5),A1
  5009.     move.l    _RGB24Size(A5),D0
  5010.     movea.l    _SysBase(A5),A6
  5011.     jsr    _LVOFreeMem(A6)
  5012.  
  5013.     moveq    #-1,D0
  5014. .endall
  5015.     movem.l    (sp)+,D2-D7/A2-A6
  5016.     rts
  5017.  
  5018. _PlanarBMtoRGB24end
  5019.     OPT    P=68000
  5020.  
  5021. *****************************************************
  5022. *
  5023. ** Same as above only for 6/8 bitplanes (HAM encoded)
  5024. *
  5025.  
  5026.     OPT    P=68020
  5027.  
  5028. _HAMtoRGB24
  5029. *    A0 - bitmap, A1 Rastport
  5030.  
  5031.     movem.l    D2-D7/A2-A6,-(sp)
  5032.  
  5033.     movea.l    A0,A3            ; Bitmap
  5034.     movea.l    A1,A2            ; RastPort
  5035.  
  5036.     tst.l    _CyberGfxBase(A5)
  5037.     bne.s    .start
  5038.     movea.l    _SysBase(A5),A6
  5039.     lea    _CyberGfxName(pc),A1
  5040.     moveq    #40,D0
  5041.     jsr    _LVOOpenLibrary(A6)
  5042.     move.l    D0,_CyberGfxBase(A5)
  5043.     beq.w    .endall
  5044. .start
  5045.     OPT    OW-
  5046.     move.w    bm_BytesPerRow(A3),D0
  5047.     mulu.w    #24,D0
  5048.     move.l    D0,D3
  5049.     addq.l    #8,D0            ; For one black RGB pixel (mem-allocation boundary = 8 - thus use 8 instead of 3) at left of image
  5050.     move.l    D0,_RGB24Size(A5)
  5051.     move.l    #MEMF_PUBLIC|MEMF_CLEAR,D1
  5052.     movea.l    _SysBase(A5),A6
  5053.     jsr    _LVOAllocMem(A6)
  5054.     move.l    D0,_RGB24Ptr(A5)    ; Buffer for RGB24 format
  5055.     beq.w    .endall
  5056.     OPT    OW+
  5057.  
  5058.     move.l    _CyberGfxBase(A5),D1
  5059.     move.l    _ImageWidth(A5),D2
  5060.     lea    _RGB32Colours(A5),A0
  5061.     move.l    A0,D4
  5062.     addq.l    #4,D4            ; Pointer to colours (RGB) for index 0
  5063.  
  5064.     move.l    _HAMSet(A5),D5
  5065.  
  5066.     move.l    A5,-(sp)
  5067.     lea    -56(sp),sp        ; Mixed buffer
  5068.     movea.l    sp,A5
  5069.  
  5070.     addq.l    #8,D0            ; Ignore the black pixel
  5071.     move.l    D0,24(A5)        ; Data buffer
  5072.     move.l    D1,28(A5)        ; CyberGfxBase
  5073.     move.l    D2,32(A5)        ; ImageWidth
  5074.     move.l    A2,36(A5)        ; RastPort
  5075.     move.l    D3,44(A5)        ; Size of one 24 bit RGB row
  5076.     move.l    D4,48(A5)        ; RGB32Colours
  5077.     move.l    D5,52(A5)        ; HAM indicator (HAM6/HAM8)
  5078.     
  5079.     movea.l    D0,A4            ; Data
  5080.  
  5081.     OPT    OW-
  5082.     moveq    #0,D3            ; Line
  5083.     moveq    #0,D4            ; Bytes per row
  5084.     move.w    bm_BytesPerRow(A3),D4    ; As it tells
  5085.     moveq    #0,D5            ; Offset (X) in planar bitmap
  5086.     moveq    #0,D6            ; Pixel per line
  5087.     OPT    OW+
  5088.  
  5089. .nextpixel
  5090.     move.l    52(A5),D0        ; For `n´ bit-planes
  5091.     subq.w    #1,D0
  5092.     lea    8(A3),A0        ; 1st plane ptr
  5093.     movea.l    A5,A2            ; Mixed buffer
  5094.  
  5095. .getB
  5096.     movea.l    (A0)+,A1
  5097.     move.b    0(A1,D5.l),(A2)+    ; Read eight pixel (one byte) of each bitplane
  5098.     subq.w    #1,D0
  5099.     bcc.s    .getB            ; For `n´ bitplanes
  5100.  
  5101.     cmpi.l    #7,52(A5)        ; HAM6 ?
  5102.     bhi.s    .doconvert
  5103.  
  5104.     clr.b    (A2)+            ; HAM6 has got 2 bits less than HAM8
  5105.     clr.b    (A2)+
  5106.  
  5107. .doconvert
  5108.     movem.l    D3-D6/A3-A5,-(sp)
  5109.     bsr.s    .getC
  5110.     movem.l    (sp)+,D3-D6/A3-A5
  5111.  
  5112.     addq.l    #1,D5            ; Worked out 8 pixel
  5113.     lea    24(A4),A4        ; Increase RGB24 buffer
  5114.  
  5115.     addq.w    #1,D6            ; New byte (8 pixel)
  5116.     cmp.w    D6,D4            ; End of line?
  5117.     bne.s    .nextpixel        ; If no new line
  5118.  
  5119.     movem.l    D3-D5,-(sp)
  5120.  
  5121. * WritePixelArray( SrcRect [pointer to src datas A0]
  5122. *           SrcX    X position D0
  5123. *           SrcY    Y position D1
  5124. *           SrcMod bytes per row in source rectangle D2
  5125. *           RastPort A1
  5126. *           DestX  D3
  5127. *           DestY  D4
  5128. *           SizeX  D5
  5129. *           SizeY  D6
  5130. *           SrcFmt RECTFMT_RGB )
  5131.  
  5132.     OPT    OW-
  5133.     movea.l    24(A5),A0        ; Datas
  5134.     moveq    #0,D0
  5135.     moveq    #0,D1
  5136.     moveq    #0,D2
  5137.     move.l    44(A5),D2
  5138.     movea.l    36(A5),A1        ; RastPort
  5139.     move.l    D3,D4            ; DestY
  5140.     moveq    #0,D3            ; DestX
  5141.     move.l    32(A5),D5        ; Width
  5142.     move.w    #1,D6            ; Height
  5143.     moveq    #RECTFMT_RGB,D7
  5144.     movea.l    28(A5),A6
  5145.     jsr    _LVOWritePixelArray(A6)
  5146.     OPT    OW+
  5147.  
  5148.     movem.l    (sp)+,D3-D5
  5149.  
  5150.     move.l    24(A5),A4        ; RGB24 buffer
  5151.  
  5152.     moveq    #0,D6            ; New X position (starting at zero)
  5153.     addq.w    #1,D3            ; Increase line number
  5154.  
  5155.     cmp.w    bm_Rows(A3),D3        ; Already done for all lines?
  5156.     bne.s    .nextpixel
  5157.  
  5158.     lea    56(sp),sp
  5159.     movea.l    (sp)+,A5
  5160.  
  5161.     move.l    _RGB24Ptr(A5),A1
  5162.     move.l    _RGB24Size(A5),D0
  5163.     movea.l    _SysBase(A5),A6
  5164.     jsr    _LVOFreeMem(A6)
  5165.  
  5166.     moveq    #-1,D0
  5167. .endall
  5168.     movem.l    (sp)+,D2-D7/A2-A6
  5169.     rts
  5170.  
  5171. *
  5172. ** Buffer filled with 24 bytes which hold 8 pixel
  5173. *
  5174. .getC
  5175.     movea.l    A5,A0            ; Mixed buffer
  5176.  
  5177.     move.l    (A0)+,D1        ; 4 bytes (plane0 pixel 0-7, plane1 pixel 0-7 and so on
  5178.     move.l    (A0)+,D2
  5179.     moveq    #0,D3
  5180.  
  5181.     movea.l    A4,A0            ; RGB24 buffer
  5182.     movea.l    48(A5),A3        ; Index colour table
  5183.     move.l    D1,A1
  5184.     move.l    D2,A2
  5185.  
  5186.     move.l    #$80808080,D0
  5187.     and.l    D0,D1            ; bit 0 of plane 0,1,2,3
  5188.     and.l    D0,D2            ; bit 0 of plane 4,5,6,7
  5189.  
  5190.     moveq    #-14,D0            ; See 'Counting ...' below for explantion
  5191.     move.l    D0,-(sp)
  5192.  
  5193. .GetPixelColour
  5194.  
  5195. * Original D1 pixel-0 bit 0 , P1 pixel-0 0 bit 1, P2 pixel-0 bit 2, P3 pixel-0 bit 4
  5196.  
  5197.     move.b    D1,D0            ; P3 pixel 0 in D0.b
  5198.     lsr.w    #8,D1            ; Get P2 pixel 0 on byte position in D1.b
  5199.     lsr.b    #4,D0            ; P3 pixel 0 on position 3
  5200.     lsr.b    #5,D1            ; P2 pixel 0 on position 2
  5201.     or.b    D0,D1
  5202.     move.b    D1,D7            ; Half lower nibble in D7 (bits 3 and 2)    
  5203.  
  5204.     swap.w    D1            ; Original P2 pixel 0, P3 pixel 0, P0 pixel 0, P1 pixel 0
  5205. *                      P0 pixel 0 and P1 pixel 0 in D1.w
  5206.  
  5207.     move.b    D1,D0            ; P1 pixel 0 in D0
  5208.     lsr.w    #8,D1            ; Get P1 pixel 0 on byte position
  5209.     lsr.b    #6,D0            ; P1 pixel 0 on position 1
  5210.     lsr.b    #7,D1            ; P0 pixel 0 on position 0
  5211.     or.b    D0,D1
  5212.     or.b    D1,D7            ; P3 P2 P1 P0
  5213.  
  5214. * --------------------
  5215.  
  5216. * Original P4 pixel 0 bit 4, P5 pixel 0 bit 5 , P6 pixel 0 bit 6, P7 pixel 0 bit 7
  5217.  
  5218.     move.b    D2,D0            ; P7 pixel 0 in D0
  5219.     lsr.w    #8,D2            ; Get P6 pixel 0 on byte position
  5220. *    lsr.b    #0,D0            ; P7 pixel 0 on position 7
  5221.     lsr.b    #1,D2            ; P6 pixel 0 on position 6
  5222.     or.b    D0,D2
  5223.     or.b    D2,D7            ; P7 P6 nn nn P3, P2, P1, P0
  5224.  
  5225.     swap.w    D2            ; Original P6 pixel 0, P7 pixel 0
  5226. *                      P6 pixel 0, P7 pixel 0 in D2.w
  5227.  
  5228.     move.b    D2,D0            ; P4 pixel 0 in D0
  5229.     lsr.w    #8,D2            ; Get P5 pixel 0 on byte position
  5230.     lsr.b    #2,D0            ; P4 pixel 0 on position 5
  5231.     lsr.b    #3,D2            ; P5 pixel 0 on position 4
  5232.     or.b    D0,D2
  5233.     or.b    D2,D7            ; P7, P6, P5, P4, P3, P2 P1 P0
  5234.  
  5235.     cmpi.l    #7,52(A5)        ; HAMSet equal to HAM8?
  5236.     bhi.s    .checkham8
  5237.  
  5238.     cmpi.b    #15,D7            ; Index = 15? (HAM6 used)
  5239.     bls.s    .storeHAM6        ; If index lower or equal 15 store unmodified index
  5240.     bra.s    .modifyHAM6        ; Else compute modified index
  5241.  
  5242. .checkham8
  5243.     cmpi.b    #63,D7            ; Index = 63? (HAM8 used)
  5244.     bls.s    .store            ; If index lower or equal 63 store unmodified index
  5245.  
  5246. .modify                    ; Modifiy new pixel by last stored
  5247.     move.b    -3(A0),(A0)+        ; Get red and take over
  5248.     move.b    -3(A0),(A0)+        ; Get green and take over
  5249.     move.b    -3(A0),(A0)+        ; Get blue and take over
  5250.  
  5251.     move.w    D7,D6            ; Index
  5252.  
  5253.     andi.w    #63,D7            ; Without H(old)A(nd)M(odified) bits
  5254.     lsl.b    #2,D7            ; 6-bit value to an 8 bit one
  5255.  
  5256.     andi.w    #192,D6            ; Only H(old)A(nd)M(odified) bits
  5257.     lsr.w    #6,D6            ; into lowest bit positions
  5258.     jmp    (pc,D6.w*2)        ; Calls one of the three `bra.s´ below
  5259.  
  5260.     bra.s    .modifyblue
  5261.     bra.s    .modifyred
  5262.     bra.s    .modifygreen
  5263.  
  5264. .modifyblue
  5265.     move.b    D7,-1(A0)
  5266.     bra.s    .repeat
  5267. .modifygreen
  5268.     move.b    D7,-2(A0)
  5269.     bra.s    .repeat
  5270. .modifyred
  5271.     move.b    D7,-3(A0)
  5272.     bra.s    .repeat
  5273.  
  5274. .modifyHAM6
  5275.     move.b    -3(A0),(A0)+        ; Get red
  5276.     move.b    -3(A0),(A0)+        ; Get green
  5277.     move.b    -3(A0),(A0)+        ; Get blue
  5278.  
  5279.     move.w    D7,D6
  5280.  
  5281.     andi.w    #15,D7            ; Without H(old)A(nd)M(odified) bits
  5282.     move.b    D7,D5            ; Save result
  5283.     lsl.b    #4,D5            ; Low nibble to high nibble
  5284.     or.b    D5,D7            ; Make new value
  5285.  
  5286.     andi.w    #48,D6            ; Only H(old)A(nd)M(odified) bits
  5287.     lsr.w    #4,D6            ; into lowest bit positions
  5288.     jmp    (pc,D6.w*2)
  5289.  
  5290.     bra.s    .modifyblue
  5291.     bra.s    .modifyred
  5292.     bra.s    .modifygreen
  5293.  
  5294. .storeHAM6
  5295.     andi.w    #15,D7
  5296.     move.w    D7,D3            ; INDEX to colour value
  5297.     lsl.w    #3,D3            ; INDEX * 8
  5298.     move.w    D7,D4
  5299.     lsl.w    #2,D4            ; INDEX * 4
  5300.     add.w    D4,D3            ; == mulu 12 D3 (12 bytes per RGB gun used by OS3 structure)
  5301.     lea    0(A3,D3.w),A4        ; Colour values (longwords)
  5302.     move.b    (A4),(A0)+        ; Get only most significant byte
  5303.     move.b    4(A4),(A0)+        ; the same...
  5304.     move.b    8(A4),(A0)+        ; and again
  5305.     bra.s    .repeat
  5306.  
  5307. .store
  5308.     andi.w    #63,D7
  5309.     move.w    D7,D3            ; INDEX to colour value
  5310.     lsl.w    #3,D3            ; INDEX * 8
  5311.     move.w    D7,D4
  5312.     lsl.w    #2,D4            ; INDEX * 4
  5313.     add.w    D4,D3            ; == mulu 12 D3
  5314.     lea    0(A3,D3.w),A4        ; Colour values (longwords)
  5315.     move.b    (A4),(A0)+        ; See above
  5316.     move.b    4(A4),(A0)+
  5317.     move.b    8(A4),(A0)+
  5318.  
  5319. * Repeat GetPixelColour until a complete byte (8 pixel) is worked out...
  5320. .repeat
  5321.     move.l    (sp)+,D0
  5322.  
  5323.     move.l    A1,D1
  5324.     move.l    A2,D2
  5325.  
  5326. .thejump
  5327.     addi.l    #20,D0
  5328.     move.l    D0,-(sp)
  5329.  
  5330.     jmp    (pc,D0.w)        ; Call one of the masks below depending on value in D0
  5331.  
  5332. .end
  5333.     move.l    (sp)+,D0        ; Counting 2
  5334.     rts                ; Counting 4
  5335.  
  5336. .mask1                    ; Counting 6 :: (-14) = (+6 - +20 = -14) -> 1st offset to PC to reach this (.mask1)
  5337.     move.l    #$40404040,D0        ; -- Each mask has got 15 instruction surrounded by 20 bytes code
  5338.     and.l    D0,D1            ; bit 1 of plane 0,1,2,3
  5339.     and.l    D0,D2            ; bit 1 of plane 4,5,6,7
  5340.     moveq    #1,D0
  5341.     lsl.l    D0,D1
  5342.     lsl.l    D0,D2
  5343.     bra.w    .GetPixelColour
  5344.  
  5345. .mask2                    ; 26
  5346.     move.l    #$20202020,D0
  5347.     and.l    D0,D1            ; bit 2 of plane 0,1,2,3
  5348.     and.l    D0,D2            ; bit 2 of plane 4,5,6,7
  5349.     moveq    #2,D0
  5350.     lsl.l    D0,D1
  5351.     lsl.l    D0,D2
  5352.     bra.w    .GetPixelColour
  5353.  
  5354. .mask3                    ; 46
  5355.     move.l    #$10101010,D0
  5356.     and.l    D0,D1            ; bit 3 of plane 0,1,2,3
  5357.     and.l    D0,D2            ; bit 3 of plane 4,5,6,7
  5358.     moveq    #3,D0
  5359.     lsl.l    D0,D1
  5360.     lsl.l    D0,D2
  5361.     bra.w    .GetPixelColour
  5362.  
  5363. .mask4                    ; 66
  5364.     move.l    #$08080808,D0
  5365.     and.l    D0,D1            ; bit 4 of plane 0,1,2,3
  5366.     and.l    D0,D2            ; bit 4 of plane 4,5,6,7
  5367.     moveq    #4,D0
  5368.     lsl.l    D0,D1
  5369.     lsl.l    D0,D2
  5370.     bra.w    .GetPixelColour
  5371.  
  5372. .mask5                    ; 86
  5373.     move.l    #$04040404,D0
  5374.     and.l    D0,D1            ; bit 5 of plane 0,1,2,3
  5375.     and.l    D0,D2            ; bit 5 of plane 4,5,6,7
  5376.     moveq    #5,D0
  5377.     lsl.l    D0,D1
  5378.     lsl.l    D0,D2
  5379.     bra.w    .GetPixelColour
  5380.  
  5381. .mask6
  5382.     move.l    #$02020202,D0
  5383.     and.l    D0,D1            ; bit 6 of plane 0,1,2,3
  5384.     and.l    D0,D2            ; bit 6 of plane 4,5,6,7
  5385.     moveq    #6,D0
  5386.     lsl.l    D0,D1
  5387.     lsl.l    D0,D2
  5388.     bra.w    .GetPixelColour
  5389.  
  5390. .mask7
  5391.     move.l    #$01010101,D0
  5392.     and.l    D0,D1            ; bit 7 of plane 0,1,2,3
  5393.     and.l    D0,D2            ; bit 7 of plane 4,5,6,7
  5394.     moveq    #7,D0
  5395.     lsl.l    D0,D1
  5396.     lsl.l    D0,D2
  5397.     bra.w    .GetPixelColour
  5398.  
  5399. .mask8                    ; Does not exists!!!
  5400.     bra.w    .end
  5401.  
  5402. _HAMtoRGB24end
  5403.     OPT    P=68000
  5404.  
  5405. *****************************************************
  5406. *
  5407. ** Same as above only for more than 9 and less than 17 bitplanes (not HAM) encoded
  5408. *
  5409.  
  5410.     OPT    P=68020
  5411.  
  5412. _CLUTtoRGB16
  5413. *    A0 - bitmap, A1 Rastport
  5414.  
  5415.     movem.l    D2-D7/A2-A6,-(sp)
  5416.  
  5417.     movea.l    A0,A3            ; Bitmap
  5418.     movea.l    A1,A2            ; RastPort
  5419.  
  5420.     tst.l    _CyberGfxBase(A5)
  5421.     bne.s    .start
  5422.     movea.l    _SysBase(A5),A6
  5423.     lea    _CyberGfxName(pc),A1
  5424.     moveq    #40,D0
  5425.     jsr    _LVOOpenLibrary(A6)
  5426.     move.l    D0,_CyberGfxBase(A5)
  5427.     beq.w    .endall
  5428. .start
  5429.     OPT    OW-
  5430.     move.w    bm_BytesPerRow(A3),D0    ; CLUT (9-16 bits) become to a RGB (24 bit) gun, which is written to a 16 bit display
  5431.     mulu.w    #24,D0
  5432.     move.l    D0,D3
  5433.     move.l    D0,_RGB24Size(A5)
  5434.     move.l    #MEMF_PUBLIC|MEMF_CLEAR,D1
  5435.     movea.l    _SysBase(A5),A6
  5436.     jsr    _LVOAllocMem(A6)
  5437.     move.l    D0,_RGB24Ptr(A5)    ; Buffer for RGB24 format
  5438.     beq.w    .endall
  5439.     OPT    OW+
  5440.  
  5441.     move.l    _CyberGfxBase(A5),D1
  5442.     move.l    _ImageWidth(A5),D2
  5443.     move.l    _RGB32Values(A5),D4
  5444.  
  5445.     move.l    A5,-(sp)
  5446.     lea    -56(sp),sp        ; Mixed buffer
  5447.     movea.l    sp,A5
  5448.  
  5449. *    move.l    D0,24(A5)        ; Data buffer
  5450. *    move.l    D1,28(A5)        ; CyberGfxBase
  5451. *    move.l    D2,32(A5)        ; ImageWidth
  5452. *    move.l    A2,36(A5)        ; RastPort
  5453. *    move.l    D3,44(A5)        ; Size of one 24 bit RGB row
  5454. *    move.l    D4,48(A5)        ; RGB32Values
  5455.  
  5456.     move.l    D0,32(A5)        ; Data buffer
  5457.     move.l    D1,36(A5)        ; CyberGfxBase
  5458.     move.l    D2,40(A5)        ; ImageWidth
  5459.     move.l    A2,44(A5)        ; RastPort
  5460.     move.l    D3,48(A5)        ; Size of one 24 bit RGB row
  5461.     move.l    D4,52(A5)        ; RGB32Values
  5462.     
  5463.     movea.l    D0,A4            ; Data
  5464.  
  5465.     OPT    OW-
  5466.     moveq    #0,D3            ; Line
  5467.     moveq    #0,D4            ; Bytes per row
  5468.     move.w    bm_BytesPerRow(A3),D4    ; As it tells
  5469.     moveq    #0,D5            ; Offset (X) in planar bitmap
  5470.     moveq    #0,D6            ; Pixel per line
  5471.     OPT    OW+
  5472.  
  5473. .nextpixel
  5474.     moveq    #15,D0            ; For 16 bit-planes
  5475.     lea    8(A3),A0        ; 1st plane ptr
  5476.     movea.l    A5,A2            ; Mixed buffer
  5477.  
  5478. .getB
  5479.     move.l    (A0)+,D1
  5480.     bne.s    .exists
  5481.     move.b    D1,(A2)+        ; No data (e.g. 13 bitplanes and bitplane 14/15/16 encountered)
  5482.     bra.s    .further
  5483. .exists
  5484.     movea.l    D1,A1
  5485.     move.b    0(A1,D5.l),(A2)+    ; Read eight pixel (one byte) of each bitplane
  5486. .further
  5487.     subq.w    #1,D0
  5488.     bcc.s    .getB            ; For `n´ bitplanes
  5489.  
  5490. .doconvert
  5491.     movem.l    D3-D6/A3-A5,-(sp)
  5492.     bsr.s    .getC
  5493.     movem.l    (sp)+,D3-D6/A3-A5
  5494.  
  5495.     addq.l    #1,D5            ; Worked out 8 pixel
  5496.     lea    24(A4),A4        ; Increase RGB24 buffer
  5497.  
  5498.     addq.w    #1,D6            ; New byte (8 pixel)
  5499.     cmp.w    D6,D4            ; End of line?
  5500.     bne.s    .nextpixel        ; If no new line
  5501.  
  5502.     movem.l    D3-D5,-(sp)
  5503.  
  5504. * WritePixelArray( SrcRect [pointer to src datas A0]
  5505. *           SrcX    X position D0
  5506. *           SrcY    Y position D1
  5507. *           SrcMod bytes per row in source rectangle D2
  5508. *           RastPort A1
  5509.  
  5510. *           DestX  D3
  5511. *           DestY  D4
  5512. *           SizeX  D5
  5513. *           SizeY  D6
  5514. *           SrcFmt RECTFMT_RGB )
  5515.  
  5516.     OPT    OW-
  5517.     movea.l    32(A5),A0        ; Datas
  5518.     moveq    #0,D0
  5519.     moveq    #0,D1
  5520.     moveq    #0,D2
  5521.     move.l    48(A5),D2
  5522.     movea.l    44(A5),A1        ; RastPort
  5523.     move.l    D3,D4            ; DestY
  5524.     moveq    #0,D3            ; DestX
  5525.     move.l    40(A5),D5        ; Width
  5526.     move.w    #1,D6            ; Height
  5527.     moveq    #RECTFMT_RGB,D7
  5528.     movea.l    36(A5),A6
  5529.     jsr    _LVOWritePixelArray(A6)
  5530.     OPT    OW+
  5531.  
  5532.     movem.l    (sp)+,D3-D5
  5533.  
  5534.     move.l    32(A5),A4        ; RGB24 buffer
  5535.  
  5536.     moveq    #0,D6            ; New X position (starting at zero)
  5537.     addq.w    #1,D3            ; Increase line number
  5538.  
  5539.     cmp.w    bm_Rows(A3),D3        ; Already done for all lines?
  5540.     bne.s    .nextpixel
  5541.  
  5542.     lea    56(sp),sp
  5543.     movea.l    (sp)+,A5
  5544.  
  5545.     move.l    _RGB24Ptr(A5),A1
  5546.     move.l    _RGB24Size(A5),D0
  5547.     movea.l    _SysBase(A5),A6
  5548.     jsr    _LVOFreeMem(A6)
  5549.  
  5550.     moveq    #-1,D0
  5551. .endall
  5552.     movem.l    (sp)+,D2-D7/A2-A6
  5553.     rts
  5554.  
  5555. *
  5556. ** Buffer filled with 24 bytes which hold 8 pixel
  5557. *
  5558. .getC
  5559.     movea.l    A5,A0            ; Mixed buffer
  5560.     move.l    52(A5),A5        ; RGB32Values
  5561.     movem.l    (A0)+,D1-D4        ; 8 bytes (plane0 pixel 0-15, plane1 pixel 0-15 and so on
  5562.     movea.l    A4,A0            ; RGB24 buffer
  5563.  
  5564.     move.l    D1,A1
  5565.     move.l    D2,A2
  5566.     move.l    D3,A3
  5567.     move.l    D4,A4
  5568.  
  5569.     move.l    #$80808080,D0
  5570.     and.l    D0,D1            ; bit 0 of plane 0,1,2,3
  5571.     and.l    D0,D2            ; bit 0 of plane 4,5,6,7
  5572.     and.l    D0,D3            ; bit 0 of plane 8,9,10,11
  5573.     and.l    D0,D4            ; bit 0 of plane 12,13,14,15
  5574.  
  5575.     moveq    #-22,D0            ; See 'Counting ...' below for explantion
  5576.     move.l    D0,-(sp)
  5577.  
  5578. .GetPixelColour
  5579.     moveq    #0,D7
  5580.     move.l    D7,D5
  5581.  
  5582. * Original D1 pixel-0 bit 0 , P1 pixel-0 bit 1, P2 pixel-0 bit 2, P3 pixel-0 bit 4
  5583.  
  5584.     move.b    D1,D0            ; P3 pixel 0 in D0.b
  5585.     lsr.w    #8,D1            ; Get P2 pixel 0 on byte position in D1.b
  5586.     lsr.b    #4,D0            ; P3 pixel 0 on position 3
  5587.     lsr.b    #5,D1            ; P2 pixel 0 on position 2
  5588.     or.b    D0,D1
  5589.     move.b    D1,D7            ; Half lower nibble in D7 (bits 3 and 2)    
  5590.  
  5591.     swap.w    D1            ; Original P2 pixel 0, P3 pixel 0, P0 pixel 0, P1 pixel 0
  5592. *                      P0 pixel 0 and P1 pixel 0 in D1.w
  5593.  
  5594.     move.b    D1,D0            ; P1 pixel 0 in D0
  5595.     lsr.w    #8,D1            ; Get P1 pixel 0 on byte position
  5596.     lsr.b    #6,D0            ; P1 pixel 0 on position 1
  5597.     lsr.b    #7,D1            ; P0 pixel 0 on position 0
  5598.     or.b    D0,D1
  5599.     or.b    D1,D7            ; P3 P2 P1 P0
  5600.  
  5601. * --------------------
  5602.  
  5603. * Original P4 pixel 0 bit 4, P5 pixel 0 bit 5 , P6 pixel 0 bit 6, P7 pixel 0 bit 7
  5604.  
  5605.     move.b    D2,D0            ; P7 pixel 0 in D0
  5606.     lsr.w    #8,D2            ; Get P6 pixel 0 on byte position
  5607. *    lsr.b    #0,D0            ; P7 pixel 0 on position 7
  5608.     lsr.b    #1,D2            ; P6 pixel 0 on position 6
  5609.     or.b    D0,D2
  5610.     or.b    D2,D7            ; P7 P6 nn nn P3, P2, P1, P0
  5611.  
  5612.     swap.w    D2            ; Original P6 pixel 0, P7 pixel 0
  5613. *                      P6 pixel 0, P7 pixel 0 in D2.w
  5614.  
  5615.     move.b    D2,D0            ; P4 pixel 0 in D0
  5616.     lsr.w    #8,D2            ; Get P5 pixel 0 on byte position
  5617.     lsr.b    #2,D0            ; P4 pixel 0 on position 5
  5618.     lsr.b    #3,D2            ; P5 pixel 0 on position 4
  5619.     or.b    D0,D2
  5620.     or.b    D2,D7            ; P7, P6, P5, P4, P3, P2 P1 P0
  5621.  
  5622. * --------------------
  5623.  
  5624.     move.b    D3,D0            ; P3 pixel 0 in D0.b
  5625.     lsr.w    #8,D3            ; Get P2 pixel 0 on byte position in D1.b
  5626.     lsr.b    #4,D0            ; P3 pixel 0 on position 3
  5627.     lsr.b    #5,D3            ; P2 pixel 0 on position 2
  5628.     or.b    D0,D3
  5629.     move.b    D3,D5            ; Half lower nibble in D7 (bits 3 and 2)    
  5630.  
  5631.     swap.w    D3            ; Original P2 pixel 0, P3 pixel 0, P0 pixel 0, P1 pixel 0
  5632. *                      P0 pixel 0 and P1 pixel 0 in D1.w
  5633.  
  5634.     move.b    D3,D0            ; P1 pixel 0 in D0
  5635.     lsr.w    #8,D3            ; Get P1 pixel 0 on byte position
  5636.     lsr.b    #6,D0            ; P1 pixel 0 on position 1
  5637.     lsr.b    #7,D3            ; P0 pixel 0 on position 0
  5638.     or.b    D0,D3
  5639.     or.b    D3,D5            ; P3 P2 P1 P0
  5640.  
  5641. * --------------------
  5642.  
  5643. * Original P4 pixel 0 bit 4, P5 pixel 0 bit 5 , P6 pixel 0 bit 6, P7 pixel 0 bit 7
  5644.  
  5645.     move.b    D4,D0            ; P7 pixel 0 in D0
  5646.     lsr.w    #8,D4            ; Get P6 pixel 0 on byte position
  5647. *    lsr.b    #0,D0            ; P7 pixel 0 on position 7
  5648.     lsr.b    #1,D4            ; P6 pixel 0 on position 6
  5649.     or.b    D0,D4
  5650.     or.b    D4,D5            ; P7 P6 nn nn P3, P2, P1, P0
  5651.  
  5652.     swap.w    D4            ; Original P6 pixel 0, P7 pixel 0
  5653. *                      P6 pixel 0, P7 pixel 0 in D2.w
  5654.  
  5655.     move.b    D4,D0            ; P4 pixel 0 in D0
  5656.     lsr.w    #8,D4            ; Get P5 pixel 0 on byte position
  5657.     lsr.b    #2,D0            ; P4 pixel 0 on position 5
  5658.     lsr.b    #3,D4            ; P5 pixel 0 on position 4
  5659.     or.b    D0,D4
  5660.     or.b    D4,D5            ; P7, P6, P5, P4, P3, P2 P1 P0
  5661.  
  5662.     lsl.w    #8,D5
  5663.     or.w    D5,D7
  5664.  
  5665. .store
  5666.     move.w    D7,D5            ; INDEX
  5667.     add.l    D5,D5            ; Index * 2
  5668.     add.l    D5,D7            ; = Index * 3
  5669.     
  5670.     move.b    0(A5,D7.l),(A0)+    ; Colour value R
  5671.     move.b    1(A5,D7.l),(A0)+    ; Colour value G
  5672.     move.b    2(A5,D7.l),(A0)+    ; Colour value B
  5673.  
  5674.  
  5675. * Repeat GetPixelColour until a complete byte (8 pixel) is worked out...
  5676. .repeat
  5677.     move.l    (sp)+,D0
  5678.  
  5679.     move.l    A1,D1
  5680.     move.l    A2,D2
  5681.     move.l    A3,D3
  5682.     move.l    A4,D4
  5683.  
  5684. .thejump
  5685.     addi.l    #28,D0
  5686.     move.l    D0,-(sp)
  5687.  
  5688.     jmp    (pc,D0.w)        ; Call one of the masks below depending on value in D0
  5689.  
  5690. .end
  5691.     move.l    (sp)+,D0        ; Counting 2
  5692.     rts                ; Counting 4
  5693.  
  5694. .mask1                    ; Counting 6 :: (-22) = (+6 - +28 = -22) -> 1st offset to PC to reach this (.mask1)
  5695.     move.l    #$40404040,D0        ; -- Each mask has got 19 instruction surrounded by 28 bytes code
  5696.     and.l    D0,D1            ; bit 1 of plane 0,1,2,3
  5697.     and.l    D0,D2            ; bit 1 of plane 4,5,6,7
  5698.     and.l    D0,D3
  5699.     and.l    D0,D4
  5700.     moveq    #1,D0
  5701.     lsl.l    D0,D1
  5702.     lsl.l    D0,D2
  5703.     lsl.l    D0,D3
  5704.     lsl.l    D0,D4
  5705.     bra.w    .GetPixelColour
  5706.  
  5707. .mask2                    ; 26
  5708.     move.l    #$20202020,D0
  5709.     and.l    D0,D1            ; bit 2 of plane 0,1,2,3
  5710.     and.l    D0,D2            ; bit 2 of plane 4,5,6,7
  5711.     and.l    D0,D3            ; bit 2 of plane 4,5,6,7
  5712.     and.l    D0,D4            ; bit 2 of plane 4,5,6,7
  5713.     moveq    #2,D0
  5714.     lsl.l    D0,D1
  5715.     lsl.l    D0,D2
  5716.     lsl.l    D0,D3
  5717.     lsl.l    D0,D4
  5718.     bra.w    .GetPixelColour
  5719.  
  5720. .mask3                    ; 46
  5721.     move.l    #$10101010,D0
  5722.     and.l    D0,D1            ; bit 3 of plane 0,1,2,3
  5723.     and.l    D0,D2            ; bit 3 of plane 4,5,6,7
  5724.     and.l    D0,D3            ; bit 3 of plane 4,5,6,7
  5725.     and.l    D0,D4            ; bit 3 of plane 4,5,6,7
  5726.     moveq    #3,D0
  5727.     lsl.l    D0,D1
  5728.     lsl.l    D0,D2
  5729.     lsl.l    D0,D3
  5730.     lsl.l    D0,D4
  5731.     bra.w    .GetPixelColour
  5732.  
  5733. .mask4                    ; 66
  5734.     move.l    #$08080808,D0
  5735.     and.l    D0,D1            ; bit 4 of plane 0,1,2,3
  5736.     and.l    D0,D2            ; bit 4 of plane 4,5,6,7
  5737.     and.l    D0,D3            ; bit 4 of plane 4,5,6,7
  5738.     and.l    D0,D4            ; bit 4 of plane 4,5,6,7
  5739.     moveq    #4,D0
  5740.     lsl.l    D0,D1
  5741.     lsl.l    D0,D2
  5742.     lsl.l    D0,D3
  5743.     lsl.l    D0,D4
  5744.     bra.w    .GetPixelColour
  5745.  
  5746. .mask5                    ; 86
  5747.     move.l    #$04040404,D0
  5748.     and.l    D0,D1            ; bit 5 of plane 0,1,2,3
  5749.     and.l    D0,D2            ; bit 5 of plane 4,5,6,7
  5750.     and.l    D0,D3            ; bit 5 of plane 4,5,6,7
  5751.     and.l    D0,D4            ; bit 5 of plane 4,5,6,7
  5752.     moveq    #5,D0
  5753.     lsl.l    D0,D1
  5754.     lsl.l    D0,D2
  5755.     lsl.l    D0,D3
  5756.     lsl.l    D0,D4
  5757.     bra.w    .GetPixelColour
  5758.  
  5759. .mask6
  5760.     move.l    #$02020202,D0
  5761.     and.l    D0,D1            ; bit 6 of plane 0,1,2,3
  5762.     and.l    D0,D2            ; bit 6 of plane 4,5,6,7
  5763.     and.l    D0,D3            ; bit 6 of plane 4,5,6,7
  5764.     and.l    D0,D4            ; bit 6 of plane 4,5,6,7
  5765.     moveq    #6,D0
  5766.     lsl.l    D0,D1
  5767.     lsl.l    D0,D2
  5768.     lsl.l    D0,D3
  5769.     lsl.l    D0,D4
  5770.     bra.w    .GetPixelColour
  5771.  
  5772. .mask7
  5773.     move.l    #$01010101,D0
  5774.     and.l    D0,D1            ; bit 7 of plane 0,1,2,3
  5775.     and.l    D0,D2            ; bit 7 of plane 4,5,6,7
  5776.     and.l    D0,D3            ; bit 7 of plane 4,5,6,7
  5777.     and.l    D0,D4            ; bit 7 of plane 4,5,6,7
  5778.     moveq    #7,D0
  5779.     lsl.l    D0,D1
  5780.     lsl.l    D0,D2
  5781.     lsl.l    D0,D3
  5782.     lsl.l    D0,D4
  5783.     bra.w    .GetPixelColour
  5784.  
  5785. .mask8                    ; Does not exists!!!
  5786.     bra.w    .end
  5787.  
  5788. _CLUT16oRGB16end
  5789.     OPT    P=68000
  5790.  
  5791. ***********************************
  5792. * ONIX 02.10.'91
  5793. *
  5794. * MakeCounteven
  5795. *
  5796. * Inputs: D0 - value
  5797. * Results: D0 - value
  5798. *
  5799.  
  5800. _MakeCountEven
  5801.     addq.l    #7,D0
  5802.     andi.l    #-8,D0
  5803.     rts
  5804.  
  5805. ********************************
  5806. *
  5807. * Filter ANSI-escape code.
  5808. *
  5809. * Inputs: none
  5810. * Results: none
  5811. *
  5812.  
  5813. _IgnoreSettings
  5814.     movea.l    _TextPtr(A5),A0        ; Address file in memory
  5815.     addq.l    #2,A0            ; Overread #$200A
  5816.     move.l    _FileSize(A5),D0    ; Length of this file
  5817.     moveq    #0,D1            ; Amount lines
  5818.  
  5819. 1$
  5820.     subq.l    #1,D0            ; Length -1
  5821.     bmi.s    .done
  5822.  
  5823.     cmpi.b    #10,(A0)+        ; LineFeed?
  5824.     beq.s    6$            ; If so...
  5825.  
  5826.     cmpi.b    #12,-1(A0)        ; ANSI-sequence?
  5827.     beq.s    5$            ; If so...
  5828.  
  5829.     cmpi.b    #13,-1(A0)        ; LineFeed?
  5830.     beq.s    5$            ; If not...
  5831.  
  5832. 2$
  5833.     cmpi.b    #31,-1(A0)
  5834.     bhi.s    1$
  5835.  
  5836.     cmpi.b    #27,-1(A0)
  5837.     beq.s    1$
  5838.  
  5839.     cmpi.b    #8,-1(A0)
  5840.     bls.s    3$    
  5841.  
  5842.     bra.s    1$
  5843.  
  5844. 3$
  5845.     move.b    #' ',-1(A0)
  5846.     bra.s    1$
  5847.  
  5848. .done
  5849.     move.l    D1,_LinesInFile(A5)    ; Lines in file
  5850.     bra.s    _SetTitle
  5851.  
  5852. 5$
  5853.     move.b    #10,-1(A0)        ; LineFeed instead of ANSI!
  5854. 6$
  5855.     addq.l    #1,D1
  5856.     bra.s    1$
  5857. ************************************
  5858. *
  5859. * Make title for main-window
  5860. *
  5861. * Inputs: none
  5862. * Results: none
  5863. *
  5864.  
  5865. _SetTitle
  5866.     move.l    A2,-(sp)
  5867.     lea    _WindowTitle(A5),A2    ; Address buffer
  5868.     lea    _FIB(A5),A0        ; Address FileInfoBlock
  5869.     addq.l    #8,A0            ; Get the name of the file
  5870. 1$
  5871.     move.b    (A0)+,(A2)+        ; Copy the file's name
  5872.     tst.b    (A0)
  5873.     bne.s    1$
  5874.     move.b    #' ',(A2)+        ; Write Blank
  5875.     move.b    #'(',(A2)+
  5876.     movea.l    A2,A0            ; Address buffer
  5877.     move.l    _LinesInFile(A5),D0    ; Number of lines in file
  5878.     bsr.w    _comdec            ; Convert count into ascii
  5879.     move.b    #' ',(A0)+        ; Write String ' Lines)  Current line: '
  5880.     move.b    #'L',(A0)+
  5881.     move.b    #'i',(A0)+
  5882.     move.b    #'n',(A0)+
  5883.     move.b    #'e',(A0)+
  5884.     move.b    #'s',(A0)+
  5885.     move.b    #')',(A0)+
  5886.     move.b    #' ',(A0)+
  5887.     move.b    #' ',(A0)+
  5888.     move.b    #'C',(A0)+
  5889.     move.b    #'u',(A0)+
  5890.     move.b    #'r',(A0)+
  5891.     move.b    #'r',(A0)+
  5892.     move.b    #'e',(A0)+
  5893.     move.b    #'n',(A0)+
  5894.     move.b    #'t',(A0)+
  5895.     move.b    #' ',(A0)+
  5896.     move.b    #'l',(A0)+
  5897.     move.b    #'i',(A0)+
  5898.     move.b    #'n',(A0)+
  5899.     move.b    #'e',(A0)+
  5900.     move.b    #':',(A0)+
  5901.     move.b    #' ',(A0)+
  5902.     move.l    A0,_PtrToWTitle(A5)    ; Remember current buffer address
  5903.  
  5904.     movea.l    _IntuitionBase(A5),A6
  5905.     movea.l    _WindowPtr(A5),A0
  5906.     lea    _WindowTitle(A5),A1    ; Address new window title
  5907.     lea    _WindowName(pc),A2    ; Address new screen title
  5908.     jsr    _LVOSetWindowTitles(A6)    ; Set window and screen title
  5909.  
  5910.     movea.l    (sp)+,A2    
  5911.     rts
  5912.  
  5913. _ComLine
  5914.     tst.l    _TextPtr(A5)        ; File in memory?
  5915.     beq.w    2$            ; No...
  5916.  
  5917.     tst.b    _AudGadget(A5)        ; We make a sound audible, thus no text and lines!
  5918.     bne.w    2$
  5919.  
  5920.     move.l    A2,-(sp)
  5921.  
  5922.     movea.l    _PtrToWTitle(A5),A0    ; Save current buffer address for later
  5923.     move.l    _Line(A5),D0        ; Current line
  5924.     bsr.w    _comdec
  5925.     move.b    #' ',(A0)+        ; Write blanks...
  5926.     move.b    #' ',(A0)+
  5927.     move.b    #' ',(A0)+
  5928.     move.b    #' ',(A0)+
  5929.     move.b    #' ',(A0)+
  5930.     move.b    #' ',(A0)+
  5931.     move.b    #' ',(A0)+
  5932.     clr.b    (A0)            ; End of window-title
  5933.  
  5934.     movea.l    _GfxBase(A5),A6
  5935.     movea.l    _WindowPtr(A5),A0
  5936.     movea.l    wd_BorderRPort(A0),A2    ; RastPort
  5937.  
  5938.  
  5939.     move.w    _BgPen(A5),D0        ; Backgroundcolour of window's titel bar
  5940.     movea.l    A2,A1
  5941.     jsr    _LVOSetBPen(A6)
  5942.  
  5943.     moveq    #1,D0            ; Foregroundcolour
  5944.     movea.l    A2,A1
  5945.     jsr    _LVOSetAPen(A6)
  5946.  
  5947.     movea.l    rp_BitMap(A2),A0    ; Bitmap for the title
  5948.     cmpi.b    #1,bm_Depth(A0)        ; Only one bitplane used?
  5949.     bne.s    .normal            ; No, more.
  5950.  
  5951.     moveq    #0,D0            ; Because of the inversed title bar
  5952.     movea.l    A2,A1
  5953.     jsr    _LVOSetAPen(A6)
  5954.  
  5955. .normal
  5956.     move.b    #RP_JAM2,D0
  5957.     movea.l    A2,A1
  5958.     jsr    _LVOSetDrMd(A6)
  5959.  
  5960.     moveq    #30,D0            ; X
  5961.     moveq    #1,D1            ; Y
  5962.     movea.l    A2,A1
  5963.     add.w    62(A2),D1        ; TxBaseLine
  5964.     jsr    _LVOMove(A6)
  5965.  
  5966.     lea    _WindowTitle(A5),A0
  5967.     moveq    #-1,D0
  5968. 1$
  5969.     tst.b    (A0)+
  5970.     dbeq    D0,1$
  5971.     not.l    D0
  5972.     lea    _WindowTitle(A5),A0
  5973.     movea.l    A2,A1
  5974.     jsr    _LVOText(A6)
  5975.     movea.l    (sp)+,A2
  5976. 2$
  5977.     rts
  5978.  
  5979. **********************************************
  5980. *
  5981. * Size window to maximum "!?!?|?" .
  5982. *
  5983. * Inputs: none
  5984. * Results: none
  5985. *
  5986.  
  5987. _EnlargeWindow
  5988.     movem.l    D0-D3/A0-A2/A6,-(sp)
  5989.     movea.l    _IntuitionBase(A5),A6
  5990.     movea.l    _WindowPtr(A5),A0
  5991.     movea.l    A0,A2
  5992.     lea    _WindowRecord(A5),A1
  5993.     move.w    wd_LeftEdge(A0),D0
  5994.     move.w    wd_TopEdge(A0),D1
  5995.     neg.w    D0            ; Place it to 0,
  5996.     neg.w    D1            ; 0
  5997.     add.w    (A1),D0            ; leftEdge
  5998.     add.w    nw_TopEdge(A1),D1    ; topEdge
  5999.     jsr    _LVOMoveWindow(A6)    ; Move window to 0,0 or to user specified X- and Y-position
  6000.  
  6001.     bsr.s    1$            ; Wait for intuition timer tick
  6002.     movea.l    A2,A0            ; Intuition-Engage-Window-Record
  6003.     move.w    wd_Width(A0),D2        ; Current window-width
  6004.     move.w    wd_Height(A0),D3    ; Current window-height
  6005.  
  6006.     lea    _WindowRecord(A5),A1    ; Address window-record
  6007.     move.w    nw_Width(A1),D0        ; User's width
  6008.     move.w    nw_Height(A1),D1    ; Users's height
  6009.     sub.w    D2,D0            ; Substract
  6010.     sub.w    D3,D1
  6011.     jsr    _LVOSizeWindow(A6)    ; Enlarge? window
  6012.     movem.l    (sp)+,D0-D3/A0-A2/A6
  6013.  
  6014.     bsr.s    1$            ; Wait
  6015.  
  6016.     bsr.w    _SetPageWidthAndLen
  6017.     bsr.w    _RestoreCurrentPage
  6018.     bra.w    _Loop
  6019.  
  6020. 1$
  6021.     movem.l    D0-D3/A0-A3/A6,-(sp)
  6022.     moveq    #6,D1            ; 6/60 seconds = 1/10 second == int. timer tick
  6023.     movea.l    _DOSBase(A5),A6
  6024.     jsr    _LVODelay(A6)
  6025.     movem.l    (sp)+,D0-D3/A0-A3/A6
  6026.     rts
  6027.  
  6028. *******************************************************************
  6029. *
  6030. * Format text, display that text in a window, get Gadget-status and
  6031. * return.
  6032. *
  6033. * Inputs: Stack - reverse arguments on stack
  6034. * Results: D0 = NULL = FALSE , D0 ~NULL = OK
  6035. *
  6036.  
  6037.     IFD    __G2
  6038.     OPT    OW-            ; Devpac: Don't display optimisation warnings
  6039.     ENDC
  6040.  
  6041. _FmtDisplay
  6042.  
  6043.      STRUCTURE    printfBuf,0
  6044.     STRUCT    _Cnt,4            ; Counter for number of chars
  6045.     STRUCT    _Buffer,512        ; Room for max. 511 chars
  6046.     LABEL    _Args            ; Dynamic wide
  6047.     LABEL    _pfbso
  6048.  
  6049. .printf
  6050.     movem.l    D2-D6/A2-A3,-(sp)
  6051.     movea.l    32(sp),A0        ; Pointer to the string which should be formatted
  6052.     moveq    #-1,D1            ; Dummy-counter
  6053.     moveq    #0,D0            ; Counter for arguments
  6054. 0$
  6055.     cmpi.b    #'%',(A0)        ; Argument?
  6056.     bne.s    .NoArg            ; No...
  6057.     addq.w    #1,D0            ; Argument +1
  6058. .NoArg
  6059.     tst.b    (A0)+            ; End of string?
  6060.     dbeq    D1,0$            ; If not
  6061.  
  6062.     lsl.l    #2,D0            ; * 4 == longwords
  6063.     addi.l    #_pfbso,D0        ; 4 bytes count, plus buffer
  6064.     addq.l    #7,D0
  6065.     andi.l    #-8,D0            ; Align size
  6066.     move.l    D0,D5            ; Save size
  6067.     move.l    #MEMF_PUBLIC|MEMF_CLEAR,D1
  6068.     movea.l    _SysBase(A5),A6
  6069.     jsr    _LVOAllocMem(A6)
  6070.     move.l    D0,D4            ; Address table
  6071.     beq.s    3$            ; Upon error
  6072.  
  6073.     movea.l    32(sp),A0        ; Pointer to string
  6074.     lea    36(sp),A1        ; Pointer to 1. argument
  6075.     movea.l    D4,A2            ; Address table
  6076.     lea    _Args(A2),A2        ; Address arguments-buffer (up from 516)
  6077.  
  6078.     moveq    #-1,D1            ; Dummy-counter
  6079.     bra.s    1$
  6080.  
  6081. * --    #############  -- *
  6082. .skip
  6083.     addq.l    #2,A0            ; Overread both %-chars
  6084.     subq.w    #2,D1            ; 2 chars less in text
  6085.     bmi.s    3$            ; Upon error
  6086.  
  6087. * --- Here we start! --- *
  6088. 1$
  6089.     cmpi.b    #'%',(A0)        ; Argument?
  6090.     bne.s    2$            ; No
  6091.     cmpi.b    #'%',1(A0)        ; or only to display %-char?
  6092.     beq.s    .skip            ; If so, overread both %-chars
  6093.     addq.l    #1,A0            ; Else only one %-char
  6094.     subq.w    #1,D1            ; Counter -1
  6095. .getType
  6096.     cmpi.b    #'b',(A0)        ; Argument = BCPL?
  6097.     beq.s    .typeFound        ; If so
  6098.     cmpi.b    #'d',(A0)        ; Decimal?
  6099.     beq.s    .typeFound.1
  6100.     cmpi.b    #'x',(A0)        ; Sedicimal?
  6101.     beq.s    .typeFound.1
  6102.     cmpi.b    #'s',(A0)        ; String?
  6103.     beq.s    .typeFound
  6104.     cmpi.b    #'c',(A0)        ; One char?
  6105.     beq.s    .typeFound.1
  6106. *
  6107. ** Because an argument can look like this: '%-08ld' we only search for the
  6108. ** valid description of the argument, here 'd' in a loop.
  6109. *
  6110.     tst.b    (A0)+            ; Search further
  6111.     dbeq    D1,.getType
  6112.  
  6113.     bra.s    3$            ; Upon error, string without end of argument
  6114.  
  6115. .typeFound.1
  6116.     cmpi.b    #'l',-1(A0)        ; Longword?
  6117.     beq.s    .typeFound        ; then the other routine
  6118.     move.l    (A1),D0            ; Get argument (ever longword)
  6119.     move.w    D0,(A2)+        ; write down for Exec only a word
  6120.     addq.l    #4,A1            ; Pointer to following argument
  6121.     bra.s    2$            ; and do it normal
  6122. .typeFound
  6123.     move.l    (A1),(A2)+        ; Argument-contents into buffer
  6124.     addq.l    #4,A1            ; see above
  6125. 2$
  6126.     tst.b    (A0)+            ; Search for NULL-byte
  6127.     dbeq    D1,1$
  6128.     bra.s    .FmtString        ; == End of string, now format string
  6129. 3$
  6130.     moveq    #0,D6            ; Return error
  6131. .printf_end
  6132.     tst.l    D4            ; Address table?
  6133.     beq.s    4$
  6134.     movea.l    D4,A1            ; Address table
  6135.     move.l    D5,D0            ; Size table
  6136.     movea.l    _SysBase(A5),A6
  6137.     jsr    _LVOFreeMem(A6)        ; Free table
  6138. 4$
  6139.     move.l    D6,D0
  6140.     movem.l    (sp)+,D2-D6/A2-A3
  6141.     rts
  6142.  
  6143.  
  6144. .FmtString
  6145.     movea.l    32(sp),A0        ; Pointer to unformatted string
  6146.     movea.l    D4,A3            ; Address table
  6147.     lea    _Args(A3),A1        ; Address arguments-buffer
  6148.     lea    .Hook(pc),A2        ; Call-Back-Routine
  6149. *    movea.l    A3,A3            ; Address table already in A3
  6150.     movea.l    _SysBase(A5),A6        ; Base Exec
  6151.     jsr    _LVORawDoFmt(A6)    ; Format the string
  6152.  
  6153.     movea.l    D4,A1
  6154.     lea    _Buffer(A1),A0        ; Address formatted text in buffer
  6155.     move.l    _Cnt(A1),D0        ; Size of text
  6156.     beq.s    .okEnd            ; If zero
  6157.     bsr.s    _DisplayError        ; else print text to window
  6158.     move.l    D0,D6
  6159. .okEnd
  6160.     bra.s    .printf_end
  6161.  
  6162.  
  6163. .Hook
  6164. * D0 == char, returned by RawDoFmt()
  6165. * A3 == Pointer to table, returned by RawDoFmt()
  6166.     movem.l    D1/A0,-(sp)
  6167.     lea    _Buffer(A3),A0        ; Buffer for formatted text
  6168.     move.l    _Cnt(A3),D1        ; Number of chars that are in buffer
  6169.     move.b    D0,0(A0,D1.w)        ; Store current
  6170.     addq.l    #1,_Cnt(A3)        ; Counter plus 1
  6171.     cmpi.l    #510,D1            ; 511 chars in buffer?
  6172.     bls.s    .ok            ; If ok.
  6173.     subq.l    #1,_Cnt(A3)        ; One too far
  6174.     clr.b    0(A0,D1.w)        ; Clear byte
  6175. .ok    
  6176.     movem.l    (sp)+,D1/A0
  6177.     rts
  6178.  
  6179.     IFD    __G2
  6180.     OPT    OW+
  6181.     ENDC
  6182.  
  6183. ******************************************************************
  6184. *
  6185. * Open in the middle of a screen a window where we will display
  6186. * a text.
  6187. * 
  6188. *
  6189. * Inputs: A0 - text
  6190. * Results: D0 - NULL == ABORT, else OK
  6191.  
  6192.  
  6193. _DisplayError
  6194.     movem.l    D1-D4/A0-A4,-(sp)
  6195.  
  6196.     movea.l    A0,A4            ; Save text for later
  6197.     lea    _ErrWindowStruc(A5),A0
  6198.  
  6199.     tst.l    _ScreenPtr(A5)
  6200.     bne.s    .GotScreen
  6201.  
  6202.     movea.l    _IntuitionBase(A5),A1
  6203.     movea.l    ib_ActiveScreen(A1),A1
  6204. .GotScreen
  6205.     movea.l    _ScreenPtr(A5),A1
  6206.     move.l    A1,nw_Screen(A0)     ; ScreenPtr->WindowRecord
  6207.  
  6208. * Center window on screen.
  6209.     move.w    sc_Width(A1),D0        ; Width of screen
  6210.     subi.w    #320,D0            ; Width of ErrorWindow
  6211.     lsr.w    #1,D0            ; Half
  6212.     move.w    D0,(A0)            ; == leftEdge
  6213.  
  6214.     move.w    sc_Height(A1),D0    ; Height of screen
  6215.     subi.w    #100,D0            ; Height of ErrorWindow
  6216.     lsr.w    #1,D0            ; Half
  6217.     move.w    D0,nw_TopEdge(A0)    ; == topEdge
  6218.  
  6219. * Open the window.
  6220.     clr.l    nw_FirstGadget(A0)
  6221.     movea.l    _IntuitionBase(A5),A6
  6222.     jsr    _LVOOpenWindow(A6)
  6223.     move.l    D0,_ErrWindowPtr(A5)
  6224.     beq.w    .NoErrWindow        ; Upon error
  6225.     movea.l    D0,A0            ; Window
  6226.     movea.l    wd_RPort(A0),A3        ; ^RastPortPtr
  6227.  
  6228.     bsr.w    _InitGadgets        ; Init gadgets
  6229.     lea    _Gad1(A5),A1        ; First gadget
  6230.     moveq    #0,D0            ; Begin with number zero
  6231.     moveq    #-1,D1            ; All gadgets
  6232.     moveq    #0,D2
  6233.     movea.l    D2,A2            ; No requester
  6234.     jsr    _LVOAddGList(A6)    ; Set gadgets to window
  6235.     lea    _Gad1(A5),A0        ; Gadgets
  6236.     movea.l    _ErrWindowPtr(A5),A1    ; Window
  6237.     moveq    #0,D2
  6238.     movea.l    D2,A2            ; No requester
  6239.     jsr    _LVORefreshGList(A6)    ; Draw gadgets
  6240.  
  6241. * Set pens.
  6242.     moveq    #1,D0            ; 1. foregroundcolour
  6243.     movea.l    A3,A1            ; RastPort
  6244.     movea.l    _GfxBase(A5),A6
  6245.     jsr    _LVOSetAPen(A6)        ; Set text-pen
  6246.  
  6247. * Fill background of window with 1. foreground colour.
  6248.     movea.l    _ErrWindowPtr(A5),A0
  6249.     movea.l    A3,A1            ; RastPort
  6250.     move.w    #0,D0            ; leftEdge
  6251.     move.w    #0,D1            ; topEdge
  6252.     move.w    #319,D2            ; width
  6253.     move.w    #79,D3            ; height
  6254.  
  6255.     moveq    #0,D4
  6256.     move.b    wd_BorderLeft(A0),D4
  6257.     add.w    D4,D0
  6258.     addq.w    #1,D0
  6259.     move.b    wd_BorderRight(A0),D4
  6260.     sub.w    D4,D2
  6261.     subq.w    #1,D2
  6262.     move.b    wd_BorderTop(A0),D4
  6263.     add.w    D4,D1
  6264.     addq.w    #1,D1
  6265.     move.b    wd_BorderBottom(A0),D4
  6266.     sub.w    D4,D3    
  6267.     subq.w    #1,D3
  6268.     movem.l    D0/D2,-(sp)        ; Save coordinates
  6269.     jsr    _LVORectFill(A6)    ; Draw rectangle
  6270.  
  6271.     move.w    #2,D0            ; 2. Foregroundcolour
  6272.     movea.l    A3,A1            ; RastPort
  6273.     jsr    _LVOSetAPen(A6)        ; Set text-pen
  6274.  
  6275.     movea.l    A3,A1            ; RastPort
  6276.     move.w    #RP_JAM1,D0
  6277.     jsr    _LVOSetDrMd(A6)
  6278.  
  6279.     movem.l    (sp)+,D0/D2        ; Get coordinates
  6280.  
  6281. *    D0 contains X-Offset
  6282.     moveq    #76,D1            ; Y-Offset
  6283.     movea.l    A3,A1
  6284.     jsr    _LVOMove(A6)
  6285.     move.l    D2,D0            ; D2 == X-Offset - to D0
  6286.     moveq    #76,D1            ; Y-Offset
  6287.     movea.l    A3,A1
  6288.     jsr    _LVODraw(A6)
  6289.  
  6290.     moveq    #0,D0            ; X-, Y-offsets = 0
  6291.     move.l    D0,D1
  6292.     move.b    (A4)+,D1        ; Y-Offset out of text
  6293.     movea.l    A3,A1            ; RastPortPtr
  6294.     jsr    _LVOMove(A6)        ; Set Gfx-cursor
  6295.  
  6296.     move.l    A4,-(sp)        ; Text
  6297.     moveq    #0,D0
  6298.     move.w    rp_TxHeight(A3),D0
  6299.     addq.w    #2,D0            ; Spacing
  6300.     sub.w    rp_TxBaseline(A3),D0
  6301.     move.l    D0,-(sp)
  6302.     move.l    _ErrWindowPtr(A5),-(sp)    ; Window
  6303.     bsr.w    _CenterPage        ; CenterText (struct Window *, ULONG Spacing, char *)
  6304.     lea    12(sp),sp        ; Restore stack
  6305.  
  6306. .Wait
  6307.     movea.l    _ErrWindowPtr(A5),A0    ; WindowPointer
  6308.     movea.l    wd_UserPort(A0),A0    ; MsgPort
  6309.     movea.l    A0,A3            ; save it
  6310.     movea.l    _SysBase(A5),A6
  6311.     jsr    _LVOWaitPort(A6)    ; Sleep
  6312.  
  6313.     movea.l    A3,A0            ; MsgPort
  6314.     jsr    _LVOGetMsg(A6)        ; Get the message
  6315.     tst.l    D0
  6316.     beq.s    .Wait
  6317.     movea.l    D0,A1            ; into A1
  6318.     movea.l    A1,A2
  6319.     move.l    im_Class(A2),D2
  6320.     move.w    im_Code(A2),D3
  6321.     swap    D3
  6322.     move.w    im_Qualifier(A2),D3
  6323.     jsr    _LVOReplyMsg(A6)
  6324.  
  6325.     cmpi.l    #$40,D2            ; GadgetUp?
  6326.     beq.s    .Gadget
  6327.  
  6328.     btst.l    #6,D3            ; Left AMIGA (Commodore) key?
  6329.     beq.s    .Wait            ; If not...
  6330.  
  6331.     swap    D3
  6332.  
  6333.     cmpi.b    #53,D3
  6334.     beq.s    .KeyB
  6335.  
  6336.     cmpi.b    #52,D3
  6337.     beq.s    .KeyV
  6338.  
  6339.     bra.s    .Wait
  6340. .KeyB
  6341.     moveq    #0,D3
  6342.     bra.s    .EndDisplayError
  6343. .KeyV
  6344.     moveq    #1,D3
  6345.     bra.s    .EndDisplayError
  6346. .Gadget
  6347.     tst.l    im_IAddress(A2)
  6348.     beq.s    .Wait            ; No gadget?
  6349.     movea.l    im_IAddress(A2),A0    ; Get gadget's address
  6350.     move.w    gg_GadgetID(A0),D3    ; Get my ID
  6351.  
  6352. .EndDisplayError
  6353.     movea.l    _ErrWindowPtr(A5),A0
  6354.     movea.l    _IntuitionBase(A5),A6
  6355.     jsr    _LVOCloseWindow(A6)
  6356.     move.w    D3,D0            ; im_Code (gadget's ID)
  6357.     cmpi.w    #1,D0            ; Left gadget (OK) ?
  6358.     beq.s    .NoErrWindow        ; If so...
  6359.     moveq    #0,D0            ; It was the right one
  6360. .NoErrWindow
  6361.     movem.l    (sp)+,D1-D4/A0-A4
  6362.     rts
  6363.  
  6364. *
  6365. * void CenterPage( struct Window *Window, ULONG Spacing, STRPTR TextPage );
  6366. *
  6367.  
  6368. _CenterPage
  6369.     movem.l    D2-D3/A2-A3,-(sp)
  6370.  
  6371.     movea.l    _GfxBase(A5),A6
  6372.     movea.l    20(sp),A0        ; Window
  6373.     movea.l    50(A0),A3        ; RastPort
  6374.     moveq    #0,D3
  6375.     move.l    24(A0),D0        ; Window flags
  6376.     btst.l    #10,D0            ; gimme zero zero ?
  6377.     bne.s    0$            ; if gzz
  6378.     move.w    8(A0),D3        ; Window-width
  6379.     lsr.w    #1,D3            ; == half window width
  6380.     bra.s    1$
  6381. 0$
  6382.     move.w    112(A0),D3        ; gzzWidth
  6383.     lsr.w    #1,D3            ; == half window width
  6384. 1$
  6385.     movea.l    28(sp),A2        ; Text
  6386. 2$
  6387.     movea.l    A2,A0
  6388.     moveq    #-1,D2            ; Counter
  6389. 3$
  6390.     tst.b    (A0)            ; End?
  6391.     beq.s    4$
  6392.     cmpi.b    #10,(A0)+        ; Search for line-end
  6393.     dbeq    D2,3$
  6394.  
  6395.     move.l    A0,-(sp)        ; Save pointer to next line
  6396.  
  6397.     not.l    D2            ; Compute length
  6398.     move.l    D2,D0            ; Length in number of chars
  6399.     movea.l    A3,A1            ; RastPort
  6400.     movea.l    A2,A0            ; Text
  6401.     jsr    _LVOTextLength(A6)
  6402.     move.l    D0,D1            ; Length in pixels 
  6403.     lsr.w    #1,D1            ; == half length
  6404.     move.l    D3,D0            ; Half window-width
  6405.     sub.w    D1,D0            ; minus half text-width == X-offset for 1. char
  6406.     move.w    38(A3),D1        ; Current Y
  6407.     add.w    62(A3),D1        ; plus rp_TxBaseline
  6408.     movea.l    A3,A1            ; RastPort
  6409.     jsr    _LVOMove(A6)
  6410.  
  6411.     movea.l    (sp)+,A0        ; Get pointer to next line
  6412.  
  6413.     exg.l    A0,A2            ; A0 == now old position, A2 new position of text
  6414.     move.l    D2,D0            ; TextLength in number of chars
  6415.     movea.l    A3,A1            ; RastPort    
  6416.     jsr    _LVOText(A6)
  6417.  
  6418.     move.w    38(A3),D1        ; Current Y-Offset
  6419.     move.l    24(sp),D0        ; Spacing (user's Y-offset)
  6420.     add.w    D0,D1            ; Next line offset (Y)
  6421.     move.w    36(A3),D0        ; Current X-Offset
  6422.     movea.l    A3,A1            ; RastPort
  6423.     jsr    _LVOMove(A6)
  6424.  
  6425.     bra.s    2$
  6426. 4$
  6427.     movem.l    (sp)+,D2-D3/A2-A3
  6428.     rts
  6429.  
  6430. ***************************************
  6431. *
  6432. * Convert long-value into ascii-string.
  6433. *
  6434. * Inputs: D0 - value (ulong), A0 - buffer
  6435. * Result: none
  6436. *
  6437.  
  6438. _comdec
  6439.     movem.l    D2/A2,-(sp)
  6440.     move.l    D0,D2
  6441.     lea    _Divutable(pc),A2
  6442.     movea.l    A0,A1
  6443.     moveq    #9,D0
  6444.  
  6445. 1$
  6446.     moveq    #48,D1
  6447. 2$
  6448.     addq.b    #1,D1
  6449.     sub.l    (A2),D2
  6450.     bcc.s    2$
  6451.     subq.b    #1,D1
  6452.     add.l    (A2)+,D2
  6453.  
  6454.     cmpi.b    #'0',D1
  6455.     bne.s    3$
  6456.     cmpi.b    #0,D0
  6457.     beq.s    3$
  6458.     cmpa.l    A1,A0
  6459.     bne.s    3$
  6460.  
  6461.     dbf    D0,1$
  6462. 3$
  6463.     move.b    D1,(A0)+
  6464. 4$
  6465.     dbf    D0,1$
  6466.     clr.b    (A0)
  6467.     movem.l    (sp)+,D2/A2
  6468.     rts
  6469.  
  6470. *************************************************************
  6471. *
  6472. * Print file to ???.
  6473. *
  6474. * Inputs: D0 - length datas, A0 - filename, A1 - startaddress
  6475. * Results: none
  6476. * Note: The datas are not stored in once to the device (PRT:/DFx:)
  6477. * because when a disk-error occurs, we get the chance to terminate
  6478. * saving/printing earlier, which in fact will not destroy the whole
  6479. * disk as it is possible under OS1.x .
  6480.  
  6481. _PrintFile
  6482.     movem.l    D2-D5/A2,-(sp)
  6483.     move.l    D0,D5            ; Save length
  6484.     movea.l    A1,A2            ; Save address datas
  6485.     move.l    A0,D1            ; Name
  6486.     move.l    #MODE_NEWFILE,D2    ; Mode: New
  6487.     movea.l    _DOSBase(A5),A6
  6488.     jsr    _LVOOpen(A6)
  6489.     move.l    D0,D4            ; FileHandle
  6490.     beq.s    .PrintOpenError
  6491. 3$
  6492.     subi.l    #4096,D5        ; Length -4096 bytes
  6493.     bcs.s    1$            ; If there aren't at least 4096 chars to store
  6494.     move.l    #4096,D3        ; Number of chars to write: 4096
  6495.     bra.s    2$            ; Go and write these chars...
  6496. 1$
  6497.     addi.l    #4096,D5        ; Add these - now D5 contains again the rest to store
  6498.     move.l    D5,D3            ; Number of chars to store
  6499.     moveq    #0,D5            ; Indicates: no chars anymore for next loop
  6500. 2$
  6501.     move.l    D4,D1            ; FileHandle
  6502.     move.l    A2,D2            ; Address
  6503.     jsr    _LVOWrite(A6)
  6504.     tst.l    D0
  6505.     bmi.s    .WriteError
  6506.     lea    4096(A2),A2        ; Increase address by 4096 bytes
  6507.     tst.l    D5            ; Rest there?
  6508.     bne.s    3$            ; If there...
  6509.     move.l    D4,D1            ; FileHandle
  6510.     jsr    _LVOClose(A6)        ; Close file/prt: or something like that
  6511.  
  6512. .PrintFileEnd
  6513.     movem.l    (sp)+,D2-D5/A2
  6514.     rts
  6515. .PrintOpenError
  6516.     jsr    _LVOIoErr(A6)
  6517.     bsr.w    _SetError
  6518.     lea    _OpenPrintErrTxt(pc),A0
  6519.     bsr.w    _DisplayError
  6520.     bra.s    .PrintFileEnd
  6521. .WriteError
  6522.     movea.l    _DOSBase(A5),A6        ; - Because of a bug in DOS v39
  6523. *                      we have to restore DOSBase....
  6524.     jsr    _LVOIoErr(A6)
  6525.     bsr.w    _SetError
  6526.     move.l    D4,D1
  6527.     jsr    _LVOClose(A6)
  6528.     lea    _WriteErrTxt(pc),A0
  6529.     bsr.w    _DisplayError
  6530.     bra.s    .PrintFileEnd    
  6531.  
  6532. ************************
  6533. *
  6534. * Erase window contents.
  6535. *
  6536. * Inputs: none
  6537. * Results: none
  6538. *
  6539.  
  6540. _ClearWindow
  6541.     lea    _ConBuffer(A5),A0
  6542.     move.l    #$9B489B4A,(A0)        ; Cursor Home & erase to end of display
  6543.     moveq    #4,D0
  6544.     bra.w    _ConOut_Rel
  6545.  
  6546. *****************************************************************
  6547. *
  6548. * Search for overgiven string....
  6549. *
  6550. * Will use the console.device as input stream and also for output.
  6551. * Searching is done only forward and also case insensitive.
  6552. *
  6553.  
  6554. _SearchSequence
  6555.     movem.l    D2-D4/A2-A4,-(sp)
  6556.  
  6557.     move.l    #$200,D0
  6558.     movea.l    _WindowPtr(A5),A0
  6559.     movea.l    _IntuitionBase(A5),A6
  6560.     jsr    _LVOModifyIDCMP(A6)
  6561.  
  6562.     bsr.s    _ClearWindow
  6563.  
  6564.     tst.l    _TextPtr(A5)
  6565.     beq.s    .end
  6566.  
  6567.     lea    _ConBuffer(A5),A0
  6568.     move.w    #$9B48,(A0)        ; Cursor Home
  6569.     moveq    #2,D0
  6570.     bsr.w    _ConOut_Rel
  6571.  
  6572.     lea    _SearchText(pc),A0
  6573.     lea    _SearchTextEnd(pc),A1    ; Address end of help-text
  6574.     suba.l    A0,A1            ; == length text
  6575.     move.l    A1,D0            ; into D0
  6576.     bsr.w    _ConOut_Reloc        ; Output
  6577.  
  6578.     bsr.w    _CursorOn
  6579.  
  6580.     lea    _IOReqString(A5),A3    ; Buffer to store the complete string the user enters
  6581.     moveq    #0,D3            ; Amount of already stored chars
  6582.     moveq    #0,D4            ; Position in textbuffer
  6583.  
  6584.     movea.l    A3,A0            ; Clear IOReqString
  6585.     move.w    #256-1,D0
  6586. .clear
  6587.     clr.b    (A0)+
  6588.     subq.w    #1,D0
  6589.     bcc.s    .clear
  6590.  
  6591.     lea    _CharBuffer(A5),A0    ; At least, two chars wide (only for console reading)
  6592.     clr.l    (A0)            ; Indicator: Nothing entered!
  6593.  
  6594. .loop
  6595.     moveq    #2,D0
  6596.     lea    _CharBuffer(A5),A0
  6597.     lea    _ReadIo(A5),A1
  6598.     move.l    D0,IO_LENGTH(A1)    ; Number of chars to read
  6599.     move.l    A0,IO_DATA(A1)
  6600.     move.b    #IOF_QUICK,IO_FLAGS(A1)
  6601.     move.w    #CMD_READ,IO_COMMAND(A1) ; Command READ
  6602.     movea.l    _SysBase(A5),A6
  6603.     jsr    _LVODoIO(A6)        ; Send command
  6604.  
  6605.     lea    _CharBuffer(A5),A0    ; Get the chars
  6606.     tst.b    (A0)            ; Too bad, no char
  6607.     beq.s    .loop
  6608.     
  6609.     lea    _CharBuffer(A5),A0    ; Get address of buffer
  6610.     move.b    (A0),D0            ; Get the char (or sequencer <CSI> ($9B))
  6611.     move.b    1(A0),D1        ; When D0 sequencer, D1 keycode
  6612.  
  6613.     clr.l    (A0)            ; Indicator: No char stored!
  6614.     bra.s    .SetString        ; Parse that char...
  6615.  
  6616.  
  6617. * ------ finish (not found) ------ *
  6618. .end
  6619.     bsr.w    _CursorOff
  6620.  
  6621.     move.l    #$8|$200|$400,D0
  6622.     movea.l    _WindowPtr(A5),A0
  6623.     movea.l    _IntuitionBase(A5),A6
  6624.     jsr    _LVOModifyIDCMP(A6)
  6625.  
  6626.     movem.l    (sp)+,D2-D4/A2-A4
  6627.  
  6628.     bsr.w    _RestoreCurrentPage
  6629.     bra.w    _Loop
  6630.  
  6631. ***********************************
  6632. *
  6633. * React to read char
  6634. *
  6635. * INPUTS:    D0 - char
  6636. *    or    D0 - sequence ($9B)
  6637. *    then    D1 - char
  6638.  
  6639. .SetString
  6640.     cmpi.b    #13,D0            ; Carridge return?
  6641.     beq.w    .done
  6642.     cmpi.b    #8,D0            ; Backspace
  6643.     beq.s    .BackSpace
  6644.     cmpi.b    #$7F,D0            ; DEL
  6645.     beq.s    .Delete
  6646.     cmpi.b    #$9B,D0            ; <CSI> (sequence)
  6647.     beq.w    .Sequencer
  6648.     cmpi.b    #$1B,D0            ; ESC
  6649.     beq.w    .Escape
  6650.  
  6651. * ############ -------- Any other char -------- *
  6652.     cmpi.b    #255,D3            ; Maximum editable chars
  6653.     beq.w    .loop
  6654.     move.b    D0,D2            ; The char
  6655.     bsr.w    _InsertChar        ; Store char (D2) to TextBuffer
  6656.     bsr.w    _PrintChar
  6657.     bra.w    .loop            ; and normal...
  6658.  
  6659. * ############ -------- Delete last character -------- *
  6660. .BackSpace
  6661.     tst.l    D3            ; At least one char stored?
  6662.     beq.w    .loop    
  6663.  
  6664.     tst.l    D4
  6665.     beq.w    .loop
  6666.  
  6667.     cmpi.b    #9,-1(A3,D4.l)
  6668.     bne.s    .donormal
  6669.  
  6670.     moveq    #0,D2
  6671.     bsr.w    _MoveTAB
  6672.     bsr.w    _RemChar
  6673.     bra.s    .delete            ; <- see there...
  6674.  
  6675. * ------------------------------ *
  6676.  
  6677. .donormal
  6678.     lea    _ConBuffer(A5),A0
  6679.     move.w    #$9B44,(A0)        ; <CSI>D
  6680.     moveq    #2,D0
  6681.     bsr.w    _ConOut_Rel
  6682.  
  6683.     subq.l    #1,D4
  6684.     bsr.w    _RemChar
  6685.  
  6686.     bra.s    .delete            ; <- see there...
  6687.  
  6688. * ############ ------ Delete current character ------ *
  6689. .Delete
  6690.     tst.l    D3
  6691.     beq.w    .loop
  6692.  
  6693.     cmp.l    D3,D4
  6694.     beq.w    .loop
  6695.  
  6696.     bsr.w    _RemChar
  6697.  
  6698. .delete
  6699.     tst.l    D4
  6700.     beq.s    .dprint            ; Start of line (first char)
  6701.     lea    _ConBuffer(A5),A0
  6702.     move.w    #$9B44,(A0)        ; <CSI>D
  6703.     moveq    #2,D0
  6704.     bsr.w    _ConOut_Rel
  6705. .dprint
  6706.     bsr.w    _PrintChar
  6707.  
  6708.     cmp.l    D3,D4
  6709.     bne.s    .chardeleted
  6710.  
  6711.     lea    _ConBuffer(A5),A0
  6712.     move.w    #$9B50,(A0)        ; <CSI>1D
  6713.     moveq    #2,D0
  6714.     bsr.w    _ConOut_Rel
  6715.  
  6716. .chardeleted
  6717.     bra.w    .loop
  6718.  
  6719.  
  6720. * ############ ------ Cursor keys or something like that picked... ------ *
  6721. .Sequencer    ; D0=$9B, D1=xx,
  6722. *     where xx is:
  6723. *    HELP        $3F
  6724. *    CursorLeft     $44
  6725. *    CursorRight    $43
  6726. *    CursorUp    $41
  6727. *    CursorDown    $42
  6728.     tst.l    D3
  6729.     beq.w    .loop
  6730.  
  6731.     cmpi.b    #$44,D1
  6732.     beq.s    .left
  6733. .right
  6734.     cmp.w    D3,D4
  6735.     beq.w    .loop
  6736.  
  6737.     moveq    #~0,D2
  6738.     cmpi.b    #9,0(A3,D4.l)
  6739.     bne.s    .charright
  6740.     bsr.w    _MoveTAB
  6741.     bra.w    .loop
  6742. .charright
  6743.     addq.l    #1,D4
  6744.     lea    _ConBuffer(A5),A0
  6745.     move.w    #$9B43,(A0)        ; <CSI>C
  6746.     moveq    #2,D0
  6747.     bsr.w    _ConOut_Rel    
  6748.     bra.w    .loop
  6749. * ------------------------------ *
  6750.  
  6751. .left
  6752.     tst.w    D4
  6753.     beq.w    .loop
  6754.  
  6755.     moveq    #0,D2
  6756.     cmpi.b    #9,-1(A3,D4.l)
  6757.     bne.s    .charleft
  6758.     bsr.w    _MoveTAB
  6759.     bra.w    .loop
  6760.  
  6761. .charleft
  6762.     subq.l    #1,D4
  6763.     lea    _ConBuffer(A5),A0
  6764.     move.w    #$9B44,(A0)        ; <CSI>D
  6765.     moveq    #2,D0
  6766.     bsr.w    _ConOut_Rel
  6767.     bra.w    .loop
  6768.  
  6769. * ############ ------- Escape key pressed... -------- *
  6770. .Escape
  6771.     cmpi.b    #255,D3            ; Maximum editable chars
  6772.     beq.w    .loop
  6773.     move.b    #'·',D2
  6774.     bsr.w    _InsertChar
  6775.     bsr.w    _PrintChar
  6776.     bra.w    .loop
  6777.  
  6778. * ############ ------- Carridge Return - string complete! ------- *
  6779. .done
  6780.     tst.l    D3            ; If user cancled entering
  6781.     beq.w    .end
  6782.  
  6783.     clr.b    (A3,D3.l)        ; Terminator
  6784.     bsr.w    _CursorOff
  6785.  
  6786. * ------- Replace '·' (synonym for escape) through escape character ------- *
  6787.     lea    _IOReqString(A5),A0    ; Buffer with chars...
  6788. .escapeSearch
  6789.     tst.b    (A0)
  6790.     beq.s    .searchStart
  6791.     cmpi.b    #'·',(A0)+
  6792.     bne.s    .escapeSearch
  6793.     move.b    #27,-1(A0)
  6794.     bra.s    .escapeSearch
  6795.  
  6796. * -------- Search for the overgiven string --------- *
  6797. .searchStart
  6798.     lea    _IOReqString(A5),A2    ; Buffer with chars...
  6799.     movea.l    _TextPtr(A5),A3        ; Text start
  6800.     addq.l    #2,A3            ; Overread #$200A
  6801.     movea.l    A3,A4
  6802.     adda.l    _BufferSize(A5),A4    ; Size of chars of text
  6803.     subq.l    #4,A4            ; Ignore introducing ($200A) and terminator
  6804. .search
  6805.     move.l    D3,-(sp)
  6806.     move.l    A2,-(sp)
  6807.     move.l    A3,-(sp)
  6808.     bsr.w    _strincmp        ; Compare case insensitive strings
  6809.     lea    12(sp),sp
  6810.     tst.l    D0
  6811.     beq.s    .found            ; D0 = 0 means ok.
  6812.  
  6813.     addq.l    #1,A3            ; Else, next char
  6814.     cmpa.l    A3,A4            ; Check against limit
  6815.     bls.s    .notfound        ; If out of limit
  6816.     bra.s    .search            ; Else, search
  6817. .found
  6818.     move.l    A3,D0            ; Found text
  6819.     addq.l    #1,D0            ; No trouble shooting....
  6820.     move.l    D0,_SearchStrPtr(A5)    ; There where we can continue if user said "search next"
  6821.     move.l    D3,_SearchStrLen(A5)    ; Remember length of string to search for
  6822.  
  6823. * -------- Search for linestart -------- *
  6824.     movea.l    _TextPtr(A5),A0
  6825.     addq.l    #2,A0            ; Overread #$200A
  6826. .searchLF
  6827.     cmpi.b    #10,(A3)        ; LineFeed (line start)
  6828.     beq.s    .foundLineStart
  6829.     cmpa.l    A0,A3            ; Does it fit?
  6830.     bls.s    .notfound
  6831.     subq.l    #1,A3            ; Else one less char...
  6832.     bra.s    .searchLF
  6833. .foundLineStart
  6834.     move.l    #$8|$200|$400,D0
  6835.     movea.l    _WindowPtr(A5),A0
  6836.     movea.l    _IntuitionBase(A5),A6
  6837.     jsr    _LVOModifyIDCMP(A6)
  6838.  
  6839.     move.l    A3,D0
  6840.     movem.l    (sp)+,D2-D4/A2-A4
  6841.  
  6842.     move.l    D0,-(sp)
  6843.     bsr.w    _GetCurrentLine        ; Compute the line (last one in window)
  6844.     move.l    (sp)+,D6        ; First char in window
  6845.     bsr.w    _RestoreCurrentPage
  6846.     bra.w    _Loop
  6847.  
  6848. * ############ ------- Couldn't find the string... ------- *
  6849. .notfound
  6850.     suba.l    A0,A0
  6851.     movea.l    _IntuitionBase(A5),A6
  6852.     jsr    _LVODisplayBeep(A6)
  6853.  
  6854.     clr.l    _SearchStrPtr(A5)
  6855.     clr.l    _SearchStrLen(A5)
  6856.  
  6857.     bra.w    .end
  6858.  
  6859. ****************************************************************
  6860. *
  6861. * Move a char which is a tabulator - to the left or to the right
  6862. *
  6863. * D2    - indicator: zero = leftmove, unequal zero = move right
  6864. *
  6865.  
  6866. _MoveTAB
  6867.     lea    _ConBuffer(A5),A0    ; Buffer for created string
  6868.     move.b    #$9B,(A0)        ;<CSI>
  6869.     lea    _IOReqString(A5),A1    ; Buffer with chars
  6870.     moveq    #12,D0            ; Initial column offset, here "Search for: " <- 12 chars
  6871. *    For a real editor replace 12 through 0, 'cause of line start...
  6872.  
  6873.     tst.b    D2
  6874.     beq.s    .leftsetup        ; ...because left move cursor
  6875. .rightsetup
  6876.     move.l    A0,-(sp)
  6877.     lea    0(A3,D4.l),A0
  6878.     bra.s    .searchtab
  6879. .leftsetup
  6880.     move.l    A0,-(sp)
  6881.     lea    -1(A3,D4.l),A0
  6882. .searchtab
  6883.     cmpa.l    A0,A1            ; Last char before tab?
  6884.     beq.s    .gottab            ; If found
  6885.     addq.w    #1,D0            ; Else counter for chars plus 1
  6886.     cmpi.b    #9,(A1)            ; A tab?
  6887.     bne.s    .next1            ; If not...
  6888.     addq.w    #7,D0            ; Else calc position (every time divisible through 8)
  6889.     andi.w    #-8,D0
  6890. .next1
  6891.     addq.l    #1,A1            ; Get next char('s position(address))
  6892.     bra.s    .searchtab        ; And search further
  6893. .gottab    ; Current position in D0 before tab
  6894.     movea.l    (sp)+,A0
  6895.     tst.b    D2
  6896.     bne.s    .rightmove
  6897. .leftmove
  6898.     move.b    #'D',D2
  6899.     move.l    D0,D1
  6900.     addq.l    #8,D1            ; Add a char (1) and make width divisible by 8 (7) 
  6901.     andi.l    #-8,D1
  6902.     sub.l    D0,D1            ; Number of space to move left
  6903.     subq.l    #1,D4
  6904.     bra.s    .write
  6905.  
  6906. .rightmove    
  6907.     move.b    #'C',D2
  6908.     move.l    D0,D1
  6909.     addq.l    #8,D1            ; Add a char (the tab) and make width divisible by 8 (7) 
  6910.     andi.l    #-8,D1
  6911.     sub.l    D0,D1
  6912.     addq.l    #1,D4
  6913.  
  6914. .write
  6915.     addi.b    #'0',D1            ; Convert it into ASCII
  6916.     move.b    D1,1(A0)        ; Into ConBuffer
  6917.     
  6918.     move.b    D2,2(A0)        ; <CSI>nD = cursor n positions backward
  6919.     moveq    #3,D0            ; Three chars for output
  6920.     bsr.w    _ConOut_Rel        ; Output!
  6921.  
  6922.     rts
  6923.  
  6924. **************************************************
  6925. *
  6926. * Print yet entered char to window.
  6927. *
  6928. * INPUTS:    D3 - amount of chars in TextBuffer
  6929. *        D4 - current BufPosition
  6930. *
  6931. _PrintChar
  6932.     cmp.l    D3,D4
  6933.     bne.s    .givestring
  6934.  
  6935.     tst.l    D3
  6936.     beq.s    .erase
  6937.  
  6938.     lea    -1(A3,D3),A0        ; Address string (including new charcter)
  6939.     moveq    #1,D0
  6940.     bsr.w    _ConOut_Reloc
  6941.     rts
  6942.  
  6943. .givestring
  6944.     lea    _ConBuffer(A5),A0
  6945.     move.w    #$9B4B,(A0)        ; <CSI>K [erase to end of line]
  6946.     moveq    #2,D0
  6947.     bsr.w    _ConOut_Rel
  6948.  
  6949.     lea    -1(A3,D4),A0        ; Address string (including new charcter)
  6950.     move.l    D3,D0            ; Length
  6951.     move.l    D4,D1            ; - minus current position
  6952.     addq.l    #1,D0
  6953.     bsr.w    _ConOut_Reloc        ; Print rest of string
  6954.  
  6955. * Because the cursor is at end of line, we have to move it to current BufPosition...
  6956.     move.l    D4,-(sp)
  6957.     move.l    D3,D4            ; End of line = current BufPosition
  6958.  
  6959. .loopmove
  6960.     moveq    #0,D2            ; Indicator: left move
  6961.     cmpi.b    #9,-1(A3,D4.l)        ; A tab?
  6962.     bne.s    .moveleft        ; If not...
  6963.     bsr.w    _MoveTAB        ; Else, move it as tab...
  6964.     bra.s    .movedone        ; done (for this time)
  6965.  
  6966. .moveleft
  6967.     subq.l    #1,D4            ; BufPosition minus 1
  6968.     lea    _ConBuffer(A5),A0
  6969.     move.l    #$9B314400,(A0)        ; <CSI>1D
  6970.     moveq    #3,D0
  6971.     bsr.w    _ConOut_Rel        ; Move cursor 1 position left
  6972.  
  6973. .movedone
  6974.     move.l    (sp),D0            ; Get original BufPosition
  6975.     cmp.l    D0,D4            ; reached?
  6976.     bne.s    .loopmove        ; If not
  6977.     addq.l    #4,sp
  6978. .done
  6979.     rts
  6980. .erase
  6981.     lea    _ConBuffer(A5),A0
  6982.     move.w    #$9B50,(A0)        ; <CSI>1D
  6983.     moveq    #2,D0
  6984.     bsr.w    _ConOut_Rel
  6985.     rts
  6986.  
  6987. *******************************
  6988. *
  6989. * Insert a char in text buffer
  6990. *
  6991. * INPUTS:    D2 - the char to store
  6992. *        D3 - amount of currently stored chars
  6993. *        D4 - currently used BufPosition
  6994. * RESULTS:    D3 - increased by one
  6995. *        D4 - increased by one
  6996.  
  6997. _InsertChar
  6998.     cmp.l    D3,D4
  6999.     beq.s    .atend            ; It's currently the last char...
  7000.  
  7001.     lea    0(A3,D4.l),A0        ; Source
  7002.     lea    1(A3,D4.l),A1        ; Destination
  7003.     move.l    D3,D0
  7004.     sub.l    D4,D0
  7005.     bsr.s    _DupCopy        ; Free room at current position in textbuffer
  7006.     move.b    D2,0(A3,D4.l)        ; and store there the char
  7007.  
  7008.     addq.l    #1,D3
  7009.     addq.l    #1,D4
  7010.     rts
  7011. .atend                    ; Insert char at last position
  7012.     move.b    D2,0(A3,D4.l)
  7013.     clr.b    1(A3,D4.l)        ; Terminator
  7014.     addq.l    #1,D3
  7015.     addq.l    #1,D4
  7016.     rts
  7017.  
  7018. *****************************************************
  7019. *
  7020. * Because Exec function CopyMem() cannot be used when
  7021. * "ascended overlay copying" is required,
  7022. * we have to make an own, which copies "reverse" the
  7023. * datas.
  7024. *
  7025. * Inputs: A0/A1/D0   -  source/destination/size
  7026. *
  7027.  
  7028. _DupCopy
  7029.     subq.l    #1,D0
  7030. .loop
  7031.     move.b    0(A0,D0.l),0(A1,D0.l)
  7032.     subq.l    #1,D0
  7033.     bcc.s    .loop
  7034.     rts
  7035.  
  7036. ******************************************************************
  7037. *
  7038. * Remove char in text buffer which currently stays on BufPosition
  7039. *
  7040. * INPUTS:    D3 - currently amount of char in buffer (old length)
  7041. *        D4 - current buffers poisition (BufPosition)
  7042. * REULTS:    char on BufPosition removed
  7043. *        D3 - decreased by one (char removed)
  7044. * NOTES:    D4 unchanged...
  7045. *
  7046.  
  7047. _RemChar
  7048.     subq.l    #1,D3            ; New size
  7049.     move.l    D3,D0            ; Amount chars in buffer
  7050.     move.l    D4,D1            ; Buffers position
  7051.     sub.l    D1,D0            ; Number of bytes behind BufPosition
  7052.     beq.s    .endchar
  7053.     bmi.s    .endchar
  7054.     lea    1(A3,D4.l),A0        ; Source
  7055.     lea    0(A3,D4.l),A1        ; Destination
  7056.     movea.l    _SysBase(A5),A6
  7057.     jsr    _LVOCopyMem(A6)
  7058. .endchar
  7059.     clr.b    0(A3,D3.l)
  7060.     rts
  7061.  
  7062. ****************************************************************
  7063. *
  7064. * Compare case insensitive string1 and string2 with width-limit.
  7065. *
  7066. * Input:  string1, string2, num-chars (stackargs)
  7067. * Result: D0 = FALSE (0L) if strings are the same.
  7068. *
  7069.  
  7070. _strincmp    ;cargs    string1.l,string2.l, num-chars.l
  7071.     move.l    D2,-(sp)
  7072.     movea.l    8(sp),A0
  7073.     movea.l    12(sp),A1
  7074.     move.l    16(sp),D2
  7075.     andi.l    #$FFFF,D2
  7076.     subq.w    #1,D2
  7077. .start
  7078.     move.b    (A0)+,D0
  7079.     bsr.s    _UpperCase
  7080.     move.b    D0,D1
  7081.     move.b    (A1)+,D0
  7082.     bsr.s    _UpperCase
  7083.     tst.b    D0
  7084.     bne.s    .tst
  7085.     tst.b    D1
  7086.     beq.s    .same
  7087. .tst
  7088.     cmp.b    D0,D1
  7089.     bne.s    .differ
  7090.     dbf    D2,.start
  7091. .same
  7092.     move.l    (sp)+,D2
  7093.     moveq    #0,D0
  7094.     rts
  7095. .differ
  7096.     move.l    (sp)+,D2
  7097.     moveq    #-1,D0
  7098.     rts
  7099.  
  7100. *********************************************
  7101. *
  7102. * Change char in D0 to uppercase if possible.
  7103. * Supports all ASCII-one characters!
  7104. *
  7105. * Returns char in D0
  7106. *
  7107.  
  7108. _UpperCase
  7109.     tst.b    D0
  7110.     beq.s    .back
  7111.     cmpi.b    #96,D0
  7112.     bls.s    .back
  7113.     cmpi.b    #122,D0
  7114.     bls.s    .change
  7115.     cmpi.b    #255,D0
  7116.     beq.s    .back
  7117.     cmpi.b    #223,D0
  7118.     bhi.s    .change
  7119.     rts
  7120. .change
  7121.     andi.b    #$DF,D0
  7122. .back
  7123.     rts
  7124.  
  7125.  
  7126. *************************************************
  7127. *
  7128. * If the N-key is pressed, we are at this point.
  7129. * Same as SearchSequence() but without any
  7130. * input()...
  7131. *
  7132. _ContinueSearch
  7133.     movem.l    D2/A2-A4,-(sp)
  7134.  
  7135.     move.l    #$200,D0
  7136.     movea.l    _WindowPtr(A5),A0
  7137.     movea.l    _IntuitionBase(A5),A6
  7138.     jsr    _LVOModifyIDCMP(A6)
  7139.  
  7140.     tst.l    _TextPtr(A5)        ; Any text to examine?
  7141.     beq.w    .end
  7142.     lea    _IOReqString(A5),A0    ; Any search string given?
  7143.     tst.b    (A0)
  7144.     beq.w    .end
  7145.     move.l    _SearchStrLen(A5),D2    ; Length of search string set?
  7146.     beq.w    .end
  7147.     tst.l    _SearchStrPtr(A5)    ; An address remembered?
  7148.     beq.s    .end
  7149.  
  7150.     lea    _IOReqString(A5),A2    ; String to search for....
  7151.     movea.l    _SearchStrPtr(A5),A3    ; Address from where to search
  7152.     movea.l    _TextPtr(A5),A4        ; Address text-start
  7153.     addq.l    #2,A4            ; Overread #$200A
  7154.     adda.l    _BufferSize(A5),A4    ; = end of text
  7155.     subq.l    #4,A4
  7156. .search
  7157.     move.l    D2,-(sp)
  7158.     move.l    A2,-(sp)
  7159.     move.l    A3,-(sp)
  7160.     bsr.w    _strincmp
  7161.     lea    12(sp),sp
  7162.     tst.l    D0
  7163.     beq.s    .found
  7164.     cmpa.l    A3,A4
  7165.     bls.s    .notfound
  7166.     addq.l    #1,A3
  7167.     bra.s    .search
  7168. .found
  7169.     move.l    A3,D0
  7170.     addq.l    #1,D0
  7171.     move.l    D0,_SearchStrPtr(A5)    ; Remember address where we found string (plus 1 byte)
  7172.     move.l    D2,_SearchStrLen(A5)
  7173.  
  7174.     movea.l    _TextPtr(A5),A0        ; Address text-start
  7175.     addq.l    #2,A0            ; Overread #$200A
  7176. .searchLF
  7177.     cmpi.b    #10,(A3)
  7178.     beq.s    .foundLineStart
  7179.     cmpa.l    A0,A3            ; Does it fit?
  7180.     bls.s    .notfound
  7181.     subq.l    #1,A3            ; Else one less char...
  7182.     bra.s    .searchLF
  7183. .foundLineStart
  7184.     move.l    A3,D0
  7185.  
  7186.     movem.l    (sp)+,D2/A2-A4
  7187.  
  7188.     move.l    D0,-(sp)
  7189.     bsr.s    _GetCurrentLine
  7190.  
  7191.     move.l    #$8|$200|$400,D0
  7192.     movea.l    _WindowPtr(A5),A0
  7193.     movea.l    _IntuitionBase(A5),A6
  7194.     jsr    _LVOModifyIDCMP(A6)
  7195.  
  7196.     move.l    (sp)+,D6            ; First char in window
  7197.     bsr.w    _RestoreCurrentPage
  7198.     bra.w    _Loop
  7199.  
  7200. .notfound
  7201.     suba.l    A0,A0
  7202.     movea.l    _IntuitionBase(A5),A6
  7203.     jsr    _LVODisplayBeep(A6)
  7204.  
  7205. .end
  7206.     move.l    #$8|$200|$400,D0
  7207.     movea.l    _WindowPtr(A5),A0
  7208.     movea.l    _IntuitionBase(A5),A6
  7209.     jsr    _LVOModifyIDCMP(A6)
  7210.     movem.l    (sp)+,D2/A2-A4
  7211.  
  7212.     bsr.w    _RestoreCurrentPage
  7213.     bra.w    _Loop
  7214.  
  7215.  
  7216. ******************************************
  7217. *
  7218. * Compute current line.
  7219. *
  7220. * Input: D0 - address within text buffer.
  7221. *
  7222.  
  7223. _GetCurrentLine
  7224.     movea.l    _TextPtr(A5),A0
  7225.     move.l    D0,A1
  7226.     moveq    #0,D1
  7227. .cmp
  7228.     cmpi.b    #10,(A0)
  7229.     beq.s    .add
  7230. .tst
  7231.     cmpa.l    A0,A1
  7232.     beq.s    .found
  7233. .next
  7234.     addq.l    #1,A0
  7235.     bra.s    .cmp
  7236. .add
  7237.     addq.l    #1,D1
  7238.     bra.s    .tst
  7239. .found
  7240.     moveq    #0,D0
  7241.     move.w    _StdPageSize(A5),D0    ; Amount of lines in window
  7242.     add.l    D0,D1
  7243.     move.l    D1,_Line(A5)
  7244.     rts
  7245.  
  7246.  
  7247. ***************************
  7248. *
  7249. * Display commands summary.
  7250. *
  7251. * Inputs: none
  7252. * Results: none
  7253. *
  7254.  
  7255. _DisplayHelp
  7256.     bsr.w    _SetActionWait        ; See there
  7257.     bsr.w    _ClearWindow
  7258.  
  7259.     lea    _HelpText(pc),A0    ; Address help-text
  7260.     lea    _HelpTextEnd(pc),A1    ; Address end of help-text
  7261.     suba.l    A0,A1            ; == length text
  7262.     move.l    A1,D0            ; into D0
  7263.     bsr.w    _ConOut_Reloc        ; Output
  7264.  
  7265.     move.l    A2,-(sp)
  7266. 1$
  7267.     movea.l    _SysBase(A5),A6
  7268.     movea.l    _WindowPtr(A5),A2
  7269.     movea.l    wd_UserPort(A2),A2
  7270.     movea.l    A2,A0
  7271.     jsr    _LVOWaitPort(A6)
  7272.     movea.l    A2,A0
  7273.     jsr    _LVOGetMsg(A6)
  7274.     movea.l    D0,A1
  7275.     movea.l    D0,A2
  7276.     jsr    _LVOReplyMsg(A6)
  7277.  
  7278.     cmpi.w    #H_Key+$80,im_Code(A2)    ; H-key released?
  7279.     bne.s    1$
  7280.  
  7281.     movea.l    _WindowPtr(A5),A2
  7282.     movea.l    wd_UserPort(A2),A2
  7283.     movea.l    A2,A0
  7284.     jsr    _LVOWaitPort(A6)    ; Wait for any event
  7285.     movea.l    A2,A0
  7286.     jsr    _LVOGetMsg(A6)
  7287.     movea.l    D0,A1
  7288.     jsr    _LVOReplyMsg(A6)
  7289.  
  7290.     movea.l    (sp)+,A2
  7291.  
  7292.     tst.l    _TextPtr(A5)        ; Any text there?
  7293.     beq.s    2$            ; If not
  7294.     bsr.w    _RestoreCurrentPage    ; Else restore the page
  7295. 2$
  7296.     bra.w    _Loop
  7297.  
  7298.  
  7299. **************************
  7300. *
  7301. * Display the standard....
  7302. *
  7303. * Inputs: none
  7304. * Results: none
  7305. *
  7306.  
  7307. _About
  7308.     lea    _AboutTxt(pc),A0        ; I like this...
  7309.     bsr.w    _DisplayError
  7310.     bra.w    _Loop
  7311.  
  7312.  
  7313. ****************************************
  7314. *
  7315. * Display informations about program....
  7316. *
  7317. * Inputs: none
  7318. * Results: none
  7319. *
  7320.  
  7321. _Info
  7322.     move.l    #_TableSize,D0        ; Size BSS
  7323.     addq.l    #7,D0
  7324.     andi.l    #-8,D0            ; Aligned size
  7325.     move.l    D0,-(sp)
  7326.  
  7327.     lea    _startup(pc),A0        ; Code start
  7328.     subq.l    #4,A0            ; Next hunk...
  7329.     movea.l    (A0),A0            ; BPTR next hunk
  7330.     adda.l    A0,A0
  7331.     adda.l    A0,A0            ; == APTR next hunk
  7332.     move.l    -4(A0),D0        ; Size next hunk
  7333.     subq.l    #8,D0            ; Ignore hunk-header (8 bytes)
  7334.     move.l    D0,-(sp)        ; Size datas-chip
  7335.  
  7336.     lea    _Divutable(pc),A0    ; Start datas
  7337.     lea    _EndDatas(pc),A1    ; End datas
  7338.     sub.l    A0,A1            ; == size datas
  7339.     move.l    A1,D0
  7340.     addq.l    #3,D0
  7341.     andi.l    #-4,D0            ; Aligned size (longword)
  7342.     move.l    D0,-(sp)
  7343.  
  7344.     lea    _startup(pc),A0        ; Entry point of program
  7345.     lea    _Divutable(pc),A1    ; End of code
  7346.     suba.l    A0,A1            ; == size of code
  7347.     move.l    A1,-(sp)
  7348.  
  7349.     pea    _InfoTxt(pc)        ; Text...
  7350.     bsr.w    _FmtDisplay
  7351.     lea    20(sp),sp        ; Restore stack    
  7352.     bra.w    _Loop
  7353.  
  7354. *************************
  7355. *
  7356. * Allow messages for now.
  7357. *
  7358. * Inputs: none
  7359. * Results: none
  7360. *
  7361.  
  7362. _SetActionWait
  7363.     move.l    A0,-(sp)
  7364.     movea.l    _WindowPtr(A5),A0
  7365.     movea.l    wd_UserPort(A0),A0
  7366.     clr.b    MP_FLAGS(A0)
  7367.     movea.l    (sp)+,A0
  7368.     rts
  7369.  
  7370. ***********************************
  7371. *
  7372. * Do not allow any message for now.
  7373. *
  7374. * Inputs: none
  7375. * Results: none
  7376. *
  7377.  
  7378. _SetNILWait
  7379.     move.l    A0,-(sp)
  7380.     movea.l    _WindowPtr(A5),A0
  7381.     movea.l    wd_UserPort(A0),A0
  7382.     move.b    #PA_IGNORE,MP_FLAGS(A0)
  7383.     movea.l    (sp)+,A0
  7384.     rts
  7385.  
  7386. ********************************************
  7387. *
  7388. * Check for user specification in tooltypes.
  7389. *
  7390. * Inputs: none
  7391. * Results: none
  7392. *
  7393.  
  7394. _CheckWarning
  7395.     lea    WB_arg_1(A5),A0        ; Address constant of 1. argument
  7396. 1$
  7397.     tst.l    (A0)            ; Address 1. argument there?
  7398.     beq.s    3$
  7399.     movea.l    (A0)+,A1        ; Out of it address 1. argument
  7400.     lea    _NoWarningName(pc),A2    ; "NOWARN",0
  7401.     moveq    #6,D0            ; 7 loops
  7402. 2$
  7403.     cmpm.b    (A1)+,(A2)+        ; Compare char for char
  7404.     bne.s    1$            ; "NOWARN"
  7405.     dbf    D0,2$
  7406.     st.b    _NoWarnFlag(A5)
  7407.  
  7408. 3$
  7409.     lea    WB_arg_1(A5),A0        ; Address constant of 1. argument
  7410. 4$
  7411.     tst.l    (A0)            ; Address 1. argument there?
  7412.     beq.s    6$
  7413.     movea.l    (A0)+,A1        ; Out of it address 1. argument
  7414.     lea    _NoCheckPrinterTxt(pc),A2    ; "NOPRTCHECK",0
  7415.     moveq    #10,D0            ; 11 loops
  7416. 5$
  7417.     cmpm.b    (A1)+,(A2)+        ; Compare char for char
  7418.     bne.s    4$
  7419.     dbf    D0,5$
  7420.     st.b    _NoCheckPrtFlag(A5)
  7421. 6$
  7422.     rts
  7423.  
  7424. *************************************************
  7425. *
  7426. * Check for user specification in tooltypes.
  7427. * If specification was made, execute the command.
  7428. * Inputs: none
  7429. * Results: none
  7430. *
  7431.  
  7432. _CheckExecute
  7433.     lea    WB_arg_1(A5),A0
  7434. .NextTType
  7435.     tst.l    (A0)            ; Argument there?
  7436.     beq.s    .EndExecute        ; No
  7437.     movea.l    (A0)+,A1        ; Address overgiven string
  7438.     lea    _ExecuteTxt(pc),A2    ; Address string to compare
  7439.     moveq    #7,D0            ; 8 chars to compare
  7440. .CheckTType
  7441.     cmpm.b    (A1)+,(A2)+        ; Compare strings
  7442.     bne.s    .NextTType        ; "EXECUTE="
  7443.     dbf    D0,.CheckTType
  7444.     movea.l    A1,A0            ; Pointer to following string
  7445.  
  7446.     moveq    #0,D4
  7447.     lea    _ConBuffer(A5),A1
  7448. 1$
  7449.     move.b    (A0)+,(A1)+
  7450.     bne.s    1$
  7451.     move.l    _stdout(A5),D3
  7452.     bne.s    2$
  7453.     lea    _NilName(pc),A0
  7454.     move.l    A0,D1
  7455.     move.l    #MODE_NEWFILE,D2
  7456.     movea.l    _DOSBase(A5),A6
  7457.     jsr    _LVOOpen(A6)
  7458.     move.l    D0,D4
  7459.     beq.s    .EndExecute
  7460.     move.l    D4,D3
  7461. 2$
  7462.     lea    _ConBuffer(A5),A0
  7463.     move.l    A0,D1
  7464.     moveq    #0,D2
  7465.     movea.l    _DOSBase(A5),A6
  7466.     jsr    _LVOExecute(A6)
  7467.     tst.l    D4
  7468.     beq.s    .EndExecute
  7469.     move.l    D4,D1
  7470.     jsr    _LVOClose(A6)    
  7471. .EndExecute
  7472.     rts
  7473.  
  7474. **********************************
  7475. *
  7476. * Init gadgets for "DisplayError".
  7477. * Do it position independent.
  7478. *
  7479. * Inputs: None
  7480. * Results: None
  7481. *
  7482.  
  7483. _InitGadgets
  7484.     movem.l    D0-D2/A0-A4/A6,-(sp)
  7485.  
  7486. BoolGadFlags    EQU    GADGIMMEDIATE|RELVERIFY
  7487.  
  7488.     lea    _Gad1(A5),A0
  7489.     move.w    #20,gg_LeftEdge(A0)
  7490.     move.w    #78,gg_TopEdge(A0)
  7491.     move.w    #74,gg_Width(A0)
  7492.     move.w    #19,gg_Height(A0)
  7493.     move.w    #GADGHIMAGE|GADGIMAGE,gg_Flags(A0)
  7494.     move.w    #BoolGadFlags,gg_Activation(A0)
  7495.     move.w    #BOOLGADGET,gg_GadgetType(A0)
  7496.     move.w    #1,gg_GadgetID(A0)
  7497.  
  7498.     lea    _Gad2(A5),A1
  7499.     moveq    #gg_SIZEOF,D0
  7500.     bra.s    2$
  7501. 1$
  7502.     move.b    (A0)+,(A1)+
  7503. 2$
  7504.     dbf    D0,1$
  7505.  
  7506.     lea    _Gad2(A5),A0
  7507.     clr.l    (A0)            ; No next gadget!  - otherwise on second
  7508. *                      initializing it would point to itself!!!
  7509.     move.w    #226,gg_LeftEdge(A0)
  7510.     move.w    #2,gg_GadgetID(A0)
  7511.  
  7512.     lea    _GTxt1(A5),A0
  7513.     move.b    #1,(A0)            ; DetailPen
  7514.     lea    _GTxt2(A5),A0
  7515.     move.b    #1,(A0)            ; DetailPen
  7516.  
  7517.     lea    _Image.1(pc),A0
  7518.     lea    _Image.2(pc),A1
  7519.     lea    _Gad1(A5),A2
  7520.     lea    _Gad2(A5),A3
  7521.  
  7522.     move.l    A3,(A2)
  7523.     move.l    A0,gg_GadgetRender(A2)
  7524.     move.l    A1,gg_SelectRender(A2)
  7525.     lea    _GTxt1(A5),A4
  7526.     move.l    A4,gg_GadgetText(A2)
  7527.  
  7528.     move.l    A0,gg_GadgetRender(A3)
  7529.     move.l    A1,gg_SelectRender(A3)
  7530.     lea    _GTxt2(A5),A4
  7531.     move.l    A4,gg_GadgetText(A3)
  7532.  
  7533.     lea    _GTxt1(A5),A0
  7534.     lea    _GStr1(pc),A1
  7535.     move.l    A1,it_IText(A0)
  7536.  
  7537.     lea    _GTxt2(A5),A0
  7538.     lea    _GStr2(pc),A1
  7539.     move.l    A1,it_IText(A0)
  7540.  
  7541.     lea    _startup(pc),A0        ; First instruction of Viewer (startup-code)
  7542.     subq.l    #4,A0            ; Pointer to BPTR next hunk
  7543.     movea.l    (A0),A0            ; BPTR NextHunk
  7544.     adda.l    A0,A0
  7545.     adda.l    A0,A0            ; APTR NextHunk
  7546.     addq.l    #4,A0            ; Section Chip (_Gad.1, size 190 bytes)
  7547.     movea.l    A0,A1
  7548.     lea    190(A1),A1        ; _Gad.2
  7549.     lea    _Image.1(pc),A2
  7550.     lea    _Image.2(pc),A3
  7551.     move.l    A0,ig_ImageData(A2)
  7552.     move.l    A1,ig_ImageData(A3)
  7553.  
  7554.     bsr.s    _CenterGadTxt
  7555.  
  7556.     movem.l    (sp)+,D0-D2/A0-A4/A6
  7557.     rts
  7558.  
  7559. _CenterGadTxt
  7560.     lea    _Gad1(A5),A2        ; First-Gadget
  7561.     bra.s    .set
  7562. .NextGadget
  7563.     tst.l    (A2)            ; Next gadget?
  7564.     beq.w    .NoNext
  7565.     movea.l    (A2),A2
  7566. .set
  7567.     move.w    gg_GadgetType(A2),D0
  7568.     btst    #0,D0            ; BoolGadget ?
  7569.     beq.s    .NextGadget        ; If not
  7570.  
  7571.     tst.l    gg_GadgetText(A2)    ; Intuition-text-structure?
  7572.     beq.s    .NextGadget
  7573.     movea.l    gg_GadgetText(A2),A0
  7574.     movea.l    A0,A3            ; Save Intuition-text-structure
  7575.     tst.l    it_IText(A0)        ; Any Text placed?
  7576.     beq.s    .NextGadget
  7577.     movea.l    it_IText(A0),A0        ; Pointer to string
  7578.     movea.l    A0,A1
  7579.     moveq    #-1,D0
  7580. .getChars
  7581.     tst.b    (A1)+
  7582.     dbeq    D0,.getChars
  7583.     not.l    D0            ; Length in chars of string
  7584.     movea.l    _ErrWindowPtr(A5),A1    ; Window
  7585.     movea.l    wd_WScreen(A1),A1    ; Screen's
  7586.     lea    sc_RastPort(A1),A1    ; RastPort!!! <- default font!!!
  7587.     movea.l    _GfxBase(A5),A6
  7588.     jsr    _LVOTextLength(A6)    ; Get stringlength in pixel
  7589.  
  7590.     move.w    gg_Width(A2),D1        ; Width of gadget
  7591.  
  7592.     lsr.w    #1,D0            ; Half textlength
  7593.     lsr.w    #1,D1            ; Half gadget width
  7594.     sub.w    D0,D1            ; Offset 1. char
  7595.     move.w    D1,it_LeftEdge(A3)    ; Store it in IntuiText-structure
  7596.  
  7597.     moveq    #0,D2            ; Flags
  7598.     movea.l    _ErrWindowPtr(A5),A0    ; Window
  7599.     movea.l    wd_WScreen(A0),A0    ; Get screen's
  7600.     lea    sc_RastPort(A0),A0    ; rastport - not window's one, because
  7601. *                      the default-font is used for a gadget-text
  7602.     move.w    rp_TxHeight(A0),D0    ; Height in pixel of font
  7603.     btst    #0,D0            ; Font-height even (8, 10, 12 a.s.o.)?
  7604.     bne.s    2$
  7605. 1$
  7606.     move.b    #1,D2    
  7607. 2$
  7608.     move.w    #19,D1            ; Height gadget
  7609.     lsr.w    #1,D0            ; Half
  7610.     lsr.w    #1,D1            ; Half
  7611.     sub.w    D0,D1            ; Y-offset font
  7612.     add.w    D2,D1            ; Add (may be NULL) for even font-sizes
  7613.     move.w    D1,it_TopEdge(A3)    ; Set Top-Offset
  7614.     bra.w    .NextGadget
  7615. .NoNext
  7616.     rts
  7617.  
  7618. ***************
  7619. *
  7620. * Init windows.
  7621. *
  7622. * Inputs: none
  7623. * Results: none
  7624. *
  7625.  
  7626. _InitStandard
  7627.     lea    _WindowRecord(A5),A0
  7628.     move.b    #1,nw_DetailPen(A0)
  7629.     move.b    #3,nw_BlockPen(A0)
  7630.     move.l    #$8|$40|$200|$400,nw_IDCMPFlags(A0)
  7631.     move.l    #1|2|4|8|$10|$400|$1000|$10000,nw_Flags(A0)
  7632.     move.w    #240,nw_MinWidth(A0)    
  7633.     move.w    #70,nw_MinHeight(A0)    
  7634.     moveq    #-1,D0
  7635.     move.w    D0,nw_MaxWidth(A0)
  7636.     move.w    D0,nw_MaxHeight(A0)
  7637.     move.w    #CUSTOMSCREEN,nw_Type(A0)
  7638.  
  7639.     lea    _ErrWindowStruc(A5),A0
  7640.     move.w    #320,nw_Width(A0)
  7641.     move.w    #100,nw_Height(A0)
  7642.     move.b    #-1,nw_DetailPen(A0)
  7643.     move.b    #-1,nw_BlockPen(A0)
  7644.     move.l    #$40|$400,nw_IDCMPFlags(A0)
  7645.     move.l    #$1000|$10000,nw_Flags(A0)
  7646.     move.w    #320,nw_MinWidth(A0)    
  7647.     move.w    #100,nw_MinHeight(A0)    
  7648.     move.w    #320,nw_MaxWidth(A0)
  7649.     move.w    #100,nw_MaxHeight(A0)
  7650.     move.w    #CUSTOMSCREEN,nw_Type(A0)
  7651.  
  7652.     rts
  7653.  
  7654.  
  7655. ****************************************************************************
  7656. *
  7657. * Allocate AudioIO-request
  7658. *
  7659. * Inputs: Priority (should be NULL or negative)  D0 (byte, word, longword, but signed!)
  7660. *
  7661. * Result: APTR IOAudio - pointer to IORequest or zero upon error
  7662. *
  7663. * Notes: IOAudio is larger than it seems, so never deallocate it on your own.
  7664. *
  7665.  
  7666. IOReq_size    EQU    68+4    ; size: divisible by eight
  7667. MsgPort_size    EQU    34+6    ; size: divisible by eight
  7668. IOAudio_size    EQU    IOReq_size+MsgPort_size
  7669.  
  7670. _AllocIOAudioA ; (D0)(Pri)
  7671.     movem.l    D2/A3-A4/A6,-(sp)
  7672.  
  7673.     move.l    D0,D2            ; Pri
  7674.  
  7675.     moveq    #IOAudio_size,D0    ; 68 bytes IOAudio, 34 bytes MsgPort - aligned!
  7676.     move.l    #MEMF_PUBLIC|MEMF_CLEAR,D1
  7677.     movea.l    _SysBase(A5),A6
  7678.     jsr    _LVOAllocMem(A6)
  7679.     tst.l    D0
  7680.     beq.w    .AllocAudioEnd        ; Error no mem
  7681.     movea.l    D0,A4            ; IOReq ( *IOAudio)
  7682.     movea.l    D0,A3            ; IOAudio
  7683.     lea    IOReq_size(A3),A3    ; Skip IOAudio - thus pointer to MessagePort
  7684.  
  7685.     moveq    #-1,D0            ; Any signal will do it
  7686.     jsr    _LVOAllocSignal(A6)
  7687.     cmpi.l    #-1,D0            ; Failed?
  7688.     beq.w    .errNoSignal
  7689.  
  7690.     move.b    D0,MP_SIGBIT(A3)    ; SignalBit
  7691.     suba.l    A1,A1
  7692.     jsr    _LVOFindTask(A6)    ; Own task
  7693.     move.l    D0,MP_SIGTASK(A3)    ; Task who is signalled
  7694.     move.b    #NT_MSGPORT,LN_TYPE(A3) ; Type = message port
  7695.     lea    MP_MSGLIST(A3),A0
  7696.     NEWLIST    A0            ; Set up empty list
  7697.  
  7698.     btst    #31,D2            ; A signed long value?
  7699.     bne.s    .signed            ; If so...
  7700.     btst    #15,D2            ; A signed word value?
  7701.     beq.s    .setup            ; If not...
  7702. .signed
  7703.     bset    #7,D2            ; Make a signed byte
  7704. .setup
  7705.     move.b    D2,LN_PRI(A4)        ; Priority of message (IOAudio->io_Message->ln_Pri)
  7706.     move.b    #NT_REPLYMSG,LN_TYPE(A4) ; Type = ~message - due to a buck in CheckIO()
  7707.     move.l    A3,MN_REPLYPORT(A4)    ; Set replyport
  7708.     move.w    #ioa_SIZEOF,MN_LENGTH(A4); Length of message
  7709.  
  7710.     lea    _Channels(pc),A0
  7711.     move.l    A0,ioa_Data(A4)        ; Address channel map
  7712.     move.l    #4,ioa_Length(A4)    ; Length channel map
  7713.     move.b    #ADIOF_NOWAIT,IO_FLAGS(A4)    ; Do not wait until channels are unlocked
  7714.     move.w    #ADCMD_ALLOCATE,IO_COMMAND(A4)    ; Alloc channels upon opening device
  7715.  
  7716.     lea    _AudioName(pc),A0    ; Device
  7717.     movea.l    A4,A1            ; IOReq
  7718.     moveq    #0,D0            ; Unit
  7719.     moveq    #0,D1            ; Flags
  7720.     jsr    _LVOOpenDevice(A6)
  7721.     tst.l    D0
  7722.     bne.s    .errNoDev
  7723.  
  7724.     move.l    A4,D0            ; IOAudio
  7725. .AllocAudioEnd
  7726.     movem.l    (sp)+,D2/A3-A4/A6
  7727.     rts
  7728.  
  7729. .errNoMem
  7730.     moveq    #ERROR_NO_FREE_STORE,D0
  7731.     bsr.s    .SetIoErr
  7732.     moveq    #0,D0
  7733.     bra.s    .AllocAudioEnd
  7734. .errNoSignal
  7735.     move.l    #ERROR_NO_MORE_ENTRIES,D0
  7736.     bsr.s    .SetIoErr
  7737.     bsr.s    .FreeAudioIOReq
  7738.     moveq    #0,D0
  7739.     bra.s    .AllocAudioEnd
  7740. .errNoDev
  7741.     move.l    #ERROR_OBJECT_IN_USE,D0
  7742.     bsr.s    .SetIoErr
  7743.     moveq    #0,D0
  7744.     move.b    MP_SIGBIT(A3),D0
  7745.     jsr    _LVOFreeSignal(A6)
  7746.     bsr.s    .FreeAudioIOReq
  7747.     moveq    #0,D0
  7748.     bra.s    .AllocAudioEnd
  7749. .FreeAudioIOReq
  7750.     movea.l    A4,A1
  7751.     moveq    #IOAudio_size,D0
  7752.     jmp    _LVOFreeMem(A6)
  7753.  
  7754. .SetIoErr
  7755.     movea.l    276(A6),A0        ; ThisTask(A6)
  7756.     cmpi.b    #NT_PROCESS,LN_TYPE(A0)    ; Are we a process or task?
  7757.     bne.s    .done
  7758.     move.l    D0,pr_Result2(A0)    ; Set error code in process' error field
  7759. .done
  7760.     rts
  7761.  
  7762. *************************************************************************
  7763. *
  7764. * Free through AllocAudioIO() allocated IORequest, MessagePort, Signalbit.
  7765. *
  7766. * Inputs: IOAudio A0, APTR
  7767. *
  7768. * Results: None
  7769. *
  7770.  
  7771. _FreeIOAudioA ; (A0)(IOAudio)
  7772.     movem.l    A3-A4/A6,-(sp)
  7773.     move.l    A0,D0
  7774.     beq.s    .out
  7775.     movea.l    A0,A4
  7776.     movea.l    A0,A3
  7777.     lea    IOReq_size(A3),A3    ; Skip IOAudio
  7778.  
  7779.     tst.l    IO_DEVICE(A4)
  7780.     beq.s    .NotInProgress
  7781.  
  7782.     movea.l    A4,A1
  7783.  
  7784. *    clr.b    LN_TYPE(A4)
  7785.  
  7786. * Although I set the type of IORequest to zero (as stated in autodocs) CheckIO() will ever hang...
  7787. *    movea.l    _SysBase(A5),A6
  7788. *    jsr    _LVOCheckIO(A6)        ; A process running?
  7789. *    tst.l    D0            ; ~0 == no process
  7790. *    bne.s    .NotInProgress
  7791.  
  7792.     movea.l    A4,A1
  7793.     ABORTIO
  7794.  
  7795. *    movea.l    A4,A1
  7796. *    jsr    _LVOWaitIO(A6)
  7797.  
  7798. .NotInProgress
  7799.     moveq    #0,D0
  7800.     move.b    MP_SIGBIT(A3),D0    ; Get allocated signal
  7801.     jsr    _LVOFreeSignal(A6)    ; Free allocated signal
  7802.  
  7803.     movea.l    A4,A1
  7804.     jsr    _LVOCloseDevice(A6)    ; Close the audio-device
  7805.  
  7806.     movea.l    A4,A1
  7807.     moveq    #IOAudio_size,D0    ; Full size (aligned)
  7808.     jsr    _LVOFreeMem(A6)        ; Free allocated memory
  7809. .out
  7810.     movem.l    (sp)+,A3-A4/A6
  7811.     rts
  7812.  
  7813. *******************************************************
  7814. *
  7815. * Move the datas to the audio-channels.
  7816. * Breaks the current IOAudio-process.
  7817. * Does not wait until datas are completely worked out.
  7818. *
  7819. * Inputs: D0 (ULONG) Length in Bytes
  7820. *      D1 (UWORD) Cycles ( NULL = neverending)
  7821. *      D2 (UWORD) Period
  7822. *      D3 (UWORD) Volume
  7823. *      A0 (APTR) IOAudio
  7824. *      A1 (APTR) AudioDatas (must stay in chip-mem)
  7825. *
  7826. * Results: NULL - error - zero IOAudio
  7827. *
  7828.  
  7829. _SendIOAudioA ; (D0,D1,D2,D3,A0,A1)(length,cycles,period,volume,IOAudio,audiodata)
  7830.     movem.l    D2-D5/A2-A3/A6,-(sp)
  7831.  
  7832.     movea.l    A0,A2            ; IOAudio
  7833.     movea.l    A1,A3            ; audiodata
  7834. *           D2            ; period
  7835. *           D3            ; volume
  7836.     move.l    D0,D4            ; length
  7837.     move.w    D1,D5            ; cycles
  7838.     move.l    A0,D0
  7839.     beq.s    .failed
  7840. *
  7841. ** There seems to be a bug in the audio.device. CheckIO() will here
  7842. ** return ever that there is a process running, even there isn't one.
  7843. ** If we _do_ ABORTIO with an afterward WaitIO() (convention!) we wait
  7844. ** here until world's ruin....
  7845. *
  7846.     movea.l    A2,A1
  7847.     movea.l    _SysBase(A5),A6
  7848.     jsr    _LVOCheckIO(A6)        ; A process running?
  7849.     tst.l    D0            ; ~0 == no process
  7850.     bne.s    .NotInProgress
  7851.  
  7852.     movea.l    A2,A1
  7853.     ABORTIO
  7854.  
  7855. .NotInProgress
  7856.     movea.l    A2,A1            ; IOAudio
  7857.     move.l    A3,ioa_Data(A1)
  7858.     move.l    D4,ioa_Length(A1)
  7859.     move.w    D2,ioa_Period(A1)
  7860.     move.w    D3,ioa_Volume(A1)
  7861.     move.w    D5,ioa_Cycles(A1)
  7862.     move.b    #ADIOF_PERVOL|ADIOF_SYNCCYCLE|IOF_QUICK,IO_FLAGS(A1)
  7863.     move.w    #CMD_WRITE,IO_COMMAND(A1)
  7864.     BEGINIO                ; BEGINIO and ABORTIO are MARCOS of "exec/io.i"!
  7865.     move.l    A2,D0
  7866. .out
  7867.     movem.l    (sp)+,D2-D5/A2-A3/A6
  7868.     rts
  7869. .failed
  7870.     moveq    #0,D0
  7871.     bra.s    .out
  7872.  
  7873. *******************************************
  7874. *
  7875. ** Make the sound audible
  7876. *
  7877.  
  7878. _AudioHit
  7879.     movem.l    D2-D7,-(sp)
  7880.     tst.b    _AudGadget(A5)
  7881.     beq.w    1$
  7882.     tst.l    _AudioBuffer(A5)
  7883.     beq.w    1$
  7884.     tst.l    _IOAudio(A5)
  7885.     beq.w    1$
  7886.  
  7887.     movea.l    _IOAudio(A5),A0
  7888.     move.b    IO_ERROR(A0),D0        ; Any error?
  7889.     bpl.s    .gogo            ; No...
  7890.  
  7891.     bsr.w    _FreeIOAudioA        ; Error, so free device block
  7892.     moveq    #-50,D0            ; and allocate a new one
  7893.     bsr.w    _AllocIOAudioA        ; with the same priority
  7894.     move.l    D0,_IOAudio(A5)
  7895.     beq.w    .errorPlay        ; If we still can't them...
  7896.  
  7897. .gogo
  7898.     move.l    _BODYSize(A5),D0
  7899.     move.l    _AudioBufferSize(A5),D1
  7900.     cmp.l    D0,D1
  7901.     bls.s    2$
  7902.  
  7903. * Normal, one shot sample play, sample size lower or equal to 28 kbyte 
  7904.     move.l    _BODYSize(A5),D0
  7905.     moveq    #1,D1
  7906.     move.l    _AudioPeriod(A5),D2
  7907.     moveq    #64,D3
  7908.     movea.l    _IOAudio(A5),A0
  7909.     move.l    _AudioBuffer(A5),A1
  7910.     bsr.w    _SendIOAudioA
  7911.  
  7912.     movea.l    _IOAudio(A5),A0
  7913.     tst.b    IO_ERROR(A0)
  7914.     bne.w    .errorPlay
  7915.  
  7916.     bra.w    .done            ; Done
  7917.  
  7918. * Smart, sample size taller than 28 kbyte
  7919. 2$
  7920.     movea.l    _IOAudio(A5),A0
  7921.     movea.l    MN_REPLYPORT(A0),A0
  7922.     move.b    MP_SIGBIT(A0),D1    ; Get SigBit of IO Request
  7923.     moveq    #0,D4
  7924.     move.b    D1,D4
  7925.     moveq    #1,D0
  7926.     lsl.l    D1,D0            ; ... and convert it into a bitmask
  7927.     move.l    D0,D7
  7928.  
  7929.     movea.l    _WindowPtr(A5),A0    ; Same for our window
  7930.     movea.l    wd_UserPort(A0),A0
  7931.     move.b    MP_SIGBIT(A0),D1
  7932.     moveq    #1,D0
  7933.     lsl.l    D1,D0
  7934.     or.l    D0,D7            ; Combine both mask
  7935.  
  7936.     move.l    _BODYSize(A5),D6    ; The size of the whole audio datas
  7937.     moveq    #0,D5            ; How many bytes already played
  7938.  
  7939.     moveq    #0,D0            ; Refer to chip-ram buffer 0
  7940.     bsr.w    .SetupAudBuffer
  7941.     move.l    D0,D2            ; Amount datas to play
  7942.  
  7943. 3$    
  7944.     tst.l    D2
  7945.     beq.w    .done
  7946.     move.l    D2,D0            ; Play how many ....
  7947.     moveq    #1,D1            ; One cycle
  7948.     move.l    _AudioPeriod(A5),D2    ; Period
  7949.     moveq    #64,D3            ; Volume
  7950.     move.l    _IOAudio(A5),A0        ; Device IO Request block
  7951.     move.l    _AudioBuffer(A5),A1    ; Datas
  7952.     bsr.w    _SendIOAudioA        ; Play them!
  7953.  
  7954.     moveq    #1,D0            ; Refer to chip-ram buffer 1
  7955.     bsr.s    .SetupAudBuffer
  7956.     move.l    D0,D2
  7957.     beq.s    .done
  7958.  
  7959.     movea.l    _IOAudio(A5),A0
  7960.     tst.b    IO_ERROR(A0)        ; Error occurred?
  7961.     bne.s    .errorPlay
  7962.  
  7963.     movea.l    _SysBase(A5),A6
  7964.     move.l    D7,D0            ; Mask
  7965.     jsr    _LVOWait(A6)        ; Wait for this part to finish
  7966.     moveq    #0,D3
  7967.     btst.l    D4,D0            ; Not an audio signal?
  7968.     beq.w    4$            ; If no audio signal!
  7969.  
  7970. .InJump
  7971.     move.l    D2,D0            ; Play how many ....
  7972.     moveq    #1,D1
  7973.     move.l    _AudioPeriod(A5),D2
  7974.     moveq    #64,D3
  7975.     movea.l    _IOAudio(A5),A0
  7976.     move.l    _AudioBuffer(A5),A1
  7977.     lea    14*1024(A1),A1
  7978.     bsr.w    _SendIOAudioA
  7979.  
  7980.     moveq    #0,D0            ; Refer to chip-ram buffer 0
  7981.     bsr.s    .SetupAudBuffer
  7982.  
  7983.     move.l    D0,D2
  7984.  
  7985.     movea.l    _IOAudio(A5),A0
  7986.     tst.b    IO_ERROR(A0)
  7987.     bne.s    .errorPlay
  7988.  
  7989.     movea.l    _SysBase(A5),A6
  7990.     move.l    D7,D0
  7991.     jsr    _LVOWait(A6)        ; Wait for that part to finish
  7992.     moveq    #1,D3
  7993.     btst.l    D4,D0            ; Not an audio signal?
  7994.     beq.s    4$            ; If no audio signal!
  7995.  
  7996.     bra.s    3$            ; Restart (next data block)
  7997.  
  7998. .errorPlay
  7999.     lea    _AudErrTxt(pc),A0
  8000.     bsr.w    _DisplayError
  8001.     bra.s    1$
  8002. .done
  8003.     movea.l    _SysBase(A5),A6
  8004.     movea.l    _IOAudio(A5),A1
  8005.     jsr    _LVOWaitIO(A6)
  8006. 1$
  8007.     movem.l    (sp)+,D2-D7
  8008.     bra.w    _Loop
  8009.  
  8010. * -------- Fill either first or second buffer with audio datas -------- *
  8011. * D0 = 0, 1st buffer, D0 = 1, second buffer
  8012.  
  8013. .SetupAudBuffer
  8014.     subi.l    #14*1024,D6        ; Try to work out 14 kbyte
  8015.     bcs.s    .overload        ; If there isn't such a amount
  8016.  
  8017.     movea.l    _BODYPtr(A5),A0        ; Pointer to datas (in fast ram/hopefully)
  8018.     add.l    D5,A0            ; Fetch datas that aren't worked out yet
  8019.     movea.l    _AudioBuffer(A5),A1    ; Chip-ram buffer (28 kbyte)
  8020.     mulu.w    #14*1024,D0        ; Two which part we refer (14 kbyte)
  8021.     adda.l    D0,A1
  8022.     move.l    #14*1024,D0        ; Size: 14 kbyte to copy
  8023.     movea.l    _SysBase(A5),A6
  8024.     jsr    _LVOCopyMemQuick(A6)
  8025.     move.l    #14*1024,D0        ; Size to play: 14 kbyte
  8026.     add.l    D0,D5            ; Amount datas that worked out already
  8027.     rts
  8028.  
  8029. .overload
  8030.     add.l    #14*1024,D6        ; Get rest of datas
  8031.  
  8032.     movea.l    _BODYPtr(A5),A0
  8033.     add.l    D5,A0
  8034.     movea.l    _AudioBuffer(A5),A1
  8035.     mulu.w    #14*1024,D0        ; To which chip-ram buffer we refer ?
  8036.     adda.l    D0,A1
  8037.     move.l    D6,D0
  8038.     movea.l    _SysBase(A5),A6
  8039.     jsr    _LVOCopyMem(A6)
  8040.     add.l    D6,D5
  8041.     move.l    D6,D0            ; Size to play
  8042.     moveq    #0,D6            ; No more datas
  8043.     rts
  8044.  
  8045. * -------- React to user input (while something is played)-------- *
  8046. 4$
  8047.     movea.l    _WindowPtr(A5),A0
  8048.     movea.l    wd_UserPort(A0),A0
  8049.     movea.l    _SysBase(A5),A6
  8050.     jsr    _LVOGetMsg(A6)
  8051.     tst.l    D0
  8052.     beq.s    7$
  8053.  
  8054.     movea.l    D0,A1
  8055.     move.l    20(A1),D0        ; im_Class
  8056.     move.w    24(A1),D1        ; im_Code
  8057.     move.l    28(A1),_IAddr(A5)
  8058.  
  8059.     movem.l    D0-D1,-(sp)
  8060.     jsr    _LVOReplyMsg(A6)
  8061.     movem.l    (sp)+,D0-D1
  8062.  
  8063.     cmpi.l    #$200,D0        ; CLOSEWINDOW ?
  8064.     bne.s    5$
  8065.     movem.l    (sp)+,D2-D7
  8066.     bsr.s    .WaitAction
  8067.     bra.w    _End            ; If so...
  8068. 5$
  8069.     cmpi.l    #$40,D0            ; GADGETUP
  8070.     bne.s    6$
  8071.     movea.l    _IAddr(A5),A0
  8072.     cmpi.w    #3,gg_GadgetID(A0)
  8073.     bne.s    7$
  8074.     bsr.s    .WaitAction
  8075.     bra.w    2$            ; Redo from start!
  8076. 6$
  8077.     cmpi.l    #$400,D0        ; RAWKEY?
  8078.     bne.s    7$            ; If not...
  8079.     cmpi.w    #L_Key,D1
  8080.     bne.s    7$
  8081.     movem.l    (sp)+,D2-D7
  8082.     bsr.s    .WaitAction
  8083.     bra.w    _LoadNew
  8084. 7$
  8085.     bsr.s    .WaitAction
  8086.     tst.l    D3
  8087.     beq.w    .InJump            ; Jump where we can continue
  8088.     bra.w    3$
  8089.  
  8090. * -------- Ignore multiple intuition messages and wait for the IO to complete -------- *
  8091. .WaitAction
  8092.     movea.l    _WindowPtr(A5),A0
  8093.     movea.l    wd_UserPort(A0),A0
  8094.     movea.l    _SysBase(A5),A6
  8095.     jsr    _LVOGetMsg(A6)
  8096.     tst.l    D0
  8097.     beq.s    8$
  8098.     movea.l    D0,A1
  8099.     jsr    _LVOReplyMsg(A6)
  8100.     bra.s    .WaitAction
  8101. 8$
  8102.     movea.l    _IOAudio(A5),A1
  8103.     jsr    _LVOWaitIO(A6)
  8104.     rts
  8105.  
  8106. *************************************************
  8107. *
  8108. ** Load Audio File
  8109. *
  8110.  
  8111. _LoadAudio
  8112.     lea    _8SVXTxt(pc),A0
  8113.     bsr.w    _DisplayError
  8114.     tst.l    D0
  8115.     beq.w    _BinaryFile
  8116.  
  8117.     bsr.s    _GetAudioSettings
  8118.  
  8119.     moveq    #-50,D0
  8120.     bsr.w    _AllocIOAudioA
  8121.     move.l    D0,_IOAudio(A5)
  8122.     beq.s    .error
  8123.  
  8124.     bsr.w    _DisplayAudioGadget
  8125.  
  8126.     addq.l    #4,sp            ; Remove "bsr.w _CheckFile"
  8127.     bra.w    _Loop
  8128.  
  8129. .error
  8130.     bsr.w    _FreeAudio
  8131.     bsr.w    _FreeFile
  8132.     lea    _8SVXErrTxt(pc),A0
  8133.     bsr.w    _DisplayError
  8134.     addq.l    #4,sp
  8135.     bra.w    _Loop
  8136.  
  8137.  
  8138. _GetAudioSettings
  8139.     bsr.w    _CheckFibDelta
  8140.     tst.l    D0
  8141.     beq.w    .error
  8142.  
  8143.     move.l    #28*1024,D0
  8144.     move.l    D0,_AudioBufferSize(A5)
  8145.     move.l    #MEMF_CLEAR|MEMF_CHIP|MEMF_PUBLIC,D1
  8146.     movea.l    _SysBase(A5),A6
  8147.     jsr    _LVOAllocMem(A6)
  8148.     move.l    D0,_AudioBuffer(A5)
  8149.     beq.w    .error
  8150.  
  8151.     movea.l    _TextPtr(A5),A0        ; Address datas
  8152.     move.l    _FileSize(A5),D0    ; Size datas
  8153.     cmpi.w    #'FO',(A0)
  8154.     beq.s    .startScan
  8155.     addq.l    #2,A0
  8156.     subq.l    #2,D0
  8157. .startScan
  8158.     lea    12(A0),A0
  8159.     subi.l    #12,D0
  8160.     move.l    #'VHDR',D1
  8161.     bsr.w    .getChunk
  8162.     tst.l    D1
  8163.     beq.s    .error
  8164. .scanBody
  8165.     move.l    A0,_VHDRPtr(A5)
  8166.     addq.l    #8,_VHDRPtr(A5)
  8167.     move.l    #'BODY',D1
  8168.     bsr.w    .getChunk
  8169.     tst.l    D1
  8170.     beq.s    .error
  8171. .gotBody
  8172.     move.l    A0,_BODYPtr(A5)
  8173.     addq.l    #8,_BODYPtr(A5)
  8174.     move.l    4(A0),_BODYSize(A5)
  8175.  
  8176.     move.l    _VHDRPtr(A5),A0
  8177.     moveq    #0,D1
  8178.     move.w    12(A0),D1
  8179.  
  8180. * Hertz to Period, the slow way...
  8181.     move.l    #100000000,D0
  8182. *    move.l    D1,D1            ; Hertz
  8183.     moveq    #28,D2
  8184.     mulu.w    D2,D1
  8185.  
  8186.     moveq    #-1,D2
  8187. .divlong
  8188.     addq.l    #1,D2
  8189.     sub.l    D1,D0
  8190.     bcc.s    .divlong
  8191.  
  8192.     move.l    D2,_AudioPeriod(A5)
  8193.  
  8194.     move.l    _BODYSize(A5),D0
  8195.     move.l    _AudioBufferSize(A5),D1
  8196.     cmp.l    D0,D1
  8197.     bhi.s    .cpy
  8198.  
  8199.     move.l    _BODYPtr(A5),A0
  8200.     move.l    _AudioBuffer(A5),A1
  8201.     move.l    #28*1024,D0
  8202.     movea.l    _SysBase(A5),A6
  8203.     jsr    _LVOCopyMemQuick(A6)
  8204.     rts
  8205.  
  8206. .cpy
  8207.     move.l    _BODYPtr(A5),A0
  8208.     move.l    _AudioBuffer(A5),A1
  8209.     move.l    _BODYSize(A5),D0
  8210.     movea.l    _SysBase(A5),A6
  8211.     jsr    _LVOCopyMem(A6)
  8212.     rts
  8213.  
  8214. .error
  8215.     lea    _8SVXErrTxt(pc),A0
  8216.     bsr.w    _DisplayError
  8217.     bsr.w    _FreeFile
  8218.     bsr.w    _FreeAudio
  8219.     addq.l    #8,sp            ; Remove "bsr.w _CheckFile" and "bsr.s GetAudioSettings"
  8220.     bra.w    _Loop
  8221.  
  8222. .getChunk
  8223.     cmp.l    (A0),D1
  8224.     beq.s    .chunkFound
  8225. .getNextChunk
  8226.     move.l    4(A0),D2        ; Size of this chunk
  8227.     addq.l    #1,D2
  8228.     andi.l    #-2,D2            ; In case it was odd, it's now even
  8229.     addq.l    #8,D2            ; Skip chunk name and its size entry
  8230.     sub.l    D2,D0            ; A rest left?
  8231.     beq.s    .chunkError
  8232.     bmi.s    .chunkError
  8233.     lea    0(A0,D2),A0        ; Point to next chunk name
  8234.     cmp.l    (A0),D1            ; Compare
  8235.     bne.s    .getNextChunk
  8236. .chunkFound
  8237.     rts
  8238. .chunkError
  8239.     moveq    #0,D1
  8240.     rts
  8241.  
  8242. _FindVHDR
  8243.     move.l    D0,D2            ; Size file
  8244.     subi.l    #12,D2
  8245.     lea    12(A0),A1        ; Chunk name
  8246. .restart
  8247.     move.l    4(A1),D1        ; Chunk size
  8248.     addq.l    #1,D1
  8249.     andi.l    #-2,D1            ; Even chunk size
  8250.     addq.l    #8,D1            ; Chunk name + sizeof(chunk size var) (4 bytes)
  8251.     sub.l    D1,D2
  8252.     beq.s    .notfound
  8253.     bmi.s    .notfound
  8254.     lea    0(A1,D1),A1        ; Next chunk name
  8255.     cmpi.l    #'VHDR',(A1)
  8256.     bne.s    .restart
  8257. .found
  8258.     addq.l    #8,A1
  8259.     bra.s    _TestIfFibDeltaComp
  8260. .notfound
  8261.     lea    _8SVXErrTxt(pc),A0
  8262.     bsr.w    _DisplayError
  8263.     bsr.w    _FreeFile
  8264.     lea    12(sp),sp            ; Remove "bsr.w _CheckFile" and "bsr.s GetAudioSettings" and "bsr.s _CheckFibDelta"
  8265.     bra.w    _Loop
  8266.  
  8267.  
  8268. _FreeAudio
  8269.     tst.l    _AudioBuffer(A5)
  8270.     beq.s    1$
  8271.     movea.l    _AudioBuffer(A5),A1
  8272.     move.l    _AudioBufferSize(A5),D0
  8273.     movea.l    _SysBase(A5),A6
  8274.     jsr    _LVOFreeMem(A6)
  8275.     clr.l    _AudioBuffer(A5)
  8276. 1$
  8277.     move.l    _IOAudio(A5),D0
  8278.     beq.s    2$
  8279.     movea.l    D0,A0    
  8280.     bsr.w    _FreeIOAudioA
  8281.     clr.l    _IOAudio(A5)
  8282. 2$
  8283.     bsr.w    _RemoveAudioGadget
  8284.     rts
  8285.  
  8286. _CheckFibDelta
  8287.     movem.l    D2-D4/A2-A4,-(sp)
  8288.     move.l    _FileSize(A5),D0
  8289.     movea.l    _TextPtr(A5),A0
  8290.     addq.l    #2,A0            ; Overread
  8291.     subq.l    #2,D0
  8292.  
  8293.     cmpi.l    #'FORM',(A0)        ; IFF?
  8294.     bne.s    _CheckFibEnd
  8295.     cmpi.l    #'8SVX',8(A0)        ; 8SVX?
  8296.     bne.s    _CheckFibEnd
  8297.     cmpi.l    #'VHDR',12(A0)        ; IFF?
  8298.     bne.w    _FindVHDR
  8299.     lea    20(A0),A1
  8300. _TestIfFibDeltaComp
  8301.     cmpi.b    #1,15(A1)
  8302.     bne.s    _CheckFibEndOk
  8303.     bra.s    _StartUnpack
  8304. _CheckFibEnd
  8305.     moveq    #0,D0
  8306.     movem.l    (sp)+,D2-D4/A2-A4
  8307.     rts
  8308. _CheckFibEndOk
  8309.     moveq    #-1,D0
  8310.     movem.l    (sp)+,D2-D4/A2-A4
  8311.     rts
  8312.  
  8313.  
  8314. _StartUnpack
  8315.     move.l    D0,D1
  8316.     movea.l    A0,A1
  8317.     moveq    #0,D2
  8318. 1$
  8319.     subq.l    #2,D1
  8320.     bls.s    _CheckFibEnd
  8321.     addq.l    #2,D2
  8322.     cmpi.w    #'BO',(A1)+
  8323.     bne.s    1$
  8324.     addq.l    #6,D2            ; plus 'BODY' text ('DY' plus room for 1 longword)
  8325.     move.l    2(A1),D3        ; Length Body
  8326.     addq.l    #6,A1            ; Ignore 'DY' plus length
  8327.  
  8328.     movea.l    A0,A2            ; IFF-Header
  8329.     movea.l    A1,A3            ; Compressed datas
  8330. *    A2 pointer to IFF header
  8331. *    A3 pointer to compressed datas
  8332. *    D2 length IFF header
  8333. *    D3 length sample (compressed) datas
  8334.     move.l    D2,D0
  8335.     add.l    D3,D0
  8336.     add.l    D3,D0            ; Length new IFF-file! (2* D3 !!!)
  8337.     addq.l    #3,D0            ; + 7 - 4 = 3 ( because of 2*(n-2) ! )
  8338.     andi.l    #-8,D0
  8339.     move.l    D0,D4            ; New IFF-file length
  8340.     move.l    #MEMF_CLEAR|MEMF_PUBLIC,D1
  8341.     movea.l    4.w,A6
  8342.     jsr    _LVOAllocMem(A6)
  8343.     tst.l    D0
  8344.     beq.s    _CheckFibEnd
  8345.     movea.l    D0,A4
  8346. *    A2 pointer to IFF header
  8347. *    A3 pointer to compressed datas
  8348. *    A4 pointer to allocated memory
  8349. *    D2 length IFF header
  8350. *    D3 length sample (compressed) datas
  8351. *    D4 size allocated memory
  8352.     move.l    A2,A0
  8353.     movea.l    A4,A1
  8354.     move.l    D2,D0
  8355.     subq.l    #4,D0            ; Minus length of 'BODY' length set
  8356.     jsr    _LVOCopyMem(A6)        ; Copy IFF-Header
  8357.  
  8358.     add.l    D3,4(A4)        ; Add double size of datas of FORM-chunk
  8359.     subq.l    #4,4(A4)
  8360.     clr.b    35(A4)            ; Erase comression sign
  8361.  
  8362.     move.l    D3,D0            ; length datas
  8363.     movea.l    A3,A0            ; Source datas
  8364.     movea.l    A4,A1
  8365.     add.l    D2,A1            ; Destination (pointer right behind IFF header!)
  8366.     move.l    D3,D1
  8367.     add.l    D1,D1            ; New length of BODY = length * 2
  8368.     subq.l    #4,D1            ; Because of 2*(n-2) !
  8369.     move.l    D1,-4(A1)        ; Set length
  8370.  
  8371.     bsr.s    _FibDeltaUnpack        ; Unpack datas
  8372.  
  8373.     bsr.w    _FreeFile
  8374.  
  8375.     move.l    D4,_BufferSize(A5)
  8376.     move.l    D2,D0
  8377.     add.l    D3,D0
  8378.     add.l    D3,D0            ; 2 * D3!!!!
  8379.     subq.l    #4,D0
  8380.     move.l    D0,_FileSize(A5)
  8381.     move.l    A4,_TextPtr(A5)
  8382.     bra.w    _CheckFibEndOk
  8383.  
  8384. ******************************************************************************
  8385. *
  8386. * FibDelatUnpack
  8387. *
  8388. * Based on Steve Hayes' DUnpack for his Fibonacci Delta compression algorythm.
  8389. *
  8390. * Converted to assembly by Jörg van de Loo
  8391. *               Hövel 15
  8392. *               47559 Kranenburg
  8393. *               Germany
  8394. *
  8395.  
  8396. _FibDeltaUnpack    ; (numdatas,source,destination)(D0,A0,A1)
  8397.     movem.l    D2-D5/A2,-(sp)
  8398.  
  8399.     subq.l    #2,D0        ; numdatas-2 ( n - 2 )
  8400.     moveq    #0,D1
  8401.     move.b    1(A0),D1    ; x = source[1] = initial value!
  8402.     addq.l    #2,A0        ; source + 2
  8403. *    movea.l    A1,A1        ; destination
  8404. *
  8405. ** (rawdatas-2,data,source+2,destination)(D0,D1,A0,A1)
  8406. *
  8407.     move.l    D0,D2        ; maximum datas =
  8408.     add.l    D2,D2        ; doubled ( 2*(n-2) )
  8409.     moveq    #0,D3        ; internal counter ( i )
  8410.     moveq    #0,D5        ; Dummy
  8411.     lea    __DeltaTable(pc),A2 ; Table of deltas to add to value x
  8412.     bra.s    .checkend
  8413. .next
  8414.     move.l    D3,D4        ; counter
  8415.     lsr.l    #1,D4        ; counter / 2
  8416.     move.b    0(A0,D4.l),D5    ; d = source[i]
  8417.     btst    #0,D3        ; even or odd, i.e. low nibble or high nibble to affect
  8418.     beq.s    .highnibble
  8419. .lownibble
  8420.     andi.b    #15,D5        ; d &= 15 (only low nibble (4 bits))
  8421.     bra.s    .store
  8422. .highnibble
  8423.     lsr.b    #4,D5        ; d / 16 (high nibble (4 bits) on low nibble's position)
  8424. .store
  8425.     move.b    0(A2,D5.w),D4    ; Delta out of table
  8426.     add.b    D4,D1        ; x += Delta
  8427.     move.b    D1,0(A1,D3.l)    ; write data value (uncompressed now!)
  8428.     addq.l    #1,D3        ; i ++
  8429.  
  8430. .checkend
  8431.     cmp.l    D3,D2
  8432.     bhi.s    .next
  8433.  
  8434.     movem.l    (sp)+,D2-D5/A2
  8435.     move.b    D1,D0        ; return x
  8436.     rts
  8437.  
  8438. __DeltaTable
  8439.     dc.b    -34,-21,-13,-8,-5,-3,-2,-1,0,1,2,3,5,8,13,21
  8440.  
  8441.  
  8442. *************************************************
  8443. *
  8444. ** Init Audio Hit Gadget
  8445. *
  8446. _DisplayAudioGadget
  8447.     movem.l    D2/A2-A3,-(sp)
  8448.  
  8449.     lea    _Gad3(A5),A2
  8450.     clr.l    (A2)
  8451.     move.w    #8,gg_LeftEdge(A2)
  8452.     move.w    #6,gg_TopEdge(A2)
  8453.     move.w    #45,gg_Width(A2)
  8454.     move.w    #28,gg_Height(A2)
  8455.     move.w    #GADGHIMAGE|GADGIMAGE,gg_Flags(A2)
  8456.     move.w    #BoolGadFlags,gg_Activation(A2)
  8457.     move.w    #BOOLGADGET,gg_GadgetType(A2)
  8458.     move.w    #3,gg_GadgetID(A2)
  8459.  
  8460.     lea    _Image.3(pc),A0
  8461.     lea    _Image.4(pc),A1
  8462.  
  8463.     move.l    A0,gg_GadgetRender(A2)
  8464.     move.l    A1,gg_SelectRender(A2)
  8465.  
  8466.     lea    _startup(pc),A0        ; First instruction of Viewer (startup-code)
  8467.     subq.l    #4,A0            ; Pointer to BPTR next hunk
  8468.     movea.l    (A0),A0            ; BPTR NextHunk
  8469.     adda.l    A0,A0
  8470.     adda.l    A0,A0            ; APTR NextHunk
  8471.     addq.l    #4,A0            ; Section Chip (_Gad.1, size 190 bytes)
  8472.     lea    380(A0),A0        ; Skip both images (each 190 bytes)
  8473.     lea    336(A0),A1        ; Pointer to Select Audio Image
  8474.     lea    _Image.3(pc),A2
  8475.     lea    _Image.4(pc),A3
  8476.     move.l    A0,ig_ImageData(A2)
  8477.     move.l    A1,ig_ImageData(A3)
  8478.  
  8479.     movea.l    _WindowPtr(A5),A0    ; Window
  8480.     movea.l    wd_RPort(A0),A3        ; ^RastPortPtr
  8481.     lea    _Gad3(A5),A1        ; Audio gadget
  8482.     moveq    #0,D0            ; Begin with number zero
  8483.     moveq    #-1,D1            ; All gadgets
  8484.     moveq    #0,D2
  8485.     movea.l    D2,A2            ; No requester
  8486.     move.l    _IntuitionBase(A5),A6
  8487.     jsr    _LVOAddGList(A6)    ; Set gadgets to window
  8488.  
  8489.     lea    _Gad3(A5),A0        ; Gadgets
  8490.     movea.l    _WindowPtr(A5),A1    ; Window
  8491.     moveq    #0,D2
  8492.     movea.l    D2,A2            ; No requester
  8493.     jsr    _LVORefreshGList(A6)    ; Draw gadgets
  8494.  
  8495.     st.b    _AudGadget(A5)
  8496.  
  8497.     movem.l    (sp)+,D2/A2-A3
  8498.     rts
  8499.  
  8500. _RemoveAudioGadget
  8501.     tst.b    _AudGadget(A5)
  8502.     beq.s    1$
  8503.     movea.l    _WindowPtr(A5),A0
  8504.     lea    _Gad3(A5),A1
  8505.     moveq    #1,D0
  8506.     movea.l    _IntuitionBase(A5),A6
  8507.     jsr    _LVORemoveGList(A6)
  8508.  
  8509.     clr.b    _AudGadget(A5)
  8510. 1$
  8511.     rts
  8512.  
  8513. ********************************************************
  8514. *
  8515. *  (C) 1994 J.v.d.Loo
  8516. *
  8517. *  AA-support routines
  8518. *
  8519. *  Decompressor and 32 bit gun colour converter
  8520. *
  8521. *  Taken out of BitMapSaver
  8522. *
  8523. * Inputs: none
  8524. * Results: D0 = 1 when all went ok
  8525. *
  8526.  
  8527. * ------------------------------------------------------ *
  8528. * This is an fully decrompress routine for images of 64bit boundary (modulo).
  8529.  
  8530. _Convert
  8531.     movem.l    D2-D6/A2-A4,-(sp)
  8532.  
  8533.     bsr.w    _Init24BitPal        ; Grey colour image setup when no palette set...
  8534.  
  8535.     movea.l    _WindowPtr(A5),A0    ; Window
  8536.     movea.l    wd_RPort(A0),A0        ; Its rastport
  8537.     movea.l    rp_BitMap(A0),A0    ; BitMap being used
  8538.     moveq    #BMA_FLAGS,D1        ; Ask for flags being used
  8539.     movea.l    _GfxBase(A5),A6
  8540.     cmpi.w    #38,LIB_VERSION(A6)    ; OS 3 required for this check
  8541.     bls.s    .std            ; If not available, treat it as the original GFX device
  8542. *                      is used...
  8543.     jsr    _LVOGetBitMapAttr(A6)
  8544.     andi.l    #BMF_STANDARD,D0    ; Standard bitmap or one created by a 3rd graphic device?
  8545.     beq.s    .alien
  8546. .std
  8547.     move.l    #MEMF_CHIP,_TypeOfMem(A5)    ; BitMap forced to CHIP-RAM (standard AMIGA device)
  8548.     bra.s    .doconvert
  8549. .alien
  8550.     move.l    #0,_TypeOfMem(A5)    ; BitMap forced to FAST-RAM (3rd party GFX device)
  8551.  
  8552. .doconvert
  8553.     movea.l    _SourceFilePtr(A5),A0    ; Address datas
  8554.     cmpi.l    #'FORM',(A0)+        ; IFF ?
  8555.     bne.w    .finish_1
  8556.     addq.l    #4,A0            ; Length IFF-file!?!?
  8557.     cmpi.l    #'ACBM',(A0)
  8558.     bne.s    .check4ILBM
  8559.     addq.l    #4,A0
  8560.     bra.s    .okType
  8561. .check4ILBM
  8562.     cmpi.l    #'ILBM',(A0)+        ; Picture?
  8563.     bne.w    .finish_1
  8564. .okType
  8565.     move.l    _SourceFileSize(A5),D4
  8566.     subi.l    #12,D4            ; Length datas - length header
  8567. .searchChunks
  8568.     subq.l    #4,D4            ; Length datas -4
  8569.     beq.w    .finish_1        ; If end reached
  8570.     bmi.w    .finish_1
  8571.     move.l    (A0)+,D3        ; Chunk-name
  8572.     cmpi.l    #'BMHD',D3        ; Bitmap-header?
  8573.     beq.s    .foundBMHD
  8574.     cmpi.l    #'CAMG',D3        ; ViewPort-display?
  8575.     beq.w    .foundCAMG
  8576.     cmpi.l    #'CMAP',D3        ; Colour-map?
  8577.     beq.w    .foundCMAP
  8578.     cmpi.l    #'BODY',D3        ; Datas?
  8579.     beq.w    .foundBODY
  8580.     cmpi.l    #'ABIT',D3        ; Amiga Bitplane Datas?
  8581.     beq.w    .foundABIT 
  8582. .unknownChunk
  8583.     subq.l    #4,D4            ; Datas -4
  8584.     move.l    (A0)+,D0        ; Length of this chunk
  8585.     addq.l    #1,D0
  8586.     andi.l    #-2,D0            ; Through 2 divisible
  8587.     sub.l    D0,D4            ; Datas minus (over)readed entries
  8588.     lea    0(A0,D0.w),A0        ; New address
  8589.     bra.s    .searchChunks
  8590.  
  8591. .foundBMHD
  8592.     subq.l    #4,D4            ; Datas -4
  8593.     move.l    (A0)+,D0        ; Save number entries
  8594.     lea    _Width(A5),A1        ; Address data-array
  8595.     moveq    #0,D1
  8596.     move.w    (A0),D1            ; Get width
  8597.     move.l    D1,_RealIWidth(A5)    ; Non aligned width of image
  8598.     addi.l    #15,D1
  8599.     andi.l    #-16,D1
  8600.     move.l    D1,_ImageWidth(A5)    ; Save dafault width (aligned)
  8601.     addi.l    #63,D1
  8602.     andi.l    #-64,D1            ; Set up to BURST-FETCH mode, needed for AGA
  8603.     move.w    D1,(A1)            ; Save width
  8604.     move.w    2(A0),2(A1)        ; Height
  8605.     move.w    4(A0),4(A1)        ; X-Position
  8606.     move.w    6(A0),6(A1)        ; Y-Position
  8607.     move.b    8(A0),8(A1)        ; Depth
  8608.     move.b    9(A0),9(A1)        ; Masking-type
  8609.     move.b    10(A0),10(A1)        ; compression-mode
  8610.     move.b    11(A0),11(A1)        ; Unused
  8611.     move.w    12(A0),12(A1)        ; Transparent colour
  8612.     move.b    14(A0),14(A1)        ; X-aspect
  8613.     move.b    15(A0),15(A1)        ; Y-aspect
  8614.     move.w    16(A0),16(A1)        ; Page width
  8615.     move.w    18(A0),18(A1)        ; Page height
  8616.     lea    (A0,D0.w),A0        ; Overread header
  8617.     sub.l    D0,D4            ; Length Datas minus entries
  8618.     bra.w    .searchChunks
  8619.  
  8620. .foundCAMG
  8621.     subq.l    #4,D4            ; Datas -4
  8622.     move.l    (A0)+,D0        ; Length
  8623.     addq.l    #1,D0
  8624.     andi.l    #-2,D0            ; Through 2 divisible
  8625.     move.l    (A0),_ViewPortMod(A5)    ; ViewPort mode
  8626.     andi.l    #$FFFF9ABD,_ViewPortMod(A5)    ; means:
  8627. *    bclr    #1,D0            ; no genlocVideo
  8628. *    bclr    #6,D0            ; no pfba
  8629. *    bclr    #8,D0            ; no genlocAudio
  8630. *    bclr    #10,D0            ; no dualpf
  8631. *    bclr    #13,D0            ; no vpHide
  8632. *    bclr    #14,D0            ; no sprites
  8633.  
  8634.     lea    0(A0,D0.w),A0        ; Skip unused
  8635.     sub.l    D0,D4            ; Length datas
  8636.     bra.w    .searchChunks
  8637.  
  8638. .foundCMAP
  8639.     subq.l    #4,D4            ; Datas -4
  8640.     move.l    (A0)+,D0        ; Entry length (ever through 2 divisible!!!)
  8641.     move.l    D0,-(sp)        ; Remember
  8642.     divu.w    #3,D0            ; /3
  8643.     andi.l    #$FFFF,D0
  8644.     move.l    D0,_CMapNumEntries(A5)    ; = number of words of Colourmap
  8645.     lea    _Colourmap(A5),A1    ; Address colour-array
  8646.     move.l    A0,_RGB32Values(A5)
  8647.     move.l    A0,-(sp)
  8648.     cmpi.l    #256*3,D0
  8649.     bhi.s    .getRGB32
  8650.  
  8651. .getRGB
  8652.     moveq    #0,D1
  8653.     move.b    (A0)+,D1        ; R-value
  8654.     andi.w    #$F0,D1
  8655.     lsl.w    #4,D1            ; Clear Half-byte position (G-value)
  8656.     move.b    (A0)+,D2        ; G-value
  8657.     andi.w    #$F0,D2            ; Mask it out
  8658.     or.w    D2,D1            ; Store G-value
  8659.     move.b    (A0)+,D2        ; B-value
  8660.     andi.w    #$F0,D2
  8661.     lsr.b    #4,D2            ; Half-byte position
  8662.     or.w    D2,D1            ; D1 = RGB-word
  8663.     move.w    D1,(A1)+        ; Store RGB-word
  8664.     subq.l    #1,D0
  8665.     bgt.s    .getRGB
  8666.  
  8667. .getRGB32
  8668.     move.l    _CMapNumEntries(A5),D0
  8669.     movea.l    _RGB32Values(A5),A0
  8670.     lea    _RGB32Colours(A5),A1
  8671.     bsr.w    _RGBtoRGB32
  8672.     movea.l    (sp)+,A0
  8673.     move.l    (sp)+,D0
  8674.     addq.l    #1,D0
  8675.     andi.l    #-2,D0    
  8676.     sub.l    D0,D4            ; Datas minus (over)readed entries
  8677.     lea    0(A0,D0.l),A0        ; New address
  8678.     bra.w    .searchChunks
  8679.  
  8680. .foundBODY
  8681.     cmpi.b    #1,_Compresstyp(A5)
  8682.     bhi.w    .finish_3
  8683.     tst.b    _Masking(A5)
  8684.     beq.s    .go
  8685.     move.b    _Masking(A5),D0
  8686.     btst.l    #0,D0
  8687.     beq.s    .go
  8688.     tst.b    _NoWarnFlag(A5)
  8689.     bne.s    .go
  8690.     movem.l    A0-A1,-(sp)
  8691.     lea    _WarnMaskingTxt(pc),A0    ; MASKING = DATA of 1st line for all bitplanes + masking line
  8692.     bsr.w    _DisplayError        ;           DATA of 2nd line for all bitplanes + masking line
  8693.     move.l    #5,_errno(A5)        ;           DATA of 3rd line for all bitplanes + masking line
  8694.     movem.l    (sp)+,A0-A1        ;           ........... and so on
  8695. .go
  8696.     lea    _BitmapStruc(A5),A2    ; Address bitmap-structure
  8697.     moveq    #23,D0
  8698.     addq.l    #8,A2
  8699. .clear
  8700.     clr.l    (A2)+            ; Clear all 24 bitplane pointers
  8701.     subq.w    #1,D0
  8702.     bcc.s    .clear
  8703.  
  8704.     lea    _BitmapStruc(A5),A2    ; Address bitmap-structure
  8705.     moveq    #0,D0            ; Clear it
  8706.     move.w    _Width(A5),D0        ; Pixel width
  8707.     lsr.w    #3,D0            ; /8 = bytes
  8708.     move.w    D0,(A2)+        ; Bytes per row
  8709.     move.w    _Height(A5),(A2)+    ; Height graphic
  8710.     move.b    _Depth(A5),1(A2)    ; Number of bitplanes
  8711.  
  8712. *
  8713. ** Allocate needed bitplanes (all in once).
  8714. ** <- D0 still holds number of bytes per line.
  8715. *
  8716.     move.l    A0,-(sp)        ; Save current address
  8717.     movea.l    _SysBase(A5),A6        ; Base Exec
  8718.     mulu.w    _Height(A5),D0        ; = size of one bitplane
  8719.     move.l    D0,D2            ; to D2
  8720.  
  8721.     moveq    #0,D1            ; Clear it
  8722.     move.b    _Depth(A5),D1        ; Number of bitplanes
  8723.  
  8724. *
  8725. ** For those bug I searched 3 days... - so stupid I'm.
  8726. ** I use normally images up to 736*566 pixel, that means that one plane is
  8727. ** 736/8*566 pixel = 52072 bytes large, this size fits in a word,
  8728. ** so "mulu" #8,Dx did not cause trouble (for 8 bitplanes).
  8729. ** While testing "BitMapSaver" with an images of 960*724 pixel width, my 
  8730. ** A4000 crashed - no guru but no input was furthermore possible!
  8731. ** Today I got it. 960/8 = 120 = fits in a word, mulu #724,120 = ? -
  8732. ** 86880 bytes = longword!!! Until that point all went ok, but after
  8733. ** mulu.w #8,86880 (8 bitplanes) the value was not as you may expect 695040
  8734. ** instead of it 170752 was returned. So the images was loaded to unallocated
  8735. ** memory, "Amiga hang up".
  8736. ** The crash occurred each time when DOS-function "Write" was called - and
  8737. ** because there is a bug in the v39 ROM of the dos.library, I thought this
  8738. ** was a bug of it, too.
  8739. ** [( v39 bug: After a read/write error occures and the "Write"-routine returns
  8740. **    to the program, the baseregister A6 does not contain the DOSBase any more.)]
  8741. ** But further:
  8742. ** The mistake I made was to multiply a longword with a word - what is not
  8743. ** possible with the 68000 instruction "mulu.w". I know this, but I never
  8744. ** cared in this routine about it....
  8745. ** But... here is the solution...
  8746. *
  8747.  
  8748.     moveq    #0,D0            ; Zero !!!
  8749.     bra.s    .x1
  8750. .mul
  8751.     add.l    D2,D0            ; Longword multiply!!!
  8752. .x1
  8753.     dbf    D1,.mul
  8754.  
  8755.     move.l    D0,_AllPlaneSize(A5)    ; Save size of all bitplanes
  8756.     move.l    _TypeOfMem(A5),D1    ; Set as CHIP or FAST
  8757.     ori.l    #MEMF_CLEAR,D1        ; Requirements
  8758.     jsr    _LVOAllocMem(A6)    ; Mem demand
  8759.     move.l    D0,_Bitplane(A5)    ; Save memory address
  8760.     beq.w    .finish_2        ; If error
  8761.  
  8762.     lea    _BitmapStruc(A5),A0    ; Address bitmap-structure
  8763.     moveq    #0,D1            ; Clear it
  8764.     move.w    (A0),D1            ; Bytes per row
  8765.     mulu.w    2(A0),D1        ; Number bytes of one bitplane
  8766.  
  8767.     moveq    #0,D2
  8768.     move.b    5(A0),D2        ; Number of bitplanes
  8769.     addq.l    #8,A0            ; Address constant for first plane
  8770.  
  8771.     movea.l    D0,A1            ; Address memory
  8772. .StoreBPPtr
  8773.     move.l    A1,(A0)+        ; Set address of bitplane to constant
  8774.     add.l    D1,A1            ; Get next bitplane's memory address
  8775.     subq.b    #1,D2            ; Decrease number of bitplanes
  8776.     bne.s    .StoreBPPtr        ; If not all are set yet...
  8777.  
  8778. *
  8779. ** Do it normal.
  8780. *
  8781.     movea.l    (sp)+,A0        ; Get back current address    
  8782.  
  8783.     move.l    D4,D2            ; Size in bytes of datas
  8784.  
  8785.     moveq    #0,D0            ; Initialiize them with NULL for first time
  8786.     move.l    D0,D1
  8787.     move.l    D1,D3
  8788.     move.l    D3,D4
  8789.     move.l    D4,D5            ; Linecounter
  8790.  
  8791.     addq.l    #4,A0
  8792.     subq.l    #4,D2
  8793.  
  8794.     lea    _BitmapStruc(A5),A2    ; Address bitmap-structure
  8795.     addq.l    #8,A2            ; Address pointer to first bitplane
  8796.  
  8797.     move.w    _Width(A5),D3        ; Pixelwidth of image
  8798.     lsr.w    #3,D3            ; in bytes
  8799.     move.b    _Depth(A5),D4        ; Number of planes
  8800.  
  8801.     tst.b    _Compresstyp(A5)
  8802.     bne.s    .Decompress        ; If compressed...
  8803.  
  8804.     movem.l    D0-D1/A0-A1,-(sp)
  8805.     tst.b    _NoWarnFlag(A5)
  8806.     bne.s    .NoWarn.1
  8807.     lea    _WarnUncompressedTxt(pc),A0
  8808.     bsr.w    _DisplayError
  8809.     move.l    #5,_errno(A5)
  8810. .NoWarn.1
  8811.     movem.l    (sp)+,D0-D1/A0-A1
  8812.  
  8813.     bra.w    .StoreUnpacked
  8814.  
  8815. .Decompress
  8816.     moveq    #0,D6            ; Bitplanecounter
  8817. .Decompressing
  8818.     lsl.w    #2,D6            ; Bitplanecounter * 4 = longword adjustment
  8819.     movea.l    0(A2,D6.w),A3        ; Current bitplane
  8820.     lsr.w    #2,D6            ; Normal
  8821. * Instead of the last three lines you can write
  8822. *    movea.l    0(A2,D6.w*4),A3
  8823. * if you have a turboboard.
  8824.  
  8825.     move.w    D3,D0            ; Bytes per line
  8826.     mulu.w    D5,D0            ; mutilply with current line
  8827.     lea    0(A3,D0.l),A3        ; Startoffset to A3
  8828.     movea.l    A3,A4            ; Address plane(x) to A4
  8829.     move.l    _ImageWidth(A5),D0    ; Real pixel width of image
  8830.     lsr.w    #3,D0            ; in bytes
  8831.     lea    0(A4,D0.w),A4        ; == End of line
  8832. .CheckOperation
  8833.     subq.l    #1,D2            ; Data counter
  8834.     bmi.w    .IncorrectSize
  8835.     moveq    #0,D0
  8836.     move.b    (A0)+,D0
  8837.     cmpi.b    #-128,D0        ; #-128 = no operation
  8838.     beq.s    .NoOperation
  8839.     cmpi.b    #127,D0
  8840.     bhi.s    .StoreNeg        ; If negativ (greater #128!)
  8841. .CopyBytes
  8842.     subq.l    #1,D2
  8843.     bmi.w    .IncorrectSize
  8844.     move.b    (A0)+,(A3)+
  8845.     dbf    D0,.CopyBytes
  8846.     bra.s    .NoOperation
  8847. .StoreNeg
  8848.     neg.b    D0            ; To positive value
  8849.     subq.l    #1,D2
  8850.     bmi.w    .IncorrectSize
  8851.     move.b    (A0)+,D1        ; Next byte
  8852. .StoreNegCopy
  8853.     move.b    D1,(A3)+        ; Store byte
  8854.     dbf    D0,.StoreNegCopy    ; While not all
  8855. .NoOperation
  8856.     tst.l    D2
  8857.     beq.w    .finish
  8858.     bmi.s    .IncorrectSize
  8859.  
  8860.     cmpa.l    A3,A4            ; Position(x),line(x) the same as
  8861. *                    ; the end of line(x),plane(x)?
  8862.     bhi.s    .CheckOperation
  8863.  
  8864.     addq.w    #1,D6            ; Increase planecounter
  8865.     cmp.w    D4,D6            ; Last plane?
  8866.     bne.s    .Decompressing
  8867.  
  8868.     move.b    _Masking(A5),D0
  8869.     btst.l    #0,D0
  8870.     beq.s    .goon
  8871.     bsr.w    _IgnoreCompMaskLine
  8872.  
  8873. .goon
  8874.     addq.w    #1,D5            ; Next line
  8875.     lea    _BitmapStruc(A5),A1
  8876.     cmp.w    2(A1),D5        ; Last line?
  8877.     bne.s    .Decompress
  8878.  
  8879.     bra.w    .finish
  8880.  
  8881. .StoreUnpacked
  8882.     moveq    #0,D6            ; Bitplanecounter
  8883. .StoreUncompress
  8884.     lsl.w    #2,D6            ; Bitplanecounter * 2 = longword adjustment
  8885.     movea.l    0(A2,D6.w),A3        ; Current bitplane
  8886.     lsr.w    #2,D6            ; Normal
  8887.  
  8888.     move.w    D3,D0            ; Bytes per line
  8889.     mulu.w    D5,D0            ; multiply with current line
  8890.     lea    0(A3,D0.l),A3        ; StartOffset to A3
  8891.     movea.l    A3,A4            ; Address plane(x) to A4
  8892.     move.l    _ImageWidth(A5),D0    ; Real pixel width of image
  8893.     lsr.w    #3,D0            ; in bytes
  8894.     lea    0(A4,D0.w),A4        ; == End of line
  8895.  
  8896. *    move.w    D0,D0            ; Set counter (already done!)
  8897.     bra.s    .StoreUncmp_1        ; 'Cause of DBF
  8898. .StoreUncmp
  8899.     move.b    (A0)+,(A3)+        ; Copy byte into bitplane
  8900. .StoreUncmp_1
  8901.     dbf    D0,.StoreUncmp        ; until all are done
  8902.  
  8903.     addq.w    #1,D6            ; Increase planecounter
  8904.     cmp.w    D4,d6            ; All planes worked out?
  8905.     bne.s    .StoreUncompress    ; No - so do further
  8906.  
  8907.     move.b    _Masking(A5),D0
  8908.     btst.l    #0,D0
  8909.     beq.s    .goon1
  8910.     bsr.w    _IgnoreMaskLine
  8911.  
  8912. .goon1
  8913.     addq.w    #1,D5            ; Next line
  8914.  
  8915.     lea    _BitmapStruc(A5),A1
  8916.     cmp.w    2(A1),D5        ; Last line?
  8917.     bne.s    .StoreUnpacked        ; No...
  8918.  
  8919.     bra.s    .finish
  8920.  
  8921. .IncorrectSize
  8922.     lea    _IncorrectSizeTxt(pc),A0
  8923.     bsr.w    _DisplayError
  8924.     move.l    #20,_errno(A5)
  8925.     movem.l    (sp)+,D2-D6/A2-A4
  8926.     moveq    #0,D0            ; Bad IFF-file
  8927.     rts
  8928. .finish_3
  8929.     lea    _NoByteRunTxt(pc),A0
  8930.     bsr.w    _DisplayError
  8931.     move.l    #20,_errno(A5)
  8932.     movem.l    (sp)+,D2-D6/A2-A4
  8933.     moveq    #0,D0            ; Unknown compression methode
  8934.     rts
  8935. .finish_2
  8936.     lea    _AllocBufErrTxt(pc),A0
  8937.     bsr.w    _DisplayError
  8938.     addq.w    #4,sp            ; Overread "move.l A0,-(sp)"
  8939.     movem.l    (sp)+,D2-D6/A2-A4
  8940.     moveq    #-1,D0            ; Error, no mem
  8941.     rts
  8942.  
  8943. .finish_1
  8944.     lea    _NoIFFFileTxt(pc),A0
  8945.     bsr.w    _DisplayError
  8946.     move.l    #20,_errno(A5)
  8947.     movem.l    (sp)+,D2-D6/A2-A4
  8948.     moveq    #0,D0            ; Not an IFF-file
  8949.     rts
  8950. .finish
  8951.     movem.l    (sp)+,D2-D6/A2-A4
  8952.     moveq    #1,D0            ; No error
  8953.     rts
  8954.  
  8955. *
  8956. ** This is the engine to store the datas of the ABIT-chunk into the
  8957. ** planar-datas needed for plain Amigas-screens. I ask myself a lot times
  8958. ** why no demo-coder use this type of data, instead of it they use RAW-datas
  8959. ** which is the same, but without an IFF-header...
  8960. *
  8961. .foundABIT
  8962.     lea    _BitmapStruc(A5),A2    ; Address bitmap-structure
  8963.     moveq    #0,D0            ; Clear it
  8964.     move.w    _Width(A5),D0        ; Pixel width
  8965.     lsr.w    #3,D0            ; /8 = bytes
  8966.     move.w    D0,(A2)+        ; Bytes per row
  8967.     move.w    _Height(A5),(A2)+    ; Height graphic
  8968.     move.b    _Depth(A5),1(A2)    ; Number of bitplanes
  8969.  
  8970. *
  8971. ** Allocate needed bitplanes (all in once).
  8972. ** <- D0 still holds number of bytes per line.
  8973. *
  8974.     move.l    A0,-(sp)        ; Save current address
  8975.  
  8976.     mulu.w    _Height(A5),D0        ; = size of one bitplane
  8977.     move.l    D0,D2            ; to D2
  8978.  
  8979.     move.b    _Depth(A5),D1        ; Number of bitplanes
  8980.     moveq    #0,D0            ; Zero !!!
  8981. .addsize
  8982.     add.l    D2,D0            ; Longword multiply!!!
  8983.     subq.b    #1,D1
  8984.     bne.s    .addsize
  8985.  
  8986.     move.l    D0,_AllPlaneSize(A5)    ; Save size of all bitplanes
  8987.     move.l    #MEMF_CHIP|MEMF_CLEAR,D1 ; Requirements
  8988.     movea.l    _SysBase(A5),A6        ; Base Exec
  8989.     jsr    _LVOAllocMem(A6)    ; Mem demand
  8990.     move.l    D0,_Bitplane(A5)    ; Save memory address
  8991.     beq.s    .finish_2        ; If error
  8992.  
  8993.     lea    _BitmapStruc(A5),A0    ; Address bitmap-structure
  8994.     move.w    (A0),D1            ; Bytes per row
  8995.     mulu.w    2(A0),D1        ; Number bytes of one bitplane
  8996.  
  8997.     move.b    5(A0),D2        ; Number of bitplanes
  8998.     addq.l    #8,A0            ; Address constant for first plane
  8999.  
  9000.     movea.l    D0,A1            ; Address memory
  9001. .StoreBAddr
  9002.     move.l    A1,(A0)+        ; Set address of bitplane to constant
  9003.     adda.l    D1,A1            ; Get next bitplane's memory address
  9004.     subq.b    #1,D2            ; Decrease number of bitplanes
  9005.     bne.s    .StoreBAddr        ; If not all are set yet...
  9006.  
  9007.     movea.l    (sp)+,A0        ; Get back current address (source)    
  9008.     addq.l    #4,A0            ; Overread length entry
  9009.     move.l    D4,D2            ; Size in bytes of datas
  9010.     subq.l    #8,D2            ; Minus two longword ( ABIT[length] )
  9011.  
  9012.     lea    _BitmapStruc(A5),A2    ; Address bitmap-structure
  9013.     addq.l    #8,A2            ; Address pointer to first bitplane
  9014.     moveq    #0,D3
  9015.     move.w    _Width(A5),D3        ; Pixelwidth of page (64 bit boundary)
  9016.     lsr.w    #3,D3            ; in bytes
  9017.     move.l    _ImageWidth(A5),D4    ; Aligned width (16 bit boundary)
  9018.     lsr.l    #4,D4            ; in words
  9019.     move.w    _Height(A5),D5        ; Number of lines
  9020.     move.b    _Depth(A5),D6        ; Number of planes
  9021.  
  9022. *    A0 - original Datas
  9023. *    A2 - BitPlane-Address-Array
  9024. *    D2 - length original Datas
  9025. *    D3 - Pagewidth (boundary 64 bit) in bytes (longword)
  9026. *    D4 - Image width ( boundary 16 bit)
  9027. *    D5 - Height of Image in number of lines
  9028. *    D6 - Depth
  9029.  
  9030.     subq.w    #1,D4            ; 'Cause of DBF
  9031.     subq.w    #1,D5            ; 'Couse of DBF
  9032.  
  9033.     move.w    D4,D1
  9034.     move.w    D5,D0
  9035.  
  9036.     movea.l    (A2)+,A3        ; Out of constant address of bitplane
  9037.     movea.l    A3,A4            ; ...also in A4
  9038.     adda.l    D3,A4            ; Next line's address (destination) after comming loop
  9039.  
  9040. .copyLine
  9041.     move.w    (A0)+,(A3)+        ; Store data-word
  9042.     subq.l    #2,D2
  9043.     beq.w    .finish
  9044.     bcs.w    .IncorrectSize
  9045.     dbf    D1,.copyLine        ; Store this line...
  9046.  
  9047.     movea.l    A4,A3            ; Next line's address into A3
  9048.     adda.l    D3,A4            ; Add  bytesize of one line to A4
  9049.     move.w    D4,D1            ; Image width in number of words
  9050.     dbf    D0,.copyLine        ; Store next line
  9051.  
  9052.     subq.b    #1,D6            ; One less bitplane to go...
  9053.     beq.w    .finish
  9054.  
  9055. * One complete Bitplane stored, so do next
  9056.     movea.l    (A2)+,A3        ; Next bitplane's address out of constant
  9057.     movea.l    A3,A4            ; Address also in A4
  9058.     adda.l    D3,A4            ; Address next line of this Bitplane
  9059.     move.w    D5,D0            ; Number of lines
  9060.     move.w    D4,D1            ; Image width in number of words
  9061.     bra.s    .copyLine        ; Store next bitplane
  9062.  
  9063.  
  9064. *
  9065. ** These routines are only called if a mask is set for the picture (brush)
  9066. *
  9067.  
  9068. _IgnoreMaskLine        ; Uncompressed IFF
  9069.     move.l    _ImageWidth(A5),D0
  9070.     lsr.w    #3,D0
  9071.     adda.l    D0,A0
  9072.     sub.l    D0,D2
  9073.     rts
  9074.  
  9075.  
  9076. _IgnoreCompMaskLine    ; Compressed IFF
  9077.     move.l    D3,-(sp)
  9078.     move.l    _ImageWidth(A5),D3
  9079.     lsr.w    #3,D3
  9080.     moveq    #0,D1
  9081.  
  9082.  
  9083. .CheckOperation
  9084.     cmp.w    D3,D1
  9085.     beq.s    .out
  9086.  
  9087.     subq.l    #1,D2            ; Data counter
  9088.     bmi.s    .out
  9089.     moveq    #0,D0
  9090.     move.b    (A0)+,D0
  9091.     cmpi.b    #-128,D0        ; #-128 = no operation
  9092.     beq.s    .NoOperation
  9093.     cmpi.b    #127,D0
  9094.     bhi.s    .StoreNeg        ; If negativ (greater #128!)
  9095. .CopyBytes
  9096.     subq.l    #1,D2
  9097.     bmi.s    .out
  9098.     addq.l    #1,A0            ; Store byte of mask to nowhere...
  9099.     addq.w    #1,D1
  9100.     dbf    D0,.CopyBytes
  9101.     bra.s    .NoOperation
  9102. .StoreNeg
  9103.     neg.b    D0            ; To positive value
  9104.     subq.l    #1,D2
  9105.     bmi.s    .out
  9106.     addq.l    #1,A0
  9107. .StoreNegCopy
  9108.     addq.w    #1,D1            ; Store byte of mask to nowhere and decrease counter...
  9109.     dbf    D0,.StoreNegCopy    ; While not all
  9110. .NoOperation
  9111.     tst.l    D2
  9112.     bmi.s    .out
  9113.     bra.s    .CheckOperation
  9114. .out
  9115.     movem.l    (sp)+,D3
  9116.     rts
  9117.  
  9118. *************************************************************
  9119. *
  9120. * Init the standard palette (RGB32) to one which contains
  9121. * only grey values, so called Grey Palette.
  9122. * Since the OS doesn't support 24 bit screens and 3rd party
  9123. * GFX boards will not allow custom applications to copy
  9124. * 24 bitplanes into a screen they made via OS functions,
  9125. * the first 8 bitplanes are treated as they contain only grey
  9126. * colours (those 8 which we gonna display).
  9127. * When there is a device that will allow to copy 24 bitplanes
  9128. * to a screen, Viewer can display it immediately, since
  9129. * I never stripped the code to support only 8 bitplanes,
  9130. * although 3rd party graphic board software emulation does!
  9131. *
  9132.  
  9133. _Init24BitPal
  9134.     move.l    #256,D0
  9135.     lea    _RGB32Colours(A5),A1
  9136.     move.l    D0,D1
  9137.     swap    D1            ; number of colours (1st word) start at colour (2nd word)
  9138.     move.l    D1,(A1)+        ; store number of entries in table and
  9139. *                      startoffset for colours
  9140.  
  9141. .GoAhead
  9142.     movem.l    D2-D4,-(sp)
  9143.  
  9144.     moveq    #0,D1
  9145.     moveq    #0,D2
  9146.     moveq    #0,D3
  9147.     bra.s    .sneek
  9148. .convert
  9149.     moveq    #2,D4            ; 3 loops
  9150. .storeOneLW
  9151. *    move.b    D1,D1            ; the value
  9152.     move.b    D1,D3            ; save it
  9153.     andi.b    #$F,D3            ; only low nibble
  9154.     move.b    D3,D2            ; also in D2
  9155.     lsl.b    #4,D2            ; store it as high nibble
  9156.     add.b    D3,D2            ; add low nibble
  9157.  
  9158.     move.b    D1,(A1)+        ; save high byte of high word
  9159.     move.b    D2,(A1)+        ; save low byte of high word
  9160.     move.b    D2,(A1)+        ; save high byte of low word
  9161.     move.b    D2,(A1)+        ; save low byte of low word
  9162.  
  9163.     dbf    D4,.storeOneLW        ; for one colour (R, G, B)
  9164.     addq.b    #1,D1
  9165. .sneek
  9166.     dbf    D0,.convert
  9167.     moveq    #0,D0
  9168.     move.l    D0,(A1)            ; terminator!!!
  9169.  
  9170.     movem.l    (sp)+,D2-D4
  9171.     rts
  9172.  
  9173. ***************************************************************
  9174. *
  9175. ** Check if the hardware display supports 8 bit per gun as the
  9176. ** original AMIGA hardware. If not, brighten up the display...
  9177. *
  9178. ** Because only simple device for the AMIGA are available (3rd
  9179. ** party gfx-boards) this routine might not work perfectly since
  9180. ** those cards don't work proberly in an AMIGA surround due to
  9181. ** their limits and not implemented AMIGA features:
  9182. ** only 3 colour sprites, only one sprite, no soft-scrolling
  9183. ** screens, no overscan, only one hardware screen, incorrect
  9184. ** bits per gun (a 256 colour display offers only 262144 colour
  9185. ** palette) where the original double A chip set offers 16.7 million!)
  9186. ** and a lot more.
  9187. *
  9188.  
  9189. _BrightenColours
  9190.     movem.l    D0-D2/A0-A1/A6,-(sp)
  9191. * GetDisplayInfoData( 0, di, sizeof( di), DTAG_DISP, DisplayID)
  9192.     suba.l    A0,A0            ; Handle
  9193.     lea    _DisplayInfo(A5),A1    ; Buffer
  9194.     moveq    #dis_SIZEOF,D0        ; sizeof
  9195.     move.l    #DTAG_DISP,D1        ; TAG
  9196.     move.l    _ViewPortMod(A5),D2    ; DisplayID
  9197.     movea.l    _GfxBase(A5),A6
  9198.     cmpi.w    #38,LIB_VERSION(A6)
  9199.     beq.s    .done            ; Since we have not AMIGA OS3...
  9200.     jsr    _LVOGetDisplayInfoData(A6)
  9201.     tst.l    D0
  9202.     beq.s    .done
  9203.  
  9204.     lea    _DisplayInfo(A5),A0
  9205.     move.b    RedBits(A0),D0
  9206.     cmpi.b    #7,D0
  9207.     bls.s    .adjust
  9208.  
  9209.     move.b    GreenBits(A0),D0
  9210.     cmpi.b    #7,D0
  9211.     bls.s    .adjust
  9212.  
  9213.     move.b    BlueBits(A0),D0
  9214.     cmpi.b    #7,D0
  9215.     bhi.s    .done
  9216.  
  9217. .adjust
  9218. * AdjustPal32( struct DisplayInfo *, struct RGB32 *)
  9219.     lea    _RGB32Colours(A5),A1
  9220.     bsr.s    _AdjustPal32
  9221. .done
  9222.     movem.l    (sp)+,D0-D2/A0-A1/A6
  9223.     rts
  9224.  
  9225. ***********************************************************
  9226. *
  9227. ** Adjust (brighten) RGB32 colour table values to supported
  9228. ** less than 8 bits per gun.
  9229. *
  9230. ** This routine was just a quick hack...
  9231. *
  9232. ** Only useful when a simple 3rd party graphic device is
  9233. ** installed, such as for IBM-compatible computers which are
  9234. ** adapted to the AMIGA system, e.g. Picasso II(+) & IV,
  9235. ** Picollo, Picollo SD 64, Retina Z2 & Z3, CyberVision 64,
  9236. ** CyberVision 64 3D etc. .
  9237. ** Does the GVP (Spectrum) and the Merlin support 8 bit per
  9238. ** gun also in non 24 bit displays? If you know, tell me.
  9239. *
  9240.  
  9241. _AdjustPal32
  9242.     movem.l    D2-D7,-(sp)
  9243.  
  9244.     btst    #7,_BMHDFlags(A5)    ; Indicates if colourmap of file is
  9245.     bne.s    .RGB32            ; stored as 8-bit values (AGA resolution (RGB32))
  9246.  
  9247. *
  9248. ** This one is to convert the original RGB4 values (now RGB32) to values
  9249. ** which looks on this simple device (3rd party gfx device) the same as
  9250. ** with the OCS or ECS CHIP SET.
  9251. *
  9252. .RGB4
  9253.     move.b    RedBits(A0),D5        ; e.g. 6
  9254.     moveq    #8,D0
  9255.     sub.b    D5,D0            ; 8 - 6 = 2
  9256.     moveq    #16,D5
  9257.     mulu.w    D0,D5            ; = 16
  9258.  
  9259.     move.b    GreenBits(A0),D6    ; e.g. 5
  9260.     moveq    #8,D0
  9261.     sub.b    D6,D0            ; 8 - 5 = 3
  9262.     moveq    #16,D6
  9263.     mulu.w    D0,D6            ; = 24
  9264.  
  9265.     move.b    BlueBits(A0),D7        ; e.g. 4
  9266.     moveq    #8,D0
  9267.     sub.b    D7,D0            ; 8 - 4 = 4
  9268.     moveq    #16,D7
  9269.     mulu.w    D0,D7            ; = 32
  9270.     bra.s    .doit
  9271.  
  9272. *
  9273. ** This one to adjust palette to reflect less bits per gun as the AA (AGA) hardware.
  9274. *
  9275. .RGB32
  9276.     moveq    #0,D0
  9277.     move.b    RedBits(A0),D0        ; e.g. 6
  9278.     moveq    #32,D1            ; = 32 (256 luminanz / 8 bit per luminanz = 32)
  9279.     mulu.w    D0,D1            ; 6 * 32  = 192
  9280.     move.l    #256,D5
  9281.     sub.w    D1,D5            ; 256 - 192 = 64
  9282.     divu.w    D0,D5            ; 64 / 6 = ~10
  9283.  
  9284.     moveq    #0,D0
  9285.     move.b    GreenBits(A0),D0    ; e.g. 5
  9286.     moveq    #32,D1            ; = 32 (256 luminanz / 8 bit per luminanz = 32)
  9287.     mulu.w    D0,D1            ; 5 * 32  = 160
  9288.     move.l    #256,D6
  9289.     sub.w    D1,D6            ; 256 - 160 = 96
  9290.     divu.w    D0,D6            ; 96 / 5 = ~19
  9291.  
  9292.     moveq    #0,D0
  9293.     move.b    BlueBits(A0),D0        ; e.g. 4
  9294.     moveq    #32,D1            ; = 32 (256 luminanz / 8 bit per luminanz = 32)
  9295.     mulu.w    D0,D1            ; 4 * 32  = 128
  9296.     move.l    #256,D7
  9297.     sub.w    D1,D7            ; 256 - 128 = 128
  9298.     divu.w    D0,D7            ; 128 / 4 = 32
  9299.  
  9300. .doit
  9301.     move.l    (A1)+,D0        ; Number of colours (1st word, offset colour 2nd word)
  9302.     swap    D0            ; D0 = number colours used
  9303.     bra.s    .dec 
  9304. .loop
  9305.     move.l    D0,-(sp)        ; number of colours
  9306.  
  9307.     move.l    (A1),D0            ; Colour value (red) (32 bit)
  9308.     moveq    #24,D1            ; into
  9309.     lsr.l    D1,D0            ; lowest byte
  9310.     add.w    D5,D0
  9311. .adjred
  9312.     cmpi.w    #255,D0            ; Range check
  9313.     bls.s    .okred
  9314.     move.l    #255,D0
  9315. .okred    
  9316.     bsr.s    .storeNew
  9317.  
  9318.     move.l    (A1),D0            ; Colour value (green) (32 bit)
  9319.     moveq    #24,D1            ; into
  9320.     lsr.l    D1,D0            ; lowest byte
  9321.     add.w    D6,D0
  9322. .adjgreen
  9323.     cmpi.w    #255,D0            ; Range check
  9324.     bls.s    .okgreen
  9325.     move.l    #255,D0
  9326. .okgreen
  9327.     bsr.s    .storeNew
  9328.  
  9329.     move.l    (A1),D0            ; Colour value (blue) (32 bit)
  9330.     moveq    #24,D1            ; into
  9331.     lsr.l    D1,D0            ; lowest byte
  9332.     add.w    D7,D0
  9333. .adjblue
  9334.     cmpi.w    #255,D0            ; Range check
  9335.     bls.s    .okblue
  9336.     move.l    #255,D0
  9337. .okblue    
  9338.     bsr.s    .storeNew
  9339.  
  9340.     move.l    (sp)+,D0
  9341. .dec
  9342.     subq.w    #1,D0
  9343.     bcc.s    .loop
  9344.     
  9345.     movem.l    (sp)+,D2-D7
  9346.     rts
  9347.  
  9348. .storeNew
  9349.     move.w    D0,D1
  9350.     lsl.w    #8,D0
  9351.     andi.w    #$F,D1            ; Only low nible
  9352.     move.b    D1,D0
  9353.     lsl.b    #4,D1
  9354.     or.b    D0,D1
  9355.     move.b    D1,D0
  9356.     lsl.l    #8,D0
  9357.     move.b    D1,D0
  9358.     lsl.l    #8,D0
  9359.     move.b    D1,D0
  9360.     move.l    D0,(A1)+        ; Store new computed red value
  9361.     rts
  9362.  
  9363. ********************************************************
  9364. * V39 RGB32 format
  9365. *
  9366. * Highest byte of longword contains colour-value, e.g. 237 (0xED).
  9367. * The rest (lower 3 bytes) containing the low nibble of
  9368. * the highest byte, here 13, fully:
  9369. * ED DD DD DD == 0xEDDDDDDD
  9370. *
  9371. * Inputs: D0 - number of colours to convert (max. 256)
  9372. *         A0 - RGB source table (like CMAP chunk)
  9373. *         A1 - RGB32 destionation buffer (safety = (256*3+2)*4 bytes large)
  9374. * Results: RGB32 buffer filled with 32bit RGB values (used by LoadRGB32, SA_Colors32)
  9375. *          D0 == -1L on error (too much colours, max. 256)
  9376.  
  9377. _RGBtoRGB32     ; (colours, tableRGB, tableRGB32)(D0, A0, A1)
  9378.     andi.l    #$1FF,D0        ; max 256 colours
  9379.     cmpi.w    #256,D0
  9380.     bls.s    .cok            ; if not more colours
  9381.     move.l    #256,D0
  9382. .cok
  9383.     move.l    D0,D1
  9384.     swap    D1            ; number of colours (1st word) start at colour (2nd word)
  9385.     move.l    D1,(A1)+        ; store number of entries in table and
  9386. *                      startoffset for colours
  9387.  
  9388.     btst    #7,_BMHDFlags(A5)    ; Full byte used by colour value?
  9389.     bne.s    .GoAhead        ; If so...
  9390.  
  9391.     cmpi.w    #32,D0            ; More than 32 colours?
  9392.     bhi.s    .AGA            ; Assumption: an AGA-picture where the programmer forgot
  9393. *                      to set the bit
  9394.  
  9395.     bsr.s    .ModifyColours        ; Else take as 4-bit
  9396.     bra.s    .GoAhead    
  9397.  
  9398. .AGA
  9399.     bset    #7,_BMHDFlags(A5)    ; Indicates it's valid
  9400.  
  9401. .GoAhead
  9402.     movem.l    D2-D4,-(sp)
  9403.  
  9404.     moveq    #0,D1
  9405.     moveq    #0,D2
  9406.     moveq    #0,D3
  9407.     bra.s    .sneek
  9408. .convert
  9409.     moveq    #2,D4            ; 3 loops
  9410. .storeOneLW
  9411.     move.b    (A0)+,D1        ; get value
  9412.     move.b    D1,D3            ; save it
  9413.     andi.b    #$F,D3            ; only low nibble
  9414.     move.b    D3,D2            ; also in D2
  9415.     lsl.b    #4,D2            ; store it as high nibble
  9416.     add.b    D3,D2            ; add low nibble
  9417.  
  9418.     move.b    D1,(A1)+        ; save high byte of high word
  9419.     move.b    D2,(A1)+        ; save low byte of high word
  9420.     move.b    D2,(A1)+        ; save high byte of low word
  9421.     move.b    D2,(A1)+        ; save low byte of low word
  9422.  
  9423.     dbf    D4,.storeOneLW        ; for one colour (R, G, B)
  9424. .sneek
  9425.     dbf    D0,.convert
  9426.     moveq    #0,D0
  9427.     move.l    D0,(A1)            ; terminator!!!
  9428.  
  9429.     movem.l    (sp)+,D2-D4
  9430.     rts
  9431.  
  9432. .failed
  9433.     moveq    #-1,D0
  9434.     rts
  9435.  
  9436. *
  9437. ** Change 4-bit colour value to 8-bit colour value ( needed for LoadRGB32() )
  9438. *
  9439. .ModifyColours
  9440.     movem.l    D0-D2/A0,-(sp)
  9441.     bra.s    2$
  9442. 1$
  9443.     move.b    (A0)+,D1        ; Get value
  9444.     andi.b    #$F0,D1            ; Ignore unused nibble
  9445.     move.b    D1,D2            ; Save result
  9446.     lsr.b    #4,D2            ; High nibble to low nibble
  9447.     add.b    D2,D1            ; Make new value
  9448.     move.b    D1,-1(A0)        ; Store new computed value
  9449. 2$
  9450.     dbf    D0,1$            ; Until all are done
  9451.     movem.l    (sp)+,D0-D2/A0
  9452.     rts
  9453.  
  9454. ********************************************************
  9455. *
  9456. ** This routine will only be called before the dimension
  9457. ** and MonitorID grab is fired up!
  9458. *
  9459. _CheckEHB
  9460.     movem.l    D0-D2/A0-A1,-(sp)
  9461.  
  9462.     move.l    _ViewPortMod(A5),D0    ; Original (not modified till now)
  9463.     andi.l    #V_EXTRA_HALFBRITE,D0
  9464.     beq.s    .done
  9465.  
  9466.     lea    _RGB32Colours(A5),A0
  9467.     move.l    (A0),D0        ; Get color offset and amount colors e.g. 0x00200000
  9468.     swap    D0        ; e.g. 0x00000020
  9469.     moveq    #0,D2
  9470.     move.w    D0,D2        ; Remember amount colors (e.g. 32)
  9471.     add.w    D0,D0        ; Double amount of colors (e.g. 64)
  9472.     swap    D0
  9473.     move.l    D0,(A0)+    ; Store new amount of colors
  9474.  
  9475.     move.l    D2,D0        ; Amount colors (e.g. 32)
  9476.     move.l    D0,D1        ; ditto
  9477.     lsl.l    #3,D0        ; Amount colors * 8
  9478.     lsl.w    #2,D1        ; Amount colors * 4
  9479.     add.l    D1,D0        ; == amount colors in bytes (e.g. 32) * 12)
  9480.     lea    0(A0,D0.l),A1    ; Destination
  9481.  
  9482.     move.l    D2,D0        ; e.g. 32
  9483.     add.w    D0,D0        ; == 64
  9484.     add.w    D2,D0        ; == 96 runs (== 384 bytes of source to touch)
  9485.     bra.s    .loopdec
  9486. .loop
  9487.     move.l    (A0)+,D1
  9488.     lsr.l    #1,D1
  9489.     move.l    D1,(A1)+
  9490. .loopdec
  9491.     dbf    D0,.loop
  9492.     clr.l    (A1)
  9493. .done
  9494.     movem.l    (sp)+,D0-D2/A0-A1
  9495.     rts
  9496.  
  9497. **************************
  9498. *
  9499. * Convert binary to ascii.
  9500. *
  9501. * Inputs: none
  9502. * Results: none
  9503. *
  9504.  
  9505. _ConvertBinary
  9506.     movem.l    D2-D7/A2-A4,-(sp)
  9507.  
  9508.     move.l    _BufferSize(A5),D2    ; Length allocated buffer
  9509.     move.l    _FileSize(A5),D3    ; Real filelength
  9510.     movea.l    _TextPtr(A5),A2        ; Adress buffer
  9511.     addq.l    #2,A2            ; Skip #$020A
  9512.  
  9513.     bsr.w    _GetConvertedSize
  9514.     move.l    D0,D4            ; Save new size
  9515.     move.l    #MEMF_PUBLIC|MEMF_CLEAR,D1
  9516.     movea.l    _SysBase(A5),A6
  9517.     jsr    _LVOAllocMem(A6)
  9518.     movea.l    D0,A4            ; Save new buffer pointer
  9519.     tst.l    D0
  9520.     beq.w    .ErrorAlloc        ; Upon error
  9521.     movea.l    D0,A3            ; Address buffer
  9522.     move.w    #$200A,(A3)+        ; Write Blank and LineFeed
  9523.  
  9524.  
  9525. * A4 - allocated buffer - do not scratch
  9526. * A3 - allocated buffer - used
  9527. * A2 - old datas - used
  9528. * D4 - allocated size - do not scratch
  9529. * D3 - FileSize - used
  9530.  
  9531.     moveq    #0,D7            ; New filesize
  9532.     moveq    #-16,D5            ; Linenumber
  9533.  
  9534.     movea.l    A3,A0            ; Address buffer
  9535. 1$
  9536.     tst.l    D3            ; Soruce file end?
  9537.     beq.w    .end            ; If so...
  9538.     cmpi.l    #15,D3            ; Do we have a rest of 4 longwords to convert?
  9539.     bls.w    .ARest            ; If not...
  9540.     addi.l    #16,D5            ; Else add 16 bytes (4 longwords)
  9541.     move.l    D5,D0            ; Line number
  9542.     bsr.w    _comhex            ; Convert count to ascii
  9543.     move.b    #':',(A0)+        ; Write colon at end of number
  9544.     move.b    #' ',(A0)+        ; Write 2 blanks
  9545.     move.b    #' ',(A0)+
  9546.     addi.l    #11,D7            ; New filelength plus 11 bytes
  9547.  
  9548.     move.l    (A2),D0            ; Get 1. longword of line to convert
  9549.     bsr.w    _comhex            ; Convert it to ascii
  9550.     move.b    #' ',(A0)+        ; Write Blank
  9551.     addi.l    #9,D7            ; New filesize plus 9
  9552.  
  9553.     move.l    4(A2),D0        ; 2. longword
  9554.     bsr.w    _comhex
  9555.     move.b    #' ',(A0)+
  9556.     addi.l    #9,D7
  9557.  
  9558.     move.l    8(A2),D0        ; 3. longword
  9559.     bsr.w    _comhex
  9560.     move.b    #' ',(A0)+
  9561.     addi.l    #9,D7
  9562.  
  9563.     move.l    12(A2),D0        ; 4. longword
  9564.     bsr.w    _comhex
  9565.     move.b    #' ',(A0)+
  9566.     move.b    #' ',(A0)+
  9567.     move.b    #' ',(A0)+
  9568.     move.b    #' ',(A0)+
  9569.     addi.l    #12,D7
  9570.  
  9571.     subi.l    #16,D3            ; Old filesize -16
  9572.     moveq    #15,D0            ; 16 bytes to write
  9573. 0$
  9574.     move.b    (A2)+,D1        ; Get byte
  9575.     cmpi.b    #31,D1            ; Displayable char?
  9576.     bls.s    .exchange        ; If not
  9577.     cmpi.b    #160,D1            ; Displayable char?
  9578.     bhi.s    .ok            ; If so
  9579.     cmpi.b    #127,D1            ; Displayable char
  9580.     bls.s    .ok            ; If so
  9581. .exchange
  9582.     move.b    #'.',(A0)+        ; Not displayable, exchange through point
  9583.     bra.s    2$
  9584. .ok
  9585.     move.b    D1,(A0)+        ; Displayable...
  9586. 2$
  9587.     dbf    D0,0$            ; Number of bytes in one line (16)
  9588.     move.b    #10,(A0)+        ; Write LineFeed
  9589.     addi.l    #17,D7            ; New filelength +17
  9590.     bra.w    1$    
  9591.  
  9592. * ------------ *
  9593.  
  9594. .ARest    ; Less than 16 bytes....
  9595.     addi.l    #16,D5            ; Linenumber
  9596.     move.l    D5,D0            ; Convert linenumber (binary)
  9597.     bsr.w    _comhex            ; into ascii-chars
  9598.     move.b    #':',(A0)+        ; Write colon after linenumber
  9599.     move.b    #' ',(A0)+
  9600.     move.b    #' ',(A0)+
  9601.     addi.l    #11,D7            ; New filelength +11 bytes
  9602.  
  9603.     movea.l    A2,A1            ; Address current offset in source file
  9604.     move.l    D3,D5            ; Rest-length of old file
  9605. .longLoop
  9606.     cmpi.b    #3,D5            ; Less than 3 bytes?
  9607.     bls.s    .byteWidth
  9608.  
  9609.     subq.l    #4,D5            ; Because one longword contains 4 bytes
  9610.  
  9611.     move.l    (A1)+,D0        ; Get longword to convert
  9612.     bsr.w    _comhex            ; into ascii
  9613.     move.b    #' ',(A0)+
  9614.     addi.l    #9,D7            ; New filesize plus 9
  9615.     bra.s    .longLoop
  9616.  
  9617. .byteWidth
  9618.     subq.b    #1,D5            ; Old filelength -1
  9619.     bcs.s    .MakeASCII        ; When end is reached
  9620.     move.b    (A1)+,D0        ; Get byte
  9621.     bsr.w    _comhexByte        ; and convert it into ascii
  9622.     addq.l    #1,D7            ; New filelength +1
  9623.     bra.s    .byteWidth
  9624.  
  9625. .MakeASCII    
  9626.     move.l    A0,-(sp)        ; Current buffer address
  9627.     moveq    #-1,D0            ; Counter
  9628. 3$
  9629.     cmpi.b    #10,-(A0)        ; Find LineFeed of last line
  9630.     dbeq    D0,3$
  9631.     not.l    D0            ; Compute length
  9632.     movea.l    (sp)+,A0        ; Current buffer address
  9633.     moveq    #49,D1            ; At this position we write down the ascii-values
  9634.     sub.b    D0,D1
  9635. 4$
  9636.     move.b    #' ',(A0)+        ; Write as much Blank until we reach position 49
  9637.     addq.l    #1,D7            ; New filelength +1
  9638.     dbf    D1,4$
  9639.  
  9640.     add.l    D3,D7            ; Add rest of old filelength to new filelength
  9641.     move.l    D3,D0            ; Rest
  9642.     subq.b    #1,D0            ; Because of DBF
  9643. 5$
  9644.     move.b    (A2)+,D1        ; Get value
  9645.     cmpi.b    #31,D1            ; Displayable char?
  9646.     bls.s    6$
  9647.     cmpi.b    #160,D1            ; Displayable char?
  9648.     bhi.s    7$
  9649.     cmpi.b    #127,D1            ; Displayable char?
  9650.     bls.s    7$
  9651. 6$
  9652.     move.b    #'.',(A0)+        ; Not displayable!
  9653.     bra.s    8$
  9654. 7$
  9655.     move.b    D1,(A0)+
  9656. 8$
  9657.     dbf    D0,5$
  9658.     bra.w    .end            ; ....finish
  9659.  
  9660. * --------------- *
  9661.  
  9662. .end
  9663.     move.b    #10,(A0)        ; Last char of file should be a LineFeed
  9664.     bsr.w    _FreeFile        ; Free old file (buffer)
  9665.     move.l    A4,_TextPtr(A5)        ; New buffer address
  9666.     move.l    D4,_BufferSize(A5)    ; New buffer size
  9667.     move.l    D7,_FileSize(A5)    ; New filesize
  9668.     movem.l    (sp)+,D2-D7/A2-A4
  9669.     rts
  9670.  
  9671. .ErrorAlloc
  9672.     lea    _AllocErrTxt(pc),A0    ; Display error
  9673.     bsr.w    _DisplayError
  9674.     bsr.w    _FreeFile        ; Free old file
  9675.     movem.l    (sp)+,D2-D7/A2-A4
  9676.     addq.l    #4,sp
  9677.     bra.w    _Loop
  9678.  
  9679. _GetConvertedSize
  9680.     move.l    _FileSize(A5),D0    ; Original
  9681.     move.l    D0,D1
  9682.     lsl.l    #2,D0            ; *4
  9683.     lsr.l    #2,D1            ; /4
  9684.     add.l    D1,D0            ; == * 4.25
  9685.     addi.l    #76,D0            ; For safety
  9686.     andi.l    #-8,D0            ; Align size
  9687.     rts
  9688.  
  9689. _comhex
  9690.     move.l    D2,-(sp)
  9691.     moveq    #7,D1
  9692. 1$
  9693.     rol.l    #4,D0
  9694.     move.l    D0,D2
  9695.     and.b    #$F,D2
  9696.     addi.b    #'0',D2
  9697.     cmpi.b    #'9',D2
  9698.     bls.s    2$
  9699.     addq.b    #7,D2
  9700. 2$
  9701.     move.b    D2,(A0)+
  9702.     dbf    D1,1$
  9703.     move.l    (sp)+,D2
  9704.     rts
  9705.  
  9706. _comhexByte
  9707.     move.l    D2,-(sp)
  9708.     moveq    #1,D1
  9709. 1$
  9710.     rol.b    #4,D0
  9711.     move.b    D0,D2
  9712.     and.b    #$F,D2
  9713.     addi.b    #'0',D2
  9714.     cmpi.b    #'9',D2
  9715.     bls.s    2$
  9716.     addq.b    #7,D2
  9717. 2$
  9718.     move.b    D2,(A0)+
  9719.     dbf    D1,1$
  9720.     move.l    (sp)+,D2
  9721.     rts
  9722.  
  9723. ******************************************************************************
  9724. *
  9725. * This routine will extract the ASCII-characters of a `known' document.
  9726. * It will only search for each known-chunk, remember the length of it, and
  9727. * then it allocates a buffer based on the computed length, and after that,
  9728. * it will re-scan the file and copy the plain characters into the new allocated
  9729. * buffer.
  9730. *
  9731. * This routine is rather a joke than useful...
  9732. *
  9733.  
  9734. _LoadFCFile
  9735.     tst.b    _NoWarnFlag(A5)        ; Allowed to display warnings?
  9736.     bne.s    .doit            ; If not...
  9737.  
  9738.     lea    _IFFAsciiTxt(pc),A0    ; Else, give out this
  9739.     bsr.w    _DisplayError        ; message
  9740.  
  9741.     tst.l    D0            ; User said ok.?
  9742.     beq.w    _BinaryFile        ; If not, don't display...
  9743.  
  9744. .doit
  9745.     movea.l    _TextPtr(A5),A0        ; Start of datas
  9746.     addq.l    #2,A0            ; Overread $200A ( Blank and LineFeed )
  9747.     movea.l    A0,A1
  9748.     move.l    _BufferSize(A5),D0    ; Get length of buffer
  9749.     subq.l    #2,D0            ; Because of Blank and LineFeed ($200A)
  9750.     move.l    D0,D1
  9751.     moveq    #0,D4            ; Amount of charcaters
  9752.  
  9753.     cmpi.l    #'CAT ',(A0)
  9754.     beq.s    .valid
  9755.     cmpi.l    #'LIST',(A0)
  9756.     beq.s    .valid
  9757.     cmpi.l    #'FORM',(A0)        ; Check IDs
  9758.     bne.w    .errNonStd
  9759.  
  9760.     cmpi.l    #'SWRT',8(A0)
  9761.     beq.s    .valid
  9762.     cmpi.l    #'WOWO',8(A0)
  9763.     beq.s    .valid
  9764.     cmpi.l    #'FTXT',8(A0)
  9765.     bne.w    .errNonStd
  9766. .valid
  9767.     lea    12(A0),A0        ; Pointer to e.g. "HYPH"-chunk
  9768.     sub.l    #12,D0
  9769.  
  9770. .ChunkName
  9771.     cmpi.l    #8,D0            ; Less than 9 bytes?
  9772.     ble.w    .gotLength        ; So call second pass
  9773.  
  9774.     move.l    (A0),D3            ; Name of chunk
  9775.     move.l    4(A0),D2        ; Length of chunk
  9776.  
  9777.     cmpi.l    #'FORM',D3
  9778.     beq.s    .skipType
  9779.  
  9780.     cmpi.l    #'CAT ',D3
  9781.     beq.s    .skipType
  9782.  
  9783.     cmpi.l    #'LIST',D3
  9784.     beq.s    .skipType
  9785.  
  9786.     cmpi.l    #'PROP',D3
  9787.     bne.s    .goon
  9788.  
  9789. .skipType
  9790.     lea    12(A0),A0
  9791.     sub.l    #12,D0
  9792.     bra.s    .ChunkName
  9793.  
  9794. .goon
  9795.     addq.l    #8,A0            ; Overread chunk-name and its size setting
  9796.     subq.l    #8,D0            ; Rest of filelength
  9797.     bmi.w    .errIncomplete        ; Upon error
  9798.  
  9799.     cmpi.l    #'CHRS',D3        ; Characters?
  9800.     beq.s    .addLength
  9801.  
  9802.     cmpi.l    #'RULE',D3        ; "RULE"-chunk treated as LineFeed
  9803.     beq.s    .addLF
  9804.  
  9805.     cmpi.l    #'WTXT',D3        ; "WTXT"-chunk treated as text
  9806.     beq.s    .addLength
  9807.  
  9808.     addq.l    #1,D2            ; Make chunk-size even
  9809.     andi.l    #-2,D2
  9810.  
  9811.     add.l    D2,A0            ; Pointer to next chunk
  9812.     sub.l    D2,D0            ; Rest of filelength
  9813.     bra.s    .ChunkName        ; and scan...
  9814.  
  9815. .addLength    ; CHRS-chunk found
  9816.     tst.l    D2            ; CHRS-chunk with size zero?
  9817.     bne.s    .asciichars        ; If size set
  9818.  
  9819.     addq.l    #1,D4            ; else size == 0 so set a LineFeed
  9820.     bra.s    .next
  9821.  
  9822. .asciichars
  9823.     add.l    D2,D4            ; else add size
  9824.  
  9825. .next
  9826.     addq.l    #1,D2            ; Make chunk-size even
  9827.     andi.l    #-2,D2
  9828.  
  9829.     add.l    D2,A0            ; Pointer to next chunk
  9830.     sub.l    D2,D0
  9831.     bra.w    .ChunkName
  9832.  
  9833. .addLF    ; RULE-chunk is treated as a LineFeed
  9834.     addq.l    #1,D4            ; Size plus 1
  9835.  
  9836.     addq.l    #1,D2            ; Make chunk-size even
  9837.     andi.l    #-2,D2
  9838.  
  9839.     add.l    D2,A0            ; Pointer to next chunk
  9840.     sub.l    D2,D0
  9841.     bra.w    .ChunkName
  9842.  
  9843. *****************************
  9844. * Parsing done ( first pass )
  9845. * Now allocate the buffer and
  9846. * store the characters.
  9847.  
  9848. .gotLength
  9849.     move.l    _PageWidth(A5),D7    ; Limit for word-wrap
  9850.  
  9851.     move.l    D4,D5            ; Size of characters
  9852.     add.l    #15,D5            ; Plus 7 and! plus 8 bytes (8-Bytes = $200A at front and $0A
  9853. *                      at end of datas ( rest for safety ))
  9854.     andi.l    #-8,D5            ; Make size divisible through eight (round it up)
  9855.  
  9856.     movem.l    D1/A1,-(sp)        ; Remember source and source's size
  9857.  
  9858.     move.l    D5,D0            ; Size in bytes
  9859.     move.l    #MEMF_CLEAR,D1
  9860.     movea.l    _SysBase(A5),A6
  9861.     jsr    _LVOAllocMem(A6)    ; Mem demand
  9862.  
  9863.     movem.l    (sp)+,D1/A1
  9864.     tst.l    D0
  9865.     beq.w    .errNoMem        ; Upon error
  9866.  
  9867.     movea.l    D0,A2            ; Destination
  9868.     movea.l    A2,A3            ; Remember
  9869.  
  9870.     move.w    #$200A,(A2)+        ; Write first down Blank and LineFeed
  9871.  
  9872.     movea.l    A1,A0            ; Source
  9873.     move.l    D1,D0            ; Length source
  9874.  
  9875.     lea    12(A0),A0        ; Pointer to first important chunk-name (e.g. HYPH)
  9876.     subi.l    #12,D0
  9877.  
  9878.     moveq    #0,D6            ; Amount of chars in line...
  9879.  
  9880. .checkChunk
  9881.     cmpi.l    #8,D0            ; At least 8 bytes?
  9882.     ble.w    .done            ; else pass 2 ends...
  9883.  
  9884.     move.l    (A0),D1            ; Name of chunk
  9885.     move.l    4(A0),D2        ; Length of chunk
  9886.  
  9887.     cmpi.l    #'FORM',D1
  9888.     beq.s    .noParseYet
  9889.  
  9890.     cmpi.l    #'CAT ',D1
  9891.     beq.s    .noParseYet
  9892.  
  9893.     cmpi.l    #'PROP',D1
  9894.     beq.s    .noParseYet
  9895.  
  9896.     cmpi.l    #'LIST',D1
  9897.     bne.s    .parse
  9898.  
  9899. .noParseYet
  9900.     lea    12(A0),A0        ; Overread e.g. FORM####ANHD
  9901.     sub.l    #12,D0            ; i.e. point to e.g. DLTA chunk (FORM####ANHDDLTA####)
  9902.     bra.s    .checkChunk        ;                         ¯¯¯¯
  9903.  
  9904. .parse
  9905.     addq.l    #8,A0            ; Overread chunk-name and its size
  9906.     subq.l    #8,D0
  9907.     bmi.w    .errIncomplete_1    ; Upon error
  9908.  
  9909.     cmpi.l    #'CHRS',D1        ; Characters?
  9910.     beq.s    .copyTxt
  9911.  
  9912.     cmpi.l    #'RULE',D1        ; Or a ruler which is interpreted as a LineFeed
  9913.     beq.w    .SetLF
  9914.  
  9915.     cmpi.l    #'WTXT',D1        ; Characters?
  9916.     beq.s    .copyTxt
  9917.  
  9918.     addq.l    #1,D2            ; Make chunk-size even
  9919.     andi.l    #-2,D2
  9920.  
  9921.     add.l    D2,A0            ; Pointer to next chunk
  9922.     sub.l    D2,D0
  9923.     bra.s    .checkChunk        ; And search again...
  9924.  
  9925. .copyTxt
  9926.     move.l    D2,D1            ; Size of this chunk
  9927.  
  9928.     addq.l    #1,D2            ; Make chunk-size even
  9929.     andi.l    #-2,D2
  9930.  
  9931.     tst.l    D1            ; Chunk-size == 0?
  9932.     beq.s    .OnlyLF            ; Interpret as linefeed
  9933.  
  9934.     movea.l    A0,A1            ; Source of characters
  9935.     bra.s    .cpy
  9936. .cpyChar
  9937.     cmpi.b    #9,(A1)            ; Tab?
  9938.     bne.s    .store            ; ...if not
  9939.     addq.b    #7,D6            ; Else, this char [1] (Tab) + [7]
  9940.     andi.b    #-8,D6            ; on a position which is divisable by eight
  9941. *    subq.b    #1,D6            ; Minus 1, because 2 lines further we add one...
  9942. .store
  9943.     cmpi.b    #$9B,(A1)        ; CSI?
  9944.     beq.s    .ignoredouble        ; Ignore CSI
  9945.     cmpi.b    #15,(A1)        ; Ignore shift-in etc.
  9946.     beq.s    .addLineFeed
  9947.     cmpi.b    #16,(A1)
  9948.     beq.s    .ignore
  9949.     cmpi.b    #17,(A1)
  9950.     beq.s    .ignore
  9951.     cmpi.b    #18,(A1)
  9952.     beq.s    .ignore
  9953.     move.b    (A1)+,(A2)+        ; Copy characters
  9954.     cmpi.b    #10,-1(A2)        ; A new line?
  9955.     beq.s    .reset
  9956.     addq.b    #1,D6            ; New line length plus 1
  9957.     cmp.b    D7,D6            ; Range limit reached?
  9958.     bls.s    .cpy            ; If not yet reached...
  9959.     bra.s    .findterminator        ; Else, split line...
  9960. .reset
  9961.     moveq    #0,D6
  9962.     bra.s    .cpy
  9963. .addLineFeed
  9964.     addq.l    #1,A1
  9965.     move.b    #10,(A2)+
  9966.     moveq    #0,D6
  9967.     bra.s    .cpy
  9968.  
  9969. .ignoredouble
  9970.     addq.l    #1,A1
  9971.     subq.l    #1,D1
  9972.     subq.l    #1,D4
  9973. .ignore
  9974.     addq.l    #1,A1
  9975.     subq.l    #1,D4
  9976. .cpy
  9977.     subq.l    #1,D1            ; One less...
  9978.     bcc.s    .cpyChar
  9979.  
  9980.     add.l    D2,A0            ; Pointer to next chunk
  9981.     sub.l    D2,D0
  9982.     bra.w    .checkChunk        ; and restart...
  9983.  
  9984. .OnlyLF    ; <- Chunk-size of CHRS-chunk zero!!!
  9985.     move.b    #10,(A2)+        ; Add a LineFeed at the end of each line
  9986.  
  9987.     add.l    D2,A0            ; Pointer to next chunk
  9988.     sub.l    D2,D0
  9989.  
  9990.     moveq    #0,D6            ; No chars in this line at the moment!
  9991.  
  9992.     bra.w    .checkChunk        ; Restart
  9993.  
  9994. .SetLF    ; <- RULER
  9995.     move.b    #10,(A2)+        ; Add a LineFeed at the end of each line
  9996.  
  9997.     addq.l    #1,D2            ; Make chunk-size even
  9998.     andi.l    #-2,D2
  9999.  
  10000.     add.l    D2,A0            ; Pointer to next chunk
  10001.     sub.l    D2,D0
  10002.  
  10003.     moveq    #0,D6            ; No chars in this line at the moment!
  10004.  
  10005.     bra.w    .checkChunk        ; Restart
  10006.  
  10007. .findterminator
  10008.     move.l    A2,-(sp)
  10009.     subq.l    #1,A2            ; Pointer to last stored char
  10010.     moveq    #0,D6            ; Chars in next line (this line will be split into two part)
  10011. .loop
  10012.     subq.l    #1,A2            ; One less char
  10013.     addq.b    #1,D6            ; Amount of chars in newline plus one
  10014.     cmp.b    D7,D6            ; Range checking...
  10015.     bhi.s    .err
  10016.     cmpi.b    #9,1(A2)        ; Tab?
  10017.     beq.s    .found            ; <- Replace Tab through LineFeed
  10018.     cmpi.b    #' ',1(A2)        ; Blank
  10019.     bne.s    .loop            ; If not
  10020. .found
  10021.     move.b    #10,1(A2)        ; Replace Blank or Tab through LineFeed
  10022.     movea.l    (sp)+,A2
  10023.     bra.s    .cpy
  10024.  
  10025. .err                    ; A line without any Blanks or Tabs
  10026.     moveq    #0,D6
  10027.     movea.l    (sp)+,A2
  10028.     bra.s    .cpy
  10029.  
  10030. ***** HELLO *****
  10031.  
  10032. .done
  10033.     move.b    #10,(A2)        ; Write as last char of ascii-file the LineFeed!
  10034.     addq.l    #1,D4
  10035.  
  10036.     bsr.w    _FreeFile        ; Free old (not more needed datas)
  10037.  
  10038.     move.l    A3,_TextPtr(A5)        ; Set up source
  10039.     move.l    D4,_FileSize(A5)    ; Set up source's size (plain ascii-chars)
  10040.     move.l    D5,_BufferSize(A5)    ; Set up source's size (extended)
  10041.     rts
  10042.  
  10043. .errNoMem
  10044.     lea    _NoFreeStoreTxt(pc),A0
  10045.     bsr.w    _DisplayError
  10046.     bra.w    _CheckFile_1        ; Set up as binary
  10047. .errNonStd
  10048.     lea    _NoAsciiDatasTxt(pc),A0
  10049.     bsr.w    _DisplayError
  10050.     bra.w    _CheckFile_1        ; Set up as binary
  10051. .errIncomplete_1
  10052.     movea.l    A3,A1
  10053.     move.l    D4,D0
  10054.     movea.l    _SysBase(A5),A6
  10055.     jsr    _LVOFreeMem(A6)
  10056. .errIncomplete
  10057.     lea    _IncompleteIFFTxt(pc),A0
  10058.     bsr.w    _DisplayError
  10059.     bra.w    _CheckFile_1        ; Set up as binary
  10060.  
  10061. ********************************************************
  10062. *
  10063. * StrToLong( ULONG mask, char *buffer );
  10064. *
  10065. *
  10066. * Convert an ascii-string into computer internal number.
  10067. * Converted are: dual, decimal, signed decimal and
  10068. * hexadecimal ascii-strings.
  10069. *
  10070. * Valid terminators for the string-counts are: NULL-byte,
  10071. * tabulator, LineFeed, Blank (Space) and the comma.
  10072. *
  10073. * Introducion for strings:
  10074. * "#" = decimal (max. 10 chars for count)
  10075. * ""  = decimal (max. 10 chars for count)
  10076. * "+" = decimal (max. 10 chars for count)
  10077. *
  10078. * "-" = signed decimal (max. 10 chars for count)
  10079. *
  10080. * "0x" = sedecimal (hexadecimal) (max. 8 chars for count)
  10081. * "$"  = sedecimal (hexadecimal) (max. 8 chars for count)
  10082. *
  10083. * "%"  = dual (max. 32 chars for count)
  10084. *
  10085. * Inputs:  D0 - when NULL (zero) the routine is working normal.
  10086. *        - You can put a key-byte (mask) into D0 - the
  10087. *          subroutine is called then directly without
  10088. *          checking introducing arguments, note: in this
  10089. *          case no introducion has to be set in the ascii-
  10090. *          string, eg: D0 contains the "$" char - then
  10091. *          the ascii-string must be pointed to a plain
  10092. *          text, eg. "0003f000" - result here: converted
  10093. *          string to hexadecimal.
  10094. *       A0 - Pointer to the string which should be converted.
  10095. * Results: Count in D0
  10096. *       D1 contains -1L on error
  10097. *          A0 points to next argument if no error occured,
  10098. *       otherwise check -1(A0) and (A0) for the error,
  10099. *       it holds the char which caused the error!
  10100. *
  10101. *
  10102.  
  10103.     XDEF    _StrToLong
  10104. _StrToLong
  10105.     movem.l    D2-D3,-(sp)
  10106.  
  10107. *
  10108. ** When called as C-stub, set following two lines.
  10109. *
  10110.     ;move.l    12(sp),D0
  10111.     ;move.l    16(sp),A0
  10112.  
  10113.  
  10114.     move.w    D0,D2            ; Save mask
  10115.  
  10116.     moveq    #0,D0            ; Count to return
  10117.     move.l    D0,D1            ; Local count-buffer
  10118.  
  10119.     tst.w    D2            ; Mask set?
  10120.     beq.s    .Sneek            ; No, do it normal
  10121.  
  10122.     cmpi.b    #'$',D2            ; Hexadecimal?
  10123.     beq.w    .Hex_01
  10124.     cmpi.w    #'0x',D2        ; Hexadecimal?
  10125.     beq.w    .Hex_01
  10126.     cmpi.b    #'#',D2            ; Decimal?
  10127.     beq.w    .Dec_01
  10128.     cmpi.b    #' ',D2            ; Decimal?
  10129.     beq.w    .Dec_01
  10130.     cmpi.b    #'-',D2            ; Signed decimal?
  10131.     beq.s    .SignedDec_01
  10132.     cmpi.b    #'%',D2            ; Dual?
  10133.     beq.w    .Dual_01
  10134.  
  10135. .Sneek
  10136. *
  10137. ** Find chars we have to skip...
  10138. *
  10139.  
  10140.     cmpi.b    #9,(A0)            ; Tab-key?
  10141.     beq.s    .Skip
  10142.     cmpi.b    #' ',(A0)        ; Blank?
  10143.     beq.s    .Skip
  10144.     cmpi.b    #'!',(A0)        ; For complex string arguments
  10145.     beq.s    .Skip
  10146.     cmpi.b    #'|',(A0)        ; For complex string arguments
  10147.     beq.s    .Skip
  10148.     cmpi.b    #',',(A0)        ; Comma?
  10149.     beq.s    .Skip
  10150.     cmpi.b    #';',(A0)        ; Semicolon?
  10151.     beq.s    .Skip
  10152. *
  10153. ** Check if an interrupted end...
  10154. *
  10155.     tst.b    (A0)            ; End?
  10156.     beq.w    .Error_StringToLong
  10157.     cmpi.b    #10,(A0)        ; CR (LF)?
  10158.     beq.w    .Error_StringToLong
  10159. *
  10160. ** Parse argument (string's introducion)...
  10161. *
  10162.     cmpi.b    #'-',(A0)        ; Minus-char?
  10163.     beq.s    .SignedDec
  10164.     cmpi.b    #'+',(A0)        ; Plus-char?
  10165.     beq.w    .Dec
  10166.     cmpi.b    #'$',(A0)        ; Hex-char?
  10167.     beq.s    .Hex
  10168.     cmpi.b    #'%',(A0)        ; Dual-char?
  10169.     beq.w    .Dual
  10170.     cmpi.b    #'#',(A0)        ; Sometimes used for decimal introducion
  10171.     beq.w    .Dec
  10172.     cmpi.b    #'0',(A0)        ; Zero-char?
  10173.     bne.w    .Dec_01
  10174.     cmpi.b    #'x',1(A0)        ; 0x == C-introducion for hex
  10175.     bne.w    .Dec_01
  10176.     addq.l    #1,A0            ; Overread '0' of '0x'
  10177.     bra.s    .Hex
  10178.  
  10179. * ----------------------- *
  10180.  
  10181. .Skip
  10182.     addq.l    #1,A0
  10183.     bra.s    .Sneek
  10184.  
  10185. * ----------------------- *
  10186.  
  10187. .SignedDec
  10188.     addq.l    #1,A0            ; Overread sign
  10189. .SignedDec_01
  10190.     moveq    #9,D2            ; 10 chars to convert
  10191. .SDC
  10192.     tst.b    (A0)            ; End?
  10193.     beq.s    .End_SDC
  10194.     cmpi.b    #9,(A0)            ; Tab-key?
  10195.     beq.s    .End_SDC
  10196.     cmpi.b    #10,(A0)        ; CR (LF)-key?
  10197.     beq.s    .End_SDC
  10198.     cmpi.b    #' ',(A0)        ; Blank-key?
  10199.     beq.s    .End_SDC
  10200.     cmpi.b    #',',(A0)        ; Comma-key?
  10201.     beq.s    .End_SDC
  10202.  
  10203.     move.b    (A0)+,D1        ; Get char
  10204.     cmpi.b    #'0',D1
  10205.     blt.w    .Error_StringToLong
  10206.     cmpi.b    #'9',D1
  10207.     bhi.w    .Error_StringToLong
  10208.     subi.b    #48,D1            ; Computer intern number
  10209.     move.l    D0,D3            ; Save D0
  10210.     lsl.l    #3,D0            ; D0 * 8
  10211.     add.l    D3,D3            ; D3 * 2
  10212.     add.l    D3,D0            ; == mulu.l #10,D0
  10213.     add.l    D1,D0            ; Store new nibble
  10214.     dbf    D2,.SDC
  10215. .End_SDC
  10216.     neg.l    D0
  10217.     bra.w    .End_StringToLong
  10218.  
  10219. * ----------------------- *
  10220. .Hex
  10221.     addq.l    #1,A0            ; Overread introducion
  10222. .Hex_01
  10223.     moveq    #7,D2            ; 8 chars to convert
  10224. .HC
  10225.     tst.b    (A0)            ; End?
  10226.     beq.w    .End_StringToLong
  10227.     cmpi.b    #9,(A0)            ; Tab-key?
  10228.     beq.w    .End_StringToLong
  10229.     cmpi.b    #10,(A0)        ; CR (LF)-key?
  10230.     beq.w    .End_StringToLong
  10231.     cmpi.b    #' ',(A0)        ; Blank-key?
  10232.     beq.w    .End_StringToLong
  10233.     cmpi.b    #',',(A0)        ; Comma-key?
  10234.     beq.w    .End_StringToLong
  10235.  
  10236.     move.b    (A0)+,D1        ; Get char
  10237.     cmpi.b    #'0',D1            ; 0-char?
  10238.     blt.w    .Error_StringToLong
  10239.     cmpi.b    #'9',D1            ; 9-char
  10240.     bls.s    .OkHC
  10241.  
  10242.     bclr.l    #5,D1            ; To uppercase
  10243.     cmpi.b    #'F',D1            ; F-char
  10244.     bhi.w    .Error_StringToLong
  10245.     cmpi.b    #'A',D1            ; A-char?
  10246.     blt.w    .Error_StringToLong
  10247.     subi.b    #55,D1
  10248.     lsl.l    #4,D0            ; Room for nibble
  10249.     or.l    D1,D0            ; Store new nibble
  10250.     dbf    D2,.HC    
  10251.     bra.w    .End_StringToLong
  10252. .OkHC    
  10253.     subi.b    #48,D1            ; Computer intern number
  10254.     lsl.l    #4,D0            ; Room for nibble
  10255.     or.l    D1,D0            ; Store new nibble
  10256.     dbf    D2,.HC
  10257.     bra.w    .End_StringToLong
  10258.  
  10259. * ----------------------- *
  10260. .Dec
  10261.     addq.l    #1,A0            ; Overread introducion
  10262. .Dec_01
  10263.     moveq    #9,D2            ; 10 chars to convert
  10264. .DC
  10265.     tst.b    (A0)            ; End?
  10266.     beq.w    .End_StringToLong
  10267.     cmpi.b    #9,(A0)            ; Tab-key?
  10268.     beq.s    .End_StringToLong
  10269.     cmpi.b    #10,(A0)        ; CR (LF)-key?
  10270.     beq.s    .End_StringToLong
  10271.     cmpi.b    #' ',(A0)        ; Blank-key?
  10272.     beq.s    .End_StringToLong
  10273.     cmpi.b    #',',(A0)        ; Comma-key?
  10274.     beq.s    .End_StringToLong
  10275.  
  10276.     move.b    (A0)+,D1        ; Get char
  10277.     cmpi.b    #'0',D1
  10278.     blt.s    .Error_StringToLong
  10279.     cmpi.b    #'9',D1
  10280.     bhi.s    .Error_StringToLong
  10281.     subi.b    #48,D1            ; Computer intern number
  10282.     move.l    D0,D3            ; Save D0
  10283.     lsl.l    #3,D0            ; D0 * 8
  10284.     add.l    D3,D3            ; D3 * 2
  10285.     add.l    D3,D0            ; == mulu.l #10,D0
  10286.     add.l    D1,D0            ; Store new nibble
  10287.     dbf    D2,.DC
  10288.     bra.s    .End_StringToLong
  10289.  
  10290. * ----------------------- *
  10291.  
  10292. .Dual
  10293.     addq.l    #1,A0            ; Overread '%'
  10294. .Dual_01
  10295.     moveq    #31,D2            ; 32 chars to convert
  10296. .DUC
  10297.     tst.b    (A0)            ; End?
  10298.     beq.s    .End_StringToLong
  10299.     cmpi.b    #9,(A0)            ; Tab-key?
  10300.     beq.s    .End_StringToLong
  10301.     cmpi.b    #10,(A0)        ; CR (LF)-key?
  10302.     beq.s    .End_StringToLong
  10303.     cmpi.b    #' ',(A0)        ; Blank-key?
  10304.     beq.s    .End_StringToLong
  10305.     cmpi.b    #',',(A0)        ; Comma-key?
  10306.     beq.s    .End_StringToLong
  10307.     cmpi.b    #'.',(A0)        ; A dot set between?
  10308.     beq.s    .Skip_Dot
  10309.  
  10310.     move.b    (A0)+,D1        ; Get char
  10311.     subi.b    #48,D1            ; Computer internal number
  10312.     cmpi.b    #1,D1
  10313.     bhi.s    .Error_StringToLong
  10314.     add.l    D0,D0            ; Base = 2 - so add it!
  10315.     add.l    D1,D0            ; Add also new count
  10316.     dbf    D2,.DUC
  10317.     bra.s    .End_StringToLong
  10318.  
  10319. .Skip_Dot
  10320.     addq.l    #1,A0
  10321.     bra.s    .DUC
  10322. * ----------------------- *
  10323.  
  10324. .Error_StringToLong
  10325.     movem.l    (sp)+,D2-D3
  10326.     moveq    #-1,D1
  10327.     rts
  10328.  
  10329. .End_StringToLong
  10330.     movem.l    (sp)+,D2-D3
  10331.     moveq    #0,D1
  10332.     rts
  10333.  
  10334. * ----------------------------------------------------- *
  10335. *                            *
  10336. *                            *
  10337. *            Data Array            *
  10338. *                            *
  10339. *                            *
  10340. * ----------------------------------------------------- *
  10341.  
  10342. _Divutable
  10343.     dc.l    1000000000
  10344.     dc.l    100000000
  10345.     dc.l    10000000
  10346.     dc.l    1000000
  10347.     dc.l    100000
  10348.     dc.l    10000
  10349.     dc.l    1000
  10350.     dc.l    100
  10351.     dc.l    10
  10352.     dc.l    1
  10353.  
  10354.  
  10355. _Image.1
  10356.     dc.w    0,0,74,19,%1
  10357.     dc.l    0
  10358.     dc.b    %1,%10            ; Plane pick, plane off
  10359.     dc.l    0
  10360.  
  10361. _Image.2
  10362.     dc.w    0,0,74,19,%1
  10363.     dc.l    0
  10364.     dc.b    %1,%10            ; Plane pick, plane off
  10365.     dc.l    0
  10366.  
  10367. _Image.3
  10368.     dc.w    0,0,45,28,%11
  10369.     dc.l    0
  10370.     dc.b    %11,%0            ; Plane pick, plane off
  10371.     dc.l    0
  10372.  
  10373. _Image.4
  10374.     dc.w    0,0,45,28,%11
  10375.     dc.l    0
  10376.     dc.b    %11,%0            ; Plane pick, plane off
  10377.     dc.l    0
  10378.  
  10379. _Channels
  10380.     dc.b    1,2,4,8            ; One of those channels I want to allocate...
  10381.  
  10382. _GStr1
  10383.     dc.b    'Ok',0
  10384. _GStr2
  10385.     dc.b    'Abort',0
  10386. _ScreenName
  10387.     dc.b    'Viewer''s image screen',0
  10388. _WindowName
  10389.     dc.b    ' Viewer V4.4 - © 92-99 ONIX',0
  10390. _IntuitionName
  10391.     dc.b    'intuition.library',0
  10392. _GfxName
  10393.     dc.b    'graphics.library',0
  10394. _DiskFontName
  10395.     dc.b    'diskfont.library',0
  10396. _DeviceName
  10397.     dc.b    'console.device',0
  10398. _AudioName
  10399.     dc.b    'audio.device',0
  10400. _ReqToolsName
  10401.     dc.b    'reqtools.library',0
  10402. _ArpName
  10403.     dc.b    'arp.library',0
  10404. _CyberGfxName
  10405.     dc.b    'cybergraphics.library',0
  10406.  
  10407. _AWTitle
  10408.     dc.b    'Load A File...',0
  10409. _SaveTitle
  10410.     dc.b    'Save Text File As...',0
  10411. _PageDef
  10412.     dc.b    'SCROLLWIDTH=',0
  10413. _WindowDef
  10414.     dc.b    'EXTENTWINDOW=',0
  10415. _WrapDef
  10416.     dc.b    'WRAP=ON',0
  10417. _FontSpecName
  10418.     dc.b    'FONT=',0
  10419. _OffsetSpecName
  10420.     dc.b    'WINDOWOFFSET=',0
  10421. _NoWarningName
  10422.     dc.b    'NOWARN',0
  10423. _NoCheckPrinterTxt
  10424.     dc.b    'NOPRTCHECK',0
  10425. _ExecuteTxt
  10426.     dc.b    'EXECUTE=',0
  10427. _NilName
  10428.     dc.b    'NIL:',0
  10429. * --------------------------------------------------- *
  10430.  
  10431. _HelpText
  10432.     dc.b    $9B,'1;31;42m'
  10433.     dc.b    'CRSR-down  :-) (n) lines down   ',10
  10434.     dc.b    'CRSR-up    :-) (n) lines up     ',10
  10435.     dc.b    'CRSR-right :-) line down        ',10
  10436.     dc.b    'CRSR-left  :-) line up          ',10
  10437.     dc.b    'L-Key      :-) load new file    ',10
  10438.     dc.b    'E-Key      :-) enlarge window   ',10
  10439.     dc.b    'H-Key      :-) this page        ',10    
  10440.     dc.b    'A-Key      :-) about page       ',10
  10441.     dc.b    'R-Key      :-) restore page     ',10
  10442.     dc.b    'T/B-Keys   :-) toggle Top/Bottom',10 
  10443.     dc.b    'HOME/END   :-) toggle Top/Bottom',10
  10444.     dc.b    'PgUp/PgDn  :-) PageUp/PageDown  ',10
  10445.     dc.b    'Ret/Enter  :-) one line down    ',10
  10446.     dc.b    'SHIFT-R    :-) single step back ',10    
  10447.     dc.b    'S_KEY      :-) search for string',10
  10448.     dc.b    'N-Key      :-) next occurrence  ',10    
  10449.     dc.b    'P/F        :-) file to prt/file ',10
  10450.     dc.b    'W/C-Keys   :-) page to prt/file ',10 
  10451.     dc.b    'PrtSc      :-) page to prt      ',10 
  10452.     dc.b    $1B,'[0m'
  10453.                         
  10454.     dc.b    $9B,$48                    ; Cursor Home
  10455.     dc.b    $9B,'33C','  For more details read',10
  10456.     dc.b    $9B,'33C','  Viewer.doc.',10,10
  10457.     dc.b    $9B,'33C','  Press any key to continue.',10
  10458. _HelpTextEnd
  10459.  
  10460.  
  10461. _SearchText
  10462.     dc.b    $1B,'c',10,$1B,'[1mSearch for: ',$1B,'[0m'
  10463. _SearchTextEnd
  10464.  
  10465. *
  10466. ** The first byte of a string contains the upper offset (Y-coordinate)
  10467. ** where the text start (X-offset is computed). A linefeed (10) tells
  10468. ** that a second (or more) string line(s) follow. NULL indicates the
  10469. ** end of the string(s).
  10470. ** If you have strings which only contain one line, the linefeed must
  10471. ** also be set, also the NULL-byte (i.e. "30,'Decrunching failed!',10,0").
  10472. *
  10473.  
  10474. _NoFileMsg
  10475.     dc.b    22,'You didn''t pick a file.',10
  10476.     dc.b    'Press key "L" to load one.',10,0
  10477. _ErrorOpenWindowTxt
  10478.     dc.b    8,'Couldn''t open main-window with',10
  10479.     dc.b    'leftedge at %d, topedge at %d -',10
  10480.     dc.b    'with a width of %d pixels and a',10
  10481.     dc.b    'height of %d rows!',10,0
  10482. _ErrorOpenDevTxt
  10483.     dc.b    22,'Couldn''t open the',10
  10484.     dc.b    '"console.device". Terminating.',10,0
  10485. _EmptyTxt
  10486.     dc.b    22,'Selected file contains no',10
  10487.     dc.b    'datas. Loading file terminated.',10,0
  10488. _DirTxt
  10489.     dc.b    22,'You have chosen a directory and',10
  10490.     dc.b    'I expected a file.',10,0
  10491. _ReadErrTxt
  10492.     dc.b    22,'Could not load that file, it',10
  10493.     dc.b    'has a read error.',10,0
  10494. _OpenFileErrTxt
  10495.     dc.b    30,'Could not open file.',10,0
  10496. _AllocErrTxt
  10497.     dc.b    22,'Impossile to allocate memory',10
  10498.     dc.b    'for this file.',10,0
  10499. _ExamineErrTxt
  10500.     dc.b    30,'DOS function examine failed!',10,0
  10501. _LockErrTxt
  10502.     dc.b    22,'Cannot get lock of file, thus',10
  10503.     dc.b    'I cannot examine the file!',10,0
  10504. _ObjectFileTxt
  10505.     dc.b    8,'The selected file is an object',10
  10506.     dc.b    'module, shall I display its',10
  10507.     dc.b    'contents?',10
  10508.     dc.b    '(Converted size: %ld bytes)',10,0
  10509. _BinaryFileTxt
  10510.     dc.b    8,'The selected file contains ',10
  10511.     dc.b    'binary datas.',10
  10512.     dc.b    'Shall I display them?',10
  10513.     dc.b    '(Converted size: %ld bytes)',10,0
  10514. _NoReqTxt
  10515.     dc.b    22,'Impossible to work without',10
  10516.     dc.b    'ReqTools or Arp libraries!',10,0
  10517. _OpenPrintErrTxt
  10518.     dc.b    22,'Unable to open file or printer',10
  10519.     dc.b    'for output. Printjob aborted.',10,0
  10520. _WriteErrTxt
  10521.     dc.b    22,'Error while printing file.',10
  10522.     dc.b    'Printjob aborted.',10,0
  10523. _PrintFileTxt
  10524.     dc.b    30,'Going to write whole file...',10,0
  10525. _PrintContentsTxt
  10526.     dc.b    30,'Going to write window contents...',10,0
  10527. _PrintCancelTxt
  10528.     dc.b    30,'Job cancelled.',10,0
  10529. _PrinterOFFTxt
  10530.     dc.b    16,'Printer is turned off or',10
  10531.     dc.b    'there is no printer.',10
  10532.     dc.b    'Printing failed.',10,0
  10533. _NotOnelineTxt
  10534.     dc.b    22,'Your printer is not online.',10
  10535.     dc.b    'Printing failed.',10,0
  10536.  
  10537. * - These messages I love... -
  10538.  
  10539. _AboutTxt
  10540.     dc.b    8,'Date: 12/08/1999  10:22:29 pm',10
  10541.     dc.b    'Programmer: Joerg van de Loo.',10
  10542.     dc.b    'Simple text, binary and image viewer.',10
  10543.     dc.b    'Granted to use free of charge.',10,0
  10544. _InfoTxt
  10545.     dc.b    8,'CODE %ld - DATA %ld bytes,',10
  10546.     dc.b    'DATA-CHIP = %ld bytes,',10
  10547.     dc.b    'BSS = %ld bytes.',10
  10548.     dc.b    'Assembled with HiSoft Devpac Amiga.',10,0
  10549.  
  10550. * - Messages for PowerPacker(.library) support -
  10551.  
  10552. _PPCrunchTxt
  10553.     dc.b    8,'This is a PowerPacker',10
  10554.     dc.b    '(library) packed file.',10
  10555.     dc.b    'Unpacked length: %ld bytes.',10
  10556.     dc.b    'Shall I unpack it?',10,0
  10557.  
  10558. _DecrunchErrTxt
  10559.     dc.b    30,'Decrunching failed!',10,0
  10560.  
  10561. * - Message for displaying/loading pictures -
  10562.  
  10563. _ILBMTxt
  10564.     dc.b    22,'This is an IFF-ILBM file.',10
  10565.     dc.b    'Shall I display it?',10,0
  10566. _ACBMTxt
  10567.     dc.b    22,'This is an IFF-ACBM file.',10
  10568.     dc.b    'Shall I display it?',10,0
  10569. _ImageInfoTxt
  10570.     dc.b    8,'Screen: %d * %d pixels.',10
  10571.     dc.b    'Bitmap: %d * %d pixels.',10
  10572.     dc.b    'Image: %d * %d pixels.',10
  10573.     dc.b    '%ld colours, %ld bytes.',10,0
  10574. _WarnMaskingTxt
  10575.     dc.b    8,'WARNING:',10
  10576.     dc.b    'IFF makes use of masking.',10
  10577.     dc.b    'This isn''t 100% supported.',10
  10578.     dc.b    'Strange output may occur!',10,0
  10579. _WarnUncompressedTxt
  10580.     dc.b    22,'INFORMATION:',10
  10581.     dc.b    'IFF already uncompressed.',10,0
  10582. _IncorrectSizeTxt
  10583.     dc.b    22,'ERROR:',10
  10584.     dc.b    'Corrupt IFF-file!',10,0
  10585. _NoByteRunTxt
  10586.     dc.b    22,'ERROR:',10
  10587.     dc.b    'Unknown compression method!',10,0
  10588. _AllocBufErrTxt
  10589.     dc.b    30,'Error allocating bitmaps!',10,0
  10590. _NoIFFFileTxt
  10591.     dc.b    22,'Bad or incomplete IFF!',10
  10592.     dc.b    'Perhaps only a palette file?',10,0
  10593. _ErrorOpeningScreen
  10594.     dc.b    22,'Can''t open monitor/screen...',10
  10595.     dc.b    'Too many bitplanes?!?!?',10,0
  10596. _ErrorInvalidIDTxt
  10597.     dc.b    16,'Cannot find right monitor for',10
  10598.     dc.b    'installed alien gfx-board which',10
  10599.     dc.b    'does support this resolution!',10,0
  10600.  
  10601. * - Messages for converting IFF to ASCII -
  10602.  
  10603. _IFFAsciiTxt
  10604.     dc.b    16,'This IFF-file perhaps',10
  10605.     dc.b    'contains embedded strings.',10
  10606.     dc.b    'Shall I try to extract them?',10,0
  10607. _NoFreeStoreTxt
  10608.     dc.b    16,'Cannot allocate buffer',10
  10609.     dc.b    'to store plain ASCII-',10
  10610.     dc.b    'characters. Extracting aborted',10,0
  10611. _NoAsciiDatasTxt
  10612.     dc.b    16,'This file does not contain',10
  10613.     dc.b    'ASCII-characters at all or I',10
  10614.     dc.b    'cannot handle them!',10,0
  10615. _IncompleteIFFTxt
  10616.     dc.b    16,'IFF-file does not contain',10
  10617.     dc.b    'all chunks it should have.',10
  10618.     dc.b    'Incomplete (bad) IFF-file!',10,0
  10619.  
  10620. * - Messages for audio files -
  10621.  
  10622. _8SVXTxt
  10623.     dc.b    22,'This is an audio file.',10
  10624.     dc.b    'Shall I make it audible?',10,0
  10625. _8SVXErrTxt
  10626.     dc.b    8,'Error during setup of',10
  10627.     dc.b    '8SVX file. VHDR on invalid',10
  10628.     dc.b    'position or I simply ran out of',10
  10629.     dc.b    'memory!',10,0
  10630. _AudErrTxt
  10631.     dc.b    22,'Error while attempting to make',10
  10632.     dc.b    'datas audible; channel stolen?',10,0
  10633.  
  10634. * - The standard...
  10635.  
  10636. _ProgID
  10637.     dc.b    '$VER: Viewer 4.4 (12.08.99)'
  10638. *                    ^^^^
  10639. *               Internal: 4
  10640.     dc.b    '© 1992-99 J.v.d.Loo (ONIX) - IFF-TEXT/ILBM/ACBM/8SVX viewer; RTG emulation.',0
  10641. _EndDatas
  10642.  
  10643. ****************************************************************
  10644. *
  10645. * Image-data. Datas for gadgets, 1 colour, 190 bytes (for each).
  10646. *
  10647.  
  10648.     SECTION    GadgetImage,DATA_C
  10649. _Gad.1
  10650.     dc.w    $AAAA,$AAAA,$AAAA,$AAAA,$AAC0,$D555,$5555,$5555,$5555,$55C0
  10651.     dc.w    $A000,$0000,$0000,$0000,$01C0,$C000,$0000,$0000,$0000,$01C0
  10652.     dc.w    $A000,$0000,$0000,$0000,$01C0,$C000,$0000,$0000,$0000,$01C0
  10653.     dc.w    $A000,$0000,$0000,$0000,$01C0,$C000,$0000,$0000,$0000,$01C0
  10654.     dc.w    $A000,$0000,$0000,$0000,$01C0,$C000,$0000,$0000,$0000,$01C0
  10655.     dc.w    $A000,$0000,$0000,$0000,$01C0,$C000,$0000,$0000,$0000,$01C0
  10656.     dc.w    $A000,$0000,$0000,$0000,$01C0,$C000,$0000,$0000,$0000,$01C0
  10657.     dc.w    $A000,$0000,$0000,$0000,$01C0,$C000,$0000,$0000,$0000,$01C0
  10658.     dc.w    $A000,$0000,$0000,$0000,$01C0,$DFFF,$FFFF,$FFFF,$FFFF,$FFC0
  10659.     dc.w    $FFFF,$FFFF,$FFFF,$FFFF,$FFC0
  10660.  
  10661. _Gad.2
  10662.     dc.w    $FFFF,$FFFF,$FFFF,$FFFF,$FFC0,$FFFF,$FFFF,$FFFF,$FFFF,$FEC0
  10663.     dc.w    $E000,$0000,$0000,$0000,$0140,$E000,$0000,$0000,$0000,$00C0
  10664.     dc.w    $E000,$0000,$0000,$0000,$0140,$E000,$0000,$0000,$0000,$00C0
  10665.     dc.w    $E000,$0000,$0000,$0000,$0140,$E000,$0000,$0000,$0000,$00C0
  10666.     dc.w    $E000,$0000,$0000,$0000,$0140,$E000,$0000,$0000,$0000,$00C0
  10667.     dc.w    $E000,$0000,$0000,$0000,$0140,$E000,$0000,$0000,$0000,$00C0
  10668.     dc.w    $E000,$0000,$0000,$0000,$0140,$E000,$0000,$0000,$0000,$00C0
  10669.     dc.w    $E000,$0000,$0000,$0000,$0140,$E000,$0000,$0000,$0000,$00C0
  10670.     dc.w    $E000,$0000,$0000,$0000,$0140,$EAAA,$AAAA,$AAAA,$AAAA,$AAC0
  10671.     dc.w    $D555,$5555,$5555,$5555,$5540
  10672.  
  10673. *
  10674. ** Normal Audio Image: 45 x 28 x 2, bitmap: 48 x 28 x 2 (336 bytes)
  10675. *
  10676. _AudioGad.1_1
  10677.     dc.w    $0000,$0000,$0000,$0000,$0000,$0008,$0000,$0000,$0008,$0000
  10678.     dc.w    $0400,$0048,$0000,$0A00,$0048,$0000,$1A00,$0048,$0000,$2A00
  10679.     dc.w    $0048,$0000,$4A00,$0048,$003C,$8A00,$0048,$0043,$8A00,$0048
  10680.     dc.w    $0042,$8A00,$0048,$0042,$8A00,$0048,$0042,$8A00,$0048,$0042
  10681.     dc.w    $8A00,$0048,$0042,$8A00,$0048,$0042,$8A00,$0048,$0042,$8A00
  10682.     dc.w    $0048,$0043,$8A00,$0048,$003C,$8A00,$0048,$0000,$4A00,$0048
  10683.     dc.w    $0000,$2A00,$0048,$0000,$1A00,$0048,$0000,$0A00,$0048,$0000
  10684.     dc.w    $0400,$0048,$0FFF,$FFFF,$FFC8,$0000,$0000,$0008,$0000,$0000
  10685.     dc.w    $0008,$7FFF,$FFFF,$FFF8
  10686. _AudioGad.1_2
  10687.     dc.w    $FFFF,$FFFF,$FFF8,$8000,$0000,$0000,$8000,$0000,$0000,$9FFF
  10688.     dc.w    $FBFF,$FF80,$9555,$5455,$5500,$9555,$4455,$5500,$9555,$5455
  10689.     dc.w    $5500,$9555,$3455,$5500,$9541,$7455,$5500,$953C,$7455,$5500
  10690.     dc.w    $953D,$7455,$5500,$953D,$7455,$5500,$953D,$7455,$5500,$953D
  10691.     dc.w    $7455,$5500,$953D,$7455,$5500,$953D,$7455,$5500,$953D,$7455
  10692.     dc.w    $5500,$953C,$7455,$5500,$9540,$7455,$5500,$9540,$3455,$5500
  10693.     dc.w    $9550,$5455,$5500,$9555,$4455,$5500,$9555,$5455,$5500,$9555
  10694.     dc.w    $5155,$5500,$9000,$0000,$0000,$8000,$0000,$0000,$8000,$0000
  10695.     dc.w    $0000,$8000,$0000,$0000
  10696.  
  10697. *
  10698. ** Select Audio Image: 45 x 28 x 2, bitmap: 48 x 28 x 2 (336 bytes)
  10699. *
  10700. _AudioGad.2_1
  10701.     dc.w    $FFFF,$FFFF,$FFF0,$8000,$0000,$0000,$8000,$0200,$4000,$8000
  10702.     dc.w    $0500,$8000,$8000,$0D01,$0020,$8000,$1502,$0020,$8000,$2504
  10703.     dc.w    $0020,$801E,$4500,$1820,$8021,$C500,$6020,$8021,$4501,$8020
  10704.     dc.w    $8021,$4500,$0020,$8021,$4500,$0020,$8021,$4500,$FC20,$8021
  10705.     dc.w    $4500,$0020,$8021,$4500,$0020,$8021,$4501,$8020,$8021,$C500
  10706.     dc.w    $6020,$801E,$4500,$1820,$8000,$2504,$0020,$8000,$1502,$0020
  10707.     dc.w    $8000,$0D01,$0020,$8000,$0500,$8020,$8000,$0200,$4020,$8000
  10708.     dc.w    $0000,$0020,$8000,$0000,$0020,$87FF,$FFFF,$FFE0,$8000,$0000
  10709.     dc.w    $0000,$8000,$0000,$0000
  10710. _AudioGad.2_2
  10711.     dc.w    $0000,$0000,$0008,$0000,$0000,$0008,$0000,$0000,$0008,$0000
  10712.     dc.w    $0200,$0008,$0FFF,$F27E,$EFC8,$0AAA,$AA28,$8A88,$0AAA,$9A2A
  10713.     dc.w    $AA88,$0AA0,$BA2A,$2288,$0A9E,$3A2A,$8A88,$0A9E,$BA2A,$2888
  10714.     dc.w    $0A9E,$BA2A,$A288,$0A9E,$BA2A,$8A88,$0A9E,$BA2A,$0288,$0A9E
  10715.     dc.w    $BA2A,$AA88,$0A9E,$BA2A,$8088,$0A9E,$BA2A,$2A88,$0A9E,$3A2A
  10716.     dc.w    $8A88,$0AA0,$3A2A,$8288,$0AA0,$1A2A,$A288,$0AA8,$2A28,$A888
  10717.     dc.w    $0AAA,$A22A,$AA88,$0AAA,$AA2A,$2A88,$0AAA,$A82A,$AA88,$0AAA
  10718.     dc.w    $AA2A,$8A88,$0AAA,$AA2A,$AA88,$0800,$0000,$0008,$0000,$0000
  10719.     dc.w    $0008,$7FFF,$FFFF,$FFF8
  10720.  
  10721.     END
  10722.