home *** CD-ROM | disk | FTP | other *** search
/ Enigma Amiga Life 113 / EnigmaAmiga113CD.iso / software / sviluppo / quakeworld_src / client / r_aclipppc.s < prev    next >
Encoding:
Text File  |  2000-06-17  |  11.6 KB  |  568 lines
  1. # 
  2. # Copyright (C) 1996-1997 Id Software, Inc. 
  3. # 
  4. # This program is free software; you can redistribute it and/or 
  5. # modify it under the terms of the GNU General Public License 
  6. # as published by the Free Software Foundation; either version 2 
  7. # of the License, or (at your option) any later version. 
  8. # 
  9. # This program is distributed in the hope that it will be useful, 
  10. # but WITHOUT ANY WARRANTY; without even the implied warranty of 
  11. # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.   
  12. # 
  13. # See the GNU General Public License for more details. 
  14. # 
  15. # You should have received a copy of the GNU General Public License 
  16. # along with this program; if not, write to the Free Software 
  17. # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA  02111-1307, USA. 
  18. # 
  19.  
  20. ##
  21. ## Quake for AMIGA
  22. ##
  23. ## r_aclipPPC.s
  24. ##
  25. ## Define WOS for PowerOpen ABI, otherwise SVR4-ABI is used.
  26. ##
  27.  
  28. .include    "macrosPPC.i"
  29.  
  30. #
  31. # external references
  32. #
  33.  
  34.     xrefa    r_refdef
  35.     xrefv    INT2DBL_0
  36.     xrefv    c0_5
  37.  
  38.  
  39. #
  40. # defines
  41. #
  42.  
  43. .set    ALIAS_LEFT_CLIP        ,1
  44. .set    ALIAS_TOP_CLIP         ,2
  45. .set    ALIAS_RIGHT_CLIP       ,4
  46. .set    ALIAS_BOTTOM_CLIP      ,8
  47.  
  48. .set    FV_V                   ,0
  49. .set    FV_FLAGS               ,24
  50. .set    FV_RESERVED            ,28
  51. .set    FV_SIZEOF              ,32
  52. .set    FV_SIZEOF_EXP          ,5
  53.  
  54. .set    REFDEF_VRECT           ,0
  55. .set    REFDEF_ALIASVRECT      ,20
  56. .set    REFDEF_VRECTRIGHT      ,40
  57. .set    REFDEF_VRECTBOTTOM     ,44
  58. .set    REFDEF_ALIASVRECTRIGHT ,48
  59. .set    REFDEF_ALIASVRECTBOTTOM,52
  60.  
  61. .set    VRECT_X                ,0
  62. .set    VRECT_Y                ,4
  63. .set    VRECT_WIDTH            ,8
  64. .set    VRECT_HEIGHT           ,12
  65. .set    VRECT_PNEXT            ,16
  66.  
  67.  
  68.  
  69.  
  70. ###########################################################################
  71. #
  72. #       void _R_Alias_clip_left (finalvert_t *pfv0, finalvert_t *pfv1,
  73. #                                finalvert_t *out)
  74. #
  75. ###########################################################################
  76.  
  77.     funcdef    R_Alias_clip_left
  78.  
  79.     init    0,16,0,0
  80.  
  81.     lf      f1,INT2DBL_0        #for int2dbl setup, tmp=r6
  82.     stfd    f1,local(r1)
  83.     lxa     r7,r_refdef
  84.     lwz     r7,REFDEF_ALIASVRECT+VRECT_X(r7)
  85.     ls      f2,c0_5
  86.     subi    r3,r3,4
  87.     subi    r4,r4,4
  88.     subi    r5,r5,4
  89.     lwzu    r8,4(r3)
  90.     lwzu    r9,4(r3)
  91.     lwzu    r10,4(r4)
  92.     lwzu    r11,4(r4)
  93.     cmpw    r9,r11
  94.     blt     .lcont
  95.     subf    r12,r8,r7
  96.     int2dbl f3,r12,r6,local,f1
  97.     fadd    f4,f2,f3
  98.     subf    r12,r8,r10
  99.     int2dbl f5,r12,r6,local,f1
  100.     fdivs   f6,f3,f5
  101.     fctiwz  f0,f4
  102.     stfd    f0,local+8(r1)
  103.     lwz     r12,local+12(r1)
  104.     add     r12,r12,r8
  105.     stwu    r12,4(r5)
  106.     li      r0,5
  107.     mtctr   r0
  108.     b       .lentry
  109. .lloop:
  110.     lwzu    r9,4(r3)
  111.     lwzu    r11,4(r4)
  112. .lentry:
  113.     subf    r12,r9,r11
  114.     int2dbl f3,r12,r6,local,f1
  115.     fmadds  f3,f3,f6,f2
  116.     fctiwz  f0,f3
  117.     stfd    f0,local+8(r1)
  118.     lwz     r12,local+12(r1)
  119.     add     r12,r12,r9
  120.     stwu    r12,4(r5)
  121.     bdnz    .lloop
  122.     b       .lexit
  123. .lcont:
  124.     subf    r12,r10,r7
  125.     int2dbl f3,r12,r6,local,f1
  126.     fadd    f4,f2,f3
  127.     subf    r12,r10,r8
  128.     int2dbl f5,r12,r6,local,f1
  129.     fdivs   f6,f3,f5
  130.     fctiwz  f0,f4
  131.     stfd    f0,local+8(r1)
  132.     lwz     r12,local+12(r1)
  133.     add     r12,r12,r10
  134.     stwu    r12,4(r5)
  135.     li      r0,5
  136.     mtctr   r0
  137.     b       .lentry2
  138. .lloop2:
  139.     lwzu    r9,4(r3)
  140.     lwzu    r11,4(r4)
  141. .lentry2:
  142.     subf    r12,r11,r9
  143.     int2dbl f3,r12,r6,local,f1
  144.     fmadds  f3,f3,f6,f2
  145.     fctiwz  f0,f3
  146.     stfd    f0,local+8(r1)
  147.     lwz     r12,local+12(r1)
  148.     add     r12,r12,r11
  149.     stwu    r12,4(r5)
  150.     bdnz    .lloop2
  151. .lexit:
  152.     exit
  153.  
  154.     funcend    R_Alias_clip_left
  155.  
  156.  
  157.  
  158.  
  159. ###########################################################################
  160. #
  161. #       void R_Alias_clip_right (finalvert_t *pfv0, finalvert_t *pfv1,
  162. #                                finalvert_t *out)
  163. #
  164. ###########################################################################
  165.  
  166.     funcdef    R_Alias_clip_right
  167.  
  168.     init    0,16,0,0
  169.  
  170.     lf      f1,INT2DBL_0        #for int2dbl_setup, tmp=r6
  171.     stfd    f1,local(r1)
  172.     lxa     r7,r_refdef
  173.     lwz     r7,REFDEF_ALIASVRECTRIGHT(r7)
  174.     ls      f2,c0_5
  175.     subi    r3,r3,4
  176.     subi    r4,r4,4
  177.     subi    r5,r5,4
  178.     lwzu    r8,4(r3)
  179.     lwzu    r9,4(r3)
  180.     lwzu    r10,4(r4)
  181.     lwzu    r11,4(r4)
  182.     cmpw    r9,r11
  183.     blt     .rcont
  184.     subf    r12,r8,r7
  185.     int2dbl f3,r12,r6,local,f1
  186.     fadd    f4,f2,f3
  187.     subf    r12,r8,r10
  188.     int2dbl f5,r12,r6,local,f1
  189.     fdivs   f6,f3,f5
  190.     fctiwz  f0,f4
  191.     stfd    f0,local+8(r1)
  192.     lwz     r12,local+12(r1)
  193.     add     r12,r12,r8
  194.     stwu    r12,4(r5)
  195.     li      r0,5
  196.     mtctr   r0
  197.     b       .rentry
  198. .rloop:
  199.     lwzu    r9,4(r3)
  200.     lwzu    r11,4(r4)
  201. .rentry:
  202.     subf    r12,r9,r11
  203.     int2dbl f3,r12,r6,local,f1
  204.     fmadds  f3,f3,f6,f2
  205.     fctiwz  f0,f3
  206.     stfd    f0,local+8(r1)
  207.     lwz     r12,local+12(r1)
  208.     add     r12,r12,r9
  209.     stwu    r12,4(r5)
  210.     bdnz    .rloop
  211.     b       .rexit
  212. .rcont:
  213.     subf    r12,r10,r7
  214.     int2dbl f3,r12,r6,local,f1
  215.     fadd    f4,f2,f3
  216.     subf    r12,r10,r8
  217.     int2dbl f5,r12,r6,local,f1
  218.     fdivs   f6,f3,f5
  219.     fctiwz  f0,f4
  220.     stfd    f0,local+8(r1)
  221.     lwz     r12,local+12(r1)
  222.     add     r12,r12,r10
  223.     stwu    r12,4(r5)
  224.     li      r0,5
  225.     mtctr   r0
  226.     b       .rentry2
  227. .rloop2:
  228.     lwzu    r9,4(r3)
  229.     lwzu    r11,4(r4)
  230. .rentry2:
  231.     subf    r12,r11,r9
  232.     int2dbl f3,r12,r6,local,f1
  233.     fmadds  f3,f3,f6,f2
  234.     fctiwz  f0,f3
  235.     stfd    f0,local+8(r1)
  236.     lwz     r12,local+12(r1)
  237.     add     r12,r12,r11
  238.     stwu    r12,4(r5)
  239.     bdnz    .rloop2
  240. .rexit:
  241.     exit
  242.  
  243.     funcend    R_Alias_clip_right
  244.  
  245.  
  246.  
  247.  
  248. ###########################################################################
  249. #
  250. #       void R_Alias_clip_top (finalvert_t *pfv0, finalvert_t *pfv1,
  251. #                                finalvert_t *out)
  252. #
  253. ###########################################################################
  254.  
  255.     funcdef    R_Alias_clip_top
  256.  
  257.     init    0,16,0,0
  258.  
  259.     lf      f1,INT2DBL_0        #for int2dbl_setup, tmp=r6
  260.     stfd    f1,local(r1)
  261.     lxa     r7,r_refdef
  262.     lwz     r7,REFDEF_ALIASVRECT+VRECT_Y(r7)
  263.     ls      f2,c0_5
  264.     subi    r3,r3,4
  265.     subi    r4,r4,4
  266.     subi    r5,r5,4
  267.     lwzu    r8,4(r3)
  268.     lwzu    r9,4(r3)
  269.     lwzu    r10,4(r4)
  270.     lwzu    r11,4(r4)
  271.     cmpw    r9,r11
  272.     blt     .tcont
  273.     subf    r12,r9,r7
  274.     int2dbl f3,r12,r6,local,f1
  275.     fadd    f4,f2,f3
  276.     subf    r12,r9,r11
  277.     int2dbl f5,r12,r6,local,f1
  278.     fdivs   f6,f3,f5
  279.     fctiwz  f0,f4
  280.     stfd    f0,local+8(r1)
  281.     lwz     r12,local+12(r1)
  282.     add     r12,r12,r9
  283.     stwu    r12,4(r5)
  284.     li      r0,5
  285.     mtctr   r0
  286.     b       .tentry
  287. .tloop:
  288.     lwzu    r8,4(r3)
  289.     lwzu    r10,4(r4)
  290. .tentry:
  291.     subf    r12,r8,r10
  292.     int2dbl f3,r12,r6,local,f1
  293.     fmadds  f3,f3,f6,f2
  294.     fctiwz  f0,f3
  295.     stfd    f0,local+8(r1)
  296.     lwz     r12,local+12(r1)
  297.     add     r12,r12,r8
  298.     stwu    r12,4(r5)
  299.     bdnz    .tloop
  300.     b       .texit
  301. .tcont:
  302.     subf    r12,r11,r7
  303.     int2dbl f3,r12,r6,local,f1
  304.     fadd    f4,f2,f3
  305.     subf    r12,r11,r9
  306.     int2dbl f5,r12,r6,local,f1
  307.     fdivs   f6,f3,f5
  308.     fctiwz  f0,f4
  309.     stfd    f0,local+8(r1)
  310.     lwz     r12,local+12(r1)
  311.     add     r12,r12,r11
  312.     stwu    r12,4(r5)
  313.     li      r0,5
  314.     mtctr   r0
  315.     b       .tentry2
  316. .tloop2:
  317.     lwzu    r8,4(r3)
  318.     lwzu    r10,4(r4)
  319. .tentry2:
  320.     subf    r12,r10,r8
  321.     int2dbl f3,r12,r6,local,f1
  322.     fmadds  f3,f3,f6,f2
  323.     fctiwz  f0,f3
  324.     stfd    f0,local+8(r1)
  325.     lwz     r12,local+12(r1)
  326.     add     r12,r12,r10
  327.     stwu    r12,4(r5)
  328.     bdnz    .tloop2
  329. .texit:
  330.     lwz     r3,-20(r5)
  331.     lwz     r4,-16(r5)
  332.     stw     r4,-20(r5)
  333.     stw     r3,-16(r5)
  334.     exit
  335.  
  336.     funcend    R_Alias_clip_top
  337.  
  338.  
  339.  
  340.  
  341. ###########################################################################
  342. #
  343. #       void R_Alias_clip_bottom (finalvert_t *pfv0, finalvert_t *pfv1,
  344. #                                finalvert_t *out)
  345. #
  346. ###########################################################################
  347.  
  348.     funcdef    R_Alias_clip_bottom
  349.  
  350.     init    0,16,0,0
  351.  
  352.     lf      f1,INT2DBL_0        #for int2dbl_setup, tmp=r6
  353.     stfd    f1,local(r1)
  354.     lxa     r7,r_refdef
  355.     lwz     r7,REFDEF_ALIASVRECTBOTTOM(r7)
  356.     ls      f2,c0_5
  357.     subi    r3,r3,4
  358.     subi    r4,r4,4
  359.     subi    r5,r5,4
  360.     lwzu    r8,4(r3)
  361.     lwzu    r9,4(r3)
  362.     lwzu    r10,4(r4)
  363.     lwzu    r11,4(r4)
  364.     cmpw    r9,r11
  365.     blt     .bcont
  366.     subf    r12,r9,r7
  367.     int2dbl f3,r12,r6,local,f1
  368.     fadd    f4,f2,f3
  369.     subf    r12,r9,r11
  370.     int2dbl f5,r12,r6,local,f1
  371.     fdivs   f6,f3,f5
  372.     fctiwz  f0,f4
  373.     stfd    f0,local+8(r1)
  374.     lwz     r12,local+12(r1)
  375.     add     r12,r12,r9
  376.     stwu    r12,4(r5)
  377.     li      r0,5
  378.     mtctr   r0
  379.     b       .bentry
  380. .bloop:
  381.     lwzu    r8,4(r3)
  382.     lwzu    r10,4(r4)
  383. .bentry:
  384.     subf    r12,r8,r10
  385.     int2dbl f3,r12,r6,local,f1
  386.     fmadds  f3,f3,f6,f2
  387.     fctiwz  f0,f3
  388.     stfd    f0,local+8(r1)
  389.     lwz     r12,local+12(r1)
  390.     add     r12,r12,r8
  391.     stwu    r12,4(r5)
  392.     bdnz    .bloop
  393.     b       .bexit
  394. .bcont:
  395.     subf    r12,r11,r7
  396.     int2dbl f3,r12,r6,local,f1
  397.     fadd    f4,f2,f3
  398.     subf    r12,r11,r9
  399.     int2dbl f5,r12,r6,local,f1
  400.     fdivs   f6,f3,f5
  401.     fctiwz  f0,f4
  402.     stfd    f0,local+8(r1)
  403.     lwz     r12,local+12(r1)
  404.     add     r12,r12,r11
  405.     stwu    r12,4(r5)
  406.     li      r0,5
  407.     mtctr   r0
  408.     b       .bentry2
  409. .bloop2:
  410.     lwzu    r8,4(r3)
  411.     lwzu    r10,4(r4)
  412. .bentry2:
  413.     subf    r12,r10,r8
  414.     int2dbl f3,r12,r6,local,f1
  415.     fmadds  f3,f3,f6,f2
  416.     fctiwz  f0,f3
  417.     stfd    f0,-8(r1)
  418.     lwz     r12,-4(r1)
  419.     add     r12,r12,r10
  420.     stwu    r12,4(r5)
  421.     bdnz    .bloop2
  422. .bexit:
  423.     lwz     r3,-20(r5)
  424.     lwz     r4,-16(r5)
  425.     stw     r4,-20(r5)
  426.     stw     r3,-16(r5)
  427.     exit
  428.  
  429.     funcend    R_Alias_clip_bottom
  430.  
  431.  
  432.  
  433.  
  434. ###########################################################################
  435. #
  436. #       int R_AliasClip  (finalvert_t *in, finalvert_t *out, int flag,
  437. #                          int count, void(*clip)(...)
  438. #
  439. ###########################################################################
  440.  
  441.     funcdef    R_AliasClip
  442.  
  443.     init    0,0,13,0
  444.     stmw    r19,gb(r1)
  445.  
  446. #        j = count-1;
  447. #        k = 0;
  448. #        for (i=0 ; i<count ; j = i, i++)
  449. #        {
  450.  
  451.     mr      r20,r6
  452.     subic.  r8,r6,1
  453.     blt     .acskip
  454.     slwi    r8,r8,FV_SIZEOF_EXP
  455.     add     r31,r3,r8               #r31 = in[j]
  456.     lxa     r10,r_refdef
  457.     lwz     r30,REFDEF_ALIASVRECT+VRECT_X(r10)
  458.     lwz     r29,REFDEF_ALIASVRECT+VRECT_Y(r10)
  459.     lwz     r28,REFDEF_ALIASVRECTRIGHT(r10)
  460.     lwz     r27,REFDEF_ALIASVRECTBOTTOM(r10)
  461.     mr      r26,r3
  462.     mr      r25,r3
  463.     mr      r24,r5
  464.     mr      r22,r7
  465.     mr      r21,r4
  466.     mr      r19,r4
  467.  
  468. #                oldflags = in[j].flags & flag;
  469. #                flags = in[i].flags & flag;
  470. #                if (flags && oldflags)
  471. #                        continue;
  472.  
  473. .acloop:
  474.     lwz     r0,FV_FLAGS(r31)
  475.     and     r0,r0,r24
  476.     lwz     r23,FV_FLAGS(r25)
  477.     and.    r23,r23,r24
  478.     beq     .acdo
  479.     mr.     r0,r0
  480.     bne     .acnext
  481. .acdo:
  482.  
  483. #                if (oldflags ^ flags)
  484. #                {
  485. #                        clip (&in[j], &in[i], &out[k]);
  486. #                        out[k].flags = 0;
  487. #                        if (out[k].v[0] < r_refdef.aliasvrect.x)
  488. #                                out[k].flags |= ALIAS_LEFT_CLIP;
  489. #                        if (out[k].v[1] < r_refdef.aliasvrect.y)
  490. #                                out[k].flags |= ALIAS_TOP_CLIP;
  491. #                        if (out[k].v[0] > r_refdef.aliasvrectright)
  492. #                                out[k].flags |= ALIAS_RIGHT_CLIP;
  493. #                        if (out[k].v[1] > r_refdef.aliasvrectbottom)
  494. #                                out[k].flags |= ALIAS_BOTTOM_CLIP;
  495. #                        k++;
  496. #                }
  497.  
  498.     xor.    r0,r0,r23
  499.     beq     .accont
  500.     mtlr    r22
  501.     mr      r3,r31
  502.     mr      r4,r25
  503.     mr      r5,r21
  504.     blrl
  505.     li      r3,0
  506.     lwz     r0,0(r21)
  507.     cmpw    r0,r30
  508.     bge     .ac1
  509.     ori     r3,r3,ALIAS_LEFT_CLIP
  510. .ac1:
  511.     cmpw    r0,r28
  512.     ble     .ac2
  513.     ori     r3,r3,ALIAS_RIGHT_CLIP
  514. .ac2:
  515.     lwz     r0,4(r21)
  516.     cmpw    r0,r29
  517.     bge     .ac3
  518.     ori     r3,r3,ALIAS_TOP_CLIP
  519. .ac3:
  520.     cmpw    r0,r27
  521.     ble     .ac4
  522.     ori     r3,r3,ALIAS_BOTTOM_CLIP
  523. .ac4:
  524.     stw     r3,FV_FLAGS(r21)
  525.     la      r21,FV_SIZEOF(r21)
  526.  
  527. #                if (!flags)
  528. #                {
  529. #                        out[k] = in[i];
  530. #                        k++;
  531. #                }
  532.  
  533. .accont:
  534.     mr.     r23,r23
  535.     bne     .acnext
  536.     lwz     r0,0(r25)
  537.     stw     r0,0(r21)
  538.     lwz     r3,4(r25)
  539.     stw     r3,4(r21)
  540.     lwz     r0,8(r25)
  541.     stw     r0,8(r21)
  542.     lwz     r3,12(r25)
  543.     stw     r3,12(r21)
  544.     lwz     r0,16(r25)
  545.     stw     r0,16(r21)
  546.     lwz     r3,20(r25)
  547.     stw     r3,20(r21)
  548.     lwz     r0,24(r25)
  549.     stw     r0,24(r21)
  550.     la      r21,FV_SIZEOF(r21)
  551. .acnext:
  552.     mr      r31,r26
  553.     la      r26,FV_SIZEOF(r26)
  554.     la      r25,FV_SIZEOF(r25)
  555.     subic.  r20,r20,1
  556.     bne     .acloop
  557.  
  558. #        return k;
  559.  
  560. .acskip:
  561.     subf    r3,r19,r21
  562.     srawi   r3,r3,FV_SIZEOF_EXP
  563.  
  564.     lmw    r19,gb(r1)
  565.     exit
  566.  
  567.     funcend    R_AliasClip
  568.