home *** CD-ROM | disk | FTP | other *** search
/ Enigma Amiga Life 113 / EnigmaAmiga113CD.iso / software / sviluppo / quakeworld_src / client / d_edge68k.s < prev    next >
Encoding:
Text File  |  2000-06-17  |  24.9 KB  |  994 lines
  1. * 
  2. * Copyright (C) 1996-1997 Id Software, Inc. 
  3. * 
  4. * This program is free software; you can redistribute it and/or 
  5. * modify it under the terms of the GNU General Public License 
  6. * as published by the Free Software Foundation; either version 2 
  7. * of the License, or (at your option) any later version. 
  8. * 
  9. * This program is distributed in the hope that it will be useful, 
  10. * but WITHOUT ANY WARRANTY; without even the implied warranty of 
  11. * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.   
  12. * 
  13. * See the GNU General Public License for more details. 
  14. * 
  15. * You should have received a copy of the GNU General Public License 
  16. * along with this program; if not, write to the Free Software 
  17. * Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA  02111-1307, USA. 
  18. * 
  19.  
  20. **
  21. ** Quake for AMIGA
  22. ** d_edge.c assembler implementations by Frank Wille <frank@phoenix.owl.de>
  23. **
  24.  
  25.         XREF    _vright
  26.         XREF    _vup
  27.         XREF    _vpn
  28.         XREF    _xscaleinv
  29.         XREF    _yscaleinv
  30.         XREF    _xcenter
  31.         XREF    _ycenter
  32.         XREF    _d_zistepu
  33.         XREF    _d_zistepv
  34.         XREF    _d_ziorigin
  35.         XREF    _d_sdivzstepu
  36.         XREF    _d_tdivzstepu
  37.         XREF    _d_sdivzstepv
  38.         XREF    _d_tdivzstepv
  39.         XREF    _d_sdivzorigin
  40.         XREF    _d_tdivzorigin
  41.         XREF    _sadjust
  42.         XREF    _tadjust
  43.         XREF    _bbextents
  44.         XREF    _bbextentt
  45.         XREF    _transformed_modelorg
  46.         XREF    _miplevel
  47.         XREF    _r_worldentity
  48.         XREF    _currententity
  49.         XREF    _r_drawflat
  50.         XREF    _surfaces
  51.         XREF    _surface_p
  52.         XREF    _r_drawnpolycount
  53.         XREF    _r_skymade
  54.         XREF    _r_clearcolor
  55.         XREF    _cacheblock
  56.         XREF    _cachewidth
  57.         XREF    _r_origin
  58.         XREF    _base_vpn
  59.         XREF    _base_vup
  60.         XREF    _base_vright
  61.         XREF    _base_modelorg
  62.         XREF    _d_drawspans
  63.         XREF    _scale_for_mip
  64.         XREF    _d_scalemip
  65.         XREF    _d_minmip
  66.         XREF    _modelorg
  67.         XREF    _screenedge
  68.         XREF    _view_clipplanes
  69.  
  70.         XREF    _D_DrawSolidSurface
  71.         XREF    _D_DrawZSpans
  72.         XREF    _R_MakeSky
  73.         XREF    _D_DrawSkyScans8
  74.         XREF    _D_DrawZSpans
  75.         XREF    _Turbulent8
  76.         XREF    _R_RotateBmodel
  77.         XREF    _D_CacheSurface
  78.  
  79.         XDEF    _D_CalcGradients
  80.         XDEF    _D_DrawSurfaces
  81.  
  82. SURF_DRAWSKY            =       4
  83. SURF_DRAWTURB           =       $10
  84. SURF_DRAWBACKGROUND     =       $40
  85.  
  86. MSURFACE_VISFRAME       =       0
  87. MSURFACE_DLIGHTFRAME    =       4
  88. MSURFACE_DLIGHTBITS     =       8
  89. MSURFACE_PLANE          =       12
  90. MSURFACE_FLAGS          =       16
  91. MSURFACE_FIRSTEDGE      =       20
  92. MSURFACE_NUMEDGES       =       24
  93. MSURFACE_CACHESPOTS     =       28
  94. MSURFACE_TEXTUREMINS    =       44
  95. MSURFACE_EXTENTS        =       48
  96. MSURFACE_TEXINFO        =       52
  97. MSURFACE_STYLES         =       56
  98. MSURFACE_SAMPLES        =       60
  99. MSURFACE_SIZEOF_EXP     =       6
  100. MSURFACE_SIZEOF         =       (1<<MSURFACE_SIZEOF_EXP)
  101.  
  102. SURF_NEXT               =       0
  103. SURF_PREV               =       4
  104. SURF_SPANS              =       8
  105. SURF_KEY                =       12
  106. SURF_LAST_U             =       16
  107. SURF_SPANSTATE          =       20
  108. SURF_FLAGS              =       24
  109. SURF_DATA               =       28
  110. SURF_ENTITY             =       32
  111. SURF_NEARZI             =       36
  112. SURF_INSUBMODEL         =       40
  113. SURF_D_ZIORIGIN         =       44
  114. SURF_D_ZISTEPU          =       48
  115. SURF_D_ZISTEPV          =       52
  116. SURF_SIZEOF_EXP         =       6
  117. SURF_SIZEOF             =       (1<<SURF_SIZEOF_EXP)
  118.  
  119. MPLANE_NORMAL           =       0
  120. MPLANE_DIST             =       12
  121. MPLANE_TYPE             =       16
  122. MPLANE_SIGNBITS         =       17
  123. MPLANE_SIZEOF           =       20
  124.  
  125. MTEXINFO_VECS           =       0
  126. MTEXINFO_MIPADJUST      =       32
  127. MTEXINFO_TEXTURE        =       36
  128. MTEXINFO_FLAGS          =       40
  129. MTEXINFO_SIZEOF         =       44
  130.  
  131. CLIP_NORMAL             =       0
  132. CLIP_DIST               =       12
  133. CLIP_NEXT               =       16
  134. CLIP_LEFTEDGE           =       20
  135. CLIP_RIGHTEDGE          =       21
  136. CLIP_RESERVED           =       22
  137. CLIP_SIZEOF             =       24
  138.  
  139. SURFCACHE_DATA          =       48
  140. SURFCACHE_WIDTH         =       32
  141.  
  142. TEXTURE_OFFSETS         =       44
  143.  
  144. ENTITY_ORIGIN           =       4
  145.  
  146. CVAR_VALUE              =       16
  147.  
  148.         fpu
  149.  
  150.  
  151.  
  152.  
  153. ******************************************************************************
  154. *
  155. *       void _D_CalcGradients (msurface_t *pface)
  156. *
  157. ******************************************************************************
  158.  
  159.         cnop    0,4
  160. _D_CalcGradients
  161.  
  162. *****   stackframe
  163.  
  164.         rsreset
  165. .fpuregs        rs.x    6
  166. .intregs        rs.l    4
  167.         rs.l    1
  168. .pface          rs.l    1
  169.  
  170.  
  171.         movem.l d2/d3/a2/a3,-(sp)
  172.         fmovem.x        fp2-fp7,-(sp)
  173.         move.l  .pface(sp),a0
  174.         move.l  MSURFACE_TEXINFO(a0),a2
  175.         lea     16(a2),a3
  176.         lea     _vright,a1
  177.         fmove.s (a1)+,fp0
  178.         fmove.s (a1)+,fp1
  179.         fmove.s (a1)+,fp2
  180.         fmove.s (a2)+,fp3
  181.         fmul    fp0,fp3
  182.         fmove.s (a2)+,fp4
  183.         fmul    fp1,fp4
  184.         fadd    fp4,fp3
  185.         fmove.s (a2)+,fp4
  186.         fmul    fp2,fp4
  187.         fadd    fp4,fp3                 ;fp3 = p_saxis[0]
  188.         fmove.s (a3)+,fp4
  189.         fmul    fp0,fp4
  190.         fmove.s (a3)+,fp5
  191.         fmul    fp1,fp5
  192.         fadd    fp5,fp4
  193.         fmove.s (a3)+,fp5
  194.         fmul    fp2,fp5
  195.         fadd    fp5,fp4                 ;fp4 = p_taxis[0]
  196.         sub     #12,a2
  197.         sub     #12,a3
  198.         lea     _vup,a1
  199.         fmove.s (a1)+,fp0
  200.         fmove.s (a1)+,fp1
  201.         fmove.s (a1)+,fp2
  202.         fmove.s (a2)+,fp5
  203.         fmul    fp0,fp5
  204.         fmove.s (a2)+,fp6
  205.         fmul    fp1,fp6
  206.         fadd    fp6,fp5
  207.         fmove.s (a2)+,fp6
  208.         fmul    fp2,fp6
  209.         fadd    fp6,fp5                 ;fp5 = p_saxis[1]
  210.         fmove.s (a3)+,fp6
  211.         fmul    fp0,fp6
  212.         fmove.s (a3)+,fp7
  213.         fmul    fp1,fp7
  214.         fadd    fp7,fp6
  215.         fmove.s (a3)+,fp7
  216.         fmul    fp2,fp7
  217.         fadd    fp7,fp6                 ;fp6 = p_taxis[1]
  218.         sub     #12,a2
  219.         sub     #12,a3
  220.  
  221.         moveq   #1,d0
  222.         move.l  _miplevel,d1            ;d1 = miplevel
  223.         asl.l   d1,d0
  224.         fmove.l d0,fp1
  225.         fmove.s #1,fp0
  226.         fdiv    fp1,fp0                 ;fp0 = mipscale
  227.         fmove.s fp0,-(sp)
  228.  
  229.         fmove.s _xscaleinv,fp1
  230.         fmul    fp0,fp1                 ;fp1 = t = xscaleinv * mipscale
  231.         fmove   fp3,fp2
  232.         fmul    fp1,fp2                 ;fp2 = d_sdivzstepu
  233.         fmove.s fp2,_d_sdivzstepu
  234.         fmul    fp4,fp1                 ;fp1 = d_tdivzstepu
  235.         fmove.s fp1,_d_tdivzstepu
  236.         fmove.s _xcenter,fp7
  237.         fmul    fp7,fp2
  238.         fmul    fp7,fp1
  239.  
  240.         fmove.s _yscaleinv,fp7
  241.         fmul    fp0,fp7                 ;fp7 = t = yscaleinv * mipscale
  242.         fmove   fp5,fp0
  243.         fmul    fp7,fp0                 ;fp0 = d_sdivzstepv
  244.         fneg    fp0
  245.         fmove.s fp0,_d_sdivzstepv
  246.         fmul.s  _ycenter,fp0
  247.         fmul    fp6,fp7                 ;fp7 = d_tdivzstepv
  248.         fneg    fp7
  249.         fmove.s fp7,_d_tdivzstepv
  250.         fmul.s  _ycenter,fp7
  251.  
  252.         fadd    fp0,fp2
  253.         fadd    fp1,fp7
  254.  
  255.         lea     _vpn,a1
  256.         fmove.s (a2)+,fp0
  257.         fmul.s  (a1),fp0
  258.         fmove.s (a2)+,fp1
  259.         fmul.s  4(a1),fp1
  260.         fadd    fp1,fp0
  261.         fmove.s (a2)+,fp1
  262.         fmul.s  8(a1),fp1
  263.         fadd    fp1,fp0
  264.         fmove   fp0,fp1                 ;fp0 = p_saxis[2]
  265.         fmul.s  (sp),fp1                ;mipscale * p_saxis[2]
  266.         fsub    fp2,fp1                 ;- fp2
  267.         fmove.s fp1,_d_sdivzorigin
  268.  
  269.         fmove.s (a3)+,fp1
  270.         fmul.s  (a1)+,fp1
  271.         fmove.s (a3)+,fp2
  272.         fmul.s  (a1)+,fp2
  273.         fadd    fp2,fp1
  274.         fmove.s (a3)+,fp2
  275.         fmul.s  (a1)+,fp2
  276.         fadd    fp2,fp1
  277.         fmove   fp1,fp2                 ;fp1 = p_taxis[2]
  278.         fmul.s  (sp),fp2                ;mipscale * p_taxis[2]
  279.         fsub    fp7,fp2                 ;- fp7
  280.         fmove.s fp2,_d_tdivzorigin
  281.  
  282.         lea     _transformed_modelorg,a1
  283.         fmove.s (a1)+,fp7
  284.         fmul    fp7,fp3
  285.         fmove.s (a1)+,fp2
  286.         fmul    fp2,fp5
  287.         fadd    fp5,fp3
  288.         fmove.s (a1)+,fp5
  289.         fmul    fp5,fp0
  290.         fadd    fp0,fp3
  291.         fmul    fp7,fp4
  292.         fmul    fp2,fp6
  293.         fadd    fp6,fp4
  294.         fmul    fp5,fp1
  295.         fadd    fp1,fp4
  296.  
  297.         fmove.s (sp)+,fp7               ;fp7 = mipscale
  298.         fmul    fp7,fp3
  299.         fmul    fp7,fp4
  300.         fmove.s #65536,fp0
  301.         fmove.s #0.5,fp1
  302.         fmul    fp0,fp7
  303.         move.l  MSURFACE_TEXINFO(a0),a1
  304.  
  305.         fmul    fp0,fp3
  306.         fadd    fp1,fp3
  307.         fmove.l fp3,d0
  308.         fmove.s 12(a1),fp2
  309.         fmul    fp7,fp2
  310.         fmove.l fp2,d2
  311.         move    MSURFACE_TEXTUREMINS(a0),d3
  312.         swap    d3
  313.         clr     d3
  314.         asr.l   d1,d3
  315.         sub.l   d2,d3
  316.         sub.l   d3,d0
  317.         move.l  d0,_sadjust
  318.  
  319.         fmul    fp0,fp4
  320.         fadd    fp1,fp4
  321.         fmove.l fp4,d0
  322.         fmove.s 12+16(a1),fp2
  323.         fmul    fp7,fp2
  324.         fmove.l fp2,d2
  325.         move    MSURFACE_TEXTUREMINS+2(a0),d3
  326.         swap    d3
  327.         clr     d3
  328.         asr.l   d1,d3
  329.         sub.l   d2,d3
  330.         sub.l   d3,d0
  331.         move.l  d0,_tadjust
  332.  
  333.         move    MSURFACE_EXTENTS(a0),d0
  334.         swap    d0
  335.         clr     d0
  336.         asr.l   d1,d0
  337.         subq.l  #1,d0
  338.         move.l  d0,_bbextents
  339.         move    MSURFACE_EXTENTS+2(a0),d0
  340.         swap    d0
  341.         clr     d0
  342.         asr.l   d1,d0
  343.         subq.l  #1,d0
  344.         move.l  d0,_bbextentt
  345.  
  346.         fmovem.x        (sp)+,fp2-fp7
  347.         movem.l (sp)+,d2/d3/a2/a3
  348.         rts
  349.  
  350.  
  351.  
  352.  
  353.  
  354.  
  355.  
  356.  
  357.  
  358. ******************************************************************************
  359. *
  360. *       void _D_DrawSurfaces (void)
  361. *
  362. ******************************************************************************
  363.  
  364.         cnop    0,4
  365. _D_DrawSurfaces
  366.  
  367.  
  368.         movem.l d2/a2-a4,-(sp)
  369.         fmovem.x        fp2-fp7,-(sp)
  370.  
  371. *        currententity = &r_worldentity;
  372. *        TransformVector (modelorg, transformed_modelorg);
  373. *        VectorCopy (transformed_modelorg, world_transformed_modelorg);
  374.  
  375.         move.l  #_r_worldentity,_currententity
  376.  
  377. ******  TransformVector (inlined)
  378.  
  379.         lea     _modelorg,a0
  380.         lea     _transformed_modelorg,a1
  381.         fmove.s (a0)+,fp0
  382.         fmove.s (a0)+,fp1
  383.         fmove.s (a0)+,fp2
  384.         lea     _vright,a2
  385.         fmove.s (a2)+,fp3
  386.         fmul    fp0,fp3
  387.         fmove.s (a2)+,fp4
  388.         fmul    fp1,fp4
  389.         fadd    fp4,fp3
  390.         fmove.s (a2)+,fp4
  391.         fmul    fp2,fp4
  392.         fadd    fp4,fp3
  393.         fmove.s fp3,(a1)+               ;fp3 = world_tr... [0]
  394.         lea     _vup,a2
  395.         fmove.s (a2)+,fp4
  396.         fmul    fp0,fp4
  397.         fmove.s (a2)+,fp5
  398.         fmul    fp1,fp5
  399.         fadd    fp5,fp4
  400.         fmove.s (a2)+,fp5
  401.         fmul    fp2,fp5
  402.         fadd    fp5,fp4
  403.         fmove.s fp4,(a1)+               ;fp4 = world_tr... [1]
  404.         lea     _vpn,a2
  405.         fmove.s (a2)+,fp5
  406.         fmul    fp0,fp5
  407.         fmove.s (a2)+,fp6
  408.         fmul    fp1,fp6
  409.         fadd    fp6,fp5
  410.         fmove.s (a2)+,fp6
  411.         fmul    fp2,fp6
  412.         fadd    fp6,fp5
  413.         fmove.s fp5,(a1)+               ;fp5 = world_tr... [2]
  414.  
  415. ******  end of TransformVector
  416.  
  417. *        if (r_drawflat.value)
  418. *        {
  419. *                for (s = &surfaces[1] ; s<surface_p ; s++)
  420.  
  421.         fmove.s _r_drawflat+CVAR_VALUE,fp0
  422.         ftst    fp0
  423.         fbeq    .notflat
  424.         move.l  _surfaces,a2
  425.         lea     SURF_SIZEOF(a2),a2
  426.         move.l  _surface_p,d2
  427. .loop
  428.         cmp.l   d2,a2
  429.         bge.w   .end
  430.  
  431. *                        if (!s->spans)
  432. *                                continue;
  433.  
  434.         tst.l   SURF_SPANS(a2)
  435.         beq.b   .next
  436.  
  437. *                        d_zistepu = s->d_zistepu;
  438. *                        d_zistepv = s->d_zistepv;
  439. *                        d_ziorigin = s->d_ziorigin;
  440. *
  441. *                        D_DrawSolidSurface (s, (long)s->data & 0xFF);
  442. *                        D_DrawZSpans (s->spans);
  443.  
  444.         move.l  SURF_D_ZISTEPU(a2),_d_zistepu
  445.         move.l  SURF_D_ZISTEPV(a2),_d_zistepv
  446.         move.l  SURF_D_ZIORIGIN(a2),_d_ziorigin
  447.         move.l  SURF_DATA(a2),d0
  448.         and.l   #$ff,d0
  449.         move.l  d0,-(sp)
  450.         move.l  a2,-(sp)
  451.         jsr     _D_DrawSolidSurface
  452.         addq    #8,sp
  453.         move.l  SURF_SPANS(a2),-(sp)
  454.         jsr     _D_DrawZSpans
  455.         addq    #4,sp
  456. .next
  457.         lea     SURF_SIZEOF(a2),a2
  458.         bra.b   .loop
  459. .notflat
  460.         move.l  _surfaces,a2
  461.         lea     SURF_SIZEOF(a2),a2
  462.         move.l  _surface_p,d2
  463.  
  464. *                for (s = &surfaces[1] ; s<surface_p ; s++)
  465. *                {
  466. *                        if (!s->spans)
  467. *                                continue;
  468.  
  469. .loop2
  470.         cmp.l   d2,a2
  471.         bge.w   .end
  472.         tst.l   SURF_SPANS(a2)
  473.         beq.b   .next2
  474.  
  475. *                        r_drawnpolycount++;
  476. *
  477. *                        d_zistepu = s->d_zistepu;
  478. *                        d_zistepv = s->d_zistepv;
  479. *                        d_ziorigin = s->d_ziorigin;
  480.  
  481.         addq.l  #1,_r_drawnpolycount
  482.         move.l  SURF_D_ZISTEPU(a2),_d_zistepu
  483.         move.l  SURF_D_ZISTEPV(a2),_d_zistepv
  484.         move.l  SURF_D_ZIORIGIN(a2),_d_ziorigin
  485.  
  486. *                        if (s->flags & SURF_DRAWSKY)
  487. *                        {
  488. *                                if (!r_skymade)
  489. *                                {
  490. *                                        R_MakeSky ();
  491. *                                }
  492. *
  493. *                                D_DrawSkyScans8 (s->spans);
  494. *                                D_DrawZSpans (s->spans);
  495. *                        }
  496.  
  497.         move.l  SURF_FLAGS(a2),d0
  498.         move.l  d0,d1
  499.         and.l   #SURF_DRAWSKY,d1
  500.         beq.b   .nosky
  501.         tst.l   _r_skymade
  502.         bne.b   .skymade
  503.         jsr     _R_MakeSky
  504. .skymade
  505.         move.l  SURF_SPANS(a2),-(sp)
  506.         jsr     _D_DrawSkyScans8
  507.         jsr     _D_DrawZSpans
  508.         addq    #4,sp
  509.         bra.w   .next2
  510.  
  511. *                        else if (s->flags & SURF_DRAWBACKGROUND)
  512. *                        {
  513. *                        // set up a gradient for the background surface that places it
  514. *                        // effectively at infinity distance from the viewpoint
  515. *                                d_zistepu = 0;
  516. *                                d_zistepv = 0;
  517. *                                d_ziorigin = -0.9;
  518. *
  519. *                                D_DrawSolidSurface (s, (int)r_clearcolor.value & 0xFF);
  520. *                                D_DrawZSpans (s->spans);
  521. *                        }
  522.  
  523. .nosky
  524.         move.l  d0,d1
  525.         and.l   #SURF_DRAWBACKGROUND,d1
  526.         beq.b   .nobackground
  527.         fmove.s #0,fp0
  528.         fmove.s fp0,_d_zistepu
  529.         fmove.s fp0,_d_zistepv
  530.         fmove.s #-0.9,fp0
  531.         fmove.s fp0,_d_ziorigin
  532.         fmove.s _r_clearcolor+CVAR_VALUE,fp0
  533.         fmove.l fp0,d0
  534.         and.l   #$ff,d0
  535.         move.l  d0,-(sp)
  536.         move.l  a2,-(sp)
  537.         jsr     _D_DrawSolidSurface
  538.         addq    #8,sp
  539.         move.l  SURF_SPANS(a2),-(sp)
  540.         jsr     _D_DrawZSpans
  541.         addq    #4,sp
  542.         bra.w   .next2
  543.  
  544. *                        else if (s->flags & SURF_DRAWTURB)
  545. *                        {
  546. *                                pface = s->data;
  547. *                                miplevel = 0;
  548. *                                cacheblock = (pixel_t *)
  549. *                                                ((byte *)pface->texinfo->texture +
  550. *                                                pface->texinfo->texture->offsets[0]);
  551. *                                cachewidth = 64;
  552.  
  553. .nobackground
  554.         move.l  d0,d1
  555.         and.l   #SURF_DRAWTURB,d1
  556.         beq.w   .noturb
  557.         move.l  SURF_DATA(a2),a3
  558.         clr.l   _miplevel
  559.         move.l  MSURFACE_TEXINFO(a3),a0
  560.         move.l  MTEXINFO_TEXTURE(a0),a0
  561.         add.l   TEXTURE_OFFSETS(a0),a0
  562.         move.l  a0,_cacheblock
  563.         move.l  #64,_cachewidth
  564.  
  565. *                                if (s->insubmodel)
  566. *                                {
  567. *                                // FIXME: we don't want to do all this for every polygon!
  568. *                                // TODO: store once at start of frame
  569. *                                        currententity = s->entity;      //FIXME: make this passed in to
  570. *                                                                                                // R_RotateBmodel ()
  571. *                                        VectorSubtract (r_origin, currententity->origin,
  572. *                                                        local_modelorg);
  573. *                                        TransformVector (local_modelorg, transformed_modelorg);
  574. *
  575. *                                        R_RotateBmodel ();      // FIXME: don't mess with the frustum,
  576. *                                                                                // make entity passed in
  577. *                                }
  578.  
  579.         tst.l   SURF_INSUBMODEL(a2)
  580.         beq.b   .nosub
  581.         move.l  SURF_ENTITY(a2),a0
  582.         move.l  a0,_currententity
  583.         lea     ENTITY_ORIGIN(a0),a0
  584.  
  585. ******  VectorSubtract (inlined)
  586.  
  587.         lea     _r_origin,a1
  588.         lea     _transformed_modelorg,a4
  589.         fmove.s (a1)+,fp0
  590.         fsub.s  (a0)+,fp0
  591.         fmove.s (a1)+,fp1
  592.         fsub.s  (a0)+,fp1
  593.         fmove.s (a1)+,fp2
  594.         fsub.s  (a0)+,fp2
  595.  
  596. ******  end of VectorSubtract (inlined)
  597.  
  598. ******  TransformVector (inlined)
  599.  
  600.         lea     _vright,a0
  601.         fmove.s (a0)+,fp6
  602.         fmul    fp0,fp6
  603.         fmove.s (a0)+,fp7
  604.         fmul    fp1,fp7
  605.         fadd    fp7,fp6
  606.         fmove.s (a0)+,fp7
  607.         fmul    fp2,fp7
  608.         fadd    fp7,fp6
  609.         fmove.s fp6,(a4)+
  610.         lea     _vup,a0
  611.         fmove.s (a0)+,fp6
  612.         fmul    fp0,fp6
  613.         fmove.s (a0)+,fp7
  614.         fmul    fp1,fp7
  615.         fadd    fp7,fp6
  616.         fmove.s (a0)+,fp7
  617.         fmul    fp2,fp7
  618.         fadd    fp7,fp6
  619.         fmove.s fp6,(a4)+
  620.         lea     _vpn,a0
  621.         fmul.s  (a0)+,fp0
  622.         fmul.s  (a0)+,fp1
  623.         fadd    fp1,fp0
  624.         fmul.s  (a0)+,fp2
  625.         fadd    fp2,fp0
  626.         fmove.s fp0,(a4)+
  627.         lea     -12(a4),a4
  628.  
  629. ****** end of TransformVector
  630.  
  631.         jsr     _R_RotateBmodel
  632.  
  633. *                                D_CalcGradients (pface);
  634. *                                Turbulent8 (s->spans);
  635. *                                D_DrawZSpans (s->spans);
  636.  
  637. .nosub
  638.         move.l  a3,-(sp)
  639.         jsr     _D_CalcGradients
  640.         addq    #4,sp
  641.         move.l  SURF_SPANS(a2),-(sp)
  642.         jsr     _Turbulent8
  643.         jsr     _D_DrawZSpans
  644.         addq    #4,sp
  645.  
  646. *                                if (s->insubmodel)
  647. *                                {
  648. *                                //
  649. *                                // restore the old drawing state
  650. *                                // FIXME: we don't want to do this every time!
  651. *                                // TODO: speed up
  652. *                                //
  653. *                                        currententity = &r_worldentity;
  654. *                                        VectorCopy (world_transformed_modelorg,
  655. *                                                                transformed_modelorg);
  656. *                                        VectorCopy (base_vpn, vpn);
  657. *                                        VectorCopy (base_vup, vup);
  658. *                                        VectorCopy (base_vright, vright);
  659. *                                        VectorCopy (base_modelorg, modelorg);
  660. *                                        R_TransformFrustum ();
  661. *                                }
  662.  
  663.         tst.l   SURF_INSUBMODEL(a2)
  664.         beq.w   .next2
  665.         move.l  #_r_worldentity,_currententity
  666.         fmove.s fp3,(a4)+
  667.         fmove.s fp4,(a4)+
  668.         fmove.s fp5,(a4)+
  669.         lea     _base_vpn,a0
  670.         lea     _vpn,a1
  671.         move.l  (a0)+,(a1)+
  672.         move.l  (a0)+,(a1)+
  673.         move.l  (a0)+,(a1)+
  674.         lea     _base_vup,a0
  675.         lea     _vup,a1
  676.         move.l  (a0)+,(a1)+
  677.         move.l  (a0)+,(a1)+
  678.         move.l  (a0)+,(a1)+
  679.         lea     _base_vright,a0
  680.         lea     _vright,a1
  681.         move.l  (a0)+,(a1)+
  682.         move.l  (a0)+,(a1)+
  683.         move.l  (a0)+,(a1)+
  684.         lea    _base_modelorg,a0
  685.         lea    _modelorg,a1
  686.         move.l  (a0)+,(a1)+
  687.         move.l  (a0)+,(a1)+
  688.         move.l  (a0)+,(a1)+
  689.         fmove.s fp3,-(sp)
  690.         fmove.s fp4,-(sp)
  691.         fmove.s fp5,-(sp)
  692.  
  693. ****** R_TransformFrustum (inlined)
  694.  
  695.         moveq   #4-1,d0
  696.         lea     _screenedge,a0
  697.         lea     _view_clipplanes,a1
  698.         lea     _modelorg,a4
  699.         fmove.s (a4)+,fp7
  700. .loop3
  701.         fmove.s (a0)+,fp1
  702.         fneg    fp1
  703.         fmove.s (a0)+,fp2
  704.         fmove.s (a0)+,fp0
  705.         lea     _vright,a3
  706.         fmove.s (a3)+,fp3
  707.         fmove.s (a3)+,fp4
  708.         fmove.s (a3)+,fp5
  709.         fmul    fp1,fp3
  710.         fmul    fp1,fp4
  711.         fmul    fp1,fp5
  712.         lea     _vup,a3
  713.         fmove.s (a3)+,fp6
  714.         fmul    fp2,fp6
  715.         fadd    fp6,fp3
  716.         fmove.s (a3)+,fp6
  717.         fmul    fp2,fp6
  718.         fadd    fp6,fp4
  719.         fmove.s (a3)+,fp6
  720.         fmul    fp2,fp6
  721.         fadd    fp6,fp5
  722.         lea     _vpn,a3
  723.         fmove.s (a3)+,fp6
  724.         fmul    fp0,fp6
  725.         fadd    fp6,fp3
  726.         fmove.s fp3,(a1)+
  727.         fmove.s (a3)+,fp6
  728.         fmul    fp0,fp6
  729.         fadd    fp6,fp4
  730.         fmove.s fp4,(a1)+
  731.         fmove.s (a3)+,fp6
  732.         fmul    fp0,fp6
  733.         fadd    fp6,fp5
  734.         fmove.s fp5,(a1)+
  735.  
  736.         fmul    fp7,fp3
  737.         fmul.s  (a4),fp4
  738.         fadd    fp4,fp3
  739.         fmul.s  4(a4),fp5
  740.         fadd    fp5,fp3
  741.         fmove.s fp3,(a1)+
  742.         lea     CLIP_SIZEOF-16(a1),a1
  743.         lea     MPLANE_SIZEOF-12(a0),a0
  744.         dbra    d0,.loop3
  745.  
  746. ******  end of R_TransformFrustum
  747.  
  748.         fmove.s (sp)+,fp5
  749.         fmove.s (sp)+,fp4
  750.         fmove.s (sp)+,fp3
  751.         bra.w   .next2
  752. .noturb
  753.  
  754. *                                if (s->insubmodel)
  755. *                                {
  756. *                                // FIXME: we don't want to do all this for every polygon!
  757. *                                // TODO: store once at start of frame
  758. *                                        currententity = s->entity;      //FIXME: make this passed in to
  759. *                                                                                                // R_RotateBmodel ()
  760. *                                        VectorSubtract (r_origin, currententity->origin, local_modelorg);
  761. *                                        TransformVector (local_modelorg, transformed_modelorg);
  762. *
  763. *                                        R_RotateBmodel ();      // FIXME: don't mess with the frustum,
  764. *                                                                                // make entity passed in
  765. *                                }
  766.  
  767.         tst.l   SURF_INSUBMODEL(a2)
  768.         beq.b   .nosub2
  769.         move.l  SURF_ENTITY(a2),a0
  770.         move.l  a0,_currententity
  771.         lea     ENTITY_ORIGIN(a0),a0
  772.  
  773. ****** VectorSubtract (inlined)
  774.  
  775.         lea     _r_origin,a1
  776.         lea     _transformed_modelorg,a4
  777.         fmove.s (a1)+,fp0
  778.         fsub.s  (a0)+,fp0
  779.         fmove.s (a1)+,fp1
  780.         fsub.s  (a0)+,fp1
  781.         fmove.s (a1)+,fp2
  782.         fsub.s  (a0)+,fp2
  783.  
  784. ****** end of VectorSubtract
  785.  
  786. ****** TransformVector (inlined)
  787.  
  788.         lea     _vright,a0
  789.         fmove.s (a0)+,fp6
  790.         fmul    fp0,fp6
  791.         fmove.s (a0)+,fp7
  792.         fmul    fp1,fp7
  793.         fadd    fp7,fp6
  794.         fmove.s (a0)+,fp7
  795.         fmul    fp2,fp7
  796.         fadd    fp7,fp6
  797.         fmove.s fp6,(a4)+
  798.         lea     _vup,a0
  799.         fmove.s (a0)+,fp6
  800.         fmul    fp0,fp6
  801.         fmove.s (a0)+,fp7
  802.         fmul    fp1,fp7
  803.         fadd    fp7,fp6
  804.         fmove.s (a0)+,fp7
  805.         fmul    fp2,fp7
  806.         fadd    fp7,fp6
  807.         fmove.s fp6,(a4)+
  808.         lea     _vpn,a0
  809.         fmul.s  (a0)+,fp0
  810.         fmul.s  (a0)+,fp1
  811.         fadd    fp1,fp0
  812.         fmul.s  (a0)+,fp2
  813.         fadd    fp2,fp0
  814.         fmove.s fp0,(a4)+
  815.         lea     -12(a4),a4
  816.  
  817. ******  end of TransformVector
  818.  
  819.         jsr     _R_RotateBmodel
  820. .nosub2
  821.  
  822. *                                pface = s->data;
  823. *                                miplevel = D_MipLevelForScale (s->nearzi * scale_for_mip
  824. *                                * pface->texinfo->mipadjust);
  825. *
  826. *                        // FIXME: make this passed in to D_CacheSurface
  827. *                                pcurrentcache = D_CacheSurface (pface, miplevel);
  828. *
  829. *                                cacheblock = (pixel_t *)pcurrentcache->data;
  830. *                                cachewidth = pcurrentcache->width;
  831.  
  832.         move.l  SURF_DATA(a2),a3
  833.         fmove.s SURF_NEARZI(a2),fp0
  834.         fmul.s  _scale_for_mip,fp0
  835.         move.l  MSURFACE_TEXINFO(a3),a0
  836.         fmul.s  MTEXINFO_MIPADJUST(a0),fp0
  837.  
  838. ******  D_MipLevelForScale (inlined)
  839.         lea     _d_scalemip,a1
  840.         moveq   #0,d0
  841.         fcmp.s  (a1),fp0
  842.         fboge.b .found
  843.         moveq   #1,d0
  844.         fcmp.s  4(a1),fp0
  845.         fboge.b .found
  846.         moveq   #2,d0
  847.         fcmp.s  8(a1),fp0
  848.         fboge.b .found
  849.         moveq   #3,d0
  850.         move.l  _d_minmip,d1
  851.         cmp.l   d1,d0
  852.         bge.b   .found
  853.         move.l  d1,d0
  854. .found
  855. ******  end of D_MipLevelForScale
  856.  
  857.         move.l  d0,_miplevel
  858.         move.l  d0,-(sp)
  859.         move.l  a3,-(sp)
  860.         jsr     _D_CacheSurface
  861.         addq    #8,sp
  862.         move.l  d0,a0
  863.         lea     SURFCACHE_DATA(a0),a1
  864.         move.l  a1,_cacheblock
  865.         move.l  SURFCACHE_WIDTH(a0),_cachewidth
  866.  
  867. *                                D_CalcGradients (pface);
  868. *
  869. *                                (*d_drawspans) (s->spans);
  870. *
  871. *                                D_DrawZSpans (s->spans);
  872.  
  873.         move.l  a3,-(sp)
  874.         jsr     _D_CalcGradients
  875.         addq    #4,sp
  876.         move.l  SURF_SPANS(a2),-(sp)
  877.         move.l  _d_drawspans,a0
  878.         jsr     (a0)
  879.         jsr     _D_DrawZSpans
  880.         addq    #4,sp
  881.  
  882. *                                if (s->insubmodel)
  883. *                                {
  884. *                                //
  885. *                                // restore the old drawing state
  886. *                                // FIXME: we don't want to do this every time!
  887. *                                // TODO: speed up
  888. *                                //
  889. *                                        VectorCopy (world_transformed_modelorg,
  890. *                                                                transformed_modelorg);
  891. *                                        VectorCopy (base_vpn, vpn);
  892. *                                        VectorCopy (base_vup, vup);
  893. *                                        VectorCopy (base_vright, vright);
  894. *                                        VectorCopy (base_modelorg, modelorg);
  895. *                                        R_TransformFrustum ();
  896. *                                        currententity = &r_worldentity;
  897. *                                }
  898.  
  899.         tst.l   SURF_INSUBMODEL(a2)
  900.         beq.w   .next2
  901.         fmove.s fp3,(a4)+
  902.         fmove.s fp4,(a4)+
  903.         fmove.s fp5,(a4)+
  904.         lea     _base_vpn,a0
  905.         lea     _vpn,a1
  906.         move.l  (a0)+,(a1)+
  907.         move.l  (a0)+,(a1)+
  908.         move.l  (a0)+,(a1)+
  909.         lea     _base_vup,a0
  910.         lea     _vup,a1
  911.         move.l  (a0)+,(a1)+
  912.         move.l  (a0)+,(a1)+
  913.         move.l  (a0)+,(a1)+
  914.         lea     _base_vright,a0
  915.         lea     _vright,a1
  916.         move.l  (a0)+,(a1)+
  917.         move.l  (a0)+,(a1)+
  918.         move.l  (a0)+,(a1)+
  919.         lea    _base_modelorg,a0
  920.         lea    _modelorg,a1
  921.         move.l  (a0)+,(a1)+
  922.         move.l  (a0)+,(a1)+
  923.         move.l  (a0)+,(a1)+
  924.         fmove.s fp3,-(sp)
  925.         fmove.s fp4,-(sp)
  926.         fmove.s fp5,-(sp)
  927.  
  928. ****** R_TransformFrustum (inlined)
  929.  
  930.         moveq   #4-1,d0
  931.         lea     _screenedge,a0
  932.         lea     _view_clipplanes,a1
  933.         lea     _modelorg,a4
  934.         fmove.s (a4)+,fp7
  935. .loop4
  936.         fmove.s (a0)+,fp1
  937.         fneg    fp1
  938.         fmove.s (a0)+,fp2
  939.         fmove.s (a0)+,fp0
  940.         lea     _vright,a3
  941.         fmove.s (a3)+,fp3
  942.         fmove.s (a3)+,fp4
  943.         fmove.s (a3)+,fp5
  944.         fmul    fp1,fp3
  945.         fmul    fp1,fp4
  946.         fmul    fp1,fp5
  947.         lea     _vup,a3
  948.         fmove.s (a3)+,fp6
  949.         fmul    fp2,fp6
  950.         fadd    fp6,fp3
  951.         fmove.s (a3)+,fp6
  952.         fmul    fp2,fp6
  953.         fadd    fp6,fp4
  954.         fmove.s (a3)+,fp6
  955.         fmul    fp2,fp6
  956.         fadd    fp6,fp5
  957.         lea     _vpn,a3
  958.         fmove.s (a3)+,fp6
  959.         fmul    fp0,fp6
  960.         fadd    fp6,fp3
  961.         fmove.s fp3,(a1)+
  962.         fmove.s (a3)+,fp6
  963.         fmul    fp0,fp6
  964.         fadd    fp6,fp4
  965.         fmove.s fp4,(a1)+
  966.         fmove.s (a3)+,fp6
  967.         fmul    fp0,fp6
  968.         fadd    fp6,fp5
  969.         fmove.s fp5,(a1)+
  970.  
  971.         fmul    fp7,fp3
  972.         fmul.s  (a4),fp4
  973.         fadd    fp4,fp3
  974.         fmul.s  4(a4),fp5
  975.         fadd    fp5,fp3
  976.         fmove.s fp3,(a1)+
  977.         lea     CLIP_SIZEOF-16(a1),a1
  978.         lea     MPLANE_SIZEOF-12(a0),a0
  979.         dbra    d0,.loop4
  980.  
  981. ******  end of R_TransformFrustum
  982.  
  983.         fmove.s (sp)+,fp5
  984.         fmove.s (sp)+,fp4
  985.         fmove.s (sp)+,fp3
  986.         move.l  #_r_worldentity,_currententity
  987. .next2
  988.         lea     SURF_SIZEOF(a2),a2
  989.         bra.w   .loop2
  990. .end
  991.         fmovem.x        (sp)+,fp2-fp7
  992.         movem.l (sp)+,d2/a2-a4
  993.         rts
  994.