home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
ftp.whtech.com
/
ftp.whtech.com.tar
/
ftp.whtech.com
/
club100
/
gam
/
horses.ba
< prev
next >
Wrap
Text File
|
2006-10-19
|
5KB
|
73 lines
0 'HORSES.BA Bill Templeton 6/86
1 'CLUB 100 Library - 415/939-1246 BBS, 937-5039 NEWSLETTER, 932-8856 VOICE
2 'Music mods by Richard Hanson
3 CLEAR200:DEFINTC-R:E$=CHR$(27):R$=E$+"p":N$=E$+"q":FORN=0TO4:READHN$(N):NEXTN
4 DATA No Choice this race,Citation,Man of War,Seabiscuit,Feedlebaum:H$=CHR$(224)+CHR$(243)+CHR$(243)+CHR$(225)
5 BT$=" SsPpWw":YE$=" YyNn":F$="$$###,###.##":F1$="#.#/1":ST(1)=85:ST(2)=125:ST(3)=165:ST(4)=205:SP=200:FORN=3TO0STEP-1
6 READWN$(N),WM$(N):NEXT:DATA WINNER,2.0-1,PLACE,1.5-1,SHOW,1.2-1,Also ran,0:GOSUB17
7 RA=RA+1:FORN=1TO4:D(N)=0:W(N)=0:NEXTN:GOSUB27:GOSUB33:GOSUB36:GOSUB39:GOSUB42:GOSUB45:GOSUB16:GOSUB48
8 GOSUB60:GOSUB60:GOSUB61:GOSUB50:CLS:PRINT@162,R$" Do you want to race again (Y/N?) "N$;
9 YE$=INKEY$:IFYE$=""THEN9
10 IFYE$="N"ORYE$="n"THEN13
11 IFYE$="Y"ORYE$="y"THEN7
12 GOTO9
13 CLS:PRINT@165,R$" Hope you had a good time... "N$:FORT=1TO1000:NEXT:MENU
14 PRINT@292,"Press <ENTER> to continue";:INPUTE:RETURN
15 FORS=1TOSP:NEXT:RETURN
16 FORS=1TO1000:NEXT:RETURN
17 CLS:PRINT@85,R$" Welcome to Hollywood Park "N$:PRINT@163,"Do you want instructions (Y/N)?";
18 Y$=INKEY$:IFY$=""THEN18
19 IFY$="N"ORY$="n"THEN22
20 IFY$="Y"ORY$="y"THEN63
21 GOTO18
22 PRINT@163,"How many players (1-4)? ";
23 PL$=INKEY$:IFPL$=""THEN23
24 PL=VAL(PL$):IFPL<1 ORPL>4THEN23
25 FORN=1TOPL:BR(N)=100:NEXTN:FORN=1TOPL:PRINT@163,SPACE$(35):PRINT@203,SPACE$(35):PRINT@163,"Name of player #"N;:INPUTNM$(N)
26 NEXTN:RETURN
27 FORN=1TOPL:CLS:PRINT@7,R$" Race #"RA" Horses are: "N$:FORK=0TO4:PRINTK" = "HN$(K):NEXTK
28 PRINT@247,R$" "NM$(N)", please select one "N$;
29 INPUTHN(N):IFHN(N)=0THEN32ELSEIFHN(N)>5GOTO29
30 PRINT@243,R$" Type bet: <W>in <P>lace <S>how "N$;:INPUTBT$(N):BT(N)=INT(INSTR(BT$,BT$(N))/2):IFBT(N)=0THEN30
31 PRINT@243,SPACE$(36):PRINT@247,R$" Amount bet in $ :"N$;:INPUTBA(N):IFBA(N)>BR(N)THEN31
32 NEXTN:RETURN
33 CLS:PRINT@7,R$" HOLLYWOOD PARK RACE TRACK "N$;:LINE(34,10)-(220,10):LINE(34,53)-(220,53):LINE(34,11)-(220,11)
34 LINE(34,54)-(220,54):LINE(34,7)-(34,58):LINE(220,7)-(220,58):LINE(34,20)-(220,20):LINE(34,28)-(220,28)
35 LINE(34,36)-(220,36):LINE(34,44)-(220,44):PRINT@81,"Cit";:PRINT@121,"Man";:PRINT@161,"Sea";:PRINT@201,"Fed";:RETURN
36 FORN=1TO4:PRINT@ST(N),H$;:NEXTN:S=VAL(RIGHT$(TIME$,2)):FORN=1TOS:D=RND(1):NEXTN:GOSUB57:GOSUB15:BEEP
37 R=INT(RND(1)*4+1):IFD(R)>=30 ANDW(R)=0THENPRINT@ST(R)+15,WN$(3);:W(R)=3:RETURN
38 D(R)=D(R)+1:PRINT@ST(R)+D(R),H$;:GOTO37
39 R=INT(RND(1)*4+1):IFW(R)=3THEN39
40 IFD(R)>=30 ANDW(R)=0THENPRINT@ST(R)+15,WN$(2);:W(R)=2:RETURN
41 D(R)=D(R)+1:PRINT@ST(R)+D(R),H$;:GOTO39
42 R=INT(RND(1)*4+1):IFW(R)=3 ORW(R)=2THEN42
43 IFD(R)>=30 ANDW(R)=0THENPRINT@ST(R)+15,WN$(1);:W(R)=1:RETURN
44 D(R)=D(R)+1:PRINT@ST(R)+D(R),H$;:GOTO42
45 R=INT(RND(1)*4+1):IFW(R)=3 ORW(R)=2 ORW(R)=1THEN45
46 IFD(R)>=30 ANDW(R)=0THENPRINT@ST(R)+15,WN$(0);:RETURN
47 D(R)=D(R)+1:PRINT@ST(R)+D(R),H$;:GOTO45
48 CLS:PRINT@44,R$" Results of race #"RA" "N$:PRINT@84,R$" Horse"SPACE$(8)"Position"SPACE$(4)"Pays "N$:FORN=1TO4
49 PRINTTAB(5)HN$(N)TAB(18)WN$(W(N))TAB(29)WM$(W(N)):NEXTN:LINE(22,5)-(220,57),1,B:RETURN
50 FORN=1TOPL:IFHN(N)=0THEN55
51 IFBT(N)>W(HN(N))THENBR(N)=BR(N)-BA(N):GOTO55
52 IFBT(N)=3THENBR(N)=BR(N)+BA(N)*2
53 IFBT(N)=2THENBR(N)=BR(N)+BA(N)*1.5
54 IFBT(N)=1THENBR(N)=BR(N)+BA(N)*1.2
55 NEXTN:CLS:PRINT@44,R$" Accumulated Earnings "N$:PRINT@84,R$" Player"SPACE$(9)" Bankroll "N$:FORN=1TOPL
56 PRINTTAB(5)NM$(N)TAB(28)BR(N):NEXTN:LINE(22,5)-(220,57),1,B:GOSUB16:RETURN
57 SOUND6269,5:SOUND4697,5:SOUND3728,5:SOUND3134,20:SOUND3134,5:SOUND3134,5:SOUND3134,5:SOUND3728,20:SOUND3728,5:SOUND3728,5
58 SOUND3728,5:SOUND4697,8:SOUND3728,8:SOUND4697,8:SOUND6269,30:SOUND0,10:SOUND6269,5:SOUND4697,5:SOUND3728,5:SOUND3134,20
59 SOUND3134,5:SOUND3134,5:SOUND3134,5:SOUND6269,8:SOUND6269,8:SOUND6269,8:SOUND4697,50:RETURN:SOUND0,4
60 SOUND7456,4:SOUND0,6:SOUND6269,18:SOUND0,4:SOUND7456,4:SOUND0,2:SOUND7032,5:SOUND0,6:SOUND6269,20:SOUND0,20:RETURN
61 SOUND0,2:SOUND3728,8:SOUND0,4:SOUND3728,18:SOUND0,2:SOUND4697,6:SOUND4184,7:SOUND0,2:SOUND4697,7:SOUND0,2:SOUND4184,7
62 SOUND0,2:SOUND4697,7:SOUND0,1:SOUND3728,7:SOUND0,1:SOUND4697,10:SOUND4697,10:SOUND4184,10:SOUND4697,30:RETURN
63 GOSUB71:PRINT" Select number of players (1-4), and enter each name when requested. The"
64 PRINT" betting will then start. Select a horse. If you decide to pass, enter `0' (no bet).";
65 PRINT" Then select: <W>in, <P>lace, or <S>how.":GOSUB14:GOSUB71
66 PRINT" You start with a bankroll of $100.00. Bet what you want. Up to your limit.
67 PRINT" Win bet pays 2-1, Place 1.5 to 1 and Show 1.2 to 1. The race will then automatically start.";
68 PRINT" At the end the winners will be shown, and bets will":GOSUB14:GOSUB71
69 PRINT" be calculated. The tote board will show the placing of the horses, and the subsequent listing will show"
70 PRINT" how your are doing on your betting. Then decide if you want to race again.":GOSUB14:CLS:PRINT@80,:GOSUB22:RETURN
71 CLS:PRINT@13,R$" Instructions "N$:RETURN