home *** CD-ROM | disk | FTP | other *** search
/ GEMini Atari / GEMini_Atari_CD-ROM_Walnut_Creek_December_1993.iso / files / gnu / libsrc87 / _cmpdf2.s < prev    next >
Encoding:
Text File  |  1993-07-30  |  3.1 KB  |  185 lines
  1. | double floating point compare routine
  2. |
  3. | written by Olaf Flebbe (flebbe@tat.physik.uni-tuebingen.de)
  4. | Based on a 68k floating point packet from Kai-Uwe Bloem, itself based
  5. | on a 80x86 floating point packet from comp.os.minix, written by P.Housel
  6. | 
  7. | Revision 2.0: olaf 12-92.
  8. |
  9.  
  10.     .text
  11.     .even
  12.     .globl    ___eqdf2, ___nedf2
  13.     .globl    ___gtdf2, ___ledf2
  14.     .globl    ___gedf2, ___ltdf2
  15.     .globl    __cmpdf2, ___cmpdf2
  16.     
  17. __cmpdf2:
  18. ___cmpdf2:
  19. ___eqdf2:
  20. ___nedf2:
  21.     moveml    sp@(4),d0-d1/a0-a1        | get numbers to compare with
  22.     tstl    d0        | check sign bit
  23.     bpl    1f
  24.     negl    d1        | negate
  25.     negxl    d0
  26.     bchg    #31,d0        | toggle sign bit
  27.  
  28. 1:    exg    a0,d0
  29.     exg    a1,d1
  30.     tstl    d0        | check sign bit
  31.     bpl    2f
  32.     negl    d1        | negate
  33.     negxl    d0
  34.     bchg    #31,d0        | toggle sign bit
  35.  
  36. 2:    cmpl    d1,a1
  37.     bne    4f
  38.     cmpl    d0,a0
  39.     bne    4f
  40.     bclr    #31,d0
  41.     cmpl    #0x7ff00000,d0        | NaN is not equal NaN !
  42.     bgt    4f
  43.     blt    3f
  44.     tstl    d1
  45.     bne    4f
  46. 3:    clrl    d0
  47.     rts
  48.  
  49. 4:    moveql    #1,d0
  50.     rts
  51.  
  52. ___gtdf2:
  53.     moveml    sp@(4),d0-d1/a0-a1        | get numbers to compare with
  54.     tstl    d0        | check sign bit
  55.     bpl    1f
  56.     negl    d1        | negate
  57.     negxl    d0
  58.     bchg    #31,d0        | toggle sign bit
  59.  
  60. 1:    exg    a0,d0
  61.     exg    a1,d1
  62.     tstl    d0        | check sign bit
  63.     bpl    2f
  64.     negl    d1        | negate
  65.     negxl    d0
  66.     bchg    #31,d0        | toggle sign bit
  67.  
  68. 2:    exg    a0,d0
  69.     exg    a1,d1
  70.     cmpl    a0,d0
  71.     bgt    4f        | d0 > a0 Test if NaN (should be false!)
  72.     blt    3f        | 
  73.     cmpl    a1,d1
  74.     bhi    4f
  75. 3:    clrl    d0        | Test is false.
  76.     rts
  77. 4:    bclr    #31,d0        
  78.     cmpl    #0x7ff00000,d0    | First operand == NaN =?
  79.     bgt    3b
  80.     blt    5f        | It is finite!
  81.     tstl    d1
  82.     bne    3b        | It *is* a NaN
  83. 5:    moveql    #1,d0        | Test True
  84.     rts
  85.  
  86. ___ledf2:
  87.     moveml    sp@(4),d0-d1/a0-a1        | get numbers to compare with
  88.     tstl    d0        | check sign bit
  89.     bpl    1f
  90.     negl    d1        | negate
  91.     negxl    d0
  92.     bchg    #31,d0        | toggle sign bit
  93.  
  94. 1:    exg    a0,d0
  95.     exg    a1,d1
  96.     tstl    d0        | check sign bit
  97.     bpl    2f
  98.     negl    d1        | negate
  99.     negxl    d0
  100.     bchg    #31,d0        | toggle sign bit
  101.  
  102. 2:    cmpl    d0,a0
  103.     blt    4f
  104.     bgt    3f
  105.     cmpl    d1,a1
  106.     bls    4f            | <= !
  107. 3:    moveql    #1,d0        | Test is false
  108.     rts
  109. 4:    bclr    #31,d0        
  110.     cmpl    #0x7ff00000,d0    | First operand == NaN =?
  111.     bgt    3b
  112.     blt    5f        | It is finite!
  113.     tstl    d1
  114.     bne    3b        | It *is* a NaN
  115. 5:    clrl    d0        | Test true
  116.     rts
  117.  
  118. ___gedf2:
  119.     moveml    sp@(4),d0-d1/a0-a1        | get numbers to compare with
  120.     tstl    d0        | check sign bit
  121.     bpl    1f
  122.     negl    d1        | negate
  123.     negxl    d0
  124.     bchg    #31,d0        | toggle sign bit
  125.  
  126. 1:    exg    a0,d0
  127.     exg    a1,d1
  128.     tstl    d0        | check sign bit
  129.     bpl    2f
  130.     negl    d1        | negate
  131.     negxl    d0
  132.     bchg    #31,d0        | toggle sign bit
  133.  
  134. 2:    exg    a0,d0
  135.     exg    a1,d1
  136.     cmpl    a0,d0
  137.     bgt    4f
  138.     blt    3f
  139.     cmpl    a1,d1
  140.     beq    4f        | >= !
  141.     bhi    4f
  142. 3:    moveql    #-1,d0        | False
  143.     rts
  144. 4:    bclr    #31,d0        
  145.     cmpl    #0x7ff00000,d0    | First operand == NaN =?
  146.     bgt    3b
  147.     blt    5f        | It is finite!
  148.     tstl    d1
  149.     bne    3b        | It *is* a NaN
  150. 5:    clrl    d0        | Test True
  151.     rts
  152.  
  153. ___ltdf2:
  154.     moveml    sp@(4),d0-d1/a0-a1        | get numbers to compare with
  155.     tstl    d0        | check sign bit
  156.     bpl    1f
  157.     negl    d1        | negate
  158.     negxl    d0
  159.     bchg    #31,d0        | toggle sign bit
  160.  
  161. 1:    exg    a0,d0
  162.     exg    a1,d1
  163.     tstl    d0        | check sign bit
  164.     bpl    2f
  165.     negl    d1        | negate
  166.     negxl    d0
  167.     bchg    #31,d0        | toggle sign bit
  168.  
  169. 2:    cmpl    d0,a0
  170.     blt    4f
  171.     bgt    3f
  172.     cmpl    d1,a1
  173.     beq    3f
  174.     bls    4f
  175. 3:    clrl    d0
  176.     rts
  177. 4:    bclr    #31,d0        
  178.     cmpl    #0x7ff00000,d0    | First operand == NaN =?
  179.     bgt    3b
  180.     blt    5f        | It is finite!
  181.     tstl    d1
  182.     bne    3b        | It *is* a NaN
  183. 5:    moveql    #-1,d0        | Test True
  184.     rts
  185.