home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
ftp.whtech.com
/
ftp.whtech.com.tar
/
ftp.whtech.com
/
compuserve
/
Basic
/
PRK1
< prev
next >
Wrap
Text File
|
2006-10-19
|
2KB
|
61 lines
100 REM********************************* PRK1 *********************************
110 REM INSERT THE PRK COMMAND MODULE AND USE THE SUBPROGRAMS THAT ARE
120 REM RESIDENT THERE TO CREATE TWO SEPARATE DISK FILES: ONE IS THE
130 REM PRK HEADER RECORD THAT DESCRIBES THE STRUCTURE OF THE DATA;
140 REM THE OTHER IS A FILE OF THE DATA ITESELF.
150 REM BEFORE LOADING THIS BASIC PROGRAM:
160 REM MAKE SURE PRK CARTRIDGE IS INSERTED. SELECT #1 FOR TI BASIC.
170 REM EXECUTE THE FOLLOWING THREE BASIC COMMANDS:
180 REM CALL FILES(1)
190 REM CALL P(10000)
200 REM NEW
210 REM NOW LOAD AND RUN THE FOLLOWING PROGRAM.
220 REM=======================================================================
230 CALL L("DSK1.PRKFILE",C)
240 IF C=0 THEN 670
250 OPEN #1:"DSK1.PRKHEADER",RELATIVE,INTERNAL,OUTPUT,FIXED
260 CALL H(1,1,0,F$)
270 CALL H(1,5,0,F)
280 CALL H(1,6,0,R)
290 PRINT #1:F$,F,R
300 PRINT F$;F;R
310 FOR I=1 TO F
320 CALL H(1,9,I,F$)
330 CALL H(1,10,I,T)
340 CALL H(1,11,I,W)
350 IF T<>1 THEN 380
360 S=S+W+1
370 GOTO 390
380 S=S+9
390 CALL H(1,12,I,D)
400 PRINT #1,REC I:F$,T,W,D
410 PRINT F$;T;W;D
420 NEXT I
430 CLOSE #1
440 OPEN #1:"DSK1.PRKDATA",SEQUENTIAL,INTERNAL,OUTPUT,VARIABLE S+2
450 FOR I=1 TO R
460 PRINT I
470 FOR J=1 TO F
480 CALL H(1,10,J,T)
490 IF T=1 THEN 560
500 CALL G(1,I,J,C,D)
510 IF C=0 THEN 530
520 D=-9.9999999999999E+127
530 PRINT #1:D;
540 PRINT D;
550 GOTO 610
560 CALL G(1,I,J,C,F$)
570 IF C=0 THEN 590
580 F$="?"
590 PRINT #1:F$;
600 PRINT F$;" ";
610 NEXT J
620 PRINT #1:"@"
630 PRINT
640 NEXT I
650 CLOSE #1
660 STOP
670 PRINT "ERROR IN LOADING PRK FILE"
680 STOP