home *** CD-ROM | disk | FTP | other *** search
/ Enigma Amiga Life 109 / EnigmaAmiga109CD.iso / software / testi / corsoasm / sorgenti5 / lezione9i2r.s < prev    next >
Text File  |  1995-10-23  |  10KB  |  300 lines
  1.  
  2. ; Lezione9i2r.s    BOB a colori (interleaved)
  3. ;        Tasto sinistro per uscire.
  4.  
  5.     SECTION    CiriCop,CODE
  6.  
  7. ;    Include    "DaWorkBench.s"    ; togliere il ; prima di salvare con "WO"
  8.  
  9. *****************************************************************************
  10.     include    "startup1.s"    ; Salva Copperlist Etc.
  11. *****************************************************************************
  12.  
  13.         ;5432109876543210
  14. DMASET    EQU    %1000001111000000    ; copper,bitplane,blitter DMA
  15.  
  16.  
  17. START:
  18.  
  19.     MOVE.L    #BITPLANE,d0    ; dove puntare
  20.     LEA    BPLPOINTERS,A1    ; puntatori COP
  21.     MOVEQ    #3-1,D1        ; numero di bitplanes (qua sono 3)
  22. POINTBP:
  23.     move.w    d0,6(a1)
  24.     swap    d0
  25.     move.w    d0,2(a1)
  26.     swap    d0
  27.                 ; QUI C'E` LA PRIMA DIFFERENZA RISPETTO
  28.                 ; ALLE IMMAGINI NORMALI!!!!!!
  29.     ADD.L    #40,d0        ; + LUNGHEZZA DI UNA RIGA !!!!!
  30.     addq.w    #8,a1
  31.     dbra    d1,POINTBP
  32.  
  33.     lea    $dff000,a5        ; CUSTOM REGISTER in a5
  34.     MOVE.W    #DMASET,$96(a5)        ; DMACON - abilita bitplane, copper
  35.     move.l    #COPPERLIST,$80(a5)    ; Puntiamo la nostra COP
  36.     move.w    d0,$88(a5)        ; Facciamo partire la COP
  37.     move.w    #0,$1fc(a5)        ; Disattiva l'AGA
  38.     move.w    #$c00,$106(a5)        ; Disattiva l'AGA
  39.     move.w    #$11,$10c(a5)        ; Disattiva l'AGA
  40.  
  41. mouse:
  42.     bsr.w    LeggiMouse        ; Leggi coordinate
  43.     bsr.s    ControllaCoordinate    ; evita che il bob esca dallo schermo
  44.     bsr.s    DisegnaOggetto        ; disegna il bob
  45.  
  46.     MOVE.L    #$1ff00,d1    ; bit per la selezione tramite AND
  47.     MOVE.L    #$13000,d2    ; linea da aspettare = $130, ossia 304
  48. Waity1:
  49.     MOVE.L    4(A5),D0    ; VPOSR e VHPOSR - $dff004/$dff006
  50.     ANDI.L    D1,D0        ; Seleziona solo i bit della pos. verticale
  51.     CMPI.L    D2,D0        ; aspetta la linea $130 (304)
  52.     BNE.S    Waity1
  53.  
  54.     bsr.w    CancellaOggetto        ; cancella il bob dalla vecchia
  55.                     ; posizione
  56.  
  57.     btst    #6,$bfe001        ; tasto sinistro del mouse premuto?
  58.     bne.s    mouse            ; se no, torna a mouse:
  59.     rts
  60.  
  61. ;****************************************************************************
  62. ; Questa routine fa in modo che le coordinate del bob rimangano sempre
  63. ; all'interno dello schermo.
  64. ;****************************************************************************
  65.  
  66. ControllaCoordinate:
  67.     tst.w    ogg_x        ; controlla X
  68.     bpl.s    NoMinX        ; controlla bordo sinistro
  69.     clr.w    ogg_x        ; se X e` negativa, pone X=0
  70.     bra.s    controllaY    ; va a controllare la Y
  71.  
  72. NoMinX:
  73.     cmp.w    #319-32,ogg_x    ; Controlla il bordo destro. In X_OGG
  74.                 ; e` memorizzata la coordinata del bordo
  75.                 ; sinistro del bob. Se esso ha raggiunto
  76.                 ; 319-32, allora il bordo destro ha raggiunto
  77.                 ; la coordinata 319.
  78.     bls.s    controllaY    ; Se e` minore tutto bene, controlla la Y
  79.     move.w    #319-32,ogg_x    ; altrimenti fissa la coordinata sul bordo.
  80.  
  81. controllaY:
  82.     tst.w    ogg_y        ; controlla bordo in alto
  83.     bpl.s    NoMinY        ; se e` positiva controlla in basso
  84.     clr.w    ogg_y        ; altrimenti poni Y=0
  85.     bra.s    EndControlla    ; ed esci
  86.  
  87. NoMinY:
  88.     cmp.w    #255-11,ogg_y    ; controlla il bordo basso. In Y_OGG
  89.                 ; e` memorizzata la coordinata del bordo
  90.                 ; alto del bob. Se esso ha raggiunto
  91.                 ; Y=255-11, allora il bordo basso ha raggiunto
  92.                 ; la coordinata Y=255
  93.     bls.s    EndControlla    ; se e` minore tutto bene, controlla la Y
  94.     move.w    #255-11,ogg_y    ; altrimenti fissa la coordinata sul bordo.
  95. EndControlla:
  96.     rts
  97.  
  98. ;****************************************************************************
  99. ; Questa routine disegna il BOB alle coordinate specificate nelle variabili
  100. ; X_OGG e Y_OGG. Il BOB e lo schermo sono in formato interleaved, e pertanto
  101. ; sono utilizzate le formule relative a questo formato nel calcolo dei
  102. ; valori da scrivere nei registri del blitter. Inoltre viene impiegata la
  103. ; tecnica di mascherare l'ultima word del BOB vista nella lezione.
  104. ;****************************************************************************
  105.  
  106. ;         _
  107. ;        /_\---.
  108. ;      _//_\ __|
  109. ;     C/ ( °\°/l)
  110. ;     /   (___)|
  111. ;    (_ ° _____!
  112. ;     `---'|,|_
  113. ;        /¯' ` |
  114. ;       //T· ·T|
  115. ;       \\l ° |l
  116. ;       (__) (_¯)
  117. ;         |¯¬¯|¯ xCz
  118. ;         l__Tl__
  119. ;         (____)_)
  120.  
  121. DisegnaOggetto:
  122.     lea    bitplane,a0    ; destinazione in a0
  123.     move.w    ogg_y(pc),d0    ; coordinata Y
  124.     mulu.w    #3*40,d0    ; calcola indirizzo: ogni riga e` costituita da
  125.                 ; 3 planes di 40 bytes ciascuno
  126.     add.w    d0,a0        ; aggiungi all'indirizzo di partenza
  127.  
  128.     move.w    ogg_x(pc),d0    ; coordinata X
  129.     move.w    d0,d1        ; copia
  130.     and.w    #$000f,d0    ; si selezionano i primi 4 bit perche' vanno
  131.                 ; inseriti nello shifter del canale A 
  132.     lsl.w    #8,d0        ; i 4 bit vengono spostati sul nibble alto
  133.     lsl.w    #4,d0        ; della word...
  134.     or.w    #$09f0,d0    ; ...giusti per inserirsi nel registro BLTCON0
  135.     lsr.w    #3,d1        ; (equivalente ad una divisione per 8)
  136.                 ; arrotonda ai multipli di 8 per il puntatore
  137.                 ; allo schermo, ovvero agli indirizzi dispari
  138.                 ; (anche ai byte, quindi)
  139.                 ; x es.: un 16 come coordinata diventa il
  140.                 ; byte 2 
  141.     and.w    #$fffe,d1    ; escludo il bit 0 del
  142.     add.w    d1,a0        ; somma all'indirizzo del bitplane, trovando
  143.                 ; l'indirizzo giusto di destinazione
  144.  
  145.     btst    #6,2(a5)
  146. WBlit2:
  147.     btst    #6,2(a5)    ; dmaconr - attendi che il blitter abbia finito
  148.     bne.s    wblit2
  149.  
  150.     move.l    #$ffff0000,$44(a5)    ; BLTAFWM = $ffff fa passare tutto
  151.                     ; BLTALWM = $0000 azzera l'ultima word
  152.  
  153.  
  154.     move.w    d0,$40(a5)        ; BLTCON0 (usa A+D)
  155.     move.w    #$0000,$42(a5)        ; BLTCON1 (nessun modo speciale)
  156.     move.l    #$fffe0022,$64(a5)    ; BLTAMOD=$fffe=-2 torna indietro
  157.                     ; all'inizio della riga.
  158.                     ; BLTDMOD=40-6=34=$22 come al solito
  159.     move.l    #figura,$50(a5)        ; BLTAPT  (fisso alla figura sorgente)
  160.     move.l    a0,$54(a5)        ; BLTDPT  (linee di schermo)
  161.     move.w    #(64*11*3)+3,$58(a5)    ; BLTSIZE (via al blitter !)
  162.     rts
  163.  
  164. ;*****************************************************************************
  165. ; Questa routine cancella il BOB mediante il blitter. La cancellazione
  166. ; viene fatta sul rettangolo che racchiude il bob alto 6 linee e largo 3 words
  167. ;****************************************************************************
  168.  
  169. CancellaOggetto:
  170.     lea    bitplane,a0    ; destinazione in a0
  171.     move.w    ogg_y(pc),d0    ; coordinata Y
  172.     mulu.w    #3*40,d0    ; calcola indirizzo: ogni riga e` costituita da
  173.                 ; 3 planes di 40 bytes ciascuno
  174.     add.w    d0,a0        ; aggiungi all'indirizzo di partenza
  175.  
  176.     move.w    ogg_x(pc),d1    ; coordinata X
  177.     lsr.w    #3,d1        ; (equivalente ad una divisione per 8)
  178.                 ; arrotonda ai multipli di 8 per il puntatore
  179.                 ; allo schermo, ovvero agli indirizzi dispari
  180.                 ; (anche ai byte, quindi)
  181.                 ; x es.: un 16 come coordinata diventa il
  182.                 ; byte 2 
  183.     and.w    #$fffe,d1    ; escludo il bit 0 del
  184.     add.w    d1,a0        ; somma all'indirizzo del bitplane, trovando
  185.                 ; l'indirizzo giusto di destinazione
  186.  
  187.     btst    #6,2(a5)
  188. WBlit3:
  189.     btst    #6,2(a5)     ; attendi che il blitter abbia finito
  190.     bne.s    wblit3
  191.  
  192.     move.l    #$01000000,$40(a5)    ; BLTCON0 e BLTCON1: Cancella
  193.     move.w    #$0022,$66(a5)        ; BLTDMOD=40-6=34=$22
  194.     move.l    a0,$54(a5)        ; BLTDPT
  195.     move.w    #(64*11*3)+3,$58(a5)    ; BLTSIZE (via al blitter !)
  196.                     ; cancella il rettangolo che racchiude
  197.     rts                ; il BOB
  198.  
  199. *****************************************************************************
  200. ; Questa routine legge il mouse e aggiorna i valori contenuti nelle
  201. ; variabili OGG_X e OGG_Y
  202. ;****************************************************************************
  203.  
  204. LeggiMouse:
  205.     move.b    $dff00a,d1    ; JOY0DAT posizione verticale mouse
  206.     move.b    d1,d0        ; copia in d0
  207.     sub.b    mouse_y(PC),d0    ; sottrai vecchia posizione mouse
  208.     beq.s    no_vert        ; se la differenza = 0, il mouse e` fermo
  209.     ext.w    d0        ; trasforma il byte in word
  210.                 ; (vedi alla fine del listato)
  211.     add.w    d0,ogg_y    ; modifica posizione oggetto
  212.  
  213. no_vert:
  214.       move.b    d1,mouse_y    ; salva posizione mouse per la prossima volta
  215.  
  216.     move.b    $dff00b,d1    ; posizione orizzontale mouse
  217.     move.b    d1,d0        ; copia in d0
  218.     sub.b    mouse_x(PC),d0    ; sottrai vecchia posizione
  219.     beq.s    no_oriz        ; se la differenza = 0, il mouse e` fermo
  220.     ext.w    d0        ; trasforma il byte in word
  221.                 ; (vedi alla fine del listato)
  222.     add.w    d0,ogg_x    ; modifica pos. oggetto
  223. no_oriz
  224.       move.b    d1,mouse_x    ; salva posizione mouse per la prossima volta
  225.     RTS
  226.  
  227. OGG_Y:        dc.w    0    ; qui viene memorizzata la Y dell'oggetto
  228. OGG_X:        dc.w    0    ; qui viene memorizzata la X dell'oggetto
  229. MOUSE_Y:    dc.b    0    ; qui viene memorizzata la Y del mouse
  230. MOUSE_X:    dc.b    0    ; qui viene memorizzata la X del mouse
  231.  
  232. ;****************************************************************************
  233.  
  234.     SECTION    GRAPHIC,DATA_C
  235.  
  236. COPPERLIST:
  237.     dc.w    $8E,$2c81    ; DiwStrt
  238.     dc.w    $90,$2cc1    ; DiwStop
  239.     dc.w    $92,$38        ; DdfStart
  240.     dc.w    $94,$d0        ; DdfStop
  241.     dc.w    $102,0        ; BplCon1
  242.     dc.w    $104,0        ; BplCon2
  243.  
  244.                 ; QUI C'E` LA SECONDA DIFFERENZA RISPETTO
  245.                 ; ALLE IMMAGINI NORMALI!!!!!!
  246.     dc.w    $108,80        ; VALORE MODULO = 2*20*(3-1)= 80
  247.     dc.w    $10a,80        ; ENTRAMBI I MODULI ALLO STESSO VALORE.
  248.  
  249.     dc.w    $100,$3200    ; bplcon0 - 3 bitplanes lowres
  250.  
  251. BPLPOINTERS:
  252.     dc.w $e0,$0000,$e2,$0000    ;primo     bitplane
  253.     dc.w $e4,$0000,$e6,$0000
  254.     dc.w $e8,$0000,$ea,$0000
  255.  
  256.     dc.w    $0180,$000    ; color0
  257.     dc.w    $0182,$475    ; color1
  258.     dc.w    $0184,$fff    ; color2
  259.     dc.w    $0186,$ccc    ; color3
  260.     dc.w    $0188,$999    ; color4
  261.     dc.w    $018a,$232    ; color5
  262.     dc.w    $018c,$777    ; color6
  263.     dc.w    $018e,$444    ; color7
  264.  
  265.     dc.w    $FFFF,$FFFE    ; Fine della copperlist
  266.  
  267. ;****************************************************************************
  268.  
  269. ; Questi sono i dati che compongono la figura del bob.
  270. ; Il bob e` in formato interleaved, largo 32 pixel (2 words)
  271. ; alto 11 righe e formato da 3 bitplanes
  272.  
  273. Figura:    dc.l    $007fc000,$00000000,$007fc000
  274.     dc.l    $03fff800,$007fc000,$03803800
  275.     dc.l    $07fffc00,$03fff800,$04000400
  276.     dc.l    $0ffffe00,$07fffc00,$081f8200
  277.     dc.l    $1fe07f00,$0fe07e00,$10204100
  278.     dc.l    $1fe07f00,$0fe07e00,$10204100
  279.     dc.l    $1fe07f00,$0fe07e00,$10204100
  280.     dc.l    $0ffffe00,$07fffc00,$081f8200
  281.     dc.l    $07fffc00,$03fff800,$04000400
  282.     dc.l    $03fff800,$007fc000,$03803800
  283.     dc.l    $007fc000,$00000000,$007fc000
  284.  
  285. ;****************************************************************************
  286.  
  287. BITPLANE:
  288.     incbin    "assembler2:sorgenti6/amiga.rawblit"
  289.                     ; qua carichiamo la figura in
  290.                     ; formato RAWBLIT (o interleaved),
  291.                     ; convertita col KEFCON.
  292.     end
  293.  
  294. ;****************************************************************************
  295.  
  296. Questo esempio e` la versione rawblit di lezione9i2.s.
  297. Confrontate le differenze nelle formule per il calcolo dei valori da scrivere
  298. nei registri del blitter.
  299.  
  300.