home *** CD-ROM | disk | FTP | other *** search
/ ftp.whtech.com / ftp.whtech.com.tar / ftp.whtech.com / club100 / gam / bugs.ba < prev    next >
Text File  |  2006-10-19  |  4KB  |  79 lines
  1. 0 'Club 100 Library - 415/939-1246 BBS     937-5039 NEWSLETTER, 932-8856 VOICE
  2. 5 'BUGS, A CHILD'S BUG BUILDING GAME, M100 VERSION BY RUSS HALL
  3. 15 CLS:CLEAR2000
  4. 20 DIM X(16.5),BODY(16.5),HEAD(16.5),ANTE(16.5),LEGS(16.5),TAIL(16.5),NECK(16.5),CNT(16.5),PLAY(16.5),Z(16.5),Y(16.5)
  5. 30 X(5.0)=46:X(16.5)=161
  6. 100 M$="      --   BUILD A BUG GAME   --"
  7. 105 Y$=STRING$(40,"*"):Z$=STRING$(39,CHR$(32))
  8. 110 PRINTY$;:PRINTM$:PRINTY$;
  9. 120 PRINT:PRINT"Enter your first name";
  10. 130 INPUTNM$
  11. 140 PRINT"Want an explanation of the rules? (Y/N)"
  12. 150 ANS$=INKEY$:R=RND(1):IFANS$=""THEN150
  13. 155 IFANS$="Y"ORANS$="y"THENCLS:GOSUB1200
  14. 160 CLS
  15. 390 FORF=1TO100:NEXT:PRINT@175,"HIT ENTER TO ROLL DIE";
  16. 400 INPUTA
  17. 402 PRINT@200,Z$:PRINT@280,Z$;
  18. 410 PLAY=5.0
  19. 420 GOSUB520:PRINT@160,"ROLL IS A"ROLL:PRINT@175,"                      "
  20. 423 GOSUB540:GOSUB 1060
  21. 440 PLAY=16.5
  22. 450 GOSUB520:PRINT@240,"ROLL IS A"ROLL
  23. 460 GOSUB540:GOSUB1060:GOTO390
  24. 520 ROLL=RND(1)*10:IFROLL>7THEN520
  25. 525 ROLL=INT(ROLL):IFROLL=0THEN520:RETURN
  26. 527 RETURN
  27. 540 IF ROLL=1THENIFBODY(PLAY)=0THENGOSUB670
  28. 560 IFROLL=2THENIFBODY(PLAY)=1THENIFNECK(PLAY)=0THENGOSUB760
  29. 580 IFROLL=3THENIFBODY(PLAY)=1THENIFNECK(PLAY)=1THENIFHEAD(PLAY)=0THENGOSUB820
  30. 600 IFROLL=4THENIFHEAD(PLAY)=1THENIFANTE(PLAY)<2THENGOSUB880
  31. 620 IFROLL=5THENIFBODY(PLAY)=1THENIFTAIL(PLAY)=0THENGOSUB940
  32. 640 IFROLL=6THENIFBODY(PLAY)=1THENIFLEGS(PLAY)<6THENGOSUB1000
  33. 660 RETURN
  34. 670 IFPLAY=5.0THENPRINT@200,NM$"'S BUG HAS A BODY"
  35. 710 IFPLAY=16.5THENPRINT@280,"COMPUTER'S BUG HAS A BODY";
  36. 715 LINE(PLAY*10,10)-(PLAY*10+20,22),1,BF
  37. 720 CNT(PLAY)=1:BODY(PLAY)=1:RETURN
  38. 760 IFPLAY=5.0THENPRINT@200,NM$"'S BUG HAS A NECK"
  39. 770 IFPLAY=16.5THENPRINT@280,"COMPUTER'S BUG HAS A NECK";
  40. 775 LINE(PLAY*10+20,15)-(PLAY*10+24,17),1,B
  41. 780 CNT(PLAY)=CNT(PLAY)+1:NECK(PLAY)=1:RETURN
  42. 820 IFPLAY=5.0THENPRINT@200,NM$"'S BUG HAS A HEAD"
  43. 830 IFPLAY=16.5THENPRINT@280,"COMPUTER'S BUG HAS A HEAD";
  44. 835 LINE(PLAY*10+24,13)-(PLAY*10+29,19),1,BF
  45. 840 CNT(PLAY)=CNT(PLAY)+1:HEAD(PLAY)=1:RETURN
  46. 880 ANTE(PLAY)=ANTE(PLAY)+1
  47. 890 IFPLAY=5.0THENPRINT@200,NM$"'S BUG HAS"ANTE(5)"ANTENNAE."
  48. 900 IFPLAY=16.5THENPRINT@280,"COMPUTER'S BUG HAS"ANTE(16.5)"ANTENNAE.";
  49. 902 IFANTE(PLAY)=2THENLINE(PLAY*10+30,14)-(PLAY*10+40,8),1:GOTO910
  50. 904 LINE(PLAY*10+30,18)-(PLAY*10+40,22),1
  51. 910 CNT(PLAY)=CNT(PLAY)+1:RETURN
  52. 940 IFPLAY=5.0THENPRINT@200,NM$"'S BUG HAS A TAIL."
  53. 950 IFPLAY=16.5THENPRINT@280,"COMPUTER'S BUG HAS A TAIL.";
  54. 955 LINE(PLAY*10,16)-(PLAY*10-10,16),1
  55. 960 CNT(PLAY)=CNT(PLAY)+1:TAIL(PLAY)=1:RETURN
  56. 1000 LEGS(PLAY)=LEGS(PLAY)+1
  57. 1010 IFPLAY=5.0THENPRINT@200,NM$"'S BUG HAS"LEGS(5)"LEGS."
  58. 1020 IFPLAY=16.5THENPRINT@280,"COMPUTER'S BUG HAS"LEGS(16.5)"LEGS.";
  59. 1022 IFZ(PLAY)=10THENZ(PLAY)=27 ELSE Z(PLAY)=10
  60. 1024 IFY(PLAY)=5THENY(PLAY)=22 ELSE Y(PLAY)=5:X(PLAY)=X(PLAY)+7
  61. 1026 LINE(X(PLAY),Y(PLAY))-(X(PLAY),Z(PLAY)),1
  62. 1030 CNT(PLAY)=CNT(PLAY)+1:RETURN
  63. 1060 IFCNT(5.0)=12THEN1090
  64. 1070 IFCNT(16.5)=12THEN1110
  65. 1080 RETURN
  66. 1090 BEEP:BEEP:PRINT@160,Y$;:PRINTNM$"'S BUG IS FINISHED. YOU WIN!":PRINTY$;:GOTO1130
  67. 1110 BEEP:BEEP:PRINT@160,Y$;:PRINT"COMPUTER'S BUG IS FINISHED, I WIN!":PRINTY$;
  68. 1130 FOR F=1TO3000:NEXT:MENU
  69. 1200 PRINT:PRINT"The game of bug is played as follows:"
  70. 1210 PRINT"A die is rolled by the computer, and    each number on the die corresponds"
  71. 1220 PRINT"to a part of the bug's body: 1=Body,    2=Neck, 3=Head, 4=Antennae, 5=Tail,"
  72. 1225 PRINT"Touch any key to continue..."
  73. 1230 K$=INKEY$:IFK$=""THEN 1230
  74. 1240 CLS:PRINT:PRINT"and 6=legs.  You need 1 body, 1 neck,   1 head, 2 antennae, 1 tail, and"
  75. 1250 PRINT"6 legs to complete a bug.  The object   of the game is to complete your bug"
  76. 1260 PRINT"before the computer builds his!         Touch any key when you're ready..."
  77. 1270 K$=INKEY$:IFK$=""THEN1270
  78. 1280 CLS:RETURN
  79.