home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
ftp.whtech.com
/
ftp.whtech.com.tar
/
ftp.whtech.com
/
compuserve
/
Basic
/
PRK2
< prev
next >
Wrap
Text File
|
2006-10-19
|
2KB
|
60 lines
8 REM********************************** PRK2 *********************************
10 REM THE FOLLOWING BASIC PROGRAM TAKES THE HEADER AND DATA FILES
12 REM CREATED IN "PRK1" AND CONVERTS THEM BACK INTO
14 REM PRK FILES WHICH CAN BE SAVED BY THE PRK SAVE ROUTINE.
16 REM
18 REM BEFORE RUNNING THE PROGRAM, ENSURE THAT THE PRK CARTRIDGE IS INSERTED,
20 REM SELECT OPTION #1 FOR TI BASIC, AND EXECUTE THE FOLLOWING COMMANDS:
22 REM
24 REM CALL FILES(1)
26 REM CALL P(10000)
28 REM NEW
30 REM
32 REM
34 REM
36 REM========================================================================
100 OPEN #1:"DSK1.PRKHEADER",RELATIVE,INTERNAL,INPUT ,FIXED
110 INPUT #1:F$,F,R
120 PRINT F$:F:R
130 CALL H(0,1,0,F$)
140 FOR I=1 TO F
150 INPUT #1,REC I:F$,T,W,D
160 PRINT F$:T;W;D
170 CALL H(0,9,I,F$)
180 CALL H(0,10,I,T)
190 IF T=4 THEN 220
200 CALL H(0,12,I,D)
210 IF T<3 THEN 230
220 CALL H(0,12,I,D)
230 NEXT I
240 CLOSE #1
250 OPEN #1:"DSK1.PRKDATA",SEQUENTIAL,INTERNAL,INPUT ,VARIABLE
260 FOR I=1 TO R
270 PRINT I
280 FOR J=1 TO F
290 CALL H(1,10,J,T)
300 IF T=1 THEN 380
310 INPUT #1:D;
320 PRINT D;
330 IF D=-9.9999999999999E+127 THEN 360
340 CALL G(0,I,J,D)
350 GOTO 440
360 CALL G(2,I,J,D)
370 GOTO 440
380 INPUT #1:F$;
390 PRINT F$;" ";
400 IF F$="?" THEN 430
410 CALL G(0,I,J,F$)
420 GOTO 440
430 CALL G(2,I,J,F$)
440 NEXT J
450 INPUT #1:F$
460 PRINT F$
470 NEXT I
480 CLOSE #1
490 CALL S("DSK1.PRKFILE",C)
500 IF C,.0 THEN 520
510 PRINT "ERROR IN SAVING PRK FILE!!"
520 STOP