home *** CD-ROM | disk | FTP | other *** search
/ Enigma Amiga Life 113 / EnigmaAmiga113CD.iso / software / utilities / viewer / source / startup.easy < prev    next >
Encoding:
Text File  |  1993-05-21  |  10.3 KB  |  423 lines
  1. *
  2. ** Startup.Easy v1.1
  3. *
  4. ** Author: Jörg van de Loo
  5. **         Hövel 15
  6. **         47559 Kranenburg
  7. **         Germany
  8. ** ...this material was written using HiSoft's "Devpac Assembler 3".
  9. *
  10. ** This  file  is  FreeWare (I would say public domain but this gives criminal
  11. ** people the right to add "their" copyright remark, so to protect myself from
  12. ** excluding  of  the  use  of  this  startup-code,  it's FreeWare and I'm the
  13. ** copyright holder).
  14. ** HiSoft  (UK) is it allowed to use/spread/include this file if they like to,
  15. ** also in modified form, for free.
  16. *
  17. ** Date: 5.21.1993
  18. *
  19. ** I  cannot  be  held  for  any  failures may happen using this startup-code.
  20. ** Unnecessary to tell that you use it at your own risk.
  21. *
  22.  
  23. *
  24. ** This  startup-code  is  reentrant,  so  if your code is it too, you may use
  25. ** Shell command "Resident".
  26. *
  27.  
  28. *
  29. ** The  BaseTable is only readable!  Don't go messing with 'em or weird things
  30. ** may happen.
  31. *
  32.  
  33. *
  34. ** The BaseTable used by this startup-code is 68 bytes large.  If you define a
  35. ** label  called  "_TableSize"  before  you  include  the  startup-code  (it's
  36. ** important!)  then  you  can  specify the bytesize of the table on your own,
  37. ** e.g.  1024 bytes.  Up from offset 68 you can now store your own datas,
  38. ** e.g. _GfxBase.
  39. *
  40. ** Note:   This  startup-code  offers only 32KB of datas that can be reached -
  41. **       BSS relative to A5.
  42. *
  43.  
  44. *
  45. ** Example:
  46. **
  47. *    STRUCTURE    mytable,68    ; begin at offset 68
  48. *    APTR        _GfxBase    ; offset 68
  49. *    APTR        _IntuitionBase    ; offset 72
  50. *    UBYTE        _myFlag        ; offset 76
  51. *    LABEL        _TableSize
  52. *        ; size for "BaseTable" and! "mytable" (here 77 bytes) -
  53. *        ; automatically allocated when startup-code is executed.
  54. *
  55. *    include        include/startup.easy    ; insert startup-code
  56. *
  57. * _main        ; this label is the entry point for your code!
  58. *    ....
  59. *    ....
  60. *
  61. **
  62. ** The  label  "_main" will be called out of the startup-code.  There your own
  63. ** code has to start.
  64. ** When  your code returns to the exit-routine, all things allocated/opened by
  65. ** the startup-code are freed/closed.
  66. * 
  67. ** The  address  register  where  the  BaseTable  is  stored, is the processor
  68. ** register A5.  Now you can store/read constants out of it, e.g.
  69. *
  70. *    movea.l    _DOSBase(A5),A6            ; get base of dos-lib
  71. *
  72.  
  73. *
  74. ** To exit your code there are different ways.
  75. *
  76. **  1. By "RTS"                stack must be ok!
  77. **  2. By calling "bsr _exit"         no need for corrected stack
  78. **  3. By calling "bra _exit"         ditto
  79. **  4. By calling "jsr _exit"         ditto
  80. **  5. By calling "jmp _exit"         ditto
  81. *
  82. ** It's not necessary to restore the stack nor to restore the A5 register when
  83. ** using exits 2,3,4,5.
  84. *
  85.  
  86. *
  87. ** This  startup-code  is  a  thined  version  of  a  startup-code which I use
  88. ** normally.   Because  I  wrote a few programs for the PD and I don't want to
  89. ** spread  my  hard  worked made startup-code (it's a lot time better than the
  90. ** original of Commodore), I wrote this one.
  91. *
  92.  
  93.  
  94.     IFND    STARTUP_EASY
  95. STARTUP_EASY    SET    1
  96.  
  97. *    incdir    :include/
  98.     IFND    EXEC_TYPES_I
  99.     include    exec/types.i
  100.     ENDC
  101.  
  102.     IFND    EXEC_MEMORY_I
  103.     include    exec/memory.i
  104.     ENDC
  105.  
  106.     IFND    EXEC_TASKS_I
  107.     include    exec/tasks.i
  108.     ENDC
  109.  
  110.     IFND    EXEC_LIBRARIES_I
  111.     include    exec/libraries.i
  112.     ENDC
  113.  
  114.     IFND    CALLEXEC
  115.     include    exec/exec_lib.i
  116.     ENDC
  117.  
  118. *    include    exec/execbase.i
  119.  
  120.     IFND    CALLDOS
  121.     include    dos/dos_lib.i
  122.     ENDC
  123.  
  124.     IFND    DOS_DOSEXTENS_I
  125.     include    dos/dosextens.i
  126.     ENDC
  127.  
  128.     IFND    WORKBENCH_STARTUP_I
  129.     include    workbench/startup.i
  130.     ENDC
  131.  
  132. *    include    workbench/icon_lib.i
  133.  
  134.     IFND    WORKBENCH_WORKBENCH_I
  135.     include    workbench/workbench.i
  136.     ENDC
  137.  
  138.  
  139.     IFND    AbsExecBase
  140. AbsExecBase    EQU    4
  141.     ENDC
  142.  
  143.     IFND    ThisTask
  144. ThisTask        EQU    276
  145.     ENDC
  146.  
  147.     IFND    _LVOGetDiskObject
  148. _LVOGetDiskObject    EQU    -78
  149.     ENDC
  150.  
  151.     IFND    _LVOFreeDiskObject
  152. _LVOFreeDiskObject    EQU    -90
  153.     ENDC
  154.  
  155.  
  156.  
  157. StoreTableSize    MACRO
  158.     IFND     _TableSize
  159.     move.l    #256,D0        ; Default, if nothing is specified
  160.  
  161.     ELSE
  162.  
  163.     IFLE    _TableSize-127    ; If _TableSize < 128 use moveq
  164.     moveq    #_TableSize,D0
  165.  
  166.     ELSE
  167.  
  168.     IFLE    _TableSize-32767 ; _TableSize not larger than 32KB
  169.     move.l    #_TableSize,D0
  170.  
  171.     ELSE
  172.     FAIL    <BSS-table exeeds 32KB!> ; else tell user
  173.     ENDC
  174.  
  175.     ENDC
  176.     ENDC
  177.  
  178.     addq.l    #7,D0        ; ...make size divisible
  179.     andi.l    #-8,D0        ; through eight -> for exec's AllocMem()...
  180.     ENDM
  181.  
  182.  
  183.  
  184. *
  185. ** This is the BaseTable....
  186. *
  187.    STRUCTURE    BaseTable,0    ; begin at offset NULL
  188.     APTR    bt_Reserved0    ; currently unused - do not use!
  189.     APTR    _SysBase    ; pointer to exec-base (readable)
  190.                 ; NOTE: « movea.l _SysBase.w,A6 » still work
  191.     APTR    bt_Reserved1    ; currently unused - do not use!
  192.     APTR    bt_Reserved2    ; currently unused - do not use!
  193.     APTR    _DOSBase    ; pointer to dos-base (opened/readable)
  194.     APTR    _IconBase    ; pointer to icon-base (readable, may not opened)
  195.     APTR    _argv        ; pointer to dos/WB-arguments (readable, may NULL)
  196.     ULONG    _argc        ; numbers of dos/WB-arguments (readable, may NULL)
  197.     APTR    _OwnTask    ; pointer to own-process-structure (readable)
  198.     APTR    _OwnName    ; pointer to own-program-name
  199.                 ; (readable, Shell: with path, WB: name only)
  200.     ULONG    _CmdNameSize    ; PRIVATE!!!
  201.     APTR    _WBenchMsg    ; pointer to Workbench-message (readable, may NULL)
  202.     APTR    _ToolTypesArray    ; pointer to tooltypes (readable, may NULL)
  203.     APTR    _OwnDiskObject    ; pointer to own-program-icon-structure (readable,
  204. *                  may NULL)
  205.     APTR    _stdin        ; pointer to standard output-handle (readable,
  206. *                  may NULL)
  207.     APTR    _stdout        ; pointer to standard input-handle (readable,
  208. *                  may NULL)
  209.     ULONG    _errno        ; place into this constant the returncode of
  210. *                  your program
  211.     LABEL    bt_SIZEOF    ; size of this table: 68 bytes - next free offset: 68!
  212.  
  213. *
  214. ** Where  "may NULL" stands it's possible that this values are not initialized
  215. ** if running from Workbench or when running from Shell.
  216. *
  217. * Examples: The WBenchMsg will be NULL if running under Shell.
  218. *        The stdin or stdout will be NULL when running from Workbench.
  219. *        So watch out!
  220.  
  221.  
  222. _startup
  223.     movem.l    D0/A0,-(sp)
  224.  
  225.     move.l    AbsExecBase.w,A6
  226.     StoreTableSize            ; MACRO - bytesize of "_TableSize"
  227.     move.l    #MEMF_PUBLIC|MEMF_CLEAR,D1
  228.     jsr    _LVOAllocMem(A6)    ; Allocate BaseTable and user's BSS
  229.     tst.l    D0
  230.     beq.w    __noTable
  231.     movea.l    D0,A5            ; Pointer to BaseTable into A5
  232.     move.l    A6,_SysBase(A5)
  233.  
  234.     move.l    (sp)+,_argc(A5)        ; Number of chars in commandline
  235.     move.l    (sp)+,_argv(A5)        ; Address commandline (if Shell)
  236.  
  237.     move.l    A5,-(sp)        ; Save BaseTable right in front
  238. *                      of ReturnAddr of task
  239.  
  240.     cmpi.w    #32,LIB_VERSION(A6)    ; Say: I need at least kickstart 1.2
  241.     bls.w    __fastout
  242.  
  243.     lea    _DOSName(pc),A1
  244.     moveq    #0,D0            ; Say: any version up from  Kickstart 1.2
  245.     jsr    _LVOOpenLibrary(A6)
  246.     move.l    D0,_DOSBase(A5)
  247.     beq.w    __fastout        ; ...only for savety...
  248.  
  249.     sub.l    A1,A1
  250.     jsr    _LVOFindTask(A6)
  251.     move.l    D0,_OwnTask(A5)        ; Pointer to process-structure
  252.  
  253.     movea.l    D0,A2
  254.     tst.l    pr_CLI(A2)        ; Are we called from CLI or WBench?
  255.     bne.s    .fromDOS
  256.  
  257. * ...it was Workbench
  258.     lea    pr_MsgPort(A2),A0
  259.     jsr    _LVOWaitPort(A6)    ; Wait for WB-message
  260.  
  261.     lea    pr_MsgPort(A2),A0
  262.     jsr    _LVOGetMsg(A6)        ; Get message
  263.     move.l    D0,_WBenchMsg(A5)    ; and save message for later
  264.  
  265.     movea.l    D0,A0            ; Message
  266.     move.l    sm_NumArgs(A0),_argc(A5) ; Number of files
  267.     move.l    sm_ArgList(A0),_argv(A5) ; Array of locks and files
  268.  
  269.     lea    _IconName(pc),A1
  270.     moveq    #33,D0
  271.     jsr    _LVOOpenLibrary(A6)    ; Open Icon-library
  272.     move.l    D0,_IconBase(A5)
  273.     beq.s    .skipToolTypes
  274.  
  275.     tst.l    _argv(A5)        ; Array empty?
  276.     beq.s    .skipToolTypes
  277.     movea.l    _argv(A5),A0        ; Array of:
  278. *    lock[0],file[0], lock[1],file[1], lock[2],file[2] and so on
  279.     move.l    (A0),D1            ; wa_Lock(A0),D1 (home-lock)
  280.     beq.s    .skipLock
  281.     movea.l    _DOSBase(A5),A6
  282.     jsr    _LVOCurrentDir(A6)    ; Change directory to PROGDIR
  283.     tst.l    D0
  284.     bmi.s    .skipToolTypes
  285. .skipLock
  286.     movea.l    _IconBase(A5),A6
  287.     movea.l    _argv(A5),A0
  288.     movea.l    wa_Name(A0),A0        ; Our name...
  289.     move.l    A0,_OwnName(A5)        ; Remember name of prg
  290.     jsr    _LVOGetDiskObject(A6)    ; Read program-icon
  291.     tst.l    D0
  292.     beq.s    .skipToolTypes
  293.     move.l    D0,_OwnDiskObject(A5)    ; Remember icon-structure of our prg
  294.     movea.l    D0,A0
  295.     move.l    do_ToolTypes(A0),_ToolTypesArray(A5)
  296. .skipToolTypes
  297.     bra.s    __main
  298.  
  299. * ...Shell start...
  300. .fromDOS
  301.     movea.l    _DOSBase(A5),A6
  302.     jsr    _LVOInput(A6)
  303.     move.l    D0,_stdin(A5)
  304.     jsr    _LVOOutput(A6)
  305.     move.l    D0,_stdout(A5)
  306.  
  307.     movea.l    _OwnTask(A5),A0
  308.     movea.l    pr_CLI(A0),A0
  309.     adda.l    A0,A0
  310.     adda.l    A0,A0
  311.     movea.l    cli_CommandName(A0),A2    ; BSTR to our prg-name
  312.     adda.l    A2,A2
  313.     adda.l    A2,A2            ; APTR
  314.     moveq    #0,D2
  315.     move.b    (A2)+,D2        ; Get length of our name
  316.  
  317.     move.l    #103,_errno(A5)        ; Setup possible error
  318.  
  319.     move.l    D2,D0            ; Length
  320.     addq.w    #8,D0            ; plus 1 byte (NULL-byte) plus 7 &
  321.     andi.w    #-8,D0            ; "and" with -8 =  make length divisible through 8
  322.     move.l    D0,_CmdNameSize(A5)    ; Remember size for later
  323.     move.l    #MEMF_PUBLIC|MEMF_CLEAR,D1
  324.     movea.l    _SysBase(A5),A6
  325.     jsr    _LVOAllocMem(A6)    ; Allocate name-buffer
  326.     move.l    D0,_OwnName(A5)        ; Save pointer to name-buffer
  327.     beq.s    __closeAndFree
  328.  
  329.     clr.l    _errno(A5)        ; Tell: no error occurred
  330.  
  331.     movea.l    D0,A0            ; Name-buffer
  332.     bra.s    .doIt            ; Because of DBF
  333. .StoreName
  334.     move.b    (A2)+,(A0)+        ; Copy CMD-name into own buffer
  335. .doIt
  336.     dbf    D2,.StoreName
  337.     clr.b    (A0)            ; Not needed....
  338. __main
  339.     move.l    _SysBase(A5),A6
  340.     bsr.w    _main            ; Call user's code with:
  341. *                      ·A5 BaseTable, A6 SysBase·
  342.  
  343. _exit
  344.     movea.l    AbsExecBase.w,A6    ; Execbase
  345.     suba.l    A1,A1            ; 0 = own task (process)
  346.     jsr    _LVOFindTask(A6)    ; Find our process
  347.     movea.l    D0,A0            ; Pointer to A0
  348.     movea.l    pr_ReturnAddr(A0),A0    ; Program's exit address
  349.     subq.l    #8,A0
  350.     move.l    A0,sp            ; Correct Stackpointer
  351.     move.l    (sp)+,A5        ; Place basetable pointer in A5
  352. *                      and make a "RTS" using right address
  353.  
  354.     tst.l    _WBenchMsg(A5)
  355.     beq.s    .fromDOS
  356.  
  357.     tst.l    _IconBase(A5)
  358.     beq.s    .ReplyMsg
  359.  
  360.     tst.l    _OwnDiskObject(A5)
  361.     beq.s    .ReplyMsg
  362.     movea.l    _OwnDiskObject(A5),A0
  363.     movea.l    _IconBase(A5),A6
  364.     jsr    _LVOFreeDiskObject(A6)    
  365.  
  366. .ReplyMsg
  367.     movea.l    _SysBase(A5),A6
  368.     tst.l    _IconBase(A5)
  369.     beq.s    .skipIt
  370.     movea.l    _IconBase(A5),A1
  371.     jsr    _LVOCloseLibrary(A6)
  372. .skipIt
  373.     jsr    _LVOForbid(A6)
  374.  
  375.     movea.l    _WBenchMsg(A5),A1
  376.     jsr    _LVOReplyMsg(A6)
  377.  
  378.     bra.s    __closeAndFree
  379.  
  380. .fromDOS
  381.     movea.l    _SysBase(A5),A6
  382.     move.l    _CmdNameSize(A5),D0
  383.     movea.l    _OwnName(A5),A1
  384.     jsr    _LVOFreeMem(A6)
  385.  
  386. __closeAndFree
  387.     move.l    _errno(A5),D2
  388.     movea.l    _DOSBase(A5),A1
  389.     movea.l    _SysBase(A5),A6
  390.     jsr    _LVOCloseLibrary(A6)
  391.     movea.l    _OwnTask(A5),A2
  392.     movea.l    A5,A1
  393.     StoreTableSize
  394.     jsr    _LVOFreeMem(A6)    
  395.     move.l    D2,D0
  396.     move.l    D0,pr_Result2(A2)    ; Back to  Shell/WB with returncode in D0
  397.     rts                ; and a valid Result2 constant...
  398.  
  399. * ------------------------------------- *
  400. __noTable
  401.     addq.w    #8,sp
  402.     moveq    #103,D0
  403.     move.l    ThisTask(A6),A0
  404.     move.l    D0,pr_Result2(A0)
  405.     rts
  406. __fastout
  407.     movea.l    A5,A1
  408.     StoreTableSize
  409.     jsr    _LVOFreeMem(A6)    
  410.     moveq    #121,D0
  411.     move.l    ThisTask(A6),A0
  412.     move.l    D0,pr_Result2(A0)
  413.     rts
  414. _DOSName
  415.     dc.b    'dos.library',0
  416. _IconName
  417.     dc.b    'icon.library',0
  418.  
  419.     CNOP    0,4
  420.  
  421.     ENDC
  422. * ------------------------------------- *
  423.