home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
ftp.whtech.com
/
ftp.whtech.com.tar
/
ftp.whtech.com
/
club100
/
gam
/
braker.ba
< prev
next >
Wrap
Text File
|
2006-10-19
|
2KB
|
71 lines
0 'Club 100 Library - 415/939-1246 BBS 937-5039 NEWSLETTER, 932-8856 VOICE
2 'BRAKER.BA, "Mastermind" code breaker, M100 VERSION BY RUSS HALL
5 GOTO40
10 FORJ1=0TO3:IFC(J1)<>B(J1)THEN13
12 N=N+1
13 NEXTJ1
14 FORJ1=0TO3:FORJ2=0TO3
16 IFJ1=J2THEN23
17 IFC(J1)=B(J1)THEN23
18 IFC(J2)=B(J2)THEN23
19 IFC(J1)<>B(J2)THEN23
20 M=M+1:B(J2)=8:GOTO24
23 NEXTJ2
24 NEXTJ1:RETURN
40 DEFINTA-Z:DIMR(9,3),S(9,1),A(6),B(3),C(3),D(3)
60 FORJ=0TO6:READA(J):NEXT
90 DATA 0,1,2,3,4,5,6
100 L0=0:L1=0:L2=0:L3=0
140 PRINT:PRINT" - MASTERMIND CODEBREAKER -"
145 PRINT:PRINT"Please be patient, sometimes I take a few moments on my move."
147 FORJ=1TOVAL(RIGHT$(TIME$,2)):T=RND(1):NEXT
150 PRINT:PRINT" Which version (1 or 2)";:INPUT V
170 V=V+4
175 PRINT" The colors are: Red, Blue, Green, Yellow, Black, White";:IFV=6THENPRINT", Space"
177 FOR F=1TO1000:NEXT
180 FORJ=0TO3:R(0,J)=INT((V+1)*RND(J)):NEXT
240 FORI=0TO9
250 PRINT:PRINT"MY MOVE FOR ROW"I+1"IS"
255 FORJ=0TO3:IFR(I,J)=0THENPRINT"Red ";
257 IFR(I,J)=1THENPRINT"Blue ";
258 IFR(I,J)=2THENPRINT"Green ";
259 IFR(I,J)=3THENPRINT"Yellow ";
260 IFR(I,J)=4THENPRINT"Black ";
261 IFR(I,J)=5THENPRINT"White ";
262 IFR(I,J)=6THENPRINT"Space ";
263 NEXTJ:PRINT:PRINT
270 PRINT"How many black pegs";:INPUTS(I,0)
290 IFS(I,0)<>4THEN320
300 PRINT" THANKS FOR THE GAME":PRINT:GOTO870
320 IFS(I,0)<>3THEN360
330 S(I,1)=0:GOTO390
360 PRINT"How many white pegs";:INPUT S(I,1)
390 FORI0=L0TOV
400 FORI1=L1TOV
410 FORI2=L2TOV
420 FORI3=L3TOV
430 D(0)=A(I0):D(1)=A(I1):D(2)=A(I2):D(3)=A(I3)
490 FORK=0TOI
500 FORJ=0TO3:C(J)=R(K,J):B(J)=D(J):NEXTJ
555 N=0:M=0:GOSUB10
580 IFN<>S(K,0)THEN700
590 IFM<>S(K,1)THEN700
600 NEXTK
620 Z=0
630 FORJ=0TO3:IFR(0,J)<>D(J)THEN660:Z=Z+1
660 NEXTJ
670 IFZ=4THEN700
690 GOTO830
700 NEXTI3
710 NEXTI2
720 NEXTI1
730 NEXTI0
740 PRINT"I have reached an impasse in my thinking Could you have made an error?":GOTO870
770 L0=I0:L1=I1:L2=I2:L3=I3+1
830 FORJ=0TO3:R(I+1,J)=D(J):NEXTJ
850 NEXTI
860 PRINT"I AM STUMPED - - YOU WIN!"
870 PRINT" ANOTHER GAME";:INPUTR$
890 IFR$="Y"ORR$="y"THEN150
900 MENU