home *** CD-ROM | disk | FTP | other *** search
/ Enigma Amiga Life 113 / EnigmaAmiga113CD.iso / software / sviluppo / quakeworld_src / client / d_edgeppc.s < prev    next >
Encoding:
Text File  |  2000-06-17  |  21.8 KB  |  986 lines
  1. # 
  2. # Copyright (C) 1996-1997 Id Software, Inc. 
  3. # 
  4. # This program is free software; you can redistribute it and/or 
  5. # modify it under the terms of the GNU General Public License 
  6. # as published by the Free Software Foundation; either version 2 
  7. # of the License, or (at your option) any later version. 
  8. # 
  9. # This program is distributed in the hope that it will be useful, 
  10. # but WITHOUT ANY WARRANTY; without even the implied warranty of 
  11. # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.   
  12. # 
  13. # See the GNU General Public License for more details. 
  14. # 
  15. # You should have received a copy of the GNU General Public License 
  16. # along with this program; if not, write to the Free Software 
  17. # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA  02111-1307, USA. 
  18. # 
  19.  
  20. ##
  21. ## Quake for AMIGA
  22. ##
  23. ## d_edgePPC.s
  24. ##
  25. ## Define WOS for PowerOpen ABI, otherwise SVR4-ABI is used.
  26. ##
  27.  
  28. .include        "macrosPPC.i"
  29.  
  30. #
  31. # external references
  32. #
  33.  
  34.     xrefa    vright
  35.     xrefa    vup
  36.     xrefa    vpn
  37.     xrefv    xscaleinv
  38.     xrefv    yscaleinv
  39.     xrefv    xcenter
  40.     xrefv    ycenter
  41.     xrefv    d_zistepu
  42.     xrefv    d_zistepv
  43.     xrefv    d_ziorigin
  44.     xrefv    d_sdivzstepu
  45.     xrefv    d_tdivzstepu
  46.     xrefv    d_sdivzstepv
  47.     xrefv    d_tdivzstepv
  48.     xrefv    d_sdivzorigin
  49.     xrefv    d_tdivzorigin
  50.     xrefv    sadjust
  51.     xrefv    tadjust
  52.     xrefv    bbextents
  53.     xrefv    bbextentt
  54.     xrefa    transformed_modelorg
  55.     xrefv    miplevel
  56.     xrefa    r_worldentity
  57.     xrefv    currententity
  58.     xrefa    r_drawflat
  59.     xrefv    surfaces
  60.     xrefv    surface_p
  61.     xrefv    r_drawnpolycount
  62.     xrefv    r_skymade
  63.     xrefa    r_clearcolor
  64.     xrefv    cacheblock
  65.     xrefv    cachewidth
  66.     xrefa    r_origin
  67.     xrefa    base_vpn
  68.     xrefa    base_vup
  69.     xrefa    base_vright
  70.     xrefa    base_modelorg
  71.     xrefv    d_drawspans
  72.     xrefv    scale_for_mip
  73.     xrefa    d_scalemip
  74.     xrefv    d_minmip
  75.     xrefa    modelorg
  76.     xrefa    screenedge
  77.     xrefa    view_clipplanes
  78.  
  79.     xrefv    D_DrawSolidSurface
  80.     xrefv    D_DrawZSpans
  81.     xrefv    R_MakeSky
  82.     xrefv    D_DrawSkyScans8
  83.     xrefv    D_DrawZSpans
  84.     xrefv    Turbulent8
  85.     xrefv    R_RotateBmodel
  86.     xrefv    D_CacheSurface
  87.  
  88.     xrefv    c0
  89.     xrefv    c0_5
  90.     xrefv    c65536
  91.  
  92.  
  93. #
  94. # defines
  95. #
  96.  
  97. .set    SURF_DRAWSKY        ,4
  98. .set    SURF_DRAWTURB       ,0x10
  99. .set    SURF_DRAWBACKGROUND ,0x40
  100.  
  101. .set    MSURFACE_VISFRAME   ,0
  102. .set    MSURFACE_DLIGHTFRAME,4
  103. .set    MSURFACE_DLIGHTBITS ,8
  104. .set    MSURFACE_PLANE      ,12
  105. .set    MSURFACE_FLAGS      ,16
  106. .set    MSURFACE_FIRSTEDGE  ,20
  107. .set    MSURFACE_NUMEDGES   ,24
  108. .set    MSURFACE_CACHESPOTS ,28
  109. .set    MSURFACE_TEXTUREMINS,44
  110. .set    MSURFACE_EXTENTS    ,48
  111. .set    MSURFACE_TEXINFO    ,52
  112. .set    MSURFACE_STYLES     ,56
  113. .set    MSURFACE_SAMPLES    ,60
  114. .set    MSURFACE_SIZEOF_EXP ,6
  115. .set    MSURFACE_SIZEOF     ,(1<<MSURFACE_SIZEOF_EXP)
  116.  
  117. .set    SURF_NEXT           ,0
  118. .set    SURF_PREV           ,4
  119. .set    SURF_SPANS          ,8
  120. .set    SURF_KEY            ,12
  121. .set    SURF_LAST_U         ,16
  122. .set    SURF_SPANSTATE      ,20
  123. .set    SURF_FLAGS          ,24
  124. .set    SURF_DATA           ,28
  125. .set    SURF_ENTITY         ,32
  126. .set    SURF_NEARZI         ,36
  127. .set    SURF_INSUBMODEL     ,40
  128. .set    SURF_D_ZIORIGIN     ,44
  129. .set    SURF_D_ZISTEPU      ,48
  130. .set    SURF_D_ZISTEPV      ,52
  131. .set    SURF_SIZEOF_EXP     ,6
  132. .set    SURF_SIZEOF         ,(1<<SURF_SIZEOF_EXP)
  133.  
  134. .set    MPLANE_NORMAL       ,0
  135. .set    MPLANE_DIST         ,12
  136. .set    MPLANE_TYPE         ,16
  137. .set    MPLANE_SIGNBITS     ,17
  138. .set    MPLANE_SIZEOF       ,20
  139.  
  140. .set    MTEXINFO_VECS       ,0
  141. .set    MTEXINFO_MIPADJUST  ,32
  142. .set    MTEXINFO_TEXTURE    ,36
  143. .set    MTEXINFO_FLAGS      ,40
  144. .set    MTEXINFO_SIZEOF     ,44
  145.  
  146. .set    CLIP_NORMAL         ,0
  147. .set    CLIP_DIST           ,12
  148. .set    CLIP_NEXT           ,16
  149. .set    CLIP_LEFTEDGE       ,20
  150. .set    CLIP_RIGHTEDGE      ,21
  151. .set    CLIP_RESERVED       ,22
  152. .set    CLIP_SIZEOF         ,24
  153.  
  154. .set    SURFCACHE_DATA      ,48
  155. .set    SURFCACHE_WIDTH     ,32
  156.  
  157. .set    TEXTURE_OFFSETS     ,44
  158.  
  159. .set    ENTITY_ORIGIN       ,4
  160.  
  161. .set    CVAR_VALUE          ,16
  162.  
  163.  
  164.  
  165.  
  166.  
  167. ###########################################################################
  168. #
  169. #       void _D_CalcGradients (msurface_t *pface)
  170. #
  171. ###########################################################################
  172.  
  173.     funcdef    D_CalcGradients
  174.  
  175.     init    0,24,0,9
  176.     stfd    f14,fb+0*8(r1)
  177.     stfd    f15,fb+1*8(r1)
  178.     stfd    f16,fb+2*8(r1)
  179.     stfd    f17,fb+3*8(r1)
  180.     stfd    f18,fb+4*8(r1)
  181.     stfd    f19,fb+5*8(r1)
  182.     stfd    f20,fb+6*8(r1)
  183.     stfd    f22,fb+8*8(r1)
  184.  
  185.     lwz     r4,MSURFACE_TEXINFO(r3)
  186.     la      r5,16(r4)
  187.     lxa     r6,vright
  188.     lxa     r7,vup
  189.     lxa     r8,vpn
  190.     lfs     f1,0(r6)
  191.     lfs     f10,0(r4)
  192.     fmuls   f0,f10,f1
  193.     lfs     f2,4(r6)
  194.     lfs     f11,4(r4)
  195.     fmadds  f0,f11,f2,f0
  196.     lfs     f3,8(r6)
  197.     lfs     f12,8(r4)
  198.     fmadds  f0,f12,f3,f0            #f0 = p_saxis[0]
  199.     lfs     f4,0(r7)
  200.     fmuls   f13,f10,f4
  201.     lfs     f5,4(r7)
  202.     fmadds  f13,f11,f5,f13
  203.     lfs     f6,8(r7)
  204.     fmadds  f13,f12,f6,f13          #f13 = p_saxis[1]
  205.     lfs     f7,0(r8)
  206.     fmuls   f14,f10,f7
  207.     lfs     f8,4(r8)
  208.     fmadds  f14,f11,f8,f14
  209.     lfs     f9,8(r8)
  210.     fmadds  f14,f12,f9,f14          #f14 = p_saxis[2]
  211.  
  212.     lfs     f15,0(r5)
  213.     fmuls   f18,f15,f1
  214.     lw      r9,miplevel
  215.     fmuls   f19,f15,f4
  216.     slwi    r0,r9,23
  217.     fmuls   f20,f15,f7
  218.     lfs     f16,4(r5)
  219.     fmadds  f18,f16,f2,f18
  220.     lis     r11,0x3f800000@h
  221.     ori     r11,r11,0x3f800000@l
  222.     fmadds  f19,f16,f5,f19
  223.     subf    r0,r0,r11
  224.     fmadds  f20,f16,f8,f20
  225.     lfs     f17,8(r5)
  226.     fmadds  f18,f17,f3,f18          #f18 = p_taxis[0]
  227.     stw     r0,local(r1)
  228.     fmadds  f19,f17,f6,f19          #f19 = p_taxis[1]
  229.     lfs     f22,local(r1)           #f22 = mipscale
  230.     fmadds  f20,f17,f9,f20          #f20 = p_taxis[2]
  231.  
  232.     ls      f1,xscaleinv
  233.     ls      f5,yscaleinv
  234.     fmuls   f1,f1,f22
  235.     fmuls   f5,f5,f22
  236.     fmuls   f2,f1,f0
  237.     fmuls   f6,f5,f13
  238.     ss      f2,d_sdivzstepu
  239.     fneg    f6,f6
  240.     ss      f6,d_sdivzstepv
  241.     fmuls   f3,f1,f18
  242.     fmuls   f7,f5,f19
  243.     ss      f3,d_tdivzstepu
  244.     fneg    f7,f7
  245.     ss      f7,d_tdivzstepv
  246.     ls      f4,xcenter
  247.     ls      f8,ycenter
  248.     fmuls   f2,f2,f4
  249.     lxa     r11,transformed_modelorg
  250.     fmadds  f6,f6,f8,f2
  251.     fmuls   f3,f3,f4
  252.     fmadds  f7,f7,f8,f3
  253.     fmsubs  f2,f14,f22,f6
  254.     ss      f2,d_sdivzorigin
  255.     fmsubs  f3,f20,f22,f7
  256.     ss      f3,d_tdivzorigin
  257.  
  258.     lfs     f1,0(r11)
  259.     lfs     f2,4(r11)
  260.     lfs     f3,8(r11)
  261.  
  262.     fmuls   f4,f1,f0
  263.     fmuls   f5,f1,f18
  264.     ls      f6,c65536
  265.     fmadds  f4,f2,f13,f4
  266.     fmadds  f5,f2,f19,f5
  267.     fmadds  f4,f3,f14,f4
  268.     fmadds  f5,f3,f20,f5
  269.     ls      f7,c0_5
  270.     fmuls   f4,f4,f22
  271.     fmuls   f5,f5,f22
  272.  
  273.     fmuls   f22,f22,f6
  274.     lwz     r8,MSURFACE_TEXTUREMINS(r3)
  275.  
  276.     fmadds  f4,f6,f4,f7
  277.     fmadds  f5,f6,f5,f7
  278.     fctiwz  f0,f4
  279.     fctiwz  f2,f5
  280.     stfd    f0,local(r1)
  281.     stfd    f2,local+8(r1)
  282.     lwz     r6,local+4(r1)
  283.     lwz     r12,local+12(r1)
  284.     lfs     f8,12(r4)
  285.     lfs     f3,12(r5)
  286.     fmuls   f8,f8,f22
  287.     fmuls   f3,f3,f22
  288.     fctiwz  f0,f8
  289.     fctiwz  f2,f3
  290.     stfd    f0,local(r1)
  291.     stfd    f2,local+8(r1)
  292.     lwz     r7,local+4(r1)
  293.     lwz     r4,local+12(r1)
  294.     clrrwi  r11,r8,16
  295.     slwi    r5,r8,16
  296.     sraw    r11,r11,r9
  297.     sraw    r5,r5,r9
  298.     subf    r11,r7,r11
  299.     subf    r5,r4,r5
  300.     subf    r6,r11,r6
  301.     subf    r12,r5,r12
  302.     sw      r6,sadjust
  303.     sw      r12,tadjust
  304.  
  305.     lwz     r8,MSURFACE_EXTENTS(r3)
  306.     clrrwi  r6,r8,16
  307.     slwi    r5,r8,16
  308.     sraw    r6,r6,r9
  309.     sraw    r5,r5,r9
  310.     subi    r6,r6,1
  311.     subi    r5,r5,1
  312.     sw      r6,bbextents
  313.     sw      r5,bbextentt
  314.  
  315.     lfd    f14,fb+0*8(r1)
  316.     lfd    f15,fb+1*8(r1)
  317.     lfd    f16,fb+2*8(r1)
  318.     lfd    f17,fb+3*8(r1)
  319.     lfd    f18,fb+4*8(r1)
  320.     lfd    f19,fb+5*8(r1)
  321.     lfd    f20,fb+6*8(r1)
  322.     lfd    f22,fb+8*8(r1)
  323.     exit
  324.  
  325.     funcend    D_CalcGradients
  326.  
  327.  
  328.  
  329.  
  330. ###########################################################################
  331. #
  332. #       void _D_DrawSurfaces (void)
  333. #
  334. ###########################################################################
  335.  
  336.     funcdef    D_DrawSurfaces
  337.  
  338. .ifdef    WOS
  339.     init    0,8,18,9
  340.     stmw    r14,gb(r1)
  341. .else
  342.     init    0,8,17,9
  343.     stmw    r15,gb(r1)
  344. .endif
  345.     stfd    f14,fb+0*8(r1)
  346.     stfd    f15,fb+1*8(r1)
  347.     stfd    f16,fb+2*8(r1)
  348.     stfd    f17,fb+3*8(r1)
  349.     stfd    f18,fb+4*8(r1)
  350.     stfd    f19,fb+5*8(r1)
  351.     stfd    f20,fb+6*8(r1)
  352.     stfd    f21,fb+7*8(r1)
  353.     stfd    f22,fb+8*8(r1)
  354.  
  355. #        currententity = &r_worldentity;
  356.     lxa     r12,r_worldentity
  357.     ls      f17,c0
  358.     ls      f18,cM0_9
  359.     sw      r12,currententity
  360.  
  361.     lxa     r31,modelorg
  362.     lxa     r30,transformed_modelorg
  363.     lxa     r29,vright
  364.     lxa     r28,vup
  365.     lxa     r27,vpn
  366.     lxa     r24,r_origin
  367.     lxa     r23,base_vright
  368.     lxa     r22,base_vup
  369.     lxa     r21,base_vpn
  370.     lxa     r19,screenedge
  371.     lxa     r18,d_scalemip
  372.     lw      r17,d_minmip
  373.     lw      r15,d_drawspans
  374.     subi    r19,r19,4
  375.     lxa     r20,view_clipplanes
  376.     subi    r20,r20,4
  377.  
  378. #        TransformVector (modelorg, transformed_modelorg);
  379. #        VectorCopy (transformed_modelorg, world_transformed_modelorg);
  380.  
  381. ######  TransformVector (inlined)
  382.  
  383.     lfs     f1,0(r31)
  384.     lfs     f4,0(r29)
  385.     fmuls   f0,f1,f4
  386.     lfs     f2,4(r31)
  387.     lfs     f5,4(r29)
  388.     fmadds  f0,f2,f5,f0
  389.     lfs     f3,8(r31)
  390.     lfs     f6,8(r29)
  391.     fmadds  f14,f3,f6,f0
  392.     stfs    f14,0(r30)              #f14 = world_transformed[0]
  393.     lfs     f4,0(r28)
  394.     fmuls   f7,f1,f4
  395.     lfs     f5,4(r28)
  396.     fmadds  f7,f2,f5,f7
  397.     lfs     f6,8(r28)
  398.     fmadds  f15,f3,f6,f7
  399.     stfs    f15,4(r30)              #f15 = world_transformed[1]
  400.     lfs     f4,0(r27)
  401.     fmuls   f8,f1,f4
  402.     lfs     f5,4(r27)
  403.     fmadds  f8,f2,f5,f8
  404.     lfs     f6,8(r27)
  405.     fmadds  f16,f3,f6,f8
  406.     stfs    f16,8(r30)              #f16 = world_transformed[2]
  407.  
  408. ######  end of TransformVector
  409.  
  410. #        if (r_drawflat.value)
  411. #        {
  412. #                for (s = &surfaces[1] ; s<surface_p ; s++)
  413.  
  414.     lxa     r3,r_drawflat
  415.     lfs     f0,CVAR_VALUE(r3)
  416.     fcmpo   cr0,f0,f17
  417.     beq     .dsnotflat
  418.     lw      r26,surfaces
  419.     la      r26,SURF_SIZEOF(r26)
  420.     lw      r25,surface_p
  421. .dsloop:
  422.     cmpw    r26,r25
  423.     bge     .dsend
  424.  
  425. #     if (!s->spans)
  426. #             continue;
  427.  
  428.     lwz     r0,SURF_SPANS(r26)
  429.     mr.     r0,r0
  430.     beq     .dsnext
  431.  
  432. #       d_zistepu = s->d_zistepu;
  433. #       d_zistepv = s->d_zistepv;
  434. #       d_ziorigin = s->d_ziorigin;
  435. #
  436. #       D_DrawSolidSurface (s, (long)s->data & 0xFF);
  437. #       D_DrawZSpans (s->spans);
  438.  
  439.     lwz     r3,SURF_D_ZISTEPU(r26)
  440.     sw      r3,d_zistepu
  441.     lwz     r3,SURF_D_ZISTEPV(r26)
  442.     sw      r3,d_zistepv
  443.     lwz     r3,SURF_D_ZIORIGIN(r26)
  444.     sw      r3,d_ziorigin
  445.     lwz     r4,SURF_DATA(r26)
  446.     andi.   r4,r4,0xff
  447.     mr      r3,r26
  448.     call    D_DrawSolidSurface
  449.     lwz     r3,SURF_SPANS(r26)
  450.     call    D_DrawZSpans
  451. .dsnext:
  452.     la      r26,SURF_SIZEOF(r26)
  453.     b       .dsloop
  454.  
  455. .dsnotflat:
  456.     lw      r26,surfaces
  457.     la      r26,SURF_SIZEOF(r26)
  458.     lw      r25,surface_p
  459.  
  460. #         for (s = &surfaces[1] ; s<surface_p ; s++)
  461. #         {
  462. #                 if (!s->spans)
  463. #                         continue;
  464.  
  465. .dsloop2:
  466.     cmpw    r26,r25
  467.     bge     .dsend
  468.     lwz     r0,SURF_SPANS(r26)
  469.     mr.     r0,r0
  470.     beq     .dsnext2
  471.  
  472. #     r_drawnpolycount++;
  473. #
  474. #     d_zistepu = s->d_zistepu;
  475. #     d_zistepv = s->d_zistepv;
  476. #     d_ziorigin = s->d_ziorigin;
  477.  
  478.     lw      r3,r_drawnpolycount
  479.     addi    r3,r3,1
  480.     sw      r3,r_drawnpolycount
  481.     lwz     r3,SURF_D_ZISTEPU(r26)
  482.     sw      r3,d_zistepu
  483.     lwz     r3,SURF_D_ZISTEPV(r26)
  484.     sw      r3,d_zistepv
  485.     lwz     r3,SURF_D_ZIORIGIN(r26)
  486.     sw      r3,d_ziorigin
  487.  
  488. #     if (s->flags & SURF_DRAWSKY)
  489. #     {
  490. #             if (!r_skymade)
  491. #             {
  492. #                     R_MakeSky ();
  493. #             }
  494. #
  495. #             D_DrawSkyScans8 (s->spans);
  496. #             D_DrawZSpans (s->spans);
  497. #     }
  498.  
  499.     lwz     r5,SURF_FLAGS(r26)
  500.     andi.   r0,r5,SURF_DRAWSKY
  501.     beq     .dsnosky
  502.     lw      r3,r_skymade
  503.     mr.     r3,r3
  504.     bne     .dsskymade
  505.     call    R_MakeSky
  506. .dsskymade:
  507.     lwz     r3,SURF_SPANS(r26)
  508.     call    D_DrawSkyScans8
  509.     lwz     r3,SURF_SPANS(r26)
  510.     call    D_DrawZSpans
  511.     b       .dsnext2
  512.  
  513. #   else if (s->flags & SURF_DRAWBACKGROUND)
  514. #   {
  515. #   // set up a gradient for the background surface that places it
  516. #   // effectively at infinity distance from the viewpoint
  517. #           d_zistepu = 0;
  518. #           d_zistepv = 0;
  519. #           d_ziorigin = -0.9;
  520. #
  521. #           D_DrawSolidSurface (s, (int)r_clearcolor.value & 0xFF);
  522. #           D_DrawZSpans (s->spans);
  523. #   }
  524.  
  525. .dsnosky:
  526.     andi.   r0,r5,SURF_DRAWBACKGROUND
  527.     beq     .dsnobackground
  528.     ss      f17,d_zistepu
  529.     ss      f17,d_zistepv
  530.     ss      f18,d_ziorigin
  531.     lxa     r3,r_clearcolor
  532.     lfs     f0,CVAR_VALUE(r3)
  533.     fctiwz  f0,f0
  534.     stfd    f0,local(r1)
  535.     lwz     r4,local+4(r1)
  536.     andi.   r4,r4,0xff
  537.     mr      r3,r26
  538.     call    D_DrawSolidSurface
  539.     lwz     r3,SURF_SPANS(r26)
  540.     call    D_DrawZSpans
  541.     b       .dsnext2
  542.  
  543. #   else if (s->flags & SURF_DRAWTURB)
  544. #   {
  545. #           pface = s->data;
  546. #           miplevel = 0;
  547. #           cacheblock = (pixel_t *)
  548. #                           ((byte *)pface->texinfo->texture +
  549. #                           pface->texinfo->texture->offsets[0]);
  550. #           cachewidth = 64;
  551.  
  552. .dsnobackground:
  553.     andi.   r0,r5,SURF_DRAWTURB
  554.     beq     .dsnoturb
  555. .ifdef    WOS
  556.     lwz     r14,SURF_DATA(r26)
  557.     li    r0,0
  558.     sw    r0,miplevel
  559.     lwz     r7,MSURFACE_TEXINFO(r14)
  560. .else
  561.     lwz     r7,SURF_DATA(r26)
  562.     li    r0,0
  563.     sw    r0,miplevel
  564.     lwz     r7,MSURFACE_TEXINFO(r7)
  565. .endif
  566.     lwz     r7,MTEXINFO_TEXTURE(r7)
  567.     lwz     r0,TEXTURE_OFFSETS(r7)
  568.     add     r7,r7,r0
  569.     sw      r7,cacheblock
  570.     li    r0,64
  571.     sw    r0,cachewidth
  572.  
  573. #      if (s->insubmodel)
  574. #      {
  575. #      // FIXME: we don't want to do all this for every polygon!
  576. #      // TODO: store once at start of frame
  577. #              currententity = s->entity;      //FIXME: make this passed in to
  578. #                                                                      // R_RotateBmodel ()
  579. #              VectorSubtract (r_origin, currententity->origin,
  580. #                              local_modelorg);
  581. #              TransformVector (local_modelorg, transformed_modelorg);
  582. #
  583. #              R_RotateBmodel ();      // FIXME: don't mess with the frustum,
  584. #                                                      // make entity passed in
  585. #      }
  586.  
  587.     lwz     r0,SURF_INSUBMODEL(r26)
  588.     mr.     r0,r0
  589.     beq     .dsnosub
  590.     lwz     r3,SURF_ENTITY(r26)
  591.     sw      r3,currententity
  592.     la      r3,ENTITY_ORIGIN(r3)
  593.  
  594. ######  VectorSubtract (inlined)
  595.  
  596.     lfs     f1,0(r24)
  597.     lfs     f5,0(r3)
  598.     fsubs   f1,f1,f5
  599.     lfs     f2,4(r24)
  600.     lfs     f6,4(r3)
  601.     fsubs   f2,f2,f6
  602.     lfs     f3,8(r24)
  603.     lfs     f7,8(r3)
  604.     fsubs   f3,f3,f7
  605.  
  606. ######  end of VectorSubtract (inlined)
  607.  
  608. ######  TransformVector (inlined)
  609.  
  610.     lfs     f4,0(r29)
  611.     fmuls   f7,f4,f1
  612.     lfs     f5,4(r29)
  613.     fmadds  f7,f5,f2,f7
  614.     lfs     f6,8(r29)
  615.     fmadds  f7,f6,f3,f7
  616.     stfs    f7,0(r30)
  617.     lfs     f4,0(r28)
  618.     fmuls   f7,f4,f1
  619.     lfs     f5,4(r28)
  620.     fmadds  f7,f5,f2,f7
  621.     lfs     f6,8(r28)
  622.     fmadds  f7,f6,f3,f7
  623.     stfs    f7,4(r30)
  624.     lfs     f4,0(r27)
  625.     fmuls   f7,f4,f1
  626.     lfs     f5,4(r27)
  627.     fmadds  f7,f5,f2,f7
  628.     lfs     f6,8(r27)
  629.     fmadds  f7,f6,f3,f7
  630.     stfs    f7,8(r30)
  631.  
  632. ###### end of TransformVector
  633.  
  634.     call    R_RotateBmodel
  635.  
  636. #              D_CalcGradients (pface);
  637. #              Turbulent8 (s->spans);
  638. #              D_DrawZSpans (s->spans);
  639.  
  640. .dsnosub:
  641. .ifdef    WOS
  642.     mr      r3,r14
  643. .else
  644.     lwz     r3,SURF_DATA(r26)
  645. .endif
  646.     call    D_CalcGradients
  647.     lwz     r3,SURF_SPANS(r26)
  648.     call    Turbulent8
  649.     lwz     r3,SURF_SPANS(r26)
  650.     call    D_DrawZSpans
  651.  
  652. #          if (s->insubmodel)
  653. #          {
  654. #          //
  655. #          // restore the old drawing state
  656. #          // FIXME: we don't want to do this every time!
  657. #          // TODO: speed up
  658. #          //
  659. #                  currententity = &r_worldentity;
  660. #                  VectorCopy (world_transformed_modelorg,
  661. #                                          transformed_modelorg);
  662. #                  VectorCopy (base_vpn, vpn);
  663. #                  VectorCopy (base_vup, vup);
  664. #                  VectorCopy (base_vright, vright);
  665. #                  VectorCopy (base_modelorg, modelorg);
  666. #                  R_TransformFrustum ();
  667. #          }
  668.  
  669.     lwz     r0,SURF_INSUBMODEL(r26)
  670.     mr.     r0,r0
  671.     beq     .dsnext2
  672.     lxa     r12,r_worldentity
  673.     sw      r12,currententity
  674.  
  675.     stfs    f14,0(r30)
  676.     stfs    f15,4(r30)
  677.     stfs    f16,8(r30)
  678.     lxa    r11,base_modelorg
  679.     lfs     f0,0(r23)
  680.     stfs    f0,0(r29)               #f0 = vright[0]
  681.     lfs     f1,0(r22)
  682.     stfs    f1,0(r28)               #f1 = vup[0]
  683.     lfs     f2,0(r21)
  684.     stfs    f2,0(r27)               #f2 = vpn[0]
  685.     lfs    f9,0(r11)
  686.     stfs    f9,0(r31)
  687.     lfs     f3,4(r23)
  688.     stfs    f3,4(r29)               #f3 = vright[1]
  689.     lfs     f4,4(r22)
  690.     stfs    f4,4(r28)               #f4 = vup[1]
  691.     lfs     f5,4(r21)
  692.     stfs    f5,4(r27)               #f5 = vpn[1]
  693.     lfs    f9,4(r11)
  694.     stfs    f9,4(r31)
  695.     lfs     f6,8(r23)
  696.     stfs    f6,8(r29)               #f6 = vright[2]
  697.     lfs     f7,8(r22)
  698.     stfs    f7,8(r28)               #f7 = vup[2]
  699.     lfs     f8,8(r21)
  700.     stfs    f8,8(r27)               #f8 = vpn[2]
  701.     lfs    f9,8(r11)
  702.     stfs    f9,8(r31)
  703.  
  704. ###### R_TransformFrustum (inlined)
  705.  
  706.     li      r0,4
  707.     mtctr   r0
  708.     lfs     f20,0(r31)
  709.     lfs     f21,4(r31)
  710.     lfs     f22,8(r31)
  711. .dsloop3:
  712.     lfsu    f9,4(r19)
  713.     lfsu    f10,4(r19)
  714.     lfsu    f11,4(r19)
  715.     fmuls   f12,f1,f10
  716.     fmuls   f13,f4,f10
  717.     fmuls   f19,f7,f10
  718.     fmadds  f12,f2,f11,f12
  719.     fmadds  f13,f5,f11,f13
  720.     fmadds  f19,f8,f11,f19
  721.     fnmsubs f12,f0,f9,f12
  722.     stfsu   f12,4(r20)
  723.     fmuls   f12,f12,f20
  724.     fnmsubs f13,f3,f9,f13
  725.     stfsu   f13,4(r20)
  726.     fmadds  f12,f13,f21,f12
  727.     fnmsubs f19,f6,f9,f19
  728.     stfsu   f19,4(r20)
  729.     fmadds  f12,f19,f22,f12
  730.     la      r19,MPLANE_SIZEOF-12(r19)
  731.     stfsu   f12,4(r20)
  732.     la      r20,CLIP_SIZEOF-16(r20)
  733.     bdnz    .dsloop3
  734.     la      r19,-4*MPLANE_SIZEOF(r19)
  735.     la      r20,-4*CLIP_SIZEOF(r20)
  736.  
  737. ######  end of R_TransformFrustum
  738.  
  739.     b       .dsnext2
  740. .dsnoturb:
  741.  
  742. #          if (s->insubmodel)
  743. #          {
  744. #          // FIXME: we don't want to do all this for every polygon!
  745. #          // TODO: store once at start of frame
  746. #                  currententity = s->entity;      //FIXME: make this passed in to
  747. #                                                                          // R_RotateBmodel ()
  748. #                  VectorSubtract (r_origin, currententity->origin, local_modelorg);
  749. #                  TransformVector (local_modelorg, transformed_modelorg);
  750. #
  751. #                  R_RotateBmodel ();      // FIXME: don't mess with the frustum,
  752. #                                                          // make entity passed in
  753. #          }
  754.  
  755.     lwz     r0,SURF_INSUBMODEL(r26)
  756.     mr.     r0,r0
  757.     beq     .dsnosub2
  758.     lwz     r3,SURF_ENTITY(r26)
  759.     sw      r3,currententity
  760.     la      r3,ENTITY_ORIGIN(r3)
  761.  
  762. ###### VectorSubtract (inlined)
  763.  
  764.     lfs     f1,0(r24)
  765.     lfs     f5,0(r3)
  766.     fsubs   f1,f1,f5
  767.     lfs     f2,4(r24)
  768.     lfs     f6,4(r3)
  769.     fsubs   f2,f2,f6
  770.     lfs     f3,8(r24)
  771.     lfs     f7,8(r3)
  772.     fsubs   f3,f3,f7
  773.  
  774. ###### end of VectorSubtract
  775.  
  776. ###### TransformVector (inlined)
  777.  
  778.     lfs     f4,0(r29)
  779.     fmuls   f7,f4,f1
  780.     lfs     f5,4(r29)
  781.     fmadds  f7,f5,f2,f7
  782.     lfs     f6,8(r29)
  783.     fmadds  f7,f6,f3,f7
  784.     stfs    f7,0(r30)
  785.     lfs     f4,0(r28)
  786.     fmuls   f7,f4,f1
  787.     lfs     f5,4(r28)
  788.     fmadds  f7,f5,f2,f7
  789.     lfs     f6,8(r28)
  790.     fmadds  f7,f6,f3,f7
  791.     stfs    f7,4(r30)
  792.     lfs     f4,0(r27)
  793.     fmuls   f7,f4,f1
  794.     lfs     f5,4(r27)
  795.     fmadds  f7,f5,f2,f7
  796.     lfs     f6,8(r27)
  797.     fmadds  f7,f6,f3,f7
  798.     stfs    f7,8(r30)
  799.  
  800. ######  end of TransformVector
  801.  
  802.     call    R_RotateBmodel
  803. .dsnosub2:
  804.  
  805. #                                pface = s->data;
  806. #                                miplevel = D_MipLevelForScale (s->nearzi * scale_for_mip
  807. #                                # pface->texinfo->mipadjust);
  808. #
  809. #                        // FIXME: make this passed in to D_CacheSurface
  810. #                                pcurrentcache = D_CacheSurface (pface, miplevel);
  811. #
  812. #                                cacheblock = (pixel_t *)pcurrentcache->data;
  813. #                                cachewidth = pcurrentcache->width;
  814.  
  815.     lwz     r16,SURF_DATA(r26)
  816.     lfs     f0,SURF_NEARZI(r26)
  817.     ls      f1,scale_for_mip
  818.     fmuls   f0,f0,f1
  819.     lwz     r3,MSURFACE_TEXINFO(r16)
  820.     lfs     f1,MTEXINFO_MIPADJUST(r3)
  821.     fmuls   f0,f0,f1
  822.  
  823. ######  D_MipLevelForScale (inlined)
  824.     li      r4,0
  825.     lfs     f1,0(r18)
  826.     fcmpo   cr0,f0,f1
  827.     bge     .dsfound
  828.     li      r4,1
  829.     lfs     f1,4(r18)
  830.     fcmpo   cr0,f0,f1
  831.     bge     .dsfound
  832.     li      r4,2
  833.     lfs     f1,8(r18)
  834.     fcmpo   cr0,f0,f1
  835.     bge     .dsfound
  836.     li      r4,3
  837.     cmpw    r4,r17
  838.     bge     .dsfound
  839.     mr      r4,r17
  840. .dsfound:
  841. ######  end of D_MipLevelForScale
  842.  
  843.     sw      r4,miplevel
  844.     mr      r3,r16
  845.     call    D_CacheSurface
  846.     la      r4,SURFCACHE_DATA(r3)
  847.     sw      r4,cacheblock
  848.     lwz     r3,SURFCACHE_WIDTH(r3)
  849.     sw      r3,cachewidth
  850.  
  851. #                                D_CalcGradients (pface);
  852. #
  853. #                                (*d_drawspans) (s->spans);
  854. #
  855. #                                D_DrawZSpans (s->spans);
  856.  
  857.     mr      r3,r16
  858.     call    D_CalcGradients
  859.     lwz     r3,SURF_SPANS(r26)
  860.     mtlr    r15
  861.     blrl
  862.     lwz     r3,SURF_SPANS(r26)
  863.     call    D_DrawZSpans
  864.  
  865. #          if (s->insubmodel)
  866. #          {
  867. #          //
  868. #          // restore the old drawing state
  869. #          // FIXME: we don't want to do this every time!
  870. #          // TODO: speed up
  871. #          //
  872. #                  VectorCopy (world_transformed_modelorg,
  873. #                                          transformed_modelorg);
  874. #                  VectorCopy (base_vpn, vpn);
  875. #                  VectorCopy (base_vup, vup);
  876. #                  VectorCopy (base_vright, vright);
  877. #                  VectorCopy (base_modelorg, modelorg);
  878. #                  R_TransformFrustum ();
  879. #                  currententity = &r_worldentity;
  880. #          }
  881.  
  882.     lwz     r0,SURF_INSUBMODEL(r16)
  883.     mr.     r0,r0
  884.     beq     .dsnext2
  885.  
  886.     stfs    f14,0(r30)
  887.     stfs    f15,4(r30)
  888.     stfs    f16,8(r30)
  889.     lxa    r11,base_modelorg
  890.     lfs     f0,0(r23)
  891.     stfs    f0,0(r29)               #f0 = vright[0]
  892.     lfs     f1,0(r22)
  893.     stfs    f1,0(r28)               #f1 = vup[0]
  894.     lfs     f2,0(r21)
  895.     stfs    f2,0(r27)               #f2 = vpn[0]
  896.     lfs    f9,0(r11)
  897.     stfs    f9,0(r31)
  898.     lfs     f3,4(r23)
  899.     stfs    f3,4(r29)               #f3 = vright[1]
  900.     lfs     f4,4(r22)
  901.     stfs    f4,4(r28)               #f4 = vup[1]
  902.     lfs     f5,4(r21)
  903.     stfs    f5,4(r27)               #f5 = vpn[1]
  904.     lfs    f9,4(r11)
  905.     stfs    f9,4(r31)
  906.     lfs     f6,8(r23)
  907.     stfs    f6,8(r29)               #f6 = vright[2]
  908.     lfs     f7,8(r22)
  909.     stfs    f7,8(r28)               #f7 = vup[2]
  910.     lfs     f8,8(r21)
  911.     stfs    f8,8(r27)               #f8 = vpn[2]
  912.     lfs    f9,8(r11)
  913.     stfs    f9,8(r31)
  914.  
  915. ###### R_TransformFrustum (inlined)
  916.  
  917.     li      r0,4
  918.     mtctr   r0
  919.     lfs     f20,0(r31)
  920.     lfs     f21,4(r31)
  921.     lfs     f22,8(r31)
  922. .dsloop4:
  923.     lfsu    f9,4(r19)
  924.     lfsu    f10,4(r19)
  925.     lfsu    f11,4(r19)
  926.     fmuls   f12,f1,f10
  927.     fmuls   f13,f4,f10
  928.     fmuls   f19,f7,f10
  929.     fmadds  f12,f2,f11,f12
  930.     fmadds  f13,f5,f11,f13
  931.     fmadds  f19,f8,f11,f19
  932.     fnmsubs f12,f0,f9,f12
  933.     stfsu   f12,4(r20)
  934.     fmuls   f12,f12,f20
  935.     fnmsubs f13,f3,f9,f13
  936.     stfsu   f13,4(r20)
  937.     fmadds  f12,f13,f21,f12
  938.     fnmsubs f19,f6,f9,f19
  939.     stfsu   f19,4(r20)
  940.     fmadds  f12,f19,f22,f12
  941.     la      r19,MPLANE_SIZEOF-12(r19)
  942.     stfsu   f12,4(r20)
  943.     la      r20,CLIP_SIZEOF-16(r20)
  944.     bdnz    .dsloop4
  945.     lxa     r12,r_worldentity
  946.     la      r19,-4*MPLANE_SIZEOF(r19)
  947.     la      r20,-4*CLIP_SIZEOF(r20)
  948.  
  949. ######  end of R_TransformFrustum
  950.  
  951.     sw      r12,currententity
  952. .dsnext2:
  953.     la      r26,SURF_SIZEOF(r26)
  954.     b       .dsloop2
  955.  
  956. .dsend:
  957.     lfd    f14,fb+0*8(r1)
  958.     lfd    f15,fb+1*8(r1)
  959.     lfd    f16,fb+2*8(r1)
  960.     lfd    f17,fb+3*8(r1)
  961.     lfd    f18,fb+4*8(r1)
  962.     lfd    f19,fb+5*8(r1)
  963.     lfd    f20,fb+6*8(r1)
  964.     lfd    f21,fb+7*8(r1)
  965.     lfd    f22,fb+8*8(r1)
  966. .ifdef    WOS
  967.     lmw    r14,gb(r1)
  968. .else
  969.     lmw    r15,gb(r1)
  970. .endif
  971.     exit
  972.  
  973.     funcend    D_DrawSurfaces
  974.  
  975.  
  976.  
  977.  
  978. .ifdef    WOS
  979.     .tocd
  980. .else
  981.     .data
  982. .endif
  983.  
  984. lab cM0_9
  985.     .float    -0.9
  986.