home *** CD-ROM | disk | FTP | other *** search
/ Enigma Amiga Life 113 / EnigmaAmiga113CD.iso / software / sviluppo / quakeworld_src / client / r_aclip68k.s < prev    next >
Encoding:
Text File  |  2000-06-17  |  12.5 KB  |  596 lines
  1. * 
  2. * Copyright (C) 1996-1997 Id Software, Inc. 
  3. * 
  4. * This program is free software; you can redistribute it and/or 
  5. * modify it under the terms of the GNU General Public License 
  6. * as published by the Free Software Foundation; either version 2 
  7. * of the License, or (at your option) any later version. 
  8. * 
  9. * This program is distributed in the hope that it will be useful, 
  10. * but WITHOUT ANY WARRANTY; without even the implied warranty of 
  11. * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.   
  12. * 
  13. * See the GNU General Public License for more details. 
  14. * 
  15. * You should have received a copy of the GNU General Public License 
  16. * along with this program; if not, write to the Free Software 
  17. * Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA  02111-1307, USA. 
  18. * 
  19.  
  20. **
  21. ** Quake for AMIGA
  22. ** r_aclip.c assembler implementations by Frank Wille <frank@phoenix.owl.de>
  23. **
  24.  
  25.         XREF    _r_refdef
  26.  
  27.         XDEF    _R_Alias_clip_left
  28.         XDEF    _R_Alias_clip_right
  29.         XDEF    _R_Alias_clip_top
  30.         XDEF    _R_Alias_clip_bottom
  31.         XDEF    _R_AliasClip
  32.  
  33. ALIAS_LEFT_CLIP         =       1
  34. ALIAS_TOP_CLIP          =       2
  35. ALIAS_RIGHT_CLIP        =       4
  36. ALIAS_BOTTOM_CLIP       =       8
  37.  
  38. FV_V                    =       0
  39. FV_FLAGS                =       24
  40. FV_RESERVED             =       28
  41. FV_SIZEOF               =       32
  42. FV_SIZEOF_EXP           =       5
  43.  
  44. REFDEF_VRECT            =       0
  45. REFDEF_ALIASVRECT       =       20
  46. REFDEF_VRECTRIGHT       =       40
  47. REFDEF_VRECTBOTTOM      =       44
  48. REFDEF_ALIASVRECTRIGHT  =       48
  49. REFDEF_ALIASVRECTBOTTOM =       52
  50.  
  51. VRECT_X                 =       0
  52. VRECT_Y                 =       4
  53. VRECT_WIDTH             =       8
  54. VRECT_HEIGHT            =       12
  55. VRECT_PNEXT             =       16
  56.  
  57.         fpu
  58.  
  59.  
  60.  
  61.  
  62. ******************************************************************************
  63. *
  64. *       void _R_Alias_clip_left (finalvert_t *pfv0, finalvert_t *pfv1,
  65. *                                finalvert_t *out)
  66. *
  67. ******************************************************************************
  68.  
  69.         cnop    0,4
  70. _R_Alias_clip_left
  71.  
  72. *****   stackframe
  73.  
  74.         rsreset
  75. .fpuregs        rs.x    2
  76. .intregs        rs.l    5
  77.         rs.l    1
  78. .pfv0           rs.l    1
  79. .pfv1           rs.l    1
  80. .out            rs.l    1
  81.  
  82.  
  83.         movem.l d2-d4/a2/a3,-(sp)
  84.         fmovem.x        fp2/fp3,-(sp)
  85.         move.l  .pfv0(sp),a0
  86.         move.l  .pfv1(sp),a1
  87.         move.l  .out(sp),a2
  88.         lea     _r_refdef,a3
  89.         fmove.s #0.5,fp2
  90.         move.l  (a0)+,d2
  91.         move.l  (a0)+,d3
  92.         move.l  (a1)+,d0
  93.         move.l  (a1)+,d1
  94.         move.l  REFDEF_ALIASVRECT+VRECT_X(a3),d4
  95.         cmp.l   d1,d3
  96.         blt.b   .cont
  97.         sub.l   d2,d4
  98.         fmove.l d4,fp0
  99.         fmove   fp0,fp3
  100.         fadd    fp2,fp3
  101.         move.l  d0,d4
  102.         sub.l   d2,d4
  103.         fmove.l d4,fp1
  104.         fdiv    fp1,fp0
  105.         fmove.l fp3,d0
  106.         add.l   d2,d0
  107.         move.l  d0,(a2)+
  108.         moveq   #5-1,d2
  109.         bra.b   .entry
  110. .loop
  111.         move.l  (a0)+,d3
  112.         move.l  (a1)+,d1
  113. .entry
  114.         sub.l   d3,d1
  115.         fmove.l d1,fp1
  116.         fmul    fp0,fp1
  117.         fadd    fp2,fp1
  118.         fmove.l fp1,d1
  119.         add.l   d3,d1
  120.         move.l  d1,(a2)+
  121.         dbra    d2,.loop
  122.         bra.b   .exit
  123. .cont
  124.         sub.l   d0,d4
  125.         fmove.l d4,fp0
  126.         fmove   fp0,fp3
  127.         fadd    fp2,fp3
  128.         move.l  d2,d4
  129.         sub.l   d0,d4
  130.         fmove.l d4,fp1
  131.         fdiv    fp1,fp0
  132.         fmove.l fp3,d2
  133.         add.l   d0,d2
  134.         move.l  d2,(a2)+
  135.         moveq   #5-1,d2
  136.         bra.b   .entry2
  137. .loop2
  138.         move.l  (a0)+,d3
  139.         move.l  (a1)+,d1
  140. .entry2
  141.         sub.l   d1,d3
  142.         fmove.l d3,fp1
  143.         fmul    fp0,fp1
  144.         fadd    fp2,fp1
  145.         fmove.l fp1,d3
  146.         add.l   d1,d3
  147.         move.l  d3,(a2)+
  148.         dbra    d2,.loop2
  149. .exit
  150.         fmovem.x        (sp)+,fp2/fp3
  151.         movem.l (sp)+,d2-d4/a2/a3
  152.         rts
  153.  
  154.  
  155.  
  156.  
  157.  
  158.  
  159. ******************************************************************************
  160. *
  161. *       void _R_Alias_clip_right (finalvert_t *pfv0, finalvert_t *pfv1,
  162. *                                 finalvert_t *out)
  163. *
  164. ******************************************************************************
  165.  
  166.         cnop    0,4
  167. _R_Alias_clip_right
  168.  
  169. *****   stackframe
  170.  
  171.         rsreset
  172. .fpuregs        rs.x    2
  173. .intregs        rs.l    5
  174.         rs.l    1
  175. .pfv0           rs.l    1
  176. .pfv1           rs.l    1
  177. .out            rs.l    1
  178.  
  179.  
  180.         movem.l d2-d4/a2/a3,-(sp)
  181.         fmovem.x        fp2/fp3,-(sp)
  182.         move.l  .pfv0(sp),a0
  183.         move.l  .pfv1(sp),a1
  184.         move.l  .out(sp),a2
  185.         lea     _r_refdef,a3
  186.         fmove.s #0.5,fp2
  187.         move.l  (a0)+,d2
  188.         move.l  (a0)+,d3
  189.         move.l  (a1)+,d0
  190.         move.l  (a1)+,d1
  191.         move.l  REFDEF_ALIASVRECTRIGHT(a3),d4
  192.         cmp.l   d1,d3
  193.         blt.b   .cont
  194.         sub.l   d2,d4
  195.         fmove.l d4,fp0
  196.         fmove   fp0,fp3
  197.         fadd    fp2,fp3
  198.         move.l  d0,d4
  199.         sub.l   d2,d4
  200.         fmove.l d4,fp1
  201.         fdiv    fp1,fp0
  202.         fmove.l fp3,d0
  203.         add.l   d2,d0
  204.         move.l  d0,(a2)+
  205.         moveq   #5-1,d2
  206.         bra.b   .entry
  207. .loop
  208.         move.l  (a0)+,d3
  209.         move.l  (a1)+,d1
  210. .entry
  211.         sub.l   d3,d1
  212.         fmove.l d1,fp1
  213.         fmul    fp0,fp1
  214.         fadd    fp2,fp1
  215.         fmove.l fp1,d1
  216.         add.l   d3,d1
  217.         move.l  d1,(a2)+
  218.         dbra    d2,.loop
  219.         bra.b   .exit
  220. .cont
  221.         sub.l   d0,d4
  222.         fmove.l d4,fp0
  223.         fmove   fp0,fp3
  224.         fadd    fp2,fp3
  225.         move.l  d2,d4
  226.         sub.l   d0,d4
  227.         fmove.l d4,fp1
  228.         fdiv    fp1,fp0
  229.         fmove.l fp3,d2
  230.         add.l   d0,d2
  231.         move.l  d2,(a2)+
  232.         moveq   #5-1,d2
  233.         bra.b   .entry2
  234. .loop2
  235.         move.l  (a0)+,d3
  236.         move.l  (a1)+,d1
  237. .entry2
  238.         sub.l   d1,d3
  239.         fmove.l d3,fp1
  240.         fmul    fp0,fp1
  241.         fadd    fp2,fp1
  242.         fmove.l fp1,d3
  243.         add.l   d1,d3
  244.         move.l  d3,(a2)+
  245.         dbra    d2,.loop2
  246. .exit
  247.         fmovem.x        (sp)+,fp2/fp3
  248.         movem.l (sp)+,d2-d4/a2/a3
  249.         rts
  250.  
  251.  
  252.  
  253.  
  254.  
  255.  
  256.  
  257. ******************************************************************************
  258. *
  259. *       void _R_Alias_clip_top (finalvert_t *pfv0, finalvert_t *pfv1,
  260. *                               finalvert_t *out)
  261. *
  262. ******************************************************************************
  263.  
  264.         cnop    0,4
  265. _R_Alias_clip_top
  266.  
  267. *****   stackframe
  268.  
  269.         rsreset
  270. .fpuregs        rs.x    2
  271. .intregs        rs.l    5
  272.         rs.l    1
  273. .pfv0           rs.l    1
  274. .pfv1           rs.l    1
  275. .out            rs.l    1
  276.  
  277.  
  278.         movem.l d2-d4/a2/a3,-(sp)
  279.         fmovem.x        fp2/fp3,-(sp)
  280.         move.l  .pfv0(sp),a0
  281.         move.l  .pfv1(sp),a1
  282.         move.l  .out(sp),a2
  283.         lea     _r_refdef,a3
  284.         fmove.s #0.5,fp2
  285.         move.l  (a0)+,d2
  286.         move.l  (a0)+,d3
  287.         move.l  (a1)+,d0
  288.         move.l  (a1)+,d1
  289.         move.l  REFDEF_ALIASVRECT+VRECT_Y(a3),d4
  290.         cmp.l   d1,d3
  291.         blt.b   .cont
  292.         sub.l   d3,d4
  293.         fmove.l d4,fp0
  294.         fmove   fp0,fp3
  295.         fadd    fp2,fp3
  296.         move.l  d1,d4
  297.         sub.l   d3,d4
  298.         fmove.l d4,fp1
  299.         fdiv    fp1,fp0
  300.         fmove.l fp3,d1
  301.         add.l   d3,d1
  302.         move.l  d1,(a2)+
  303.         moveq   #5-1,d3
  304.         bra.b   .entry
  305. .loop
  306.         move.l  (a0)+,d2
  307.         move.l  (a1)+,d0
  308. .entry
  309.         sub.l   d2,d0
  310.         fmove.l d0,fp1
  311.         fmul    fp0,fp1
  312.         fadd    fp2,fp1
  313.         fmove.l fp1,d0
  314.         add.l   d2,d0
  315.         move.l  d0,(a2)+
  316.         dbra    d3,.loop
  317.         bra.b   .exit
  318. .cont
  319.         sub.l   d1,d4
  320.         fmove.l d4,fp0
  321.         fmove   fp0,fp3
  322.         fadd    fp2,fp3
  323.         move.l  d3,d4
  324.         sub.l   d1,d4
  325.         fmove.l d4,fp1
  326.         fdiv    fp1,fp0
  327.         fmove.l fp3,d3
  328.         add.l   d1,d3
  329.         move.l  d3,(a2)+
  330.         moveq   #5-1,d3
  331.         bra.b   .entry2
  332. .loop2
  333.         move.l  (a0)+,d2
  334.         move.l  (a1)+,d0
  335. .entry2
  336.         sub.l   d0,d2
  337.         fmove.l d2,fp1
  338.         fmul    fp0,fp1
  339.         fadd    fp2,fp1
  340.         fmove.l fp1,d2
  341.         add.l   d0,d2
  342.         move.l  d2,(a2)+
  343.         dbra    d3,.loop2
  344. .exit
  345.         move.l  -24(a2),d0
  346.         move.l  -20(a2),-24(a2)
  347.         move.l  d0,-20(a2)
  348.         fmovem.x        (sp)+,fp2/fp3
  349.         movem.l (sp)+,d2-d4/a2/a3
  350.         rts
  351.  
  352.  
  353.  
  354.  
  355.  
  356.  
  357. ******************************************************************************
  358. *
  359. *       void _R_Alias_clip_bottom (finalvert_t *pfv0, finalvert_t *pfv1,
  360. *                                  finalvert_t *out)
  361. *
  362. ******************************************************************************
  363.  
  364.         cnop    0,4
  365. _R_Alias_clip_bottom
  366.  
  367. *****   stackframe
  368.  
  369.         rsreset
  370. .fpuregs        rs.x    2
  371. .intregs        rs.l    5
  372.         rs.l    1
  373. .pfv0           rs.l    1
  374. .pfv1           rs.l    1
  375. .out            rs.l    1
  376.  
  377.  
  378.         movem.l d2-d4/a2/a3,-(sp)
  379.         fmovem.x        fp2/fp3,-(sp)
  380.         move.l  .pfv0(sp),a0
  381.         move.l  .pfv1(sp),a1
  382.         move.l  .out(sp),a2
  383.         lea     _r_refdef,a3
  384.         fmove.s #0.5,fp2
  385.         move.l  (a0)+,d2
  386.         move.l  (a0)+,d3
  387.         move.l  (a1)+,d0
  388.         move.l  (a1)+,d1
  389.         move.l  REFDEF_ALIASVRECTBOTTOM(a3),d4
  390.         cmp.l   d1,d3
  391.         blt.b   .cont
  392.         sub.l   d3,d4
  393.         fmove.l d4,fp0
  394.         fmove   fp0,fp3
  395.         fadd    fp2,fp3
  396.         move.l  d1,d4
  397.         sub.l   d3,d4
  398.         fmove.l d4,fp1
  399.         fdiv    fp1,fp0
  400.         fmove.l fp3,d1
  401.         add.l   d3,d1
  402.         move.l  d1,(a2)+
  403.         moveq   #5-1,d3
  404.         bra.b   .entry
  405. .loop
  406.         move.l  (a0)+,d2
  407.         move.l  (a1)+,d0
  408. .entry
  409.         sub.l   d2,d0
  410.         fmove.l d0,fp1
  411.         fmul    fp0,fp1
  412.         fadd    fp2,fp1
  413.         fmove.l fp1,d0
  414.         add.l   d2,d0
  415.         move.l  d0,(a2)+
  416.         dbra    d3,.loop
  417.         bra.b   .exit
  418. .cont
  419.         sub.l   d1,d4
  420.         fmove.l d4,fp0
  421.         fmove   fp0,fp3
  422.         fadd    fp2,fp3
  423.         move.l  d3,d4
  424.         sub.l   d1,d4
  425.         fmove.l d4,fp1
  426.         fdiv    fp1,fp0
  427.         fmove.l fp3,d3
  428.         add.l   d1,d3
  429.         move.l  d3,(a2)+
  430.         moveq   #5-1,d3
  431.         bra.b   .entry2
  432. .loop2
  433.         move.l  (a0)+,d2
  434.         move.l  (a1)+,d0
  435. .entry2
  436.         sub.l   d0,d2
  437.         fmove.l d2,fp1
  438.         fmul    fp0,fp1
  439.         fadd    fp2,fp1
  440.         fmove.l fp1,d2
  441.         add.l   d0,d2
  442.         move.l  d2,(a2)+
  443.         dbra    d3,.loop2
  444. .exit
  445.         move.l  -24(a2),d0
  446.         move.l  -20(a2),-24(a2)
  447.         move.l  d0,-20(a2)
  448.         fmovem.x        (sp)+,fp2/fp3
  449.         movem.l (sp)+,d2-d4/a2/a3
  450.         rts
  451.  
  452.  
  453.  
  454.  
  455.  
  456. ******************************************************************************
  457. *
  458. *       int _R_AliasClip  (finalvert_t *in, finalvert_t *out, int flag,
  459. *                          int count, void(*clip)(...)
  460. *
  461. ******************************************************************************
  462.  
  463.         cnop    0,4
  464. _R_AliasClip
  465.  
  466. *****   stackframe
  467.  
  468.         rsreset
  469. .intregs        rs.l    11
  470.         rs.l    1
  471. .in             rs.l    1
  472. .out            rs.l    1
  473. .flag           rs.l    1
  474. .count          rs.l    1
  475. .clip           rs.l    1
  476.  
  477.  
  478.         movem.l d2-d7/a2-a6,-(sp)
  479.         move.l  .in(sp),a2
  480.         move.l  .out(sp),a3
  481.         move.l  .flag(sp),d2
  482.         move.l  .count(sp),d3
  483.         move.l  .clip(sp),a4
  484.  
  485. *        j = count-1;
  486. *        k = 0;
  487. *        for (i=0 ; i<count ; j = i, i++)
  488. *        {
  489.  
  490.         move.l  d3,d5
  491.         subq.l  #1,d5
  492.         bmi.w   .skip
  493.         move.l  d5,d0                   ;j = count-1
  494.         asl.l   #FV_SIZEOF_EXP,d0
  495.         lea     0(a2,d0.l),a6           ;a6 = in[j]
  496.         lea     _r_refdef,a5
  497.         move.l  REFDEF_ALIASVRECT+VRECT_X(a5),d3
  498.         move.l  REFDEF_ALIASVRECT+VRECT_Y(a5),d4
  499.         move.l  REFDEF_ALIASVRECTRIGHT(a5),d6
  500.         move.l  REFDEF_ALIASVRECTBOTTOM(a5),d7
  501.         move.l  a2,a5
  502.  
  503. *                oldflags = in[j].flags & flag;
  504. *                flags = in[i].flags & flag;
  505. *                if (flags && oldflags)
  506. *                        continue;
  507.  
  508. .loop
  509.         move.l  FV_FLAGS(a6),d0
  510.         and.l   d2,d0                   ;oldflags = in[j].flags & flag
  511.         move.l  FV_FLAGS(a2),d1
  512.         and.l   d2,d1                   ;flags = in[i].flags & flag
  513.         beq.b   .do
  514.         tst.l   d0
  515.         bne.w   .next
  516. .do
  517.  
  518. *                if (oldflags ^ flags)
  519. *                {
  520. *                        clip (&in[j], &in[i], &out[k]);
  521. *                        out[k].flags = 0;
  522. *                        if (out[k].v[0] < r_refdef.aliasvrect.x)
  523. *                                out[k].flags |= ALIAS_LEFT_CLIP;
  524. *                        if (out[k].v[1] < r_refdef.aliasvrect.y)
  525. *                                out[k].flags |= ALIAS_TOP_CLIP;
  526. *                        if (out[k].v[0] > r_refdef.aliasvrectright)
  527. *                                out[k].flags |= ALIAS_RIGHT_CLIP;
  528. *                        if (out[k].v[1] > r_refdef.aliasvrectbottom)
  529. *                                out[k].flags |= ALIAS_BOTTOM_CLIP;
  530. *                        k++;
  531. *                }
  532.  
  533.         eor.l   d1,d0                   ;if (oldflags ^ flags)
  534.         beq.b   .cont
  535.         move.l  d1,-(sp)
  536.         move.l  a3,-(sp)
  537.         move.l  a2,-(sp)
  538.         move.l  a6,-(sp)
  539.         jsr     (a4)                    ;clip (&in[j], &in[i], &out[k])
  540.         add     #12,sp
  541.         moveq   #0,d1                   ;out[k].flags = 0
  542.         move.l  (a3),d0                 ;if (out[k].v[0] < ...
  543.         cmp.l   d3,d0
  544.         bge.b   .1
  545.         or.l    #ALIAS_LEFT_CLIP,d1     ;out[k].flags |= ALIAS_LEFT_CLIP
  546. .1
  547.         cmp.l   d6,d0                   ;if (out[k].v[0] > ...
  548.         ble.b   .2
  549.         or.l    #ALIAS_RIGHT_CLIP,d1    ;out[k].flags |= ALIAS_RIGHT_CLIP
  550. .2
  551.         move.l  4(a3),d0                ;if (out[k].v[1] < ...
  552.         cmp.l   d4,d0
  553.         bge.b   .3
  554.         or.l    #ALIAS_TOP_CLIP,d1      ;out[k].flags |= ALIAS_TOP_CLIP
  555. .3
  556.         cmp.l   d7,d0                   ;if (out[k].v[1] > ...
  557.         ble.b   .4
  558.         or.l    #ALIAS_BOTTOM_CLIP,d1   ;out[k].flags |= ALIAS_BOTTOM_CLIP
  559. .4
  560.         move.l  d1,FV_FLAGS(a3)
  561.         lea     FV_SIZEOF(a3),a3        ;k++
  562.         move.l  (sp)+,d1
  563.  
  564. *                if (!flags)
  565. *                {
  566. *                        out[k] = in[i];
  567. *                        k++;
  568. *                }
  569.  
  570. .cont
  571.         tst.l   d1                      ;if (!flags)
  572.         bne.b   .next
  573.         move.l  (a2)+,(a3)+             ;out[k] = in[i]
  574.         move.l  (a2)+,(a3)+
  575.         move.l  (a2)+,(a3)+
  576.         move.l  (a2)+,(a3)+
  577.         move.l  (a2)+,(a3)+
  578.         move.l  (a2)+,(a3)+
  579.         move.l  (a2)+,(a3)+
  580.         addq    #4,a3
  581.         sub     #28,a2
  582. .next
  583.         move.l  a5,a6
  584.         lea     FV_SIZEOF(a5),a5
  585.         lea     FV_SIZEOF(a2),a2
  586.         dbra    d5,.loop
  587.  
  588. *        return k;
  589.  
  590. .skip
  591.         move.l  a3,d0
  592.         sub.l   .out(sp),d0
  593.         asr.l   #FV_SIZEOF_EXP,d0
  594.         movem.l (sp)+,d2-d7/a2-a6
  595.         rts
  596.