home *** CD-ROM | disk | FTP | other *** search
/ ftp.whtech.com / ftp.whtech.com.tar / ftp.whtech.com / club100 / bus / glchek.ba < prev    next >
Text File  |  2006-10-19  |  5KB  |  79 lines
  1. 0 'GLCHEK.BA - BY J. KAPLIN                CLUB 100 LIBRARY - 415/939-1246 BBS,    937-5039 NEWSLETTER, 932-8856 VOICE
  2. 1 CLEAR1000:MAXFILES=2:GOTO59
  3. 2 R=2
  4. 3 OPEN"lcd:"FOROUTPUTAS2:ONERRORGOTO62
  5. 4 OPEN"cj"FORINPUTAS1
  6. 5 IFEOF(1)GOTO17
  7. 6 GOSUB70:INPUT#1,A$,B$,C$,D$,E$,F,G:IF C$="SB"THENSB=G-F:GOTO5
  8. 7 IFR=1ANDE$<>""GOTO5
  9. 8 FSUM=FSUM+F:GSUM=GSUM+G:IFLC>0GOTO13
  10. 9 IFLC=0GOTO5
  11. 10 IFF>0THENLPRINTTAB(43)F
  12. 11 IFG>0THENLPRINTTAB(55)G
  13. 12 GOTO5
  14. 13 LPRINTTAB(3)LEFT$(A$,8);TAB(12)D$;TAB(18)LEFT$(B$,25);TAB(43);:IFF>0THENLPRINTUSINGS$;F;
  15. 14 IFG>0THENLPRINTTAB(53);USINGS$;G;
  16. 15 LPRINT:LC=LC+1:IFLC>54THENLPRINTCHR$(12):LC=1
  17. 16 GOTO5
  18. 17 IFLC>0ANDR=1GOTO56
  19. 18 IFLC>50THENLPRINTCHR$(12):LC=1
  20. 19 IFLC=0THENCLS
  21. 20 IFR=0GOTO22
  22. 21 IFR=2THENBAL=SB+GSUM-FSUM:GSUM=0:FSUM=0:R=1:GOTO41
  23. 22 PRINT#2,"":PRINT#2,"Start Balance =";USINGT$;SB:PRINT#2,"Total Checks  =";USINGS$;FSUM:PRINT#2,"Total Deposits=";USINGS$;GSUM:PRINT#2,"":PRINT#2,"     Balance  =";:PRINT#2,USINGT$;SB+GSUM-FSUM:CLOSE:IFLC>0THENLPRINTCHR$(12)
  24. 23 INPUT"Press <CR> to Continue";Z$:GOTO59
  25. 24 GOSUB63:ONERRORGOTO39:OPEN"cj"FORINPUTAS1:CLOSE:OPEN"cj"FORAPPENDAS1
  26. 25 CLS:PRINT:PRINT:PRINTTAB(12)"C]heck Input":PRINTTAB(12)"D]eposit Input":PRINTTAB(12)"R]eturn to Menu"
  27. 26 ONINSTR("  CcDdRr",INKEY$)GOTO26,26,27,27,28,28,59,59:GOTO26
  28. 27 Q=1:CLS:PRINT"CHECK (DEBIT)":GOSUB71:GOTO29
  29. 28 Q=0:CLS:PRINT"DEPOSIT (CREDIT)":GOSUB71
  30. 29 PRINT@240,"Date";:AP$=""
  31. 30 AP$=AP$+INKEY$:IFAP$=CHR$(13)GOTO34
  32. 31 PRINT@246,AP$:IFLEN(A$)=8ANDLEN(AP$)=1THENA$=""
  33. 32 IFLEN(AP$)<2GOTO30
  34. 33 A$=A$+AP$:AP$="":PRINT@246,SPACE$(8):GOSUB71:IFLEN(A$)<8THENA$=A$+"/":GOTO29
  35. 34 PRINT@240,"Description";:INPUTB$:GOSUB71:PRINT@240,"Category";:INPUTC$:GOSUB71:PRINT@240,"Number";:INPUTD$:GOSUB71:DM$=D$:AM$=A$:PRINT@240,"Amount";:INPUTI:GOSUB71:IFQ=1THENF=IELSEG=I
  36. 35 IFI=0GOTO77
  37. 36 PRINT@240,"<CR>Input or C]ancel":ONINSTR("Cc",INPUT$(1))GOTO77,77:IFI=0GOTO77
  38. 37 GOTO72
  39. 38 PRINT#1,A$;",";B$;",";C$;",";D$;",";E$;",";F;",";G:GOSUB70:D$=STR$(1+VAL(DM$)):A$=AM$:GOTO25
  40. 39 A$=DATE$:B$="Starting Balance":C$="SB":E$="X":F=0:CLS:INPUT"Starting Balance";G:INPUT"Date of Starting Balance";A$:OPEN"CJ"FORAPPENDAS1:GOTO38
  41. 40 CLS:ONERRORGOTO62:OPEN"cj"FORINPUTAS1:CLOSE:OPEN"lpt:"FOROUTPUTAS2
  42. 41 IFR=1THENLPRINTTAB(28)"Bank Reconciliation":GOTO43
  43. 42 LPRINT:LPRINTTAB(30)"Cash Journal"
  44. 43 LPRINTTAB(29)"As Of ";DATE$:LPRINT:LPRINT:LPRINT:LPRINTTAB(48)"Checks";TAB(56)"Deposits":LC=7:IFR=1THENCLOSE
  45. 44 GOTO4
  46. 45 ONERRORGOTO62:OPEN"cj"FORINPUTAS1:OPEN"temp"FOROUTPUTAS2
  47. 46 GOSUB70:IFEOF(1)THENGOTO55
  48. 47 INPUT#1,A$,B$,C$,D$,E$,F,G:IFE$<>""GOTO54
  49. 48 CLS:IFD$<>" "THENPRINT:PRINT"Ck #";D$;" "B$
  50. 49 IFF<>0THENPRINTUSINGS$;F:INPUT"Correct Check Amount";Z
  51. 50 IFZ<>0THENF=Z:Z=0
  52. 51 IFG<>0THENPRINTUSINGS$;G:INPUT"Correct Deposit Amount";Z
  53. 52 IFZ<>0THENG=Z:Z=0
  54. 53 INPUT"Enter X for Cleared";E$
  55. 54 PRINT#2,A$;",";B$;",";C$;",";D$;",";E$;",";F;",";G:GOTO46
  56. 55 CLOSE:KILL"cj.do":NAME"temp.do"AS"cj.do":GOTO59
  57. 56 IFLC>50THENLPRINTCHR$(12):LC=0
  58. 57 LPRINT:LPRINT"Check Balance       =";USINGT$;BAL:LPRINT"Outstanding Deposits=";USINGS$;GSUM:LPRINT"Outstanding Checks  =";USINGS$;FSUM:LPRINT
  59. 58 LPRINT"Bank Balance Should =";USINGT$;BAL+FSUM-GSUM:LPRINTCHR$(12):CLOSE:BAL=0:FSUM=0:GSUM=0:CLS:INPUT"Press <CR> to Continue";Z$
  60. 59 CLEAR:S$="########.##":T$="        $$########.##":CLS:PRINT"SELECT:":PRINTTAB(10)"I]nput Data":PRINTTAB(10)"C]heck Balance":PRINTTAB(10)"P]rint Journal":PRINTTAB(10)"S]tatement Check":PRINTTAB(10)"R]econciliation":PRINTTAB(10)"E]xit"
  61. 60 ONINSTR("  IiCcEePpSsRr",INKEY$)GOTO60,60,24,24,3,3,61,61,40,40,45,45,2,2:GOTO60
  62. 61 CLOSE:MAXFILES=1:MENU:END
  63. 62 CLS:PRINT:PRINT:PRINT:PRINT"     THERE IS NO CHECK JOURNAL":INPUT"     HIT <CR> TO CONTINUE";Z$:GOTO1
  64. 63 CLS:PRINT@135,"WAIT":N=1:OPEN"wtb"FORINPUTAS2
  65. 64 IFEOF(2)GOTO66
  66. 65 LINEINPUT#2,Z$:N=N+1:GOTO64
  67. 66 CLOSE#2:DIMU$(N):N=1:OPEN"wtb"FORINPUTAS2
  68. 67 IFEOF(2)GOTO69
  69. 68 INPUT#2,U$(N),V$,U,V,W,X,Y:N=N+1:GOTO67
  70. 69 CLOSE#2:RETURN
  71. 70 A$=" ":B$=" ":C$=" ":D$=" ":E$=" ":F=0:G=0:I=0:RETURN
  72. 71 PRINT@40,"Date: "A$"       ":PRINT@80,"Description: ";B$:PRINT@120,"Category: ";C$:PRINT@140,"Number: ";D$"     ":PRINT@160,"Amount";USINGS$;I:PRINT@240,SPACE$(39):RETURN
  73. 72 FORM=1TON:IFU$(M)=C$GOTO38
  74. 73 NEXT:CLS:PRINTA$;" ";B$;D$:PRINT"Cat#";C$:C$="":IFF>0THENPRINTUSINGT$;F
  75. 74 IFG>0THENPRINTTAB(20)USINGT$;G
  76. 75 PRINT"  INVALID CATEGORY NUMBER":PRINT"<CR> to Cancel or":INPUT"  ENTER CORRECTION";C$:IFC$=""GOTO77
  77. 76 CLS:GOTO72
  78. 77 CLS:PRINT@135,"CANCELED":FORM=1TO100:NEXT:GOSUB70:D$=DM$:A$=AM$:GOTO25
  79.