home *** CD-ROM | disk | FTP | other *** search
/ Enigma Amiga Life 113 / EnigmaAmiga113CD.iso / software / sviluppo / quake_src / d_polysetppc.s < prev    next >
Encoding:
Text File  |  2000-06-17  |  37.2 KB  |  1,502 lines
  1. # 
  2. # Copyright (C) 1996-1997 Id Software, Inc. 
  3. # 
  4. # This program is free software; you can redistribute it and/or 
  5. # modify it under the terms of the GNU General Public License 
  6. # as published by the Free Software Foundation; either version 2 
  7. # of the License, or (at your option) any later version. 
  8. # 
  9. # This program is distributed in the hope that it will be useful, 
  10. # but WITHOUT ANY WARRANTY; without even the implied warranty of 
  11. # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.   
  12. # 
  13. # See the GNU General Public License for more details. 
  14. # 
  15. # You should have received a copy of the GNU General Public License 
  16. # along with this program; if not, write to the Free Software 
  17. # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA  02111-1307, USA. 
  18. # 
  19.  
  20. ##
  21. ## Quake for AMIGA
  22. ##
  23. ## d_polysetPPC.s
  24. ##
  25. ## Define WOS for PowerOpen ABI, otherwise SVR4-ABI is used.
  26. ##
  27.  
  28. .include        "macrosPPC.i"
  29.  
  30. #
  31. # external references
  32. #
  33.  
  34.     xrefv    acolormap
  35.     xrefv    d_aspancount
  36.     xrefv    errorterm
  37.     xrefv    erroradjustup
  38.     xrefv    erroradjustdown
  39.     xrefv    d_countextrastep
  40.     xrefv    ubasestep
  41.     xrefa    r_affinetridesc
  42.     xrefv    a_ststepxwhole
  43.     xrefv    a_sstepxfrac
  44.     xrefv    a_tstepxfrac
  45.     xrefv    r_lstepx
  46.     xrefv    r_lstepy
  47.     xrefv    r_sstepx
  48.     xrefv    r_sstepy
  49.     xrefv    r_tstepx
  50.     xrefv    r_tstepy
  51.     xrefv    r_zistepx
  52.     xrefv    r_zistepy
  53.     xrefa    zspantable
  54.     xrefa    skintable
  55.     xrefa    r_p0
  56.     xrefa    r_p1
  57.     xrefa    r_p2
  58.     xrefv    d_xdenom
  59.     xrefv    d_pcolormap
  60.     xrefa    d_scantable
  61.     xrefv    d_viewbuffer
  62.     xrefv    d_pedgespanpackage
  63.     xrefv    d_pdest
  64.     xrefv    d_pz
  65.     xrefv    d_aspancount
  66.     xrefv    d_ptex
  67.     xrefv    d_sfrac
  68.     xrefv    d_tfrac
  69.     xrefv    d_light
  70.     xrefv    d_zi
  71.     xrefv    d_pdestextrastep
  72.     xrefv    d_pzextrastep
  73.     xrefv    d_countextrastep
  74.     xrefv    d_ptexextrastep
  75.     xrefv    d_sfracextrastep
  76.     xrefv    d_tfracextrastep
  77.     xrefv    d_lightextrastep
  78.     xrefv    d_ziextrastep
  79.     xrefv    d_pdestbasestep
  80.     xrefv    d_pzbasestep
  81.     xrefv    d_ptexbasestep
  82.     xrefv    d_sfracbasestep
  83.     xrefv    d_tfracbasestep
  84.     xrefv    d_lightbasestep
  85.     xrefv    d_zibasestep
  86.     xrefv    d_zwidth
  87.     xrefv    d_pzbuffer
  88.     xrefv    a_spans
  89.     xrefv    pedgetable
  90.     xrefa    edgetables
  91.     xrefv    screenwidth
  92.     xrefv    INT2DBL_0
  93.     xrefv    c2
  94.  
  95.     xrefv    FloorDivMod
  96.     xrefv    D_RasterizeAliasPolySmooth
  97.  
  98.  
  99. #
  100. # defines
  101. #
  102.  
  103. .set    ALIAS_ONSEAM      ,32        #must match the def. in r_shared.h
  104.  
  105. .set    PSPANP_PDEST      ,0
  106. .set    PSPANP_PZ         ,4
  107. .set    PSPANP_COUNT      ,8
  108. .set    PSPANP_PTEX       ,12
  109. .set    PSPANP_SFRAC      ,16
  110. .set    PSPANP_TFRAC      ,20
  111. .set    PSPANP_LIGHT      ,24
  112. .set    PSPANP_ZI         ,28
  113. .set    PSPANP_SIZEOF     ,32
  114. .set    PSPANP_SIZEOF_EXP ,5
  115.  
  116. .set    R_PSKIN           ,0
  117. .set    R_PSKINDESC       ,4
  118. .set    R_SKINWIDTH       ,8
  119. .set    R_SKINHEIGHT      ,12
  120. .set    R_PTRIANGLES      ,16
  121. .set    R_PFINALVERTS     ,20
  122. .set    R_NUMTRIANGLES    ,24
  123. .set    R_DRAWTYPE        ,28
  124. .set    R_SEAMFIXUP16     ,32
  125. .set    R_SIZEOF          ,36
  126.  
  127. .set    PTEMP_QUOTIENT    ,0
  128. .set    PTEMP_REMAINDER   ,4
  129.  
  130. .set    ETAB_ISFLATTOP    ,0
  131. .set    ETAB_NUMLEFTEDGES ,4
  132. .set    ETAB_PLEV0        ,8
  133. .set    ETAB_PLEV1        ,12
  134. .set    ETAB_PLEV2        ,16
  135. .set    ETAB_NUMRIGHTEDGES,20
  136. .set    ETAB_PREV0        ,24
  137. .set    ETAB_PREV1        ,28
  138. .set    ETAB_PREV2        ,32
  139. .set    ETAB_SIZEOF       ,36
  140.  
  141. .set    MT_FACESFRONT     ,0
  142. .set    MT_VERTINDEX      ,4
  143. .set    MT_SIZEOF         ,16
  144.  
  145. .set    FV_V              ,0
  146. .set    FV_FLAGS          ,24
  147. .set    FV_RESERVED       ,28
  148. .set    FV_SIZEOF         ,32
  149. .set    FV_SIZEOF_EXP     ,5
  150.  
  151. .set    EDGETABLE_SIZEOF  ,36
  152.  
  153.  
  154.  
  155.  
  156.  
  157. ###########################################################################
  158. #
  159. #       void D_PolysetDrawSpans8 (spanpackage_t *pspanpackage)
  160. #
  161. #       standard scan drawing function for alias models
  162. #
  163. ###########################################################################
  164.  
  165.     funcdef    D_PolysetDrawSpans8
  166.  
  167.     init    0,0,12,0
  168.     stmw    r20,gb(r1)
  169.  
  170.     lw      r4,d_aspancount
  171.     lw      r5,errorterm
  172.     lw      r6,erroradjustup
  173.     lw      r7,erroradjustdown
  174.     lw      r8,d_countextrastep
  175.     lw      r9,ubasestep
  176.     lw      r10,acolormap
  177.     lw      r11,r_zistepx
  178.     lw      r12,a_ststepxwhole
  179.     lw      r31,a_sstepxfrac
  180.     lw      r30,a_tstepxfrac
  181.     lw      r29,r_lstepx
  182.     lxa     r28,r_affinetridesc
  183.     lwz     r28,R_SKINWIDTH(r28)
  184.  
  185. .ds8loop:
  186.  
  187. #                lcount = d_aspancount - pspanpackage->count;
  188. #
  189. #                errorterm += erroradjustup;
  190. #                if (errorterm >= 0)
  191. #                {
  192. #                        d_aspancount += d_countextrastep;
  193. #                        errorterm -= erroradjustdown;
  194. #                }
  195. #                else
  196. #                {
  197. #                        d_aspancount += ubasestep;
  198. #                }
  199.  
  200.     lwz     r0,PSPANP_COUNT(r3)
  201.     subf    r0,r0,r4
  202.     add.    r5,r5,r6
  203.     blt     .ds8else
  204.     add     r4,r4,r8
  205.     subf    r5,r7,r5
  206.     b       .ds8next
  207. .ds8else:
  208.     add     r4,r4,r9
  209. .ds8next:
  210.     mr.     r0,r0
  211.     beq     .ds8loopend
  212.     mtctr   r0
  213.  
  214. #                        lpdest = pspanpackage->pdest;
  215. #                        lptex = pspanpackage->ptex;
  216. #                        lpz = pspanpackage->pz;
  217. #                        lsfrac = pspanpackage->sfrac;
  218. #                        ltfrac = pspanpackage->tfrac;
  219. #                        llight = pspanpackage->light;
  220. #                        lzi = pspanpackage->zi;
  221.  
  222.     lwz     r27,PSPANP_PDEST(r3)
  223.     lwz     r26,PSPANP_PZ(r3)
  224.     lwz     r25,PSPANP_PTEX(r3)
  225.     lwz     r24,PSPANP_SFRAC(r3)
  226.     lwz     r23,PSPANP_TFRAC(r3)
  227.     lwz     r22,PSPANP_LIGHT(r3)
  228.     lwz     r21,PSPANP_ZI(r3)
  229.  
  230. ###### main drawing loop
  231.  
  232. ###### r21 = lzi
  233. ###### r22 = llight
  234. ###### r24 = lsfrac
  235. ###### r11 = r_zistepx
  236. ###### r23 = ltfrac
  237. ###### r30 = a_tstepxfrac
  238. ###### r28 = r_affinetridesc.skinwidth
  239. ###### r27 -> lpdest
  240. ###### r26 -> lpz
  241. ###### r25 -> lptex
  242. ###### r10 -> acolormap
  243. ###### r31 = a_sstepxfrac
  244. ###### r12 = a_ststepxwhole
  245. ###### r29 = r_lstepx
  246.  
  247. #                        do
  248. #                        {
  249. #                                if ((lzi >> 16) >= *lpz)
  250. #                                {
  251. #                                        *lpdest = ((byte *)acolormap)[*lptex + (llight & 0xFF00)];
  252. #                                        *lpz = lzi >> 16;
  253. #                                }
  254. #                                lpdest++;
  255. #                                lzi += r_zistepx;
  256. #                                lpz++;
  257. #                                llight += r_lstepx;
  258. #                                lptex += a_ststepxwhole;
  259. #                                lsfrac += a_sstepxfrac;
  260. #                                lptex += lsfrac >> 16;
  261. #                                lsfrac &= 0xFFFF;
  262. #                                ltfrac += a_tstepxfrac;
  263. #                                if (ltfrac & 0x10000)
  264. #                                {
  265. #                                        lptex += r_affinetridesc.skinwidth;
  266. #                                        ltfrac &= 0xFFFF;
  267. #                                }
  268. #                        } while (--lcount);
  269.  
  270. .ds8loop2:
  271.     srwi    r0,r21,16
  272.     lhz     r20,0(r26)
  273.     cmpw    r0,r20
  274.     blt     .ds8cont
  275.     lbz     r20,0(r25)
  276.     rlwimi  r20,r22,0,16,23
  277.     lbzx    r20,r10,r20
  278.     stb     r20,0(r27)
  279.     sth     r0,0(r26)
  280. .ds8cont:
  281.     add     r24,r24,r31
  282.     addi    r26,r26,2
  283.     addi    r27,r27,1
  284.     srwi    r0,r24,16
  285.     add     r21,r21,r11
  286.     add     r22,r22,r29
  287.     add     r25,r25,r12
  288.     add     r23,r23,r30
  289.     clrlwi  r24,r24,16
  290.     add     r25,r25,r0
  291.     andis.  r0,r23,1
  292.     beq     .ds8cont2
  293.     add     r25,r25,r28
  294.     clrlwi  r23,r23,16
  295. .ds8cont2:
  296.     bdnz    .ds8loop2
  297. .ds8loopend:
  298.  
  299. #                pspanpackage++;
  300. #        } while (pspanpackage->count != -999999);
  301.  
  302.     la      r3,PSPANP_SIZEOF(r3)
  303.     lwz     r0,PSPANP_COUNT(r3)
  304.     lis     r20,-999999@h
  305.     ori     r20,r20,-999999@l
  306.     cmpw    r20,r0
  307.     bne     .ds8loop
  308.  
  309.     lmw    r20,gb(r1)
  310.     exit
  311.  
  312.     funcend    D_PolysetDrawSpans8
  313.  
  314.  
  315.  
  316.  
  317. ###########################################################################
  318. #
  319. #       void D_PolysetRecursiveTriangle (int *lp1, int *lp2, int *lp3)
  320. #
  321. ###########################################################################
  322.  
  323.     funcdef    D_PolysetRecursiveTriangle
  324.  
  325.     init    0,0,3,0
  326.     stw    r24,gb+0*4(r1)
  327.     stw    r25,gb+1*4(r1)
  328.     stw    r26,gb+2*4(r1)
  329.     lxa     r6,zspantable
  330.     lw      r7,d_viewbuffer
  331.     lxa     r26,skintable
  332.     lw      r25,d_pcolormap
  333.     lxa     r24,d_scantable
  334.     bl    DoRecursion
  335.     lwz    r24,gb+0*4(r1)
  336.     lwz    r25,gb+1*4(r1)
  337.     lwz    r26,gb+2*4(r1)
  338.     exit
  339.  
  340.  
  341. DoRecursion:
  342.     init    0,24,5,0
  343.     stmw    r27,gb(r1)
  344.  
  345.     mr      r31,r3
  346.     mr      r30,r4
  347.     mr      r29,r5
  348.     la    r28,local(r1)
  349.  
  350. #        d = lp2[0] - lp1[0];
  351. #        if (d < -1 || d > 1)
  352. #                goto split;
  353. #        d = lp2[1] - lp1[1];
  354. #        if (d < -1 || d > 1)
  355. #                goto split;
  356. #
  357. #        d = lp3[0] - lp2[0];
  358. #        if (d < -1 || d > 1)
  359. #                goto split2;
  360. #        d = lp3[1] - lp2[1];
  361. #        if (d < -1 || d > 1)
  362. #                goto split2;
  363. #
  364. #        d = lp1[0] - lp3[0];
  365. #        if (d < -1 || d > 1)
  366. #                goto split3;
  367. #        d = lp1[1] - lp3[1];
  368. #        if (d < -1 || d > 1)
  369.  
  370.     lwz     r9,0(r30)
  371.     lwz     r10,0(r31)
  372.     lwz     r11,1*4(r30)
  373.     lwz     r12,1*4(r31)
  374.     subf    r3,r10,r9
  375.     addi    r3,r3,1
  376.     cmplwi  r3,2
  377.     bgt     .rtsplit
  378.     subf    r4,r12,r11
  379.     addi    r4,r4,1
  380.     cmplwi  r4,2
  381.     bgt     .rtsplit
  382.     lwz     r3,0(r29)
  383.     subf    r5,r9,r3
  384.     addi    r5,r5,1
  385.     cmplwi  r5,2
  386.     bgt     .rtsplit2
  387.     lwz     r4,1*4(r29)
  388.     subf    r5,r11,r4
  389.     addi    r5,r5,1
  390.     cmplwi  r5,2
  391.     bgt     .rtsplit2
  392.     subf    r5,r10,r3
  393.     addi    r5,r5,1
  394.     cmplwi  r5,2
  395.     bgt     .rtsplit3
  396.     subf    r5,r12,r4
  397.     addi    r5,r5,1
  398.     cmplwi  r5,2
  399.     ble     .rtexit
  400.  
  401. #split3:
  402. #                temp = lp1;
  403. #                lp1 = lp3;
  404. #                lp3 = lp2;
  405. #                lp2 = temp;
  406. #
  407. #                goto split;
  408. #
  409. #split2:
  410. #        temp = lp1;
  411. #        lp1 = lp2;
  412. #        lp2 = lp3;
  413. #        lp3 = temp;
  414.  
  415. .rtsplit3:
  416.     mr      r0,r29
  417.     mr      r29,r30
  418.     mr      r30,r31
  419.     mr      r31,r0
  420.     lwz     r9,0(r30)
  421.     lwz     r10,0(r31)
  422.     lwz     r11,1*4(r30)
  423.     lwz     r12,1*4(r31)
  424.     b       .rtsplit
  425. .rtsplit2:
  426.     mr      r0,r31
  427.     mr      r31,r30
  428.     mr      r30,r29
  429.     mr      r29,r0
  430.     lwz     r9,0(r30)
  431.     lwz     r10,0(r31)
  432.     lwz     r11,1*4(r30)
  433.     lwz     r12,1*4(r31)
  434. .rtsplit:
  435.  
  436. #        new[0] = (lp1[0] + lp2[0]) >> 1;
  437. #        new[1] = (lp1[1] + lp2[1]) >> 1;
  438. #        new[2] = (lp1[2] + lp2[2]) >> 1;
  439. #        new[3] = (lp1[3] + lp2[3]) >> 1;
  440. #        new[5] = (lp1[5] + lp2[5]) >> 1;
  441.  
  442.     add     r3,r9,r10
  443.     srawi   r3,r3,1                 #r3 = new[0]
  444.     stw     r3,0(r28)
  445.     add     r4,r11,r12
  446.     srawi   r4,r4,1                 #r4 = new[1]
  447.     stw     r4,4(r28)
  448.     lwz     r5,2*4(r31)
  449.     lwz     r0,2*4(r30)
  450.     add     r5,r5,r0
  451.     srawi   r5,r5,1                 #r5 = new[2]
  452.     stw     r5,8(r28)
  453.     lwz     r8,3*4(r31)
  454.     lwz     r0,3*4(r30)
  455.     add     r8,r8,r0
  456.     srawi   r8,r8,1                 #r8 = new[3]
  457.     stw     r8,12(r28)
  458.     lwz     r27,5*4(r31)
  459.     lwz     r0,5*4(r30)
  460.     add     r27,r27,r0
  461.     srawi   r27,r27,1               #r27 = new[5]
  462.     stw     r27,20(r28)
  463.  
  464. #        if (lp2[1] > lp1[1])
  465. #                goto nodraw;
  466. #        if ((lp2[1] == lp1[1]) && (lp2[0] < lp1[0]))
  467. #                goto nodraw;
  468.  
  469.  
  470.     cmpw    r11,r12
  471.     bgt     .rtnodraw
  472.     bne     .rtdraw
  473.     cmpw    r9,r10
  474.     blt     .rtnodraw
  475. .rtdraw:
  476.     srwi    r27,r27,16              #r27 = z = new[5]>>16
  477.  
  478. #        z = new[5]>>16;
  479. #        zbuf = zspantable[new[1]] + new[0];
  480. #        if (z >= *zbuf)
  481. #        {
  482. #                int             pix;
  483. #
  484. #                *zbuf = z;
  485. #                pix = d_pcolormap[skintable[new[3]>>16][new[2]>>16]];
  486. #                d_viewbuffer[d_scantable[new[1]] + new[0]] = pix;
  487. #        }
  488.  
  489.     slwi    r0,r4,2
  490.     lwzx    r9,r6,r0
  491.     add     r10,r3,r3
  492.     lhzx    r11,r9,r10
  493.     cmpw    r27,r11
  494.     blt     .rtnodraw
  495.     sthx    r27,r9,r10
  496.     srawi   r5,r5,16
  497.     srawi   r8,r8,16
  498.     slwi    r8,r8,2
  499.     lwzx    r12,r26,r8
  500.     lbzx    r9,r12,r5
  501.     lbzx    r10,r25,r9
  502.     lwzx    r11,r24,r0
  503.     add     r11,r11,r3
  504.     stbx    r10,r7,r11
  505. .rtnodraw:
  506.  
  507. #// recursively continue
  508. #        D_PolysetRecursiveTriangle (lp3, lp1, new);
  509. #        D_PolysetRecursiveTriangle (lp3, new, lp2);
  510.  
  511.     mr      r3,r29
  512.     mr      r4,r31
  513.     mr      r5,r28
  514.     bl      DoRecursion
  515.     mr      r3,r29
  516.     mr      r4,r28
  517.     mr      r5,r30
  518.     bl      DoRecursion
  519.  
  520. .rtexit:
  521.     lmw    r27,gb(r1)
  522.     exit
  523.  
  524.     funcend    D_PolysetRecursiveTriangle
  525.  
  526.  
  527.  
  528.  
  529. ###########################################################################
  530. #
  531. #       void D_PolysetSetUpForLineScan (fixed8_t startvertu,
  532. #               fixed8_t startvertv, fixed8_t endvertu, fixed8_t endvertv)
  533. #
  534. #       Parameters are transferred in registers d0-d3
  535. #
  536. ###########################################################################
  537.  
  538.     funcdef    D_PolysetSetUpForLineScan
  539.  
  540. #        errorterm = -1;
  541. #
  542. #        tm = endvertu - startvertu;
  543. #        tn = endvertv - startvertv;
  544.  
  545.     li    r0,-1
  546.     sw    r0,errorterm
  547.     subf    r5,r3,r5
  548.     subf    r6,r4,r6
  549.     addi    r5,r5,15
  550.     addi    r6,r6,15
  551.  
  552. #        if (((tm <= 16) && (tm >= -15)) &&
  553. #                ((tn <= 16) && (tn >= -15)))
  554. #        {
  555. #                ptemp = &adivtab[((tm+15) << 5) + (tn+15)];
  556. #                ubasestep = ptemp->quotient;
  557. #                erroradjustup = ptemp->remainder;
  558. #                erroradjustdown = tn;
  559. #        }
  560.  
  561.     cmplwi  r5,31
  562.     bgt     .sflselse
  563.     cmplwi  r6,31
  564.     bgt     .sflselse
  565.     lxa     r8,adivtab
  566.     slwi    r5,r5,5
  567.     add     r5,r5,r6
  568.     slwi    r5,r5,3
  569.     add     r8,r8,r5
  570.     lwz     r3,PTEMP_QUOTIENT(r8)
  571.     sw      r3,ubasestep
  572.     lwz     r4,PTEMP_REMAINDER(r8)
  573.     sw      r4,erroradjustup
  574.     subi    r6,r6,15
  575.     sw      r6,erroradjustdown
  576.     b       .sflsexit
  577.  
  578. #        {
  579. #                dm = (double)tm;
  580. #                dn = (double)tn;
  581. #
  582. #                FloorDivMod (dm, dn, &ubasestep, &erroradjustup);
  583. #
  584. #                erroradjustdown = dn;
  585. #        }
  586.  
  587. .sflselse:
  588.     subi    r5,r5,15
  589.     subi    r6,r6,15
  590.     sw      r6,erroradjustdown
  591.     mr.     r5,r5
  592.     divw    r7,r5,r6
  593.     mullw   r8,r7,r6
  594.     subf    r8,r8,r5
  595.     bge     .sflscont
  596.     subi    r7,r7,1
  597.     add     r8,r8,r6
  598. .sflscont:
  599.     sw      r7,ubasestep
  600.     sw      r8,erroradjustup
  601. .sflsexit:
  602.     blr
  603.  
  604.     funcend    D_PolysetSetUpForLineScan
  605.  
  606.  
  607.  
  608.  
  609. ###########################################################################
  610. #
  611. #       void D_PolysetCalcGradients (int skinwidth)
  612. #
  613. ###########################################################################
  614.  
  615.     funcdef    D_PolysetCalcGradients
  616.  
  617. #        p00_minus_p20 = r_p0[0] - r_p2[0];
  618. #        p01_minus_p21 = r_p0[1] - r_p2[1];
  619. #        p10_minus_p20 = r_p1[0] - r_p2[0];
  620. #        p11_minus_p21 = r_p1[1] - r_p2[1];
  621. #
  622. #        xstepdenominv = 1.0 / (float)d_xdenom;
  623. #
  624. #        ystepdenominv = -xstepdenominv;
  625.  
  626.     stwu    r1,-64(r1)
  627.     lw      r11,d_xdenom
  628.     ls      f9,c2
  629.     lf      f1,INT2DBL_0            #for int2dbl_setup, r12=tmp
  630.     stfd    f1,32(r1)
  631.     lxa     r4,r_p2
  632.     lxa     r5,r_p1
  633.     lxa     r6,r_p0
  634.     int2dbl    f6,r11,r12,32,f1
  635.     lwz     r7,0(r6)
  636.     lwz     r8,1*4(r6)
  637.     fneg    f6,f6
  638.     lwz     r9,0(r4)
  639.     subf    r7,r9,r7
  640.     fmuls   f7,f6,f6
  641.     int2dbl    f2,r7,r12,32,f1        #f2 = p00_minus_p20
  642.     frsqrte f7,f7
  643.     lwz     r10,1*4(r4)
  644.     subf    r8,r10,r8
  645.     fnmsubs f8,f7,f6,f9
  646.     int2dbl f3,r8,r12,32,f1        #f3 = p01_minus_p21
  647.     fmuls   f7,f7,f8
  648.     lwz     r7,0(r5)
  649.     subf    r7,r9,r7
  650.     fnmsubs f8,f7,f6,f9
  651.     int2dbl f4,r7,r12,32,f1        #f4 = p10_minus_p20
  652.     fmuls   f7,f7,f8
  653.     lwz     r8,1*4(r5)
  654.     subf    r8,r10,r8
  655.     fneg    f6,f7
  656.     int2dbl f5,r8,r12,32,f1        #f5 = p11_minus_p21
  657.     fmuls   f3,f3,f6
  658.     fmuls   f5,f5,f6
  659.     fmuls   f2,f2,f7
  660.     fmuls   f4,f4,f7
  661.  
  662. #        t0 = r_p0[4] - r_p2[4];
  663. #        t1 = r_p1[4] - r_p2[4];
  664. #        r_lstepx = (int)
  665. #                        ceil((t1 * p01_minus_p21 - t0 * p11_minus_p21) * xstepdenominv);
  666. #        r_lstepy = (int)
  667. #                        ceil((t1 * p00_minus_p20 - t0 * p10_minus_p20) * ystepdenominv);
  668.  
  669.     mffs    f8
  670.     mtfsfi  cr7,2
  671.     lwz     r7,4*4(r4)
  672.     lwz     r8,4*4(r6)
  673.     subf    r9,r7,r8
  674.     int2dbl f9,r9,r12,32,f1        #f9 = t0
  675.     lwz     r8,4*4(r5)
  676.     subf    r9,r7,r8
  677.     int2dbl f10,r9,r12,32,f1    #f10 = t1
  678.     fmuls   f11,f9,f5
  679.     fmuls   f12,f9,f4
  680.     fmsubs  f11,f10,f3,f11
  681.     fctiw   f0,f11            #@@@ ab hier ein bißchen optimiert
  682.     stfd    f0,40(r1)
  683.     fmsubs  f12,f10,f2,f12
  684.     lwz     r7,44(r1)
  685.     fctiw   f13,f12
  686.     stfd    f13,48(r1)
  687.     mtfsf   1,f8
  688.     lwz     r8,52(r1)
  689.     sw      r7,r_lstepx
  690.     sw      r8,r_lstepy
  691.  
  692. #        t0 = r_p0[2] - r_p2[2];
  693. #        t1 = r_p1[2] - r_p2[2];
  694. #        r_sstepx = (int)((t1 * p01_minus_p21 - t0 * p11_minus_p21) *
  695. #                        xstepdenominv);
  696. #        r_sstepy = (int)((t1 * p00_minus_p20 - t0* p10_minus_p20) *
  697. #                        ystepdenominv);
  698.  
  699.     lwz     r7,2*4(r4)
  700.     lwz     r8,2*4(r6)
  701.     subf    r9,r7,r8
  702.     int2dbl f9,r9,r12,32,f1        #f9 = t0
  703.     lwz     r8,2*4(r5)
  704.     subf    r9,r7,r8
  705.     int2dbl f10,r9,r12,32,f1    #f10 = t1
  706.     fmuls   f11,f9,f5
  707.     fmuls   f12,f9,f4
  708.     fmsubs  f11,f10,f3,f11
  709.     fctiwz  f0,f11            #@@@ ab hier ein bißchen optimiert
  710.     stfd    f0,40(r1)
  711.     fmsubs  f12,f10,f2,f12
  712.     lwz     r10,44(r1)
  713.     fctiwz  f13,f12
  714.     stfd    f13,48(r1)
  715.     lwz     r8,52(r1)
  716.     sw      r10,r_sstepx
  717.     sw      r8,r_sstepy
  718.  
  719. #        t0 = r_p0[3] - r_p2[3];
  720. #        t1 = r_p1[3] - r_p2[3];
  721. #        r_tstepx = (int)((t1 * p01_minus_p21 - t0 * p11_minus_p21) *
  722. #                        xstepdenominv);
  723. #        r_tstepy = (int)((t1 * p00_minus_p20 - t0 * p10_minus_p20) *
  724. #                        ystepdenominv);
  725.  
  726.     lwz     r7,3*4(r4)
  727.     lwz     r8,3*4(r6)
  728.     subf    r9,r7,r8
  729.     int2dbl f9,r9,r12,32,f1        #f9 = t0
  730.     lwz     r8,3*4(r5)
  731.     subf    r9,r7,r8
  732.     int2dbl f10,r9,r12,32,f1    #f10 = t1
  733.     fmuls   f11,f9,f5
  734.     fmuls   f12,f9,f4
  735.     fmsubs  f11,f10,f3,f11
  736.     fctiwz  f0,f11            #@@@ ab hier ein bißchen optimiert
  737.     stfd    f0,40(r1)
  738.     fmsubs  f12,f10,f2,f12
  739.     lwz     r11,44(r1)
  740.     fctiwz  f13,f12
  741.     stfd    f13,48(r1)
  742.     lwz     r8,52(r1)
  743.     sw      r11,r_tstepx
  744.     sw      r8,r_tstepy
  745.  
  746. #        t0 = r_p0[5] - r_p2[5];
  747. #        t1 = r_p1[5] - r_p2[5];
  748. #        r_zistepx = (int)((t1 * p01_minus_p21 - t0 * p11_minus_p21) *
  749. #                        xstepdenominv);
  750. #        r_zistepy = (int)((t1 * p00_minus_p20 - t0 * p10_minus_p20) *
  751. #                        ystepdenominv);
  752.  
  753.     lwz     r7,5*4(r4)
  754.     lwz     r8,5*4(r6)
  755.     subf    r9,r7,r8
  756.     int2dbl f9,r9,r12,32,f1        #f9 = t0
  757.     lwz     r8,5*4(r5)
  758.     subf    r9,r7,r8
  759.     int2dbl f10,r9,r12,32,f1    #f10 = t1
  760.     fmuls   f11,f9,f5
  761.     fmuls   f12,f9,f4
  762.     fmsubs  f11,f10,f3,f11
  763.     fctiwz  f0,f11            #@@@ ab hier ein bißchen optimiert
  764.     stfd    f0,40(r1)
  765.     fmsubs  f12,f10,f2,f12
  766.     lwz     r7,44(r1)
  767.     fctiwz  f13,f12
  768.     stfd    f13,48(r1)
  769.     lwz     r8,52(r1)
  770.     sw      r7,r_zistepx
  771.     sw      r8,r_zistepy
  772.  
  773. #        a_sstepxfrac = r_sstepx & 0xFFFF;
  774. #        a_tstepxfrac = r_tstepx & 0xFFFF;
  775. #        a_ststepxwhole = skinwidth * (r_tstepx >> 16) + (r_sstepx >> 16);
  776.  
  777.     andi.   r4,r10,0xffff
  778.     srawi   r6,r10,16
  779.     sw      r4,a_sstepxfrac
  780.     andi.   r5,r11,0xffff
  781.     srawi   r7,r11,16
  782.     sw      r5,a_tstepxfrac
  783.     mullw   r7,r7,r3
  784.     add     r7,r7,r6
  785.     sw      r7,a_ststepxwhole
  786.     addi    r1,r1,64
  787.     blr
  788.  
  789.     funcend    D_PolysetCalcGradients
  790.  
  791.  
  792.  
  793.  
  794. ###########################################################################
  795. #
  796. #       void D_PolysetScanLeftEdge (int height)
  797. #
  798. ###########################################################################
  799.  
  800.     funcdef    D_PolysetScanLeftEdge
  801.  
  802. .ifdef    WOS
  803.     init    0,0,19,0
  804.     stmw    r13,gb(r1)
  805. .else
  806. # r14 is used and save internally, r13 may be used as small data pointer
  807.     init    0,0,17,0
  808.     stmw    r15,gb(r1)
  809. .endif
  810.  
  811.     mtctr   r3
  812.     lw      r3,d_pedgespanpackage
  813.     subi    r3,r3,4
  814.     lw      r4,d_pdest
  815.     lw      r5,d_pz
  816.     lw      r6,d_aspancount
  817.     lw      r7,d_ptex
  818.     lw      r8,d_sfrac
  819.     lw      r9,d_tfrac
  820.     lw      r10,d_light
  821.     lw      r11,d_zi
  822.     lxa     r12,r_affinetridesc
  823.     lwz     r12,R_SKINWIDTH(r12)
  824.     lw      r31,errorterm
  825.     lw      r30,erroradjustup
  826.     lw      r29,erroradjustdown
  827.     lw      r28,d_pdestextrastep
  828.     lw      r27,d_pzextrastep
  829.     add     r27,r27,r27
  830.     lw      r26,d_countextrastep
  831.     lw      r25,d_ptexextrastep
  832.     lw      r24,d_sfracextrastep
  833.     lw      r23,d_tfracextrastep
  834.     lw      r22,d_lightextrastep
  835.     lw      r21,d_ziextrastep
  836.     lw      r20,d_pdestbasestep
  837.     lw      r19,d_pzbasestep
  838.     add     r19,r19,r19
  839.     lw      r18,ubasestep
  840.     lw      r17,d_ptexbasestep
  841.     lw      r16,d_sfracbasestep
  842.     lw      r15,d_tfracbasestep
  843. .ifdef    WOS
  844.     lw      r14,d_lightbasestep
  845.     lw      r13,d_zibasestep
  846. .endif
  847.  
  848. .sleloop:
  849.  
  850. #                d_pedgespanpackage->pdest = d_pdest;
  851. #                d_pedgespanpackage->pz = d_pz;
  852. #                d_pedgespanpackage->count = d_aspancount;
  853. #                d_pedgespanpackage->ptex = d_ptex;
  854. #
  855. #                d_pedgespanpackage->sfrac = d_sfrac;
  856. #                d_pedgespanpackage->tfrac = d_tfrac;
  857. #
  858. #                d_pedgespanpackage->light = d_light;
  859. #                d_pedgespanpackage->zi = d_zi;
  860. #
  861. #                d_pedgespanpackage++;
  862. #
  863. #                errorterm += erroradjustup;
  864. #                if (errorterm >= 0)
  865.  
  866.     stwu    r4,4(r3)
  867.     add.    r31,r31,r30
  868.     stwu    r5,4(r3)
  869.     stwu    r6,4(r3)
  870.     stwu    r7,4(r3)
  871.     stwu    r8,4(r3)
  872.     stwu    r9,4(r3)
  873.     stwu    r10,4(r3)
  874.     stwu    r11,4(r3)
  875.     blt     .sleelse
  876.  
  877. #                        d_pdest += d_pdestextrastep;
  878. #                        d_pz += d_pzextrastep;
  879. #                        d_aspancount += d_countextrastep;
  880. #                        d_ptex += d_ptexextrastep;
  881. #                        d_sfrac += d_sfracextrastep;
  882. #                        d_ptex += d_sfrac >> 16;
  883. #
  884. #                        d_sfrac &= 0xFFFF;
  885. #                        d_tfrac += d_tfracextrastep;
  886. #                        if (d_tfrac & 0x10000)
  887. #                        {
  888. #                                d_ptex += r_affinetridesc.skinwidth;
  889. #                                d_tfrac &= 0xFFFF;
  890. #                        }
  891. #                        d_light += d_lightextrastep;
  892. #                        d_zi += d_ziextrastep;
  893. #                        errorterm -= erroradjustdown;
  894.  
  895.     add     r8,r8,r24
  896.     add     r4,r4,r28
  897.     add     r5,r5,r27
  898.     add     r10,r10,r22
  899.     add     r11,r11,r21
  900.     add     r7,r7,r25
  901.     srawi   r0,r8,16
  902.     add     r6,r6,r26
  903.     add     r9,r9,r23
  904.     add     r7,r7,r0
  905.     andi.   r8,r8,0xffff
  906.     andis.  r0,r9,1
  907.     subf    r31,r29,r31
  908.     beq     .slenext
  909.     add     r7,r7,r12
  910.     andi.   r9,r9,0xffff
  911.     b       .slenext
  912. .sleelse:
  913.  
  914. #                        d_pdest += d_pdestbasestep;
  915. #                        d_pz += d_pzbasestep;
  916. #                        d_aspancount += ubasestep;
  917. #                        d_ptex += d_ptexbasestep;
  918. #                        d_sfrac += d_sfracbasestep;
  919. #                        d_ptex += d_sfrac >> 16;
  920. #                        d_sfrac &= 0xFFFF;
  921. #                        d_tfrac += d_tfracbasestep;
  922. #                        if (d_tfrac & 0x10000)
  923. #                        {
  924. #                                d_ptex += r_affinetridesc.skinwidth;
  925. #                                d_tfrac &= 0xFFFF;
  926. #                        }
  927. #                        d_light += d_lightbasestep;
  928. #                        d_zi += d_zibasestep;
  929.  
  930. .ifdef    WOS
  931.     add     r8,r8,r16
  932.     add     r4,r4,r20
  933.     add     r5,r5,r19
  934.     add     r10,r10,r14
  935.     add     r11,r11,r13
  936.     add     r7,r7,r17
  937. .else
  938.     lw      r0,d_lightbasestep
  939.     add     r8,r8,r16
  940.     add     r4,r4,r20
  941.     add     r10,r10,r0
  942.     lw      r0,d_zibasestep
  943.     add     r5,r5,r19
  944.     add     r7,r7,r17
  945.     add     r11,r11,r0
  946. .endif
  947.     srawi   r0,r8,16
  948.     add     r6,r6,r18
  949.     add     r9,r9,r15
  950.     add     r7,r7,r0
  951.     andi.   r8,r8,0xffff
  952.     andis.  r0,r9,1
  953.     beq     .slenext
  954.     add     r7,r7,r12
  955.     andi.   r9,r9,0xffff
  956. .slenext:
  957.     bdnz    .sleloop
  958.     addi    r3,r3,4
  959.     sw      r3,d_pedgespanpackage
  960.  
  961. .ifdef    WOS
  962.     lmw     r13,gb(r1)
  963. .else
  964.     lmw     r15,gb(r1)
  965. .endif
  966.     exit
  967.  
  968.     funcend    D_PolysetScanLeftEdge
  969.  
  970.  
  971.  
  972.  
  973. ###########################################################################
  974. #
  975. #       void D_DrawNonSubdiv (void)
  976. #
  977. ###########################################################################
  978.  
  979.     funcdef    D_DrawNonSubdiv
  980.  
  981.     init    0,0,9,0
  982.     stmw    r23,gb(r1)
  983.  
  984. #        pfv = r_affinetridesc.pfinalverts;
  985. #        ptri = r_affinetridesc.ptriangles;
  986. #        lnumtriangles = r_affinetridesc.numtriangles;
  987.  
  988.     lxa     r29,r_affinetridesc
  989.     lwz     r31,R_PFINALVERTS(r29)
  990.     lwz     r30,R_PTRIANGLES(r29)
  991.     lwz     r23,R_NUMTRIANGLES(r29)
  992.     lwz     r29,R_SEAMFIXUP16(r29)
  993.     lxa     r27,r_p0
  994.     lxa     r26,r_p1
  995.     lxa     r25,r_p2
  996.     lxa     r24,edgetables
  997. .nsloop:
  998.  
  999. #                index0 = pfv + ptri->vertindex[0];
  1000. #                index1 = pfv + ptri->vertindex[1];
  1001. #                index2 = pfv + ptri->vertindex[2];
  1002. #
  1003. #                d_xdenom = (index0->v[1]-index1->v[1]) *
  1004. #                                (index0->v[0]-index2->v[0]) -
  1005. #                                (index0->v[0]-index1->v[0])*(index0->v[1]-index2->v[1]);
  1006.  
  1007.     lwz     r6,MT_VERTINDEX+0*4(r30)
  1008.     slwi    r6,r6,FV_SIZEOF_EXP
  1009.     add     r7,r31,r6               #r7 = index0
  1010.     lwz     r6,MT_VERTINDEX+1*4(r30)
  1011.     slwi    r6,r6,FV_SIZEOF_EXP
  1012.     add     r8,r31,r6               #r8 = index1
  1013.     lwz     r6,MT_VERTINDEX+2*4(r30)
  1014.     slwi    r6,r6,FV_SIZEOF_EXP
  1015.     add     r9,r31,r6               #r9 = index2
  1016.     lwz     r3,0(r7)                #r3 = index0->v[0]
  1017.     lwz     r4,4(r7)                #r4 = index0->v[1]
  1018.     lwz     r5,0(r8)                #r5 = index1->v[0]
  1019.     lwz     r6,4(r8)                #r6 = index1->v[1]
  1020.     lwz     r10,0(r9)               #r10 = index2->v[0]
  1021.     lwz     r11,4(r9)               #r11 = index2->v[1]
  1022.     subf    r12,r10,r3
  1023.     subf    r0,r6,r4
  1024.     mullw   r12,r12,r0
  1025.     subf    r0,r5,r3
  1026.     subf    r28,r11,r4
  1027.     mullw   r28,r28,r0
  1028.  
  1029. #                if (d_xdenom >= 0)
  1030. #                {
  1031. #                        continue;
  1032. #                }
  1033.  
  1034.     subf.   r12,r28,r12
  1035.     bge     .nsnext
  1036.     sw      r12,d_xdenom
  1037.  
  1038. #                r_p0[0] = index0->v[0];         // u
  1039. #                r_p0[1] = index0->v[1];         // v
  1040. #                r_p0[2] = index0->v[2];         // s
  1041. #                r_p0[3] = index0->v[3];         // t
  1042. #                r_p0[4] = index0->v[4];         // light
  1043. #                r_p0[5] = index0->v[5];         // iz
  1044. #
  1045. #                r_p1[0] = index1->v[0];
  1046. #                r_p1[1] = index1->v[1];
  1047. #                r_p1[2] = index1->v[2];
  1048. #                r_p1[3] = index1->v[3];
  1049. #                r_p1[4] = index1->v[4];
  1050. #                r_p1[5] = index1->v[5];
  1051. #
  1052. #                r_p2[0] = index2->v[0];
  1053. #                r_p2[1] = index2->v[1];
  1054. #                r_p2[2] = index2->v[2];
  1055. #                r_p2[3] = index2->v[3];
  1056. #                r_p2[4] = index2->v[4];
  1057. #                r_p2[5] = index2->v[5];
  1058.  
  1059.     stw     r3,0(r27)
  1060.     stw     r4,4(r27)
  1061.     lwz     r12,12(r7)
  1062.     stw     r12,12(r27)
  1063.     lwz     r0,16(r7)
  1064.     stw     r0,16(r27)
  1065.     lwz     r12,20(r7)
  1066.     stw     r12,20(r27)
  1067.     stw     r5,0(r26)
  1068.     stw     r6,4(r26)
  1069.     lwz     r12,12(r8)
  1070.     stw     r12,12(r26)
  1071.     lwz     r0,16(r8)
  1072.     stw     r0,16(r26)
  1073.     lwz     r12,20(r8)
  1074.     stw     r12,20(r26)
  1075.     stw     r10,0(r25)
  1076.     stw     r11,4(r25)
  1077.     lwz     r3,MT_FACESFRONT(r30)
  1078.     lwz     r12,12(r9)
  1079.     stw     r12,12(r25)
  1080.     lwz     r0,16(r9)
  1081.     stw     r0,16(r25)
  1082.     lwz     r12,20(r9)
  1083.     stw     r12,20(r25)
  1084.  
  1085.     lwz     r5,8(r7)
  1086.     lwz     r12,8(r8)
  1087.     lwz     r10,8(r9)
  1088.  
  1089. #                if (!ptri->facesfront)
  1090. #                {
  1091. #                        if (index0->flags & ALIAS_ONSEAM)
  1092. #                                r_p0[2] += r_affinetridesc.seamfixupX16;
  1093. #                        if (index1->flags & ALIAS_ONSEAM)
  1094. #                                r_p1[2] += r_affinetridesc.seamfixupX16;
  1095. #                        if (index2->flags & ALIAS_ONSEAM)
  1096. #                                r_p2[2] += r_affinetridesc.seamfixupX16;
  1097. #                }
  1098.  
  1099.     mr.     r3,r3
  1100.     bne     .nscont
  1101.     lwz     r0,FV_FLAGS(r7)
  1102.     andi.   r0,r0,ALIAS_ONSEAM
  1103.     beq     .ns1
  1104.     add     r5,r5,r29
  1105. .ns1:
  1106.     lwz     r0,FV_FLAGS(r8)
  1107.     andi.   r0,r0,ALIAS_ONSEAM
  1108.     beq     .ns2
  1109.     add     r12,r12,r29
  1110. .ns2:
  1111.     lwz     r0,FV_FLAGS(r9)
  1112.     andi.   r0,r0,ALIAS_ONSEAM
  1113.     beq     .nscont
  1114.     add     r10,r10,r29
  1115. .nscont:
  1116.     stw     r5,8(r27)
  1117.     stw     r12,8(r26)
  1118.     stw     r10,8(r25)
  1119.  
  1120. ######  D_PolysetSetEdgeTable (inlined)
  1121.  
  1122.     cmpw    r4,r6
  1123.     blt     .nslt1
  1124.     beq     .nseq1
  1125. .nsgt1:
  1126.     li      r3,EDGETABLE_SIZEOF
  1127.     cmpw    cr1,r4,r11
  1128.     beq     cr1,.nseq2
  1129.     cmpw    r6,r11
  1130.     beq     .nseq3
  1131.     ble     cr1,.nsskip
  1132.     addi    r3,r3,2*EDGETABLE_SIZEOF
  1133. .nsskip:
  1134.     ble     .nsskip2
  1135.     addi    r3,r3,4*EDGETABLE_SIZEOF
  1136. .nsskip2:
  1137.     add     r3,r3,r24
  1138.     sw      r3,pedgetable
  1139.     b       .nsdone
  1140. .nseq2:
  1141.     addi    r3,r24,8*EDGETABLE_SIZEOF
  1142.     sw      r3,pedgetable
  1143.     b       .nsdone
  1144. .nseq3:
  1145.     addi    r3,r24,10*EDGETABLE_SIZEOF
  1146.     sw      r3,pedgetable
  1147.     b       .nsdone
  1148. .nseq1:
  1149.     cmpw    r4,r11
  1150.     bge     .nsge
  1151.     addi    r3,r24,2*EDGETABLE_SIZEOF
  1152.     sw      r3,pedgetable
  1153.     b       .nsdone
  1154. .nsge:
  1155.     addi    r3,r24,5*EDGETABLE_SIZEOF
  1156.     sw      r3,pedgetable
  1157.     b       .nsdone
  1158. .nslt1:
  1159.     li      r3,0
  1160.     cmpw    cr1,r4,r11
  1161.     beq     cr1,.nseq4
  1162.     cmpw    r6,r11
  1163.     beq     .nseq5
  1164.     ble     cr1,.nsskip3
  1165.     addi    r3,r3,2*EDGETABLE_SIZEOF
  1166. .nsskip3:
  1167.     ble     .nsskip4
  1168.     addi    r3,r3,4*EDGETABLE_SIZEOF
  1169. .nsskip4:
  1170.     add     r3,r3,r24
  1171.     sw      r3,pedgetable
  1172.     b       .nsdone
  1173. .nseq4:
  1174.     addi    r3,r24,9*EDGETABLE_SIZEOF
  1175.     sw      r3,pedgetable
  1176.     b       .nsdone
  1177. .nseq5:
  1178.     addi    r3,r24,11*EDGETABLE_SIZEOF
  1179.     sw      r3,pedgetable
  1180. .nsdone:
  1181.  
  1182. ######  end of D_PolysetSetEdgeTable
  1183.  
  1184.     call    D_RasterizeAliasPolySmooth
  1185. .nsnext:
  1186.     subic.  r23,r23,1
  1187.     la      r30,MT_SIZEOF(r30)
  1188.     bne     .nsloop
  1189.  
  1190.     lmw    r23,gb(r1)
  1191.     exit
  1192.  
  1193.     funcend    D_DrawNonSubdiv
  1194.  
  1195.  
  1196.  
  1197.  
  1198. ###########################################################################
  1199. #
  1200. #       void D_DrawSubdiv (void)
  1201. #
  1202. ###########################################################################
  1203.  
  1204.     funcdef    D_DrawSubdiv
  1205.  
  1206.     init    0,0,11,0
  1207.     stmw    r21,gb(r1)
  1208.  
  1209. #        pfv = r_affinetridesc.pfinalverts;
  1210. #        ptri = r_affinetridesc.ptriangles;
  1211. #        lnumtriangles = r_affinetridesc.numtriangles;
  1212.  
  1213.     lxa     r29,r_affinetridesc
  1214.     lwz     r31,R_PFINALVERTS(r29)
  1215.     lwz     r30,R_PTRIANGLES(r29)
  1216.     lwz     r21,R_NUMTRIANGLES(r29)
  1217.     lwz     r29,R_SEAMFIXUP16(r29)
  1218.     lw      r25,acolormap
  1219. .sdloop:
  1220.  
  1221. #                index0 = pfv + ptri->vertindex[0];
  1222. #                index1 = pfv + ptri->vertindex[1];
  1223. #                index2 = pfv + ptri->vertindex[2];
  1224. #
  1225. #               if (((index0->v[1]-index1->v[1]) *
  1226. #                                (index0->v[0]-index2->v[0]) -
  1227. #                                (index0->v[0]-index1->v[0])*(index0->v[1]-index2->v[1]);
  1228.  
  1229.     lwz     r6,MT_VERTINDEX+0*4(r30)
  1230.     slwi    r6,r6,FV_SIZEOF_EXP
  1231.     add     r28,r31,r6              #r28 = index0
  1232.     lwz     r6,MT_VERTINDEX+1*4(r30)
  1233.     slwi    r6,r6,FV_SIZEOF_EXP
  1234.     add     r27,r31,r6              #r27 = index1
  1235.     lwz     r6,MT_VERTINDEX+2*4(r30)
  1236.     slwi    r6,r6,FV_SIZEOF_EXP
  1237.     add     r26,r31,r6              #r26 = index2
  1238.     lwz     r3,0(r28)               #r3 = index0->v[0]
  1239.     lwz     r4,4(r28)               #r4 = index0->v[1]
  1240.     lwz     r5,0(r27)               #r5 = index1->v[0]
  1241.     lwz     r6,4(r27)               #r6 = index1->v[1]
  1242.     lwz     r10,0(r26)              #r10 = index2->v[0]
  1243.     lwz     r11,4(r26)              #r11 = index2->v[1]
  1244.     subf    r12,r10,r3
  1245.     subf    r0,r6,r4
  1246.     mullw   r12,r12,r0
  1247.     subf    r0,r5,r3
  1248.     subf    r7,r11,r4
  1249.     mullw   r7,r7,r0
  1250.     subf.   r12,r7,r12
  1251.     bge     .sdnext
  1252.     lwz     r3,MT_FACESFRONT(r30)
  1253.     lwz     r8,16(r28)
  1254.     andi.   r8,r8,0xff00
  1255.     add     r9,r25,r8
  1256.     sw      r9,d_pcolormap
  1257.     mr.     r3,r3
  1258.     beq     .sdelse
  1259.     mr      r3,r28
  1260.     mr      r4,r27
  1261.     mr      r5,r26
  1262.     call    D_PolysetRecursiveTriangle
  1263.     b       .sdnext
  1264. .sdelse:
  1265.     lwz     r24,8(r28)              #s0
  1266.     lwz     r23,8(r27)              #s1
  1267.     lwz     r22,8(r26)              #s2
  1268.     lwz     r0,FV_FLAGS(r28)
  1269.     andi.   r0,r0,ALIAS_ONSEAM
  1270.     beq     .sd1
  1271.     add     r5,r24,r29
  1272.     stw     r5,8(r28)
  1273. .sd1:
  1274.     lwz     r0,FV_FLAGS(r27)
  1275.     andi.   r0,r0,ALIAS_ONSEAM
  1276.     beq     .sd2
  1277.     add     r5,r23,r29
  1278.     stw     r5,8(r27)
  1279. .sd2:
  1280.     lwz     r0,FV_FLAGS(r26)
  1281.     andi.   r0,r0,ALIAS_ONSEAM
  1282.     beq     .sdcont
  1283.     add     r5,r22,r29
  1284.     stw     r5,8(r26)
  1285. .sdcont:
  1286.     mr      r3,r28
  1287.     mr      r4,r27
  1288.     mr      r5,r26
  1289.     call    D_PolysetRecursiveTriangle
  1290.     stw     r24,8(r28)
  1291.     stw     r23,8(r27)
  1292.     stw     r22,8(r26)
  1293. .sdnext:
  1294.     subic.  r21,r21,1
  1295.     la      r30,MT_SIZEOF(r30)
  1296.     bne     .sdloop
  1297.  
  1298.     lmw    r21,gb(r1)
  1299.     exit
  1300.  
  1301.     funcend    D_DrawSubdiv
  1302.  
  1303.  
  1304.  
  1305.  
  1306. .ifdef    WOS
  1307.     .tocd
  1308. @__adivtab:
  1309.     .long    _adivtab
  1310. .endif
  1311.     .data
  1312.  
  1313. lab adivtab
  1314.     .long    1,0,1,-1,1,-2,1,-3,1,-4,1
  1315.     .long    -5,1,-6,1,-7,2,-1,2,-3,3,0
  1316.     .long    3,-3,5,0,7,-1,15,0,0,0,-15
  1317.     .long    0,-8,1,-5,0,-4,1,-3,0,-3,3
  1318.     .long    -3,6,-2,1,-2,3,-2,5,-2,7,-2
  1319.     .long    9,-2,11,-2,13,-1,0,-1,1,0,-14
  1320.     .long    1,0,1,-1,1,-2,1,-3,1,-4,1
  1321.     .long    -5,1,-6,2,0,2,-2,2,-4,3,-2
  1322.     .long    4,-2,7,0,14,0,0,0,-14,0,-7
  1323.     .long    0,-5,1,-4,2,-3,1,-3,4,-2,0
  1324.     .long    -2,2,-2,4,-2,6,-2,8,-2,10,-2
  1325.     .long    12,-1,0,-1,1,-1,2,0,-13,0,-13
  1326.     .long    1,0,1,-1,1,-2,1,-3,1,-4,1
  1327.     .long    -5,1,-6,2,-1,2,-3,3,-1,4,-1
  1328.     .long    6,-1,13,0,0,0,-13,0,-7,1,-5
  1329.     .long    2,-4,3,-3,2,-3,5,-2,1,-2,3
  1330.     .long    -2,5,-2,7,-2,9,-2,11,-1,0,-1
  1331.     .long    1,-1,2,-1,3,0,-12,0,-12,0,-12
  1332.     .long    1,0,1,-1,1,-2,1,-3,1,-4,1
  1333.     .long    -5,2,0,2,-2,3,0,4,0,6,0
  1334.     .long    12,0,0,0,-12,0,-6,0,-4,0,-3
  1335.     .long    0,-3,3,-2,0,-2,2,-2,4,-2,6
  1336.     .long    -2,8,-2,10,-1,0,-1,1,-1,2,-1
  1337.     .long    3,-1,4,0,-11,0,-11,0,-11,0,-11
  1338.     .long    1,0,1,-1,1,-2,1,-3,1,-4,1
  1339.     .long    -5,2,-1,2,-3,3,-2,5,-1,11,0
  1340.     .long    0,0,-11,0,-6,1,-4,1,-3,1,-3
  1341.     .long    4,-2,1,-2,3,-2,5,-2,7,-2,9
  1342.     .long    -1,0,-1,1,-1,2,-1,3,-1,4,-1
  1343.     .long    5,0,-10,0,-10,0,-10,0,-10,0,-10
  1344.     .long    1,0,1,-1,1,-2,1,-3,1,-4,2
  1345.     .long    0,2,-2,3,-1,5,0,10,0,0,0
  1346.     .long    -10,0,-5,0,-4,2,-3,2,-2,0,-2
  1347.     .long    2,-2,4,-2,6,-2,8,-1,0,-1,1
  1348.     .long    -1,2,-1,3,-1,4,-1,5,-1,6,0
  1349.     .long    -9,0,-9,0,-9,0,-9,0,-9,0,-9
  1350.     .long    1,0,1,-1,1,-2,1,-3,1,-4,2
  1351.     .long    -1,3,0,4,-1,9,0,0,0,-9,0
  1352.     .long    -5,1,-3,0,-3,3,-2,1,-2,3,-2
  1353.     .long    5,-2,7,-1,0,-1,1,-1,2,-1,3
  1354.     .long    -1,4,-1,5,-1,6,-1,7,0,-8,0
  1355.     .long    -8,0,-8,0,-8,0,-8,0,-8,0,-8
  1356.     .long    1,0,1,-1,1,-2,1,-3,2,0,2
  1357.     .long    -2,4,0,8,0,0,0,-8,0,-4,0
  1358.     .long    -3,1,-2,0,-2,2,-2,4,-2,6,-1
  1359.     .long    0,-1,1,-1,2,-1,3,-1,4,-1,5
  1360.     .long    -1,6,-1,7,-1,8,0,-7,0,-7,0
  1361.     .long    -7,0,-7,0,-7,0,-7,0,-7,0,-7
  1362.     .long    1,0,1,-1,1,-2,1,-3,2,-1,3
  1363.     .long    -1,7,0,0,0,-7,0,-4,1,-3,2
  1364.     .long    -2,1,-2,3,-2,5,-1,0,-1,1,-1
  1365.     .long    2,-1,3,-1,4,-1,5,-1,6,-1,7
  1366.     .long    -1,8,-1,9,0,-6,0,-6,0,-6,0
  1367.     .long    -6,0,-6,0,-6,0,-6,0,-6,0,-6
  1368.     .long    1,0,1,-1,1,-2,2,0,3,0,6
  1369.     .long    0,0,0,-6,0,-3,0,-2,0,-2,2
  1370.     .long    -2,4,-1,0,-1,1,-1,2,-1,3,-1
  1371.     .long    4,-1,5,-1,6,-1,7,-1,8,-1,9
  1372.     .long    -1,10,0,-5,0,-5,0,-5,0,-5,0
  1373.     .long    -5,0,-5,0,-5,0,-5,0,-5,0,-5
  1374.     .long    1,0,1,-1,1,-2,2,-1,5,0,0
  1375.     .long    0,-5,0,-3,1,-2,1,-2,3,-1,0
  1376.     .long    -1,1,-1,2,-1,3,-1,4,-1,5,-1
  1377.     .long    6,-1,7,-1,8,-1,9,-1,10,-1,11
  1378.     .long    0,-4,0,-4,0,-4,0,-4,0,-4,0
  1379.     .long    -4,0,-4,0,-4,0,-4,0,-4,0,-4
  1380.     .long    1,0,1,-1,2,0,4,0,0,0,-4
  1381.     .long    0,-2,0,-2,2,-1,0,-1,1,-1,2
  1382.     .long    -1,3,-1,4,-1,5,-1,6,-1,7,-1
  1383.     .long    8,-1,9,-1,10,-1,11,-1,12,0,-3
  1384.     .long    0,-3,0,-3,0,-3,0,-3,0,-3,0
  1385.     .long    -3,0,-3,0,-3,0,-3,0,-3,0,-3
  1386.     .long    1,0,1,-1,3,0,0,0,-3,0,-2
  1387.     .long    1,-1,0,-1,1,-1,2,-1,3,-1,4
  1388.     .long    -1,5,-1,6,-1,7,-1,8,-1,9,-1
  1389.     .long    10,-1,11,-1,12,-1,13,0,-2,0,-2
  1390.     .long    0,-2,0,-2,0,-2,0,-2,0,-2,0
  1391.     .long    -2,0,-2,0,-2,0,-2,0,-2,0,-2
  1392.     .long    1,0,2,0,0,0,-2,0,-1,0,-1
  1393.     .long    1,-1,2,-1,3,-1,4,-1,5,-1,6
  1394.     .long    -1,7,-1,8,-1,9,-1,10,-1,11,-1
  1395.     .long    12,-1,13,-1,14,0,-1,0,-1,0,-1
  1396.     .long    0,-1,0,-1,0,-1,0,-1,0,-1,0
  1397.     .long    -1,0,-1,0,-1,0,-1,0,-1,0,-1
  1398.     .long    1,0,0,0,-1,0,-1,1,-1,2,-1
  1399.     .long    3,-1,4,-1,5,-1,6,-1,7,-1,8
  1400.     .long    -1,9,-1,10,-1,11,-1,12,-1,13,-1
  1401.     .long    14,-1,15,0,0,0,0,0,0,0,0
  1402.     .long    0,0,0,0,0,0,0,0,0,0,0
  1403.     .long    0,0,0,0,0,0,0,0,0,0,0
  1404.     .long    0,0,0,0,0,0,0,0,0,0,0
  1405.     .long    0,0,0,0,0,0,0,0,0,0,0
  1406.     .long    0,0,0,0,0,0,0,0,0,0,0
  1407.     .long    0,-1,-14,-1,-13,-1,-12,-1,-11,-1,-10
  1408.     .long    -1,-9,-1,-8,-1,-7,-1,-6,-1,-5,-1
  1409.     .long    -4,-1,-3,-1,-2,-1,-1,-1,0,0,0
  1410.     .long    1,0,0,1,0,1,0,1,0,1,0
  1411.     .long    1,0,1,0,1,0,1,0,1,0,1
  1412.     .long    0,1,0,1,0,1,0,1,0,1,-1
  1413.     .long    -13,-1,-12,-1,-11,-1,-10,-1,-9,-1,-8
  1414.     .long    -1,-7,-1,-6,-1,-5,-1,-4,-1,-3,-1
  1415.     .long    -2,-1,-1,-1,0,-2,0,0,0,2,0
  1416.     .long    1,0,0,2,0,2,0,2,0,2,0
  1417.     .long    2,0,2,0,2,0,2,0,2,0,2
  1418.     .long    0,2,0,2,0,2,0,2,-1,-12,-1
  1419.     .long    -11,-1,-10,-1,-9,-1,-8,-1,-7,-1,-6
  1420.     .long    -1,-5,-1,-4,-1,-3,-1,-2,-1,-1,-1
  1421.     .long    0,-2,-1,-3,0,0,0,3,0,1,1
  1422.     .long    1,0,0,3,0,3,0,3,0,3,0
  1423.     .long    3,0,3,0,3,0,3,0,3,0,3
  1424.     .long    0,3,0,3,0,3,-1,-11,-1,-10,-1
  1425.     .long    -9,-1,-8,-1,-7,-1,-6,-1,-5,-1,-4
  1426.     .long    -1,-3,-1,-2,-1,-1,-1,0,-2,-2,-2
  1427.     .long    0,-4,0,0,0,4,0,2,0,1,1
  1428.     .long    1,0,0,4,0,4,0,4,0,4,0
  1429.     .long    4,0,4,0,4,0,4,0,4,0,4
  1430.     .long    0,4,0,4,-1,-10,-1,-9,-1,-8,-1
  1431.     .long    -7,-1,-6,-1,-5,-1,-4,-1,-3,-1,-2
  1432.     .long    -1,-1,-1,0,-2,-3,-2,-1,-3,-1,-5
  1433.     .long    0,0,0,5,0,2,1,1,2,1,1
  1434.     .long    1,0,0,5,0,5,0,5,0,5,0
  1435.     .long    5,0,5,0,5,0,5,0,5,0,5
  1436.     .long    0,5,-1,-9,-1,-8,-1,-7,-1,-6,-1
  1437.     .long    -5,-1,-4,-1,-3,-1,-2,-1,-1,-1,0
  1438.     .long    -2,-4,-2,-2,-2,0,-3,0,-6,0,0
  1439.     .long    0,6,0,3,0,2,0,1,2,1,1
  1440.     .long    1,0,0,6,0,6,0,6,0,6,0
  1441.     .long    6,0,6,0,6,0,6,0,6,0,6
  1442.     .long    -1,-8,-1,-7,-1,-6,-1,-5,-1,-4,-1
  1443.     .long    -3,-1,-2,-1,-1,-1,0,-2,-5,-2,-3
  1444.     .long    -2,-1,-3,-2,-4,-1,-7,0,0,0,7
  1445.     .long    0,3,1,2,1,1,3,1,2,1,1
  1446.     .long    1,0,0,7,0,7,0,7,0,7,0
  1447.     .long    7,0,7,0,7,0,7,0,7,-1,-7
  1448.     .long    -1,-6,-1,-5,-1,-4,-1,-3,-1,-2,-1
  1449.     .long    -1,-1,0,-2,-6,-2,-4,-2,-2,-2,0
  1450.     .long    -3,-1,-4,0,-8,0,0,0,8,0,4
  1451.     .long    0,2,2,2,0,1,3,1,2,1,1
  1452.     .long    1,0,0,8,0,8,0,8,0,8,0
  1453.     .long    8,0,8,0,8,0,8,-1,-6,-1,-5
  1454.     .long    -1,-4,-1,-3,-1,-2,-1,-1,-1,0,-2
  1455.     .long    -7,-2,-5,-2,-3,-2,-1,-3,-3,-3,0
  1456.     .long    -5,-1,-9,0,0,0,9,0,4,1,3
  1457.     .long    0,2,1,1,4,1,3,1,2,1,1
  1458.     .long    1,0,0,9,0,9,0,9,0,9,0
  1459.     .long    9,0,9,0,9,-1,-5,-1,-4,-1,-3
  1460.     .long    -1,-2,-1,-1,-1,0,-2,-8,-2,-6,-2
  1461.     .long    -4,-2,-2,-2,0,-3,-2,-4,-2,-5,0
  1462.     .long    -10,0,0,0,10,0,5,0,3,1,2
  1463.     .long    2,2,0,1,4,1,3,1,2,1,1
  1464.     .long    1,0,0,10,0,10,0,10,0,10,0
  1465.     .long    10,0,10,-1,-4,-1,-3,-1,-2,-1,-1
  1466.     .long    -1,0,-2,-9,-2,-7,-2,-5,-2,-3,-2
  1467.     .long    -1,-3,-4,-3,-1,-4,-1,-6,-1,-11,0
  1468.     .long    0,0,11,0,5,1,3,2,2,3,2
  1469.     .long    1,1,5,1,4,1,3,1,2,1,1
  1470.     .long    1,0,0,11,0,11,0,11,0,11,0
  1471.     .long    11,-1,-3,-1,-2,-1,-1,-1,0,-2,-10
  1472.     .long    -2,-8,-2,-6,-2,-4,-2,-2,-2,0,-3
  1473.     .long    -3,-3,0,-4,0,-6,0,-12,0,0,0
  1474.     .long    12,0,6,0,4,0,3,0,2,2,2
  1475.     .long    0,1,5,1,4,1,3,1,2,1,1
  1476.     .long    1,0,0,12,0,12,0,12,0,12,-1
  1477.     .long    -2,-1,-1,-1,0,-2,-11,-2,-9,-2,-7
  1478.     .long    -2,-5,-2,-3,-2,-1,-3,-5,-3,-2,-4
  1479.     .long    -3,-5,-2,-7,-1,-13,0,0,0,13,0
  1480.     .long    6,1,4,1,3,1,2,3,2,1,1
  1481.     .long    6,1,5,1,4,1,3,1,2,1,1
  1482.     .long    1,0,0,13,0,13,0,13,-1,-1,-1
  1483.     .long    0,-2,-12,-2,-10,-2,-8,-2,-6,-2,-4
  1484.     .long    -2,-2,-2,0,-3,-4,-3,-1,-4,-2,-5
  1485.     .long    -1,-7,0,-14,0,0,0,14,0,7,0
  1486.     .long    4,2,3,2,2,4,2,2,2,0,1
  1487.     .long    6,1,5,1,4,1,3,1,2,1,1
  1488.     .long    1,0,0,14,0,14,-1,0,-2,-13,-2
  1489.     .long    -11,-2,-9,-2,-7,-2,-5,-2,-3,-2,-1
  1490.     .long    -3,-6,-3,-3,-3,0,-4,-1,-5,0,-8
  1491.     .long    -1,-15,0,0,0,15,0,7,1,5,0
  1492.     .long    3,3,3,0,2,3,2,1,1,7,1
  1493.     .long    6,1,5,1,4,1,3,1,2,1,1
  1494.     .long    1,0,0,15,-2,-14,-2,-12,-2,-10,-2
  1495.     .long    -8,-2,-6,-2,-4,-2,-2,-2,0,-3,-5
  1496.     .long    -3,-2,-4,-4,-4,0,-6,-2,-8,0,-16
  1497.     .long    0,0,0,16,0,8,0,5,1,4,0
  1498.     .long    3,1,2,4,2,2,2,0,1,7,1
  1499.     .long    6,1,5,1,4,1,3,1,2,1,1
  1500.     .long    1,0
  1501.  
  1502.