home *** CD-ROM | disk | FTP | other *** search
/ GEMini Atari / GEMini_Atari_CD-ROM_Walnut_Creek_December_1993.iso / files / gnu / libsrc87 / _addsubs.cpp < prev    next >
Encoding:
Text File  |  1993-07-30  |  6.1 KB  |  273 lines
  1. |
  2. | single floating point add/subtract routine
  3. |
  4. #ifndef    __M68881__
  5.     .text
  6.     .even
  7.     .globl    __subsf3, ___subsf3
  8.     .globl    __addsf3, ___addsf3
  9. # ifndef sfp004
  10. |
  11. | written by Kai-Uwe Bloem (I5110401@dbstu1.bitnet).
  12. | Based on a 80x86 floating point packet from comp.os.minix, written by P.Housel
  13. | patched by Olaf Flebbe (flebbe@tat.physik.uni-tuebingen.de)
  14. |
  15. | Revision 1.3.4 olaf 11-92 :
  16. |  + added support for NaN and infinities
  17. |    > paranoia now dont complains about unbalanced range any more
  18. |  -- still lacks trap handling for exceptions
  19. |  -- dont know the external representation of quiet and signaling NaN
  20. |     I decided 0x7fffffff to be a quiet NaN
  21. |     the rest should be signaling (but isnt)
  22. |
  23. | Revision 1.3.3 olaf 11-92 :
  24. |  + changed to get rid of rounding bits. a sticky register (d3) is
  25. |    sufficient.
  26. |
  27. | Revision 1.3.2 olaf 10-92 :
  28. |  + increased comparson by one again. (Dont understand, but it works)
  29. |  + corrected negation of rounding bits and mantissa
  30. |     >enquire now detects correct IEEE precision
  31. |     >paranoia now qualifies add/sub as correctly rounded
  32. |
  33. | Revision 1.3.1 olaf 10-92 :
  34. |  + increased comparison of exponents by one.
  35. |  + initialized sticky byte
  36. |  + corrected handling of rounding bits
  37. |  + corrected swapping of register halves
  38. |     >paranoia now detects only one (obscure) SERIOUS DEFECT.
  39. |     ** Patches need _normsf Rev 1.4.1 (or higher) **
  40. |
  41. | Revision 1.3, kub 01-90 :
  42. | added support for denormalized numbers
  43. |
  44. | Revision 1.2, kub 01-90 :
  45. | replace far shifts by swaps to gain speed (more optimization is of course
  46. | possible by doing shifts all in one intruction, but what about the rounding
  47. | bits)
  48. |
  49. | Revision 1.1, kub 12-89 :
  50. | Created single float version for 68000
  51. |
  52. | Revision 1.0:
  53. | original 8088 code from P.S.Housel for double floats
  54.  
  55. __subsf3:
  56. ___subsf3:
  57.     eorb    #0x80,sp@(8)    | reverse sign of v
  58. __addsf3:
  59. ___addsf3:
  60.     lea    sp@(4),a0    | pointer to u and v parameter
  61.     moveml    d2-d5,sp@-    | save registers
  62.     moveml    a0@,d4/d5    | d4 = v, d5 = u
  63.  
  64.     movel    d5,d0        | d0 = u.exp
  65.     swap    d0
  66.     movel    d5,d2        | d2.h = u.sign
  67.     movew    d0,d2
  68.     lsrw    #7,d0
  69.     andw    #0xff,d0    | kill sign bit (exponent is 8 bits)
  70.  
  71.     movel    d4,d1        | d1 = v.exp
  72.     swap    d1
  73.     eorw    d1,d2        | d2.l = u.sign ^ v.sign
  74.     lsrw    #7,d1
  75.     andw    #0xff,d1    | kill sign bit (exponent is 8 bits)
  76.  
  77.     andl    #0x7fffff,d5    | remove exponent from mantissa
  78.     andl    #0x7fffff,d4    | remove exponent from mantissa
  79. |
  80. | Now perform testing of NaN And infinities
  81. |
  82.     cmpb    #0xff,d0
  83.     beq    0f
  84.     cmpb    #0xff,d1
  85.     bne    nospec        
  86.     bra    1f
  87. |    first operand is special
  88. |
  89. 0:    cmpb    d0,d1
  90.     beq    bothspec
  91. |
  92. |    u is special
  93. | 
  94.     tstl    d5
  95.     bne    retnan        | arith with Nan gives always Nan
  96.  
  97.     movel    a0@(4),d0        | copy infinity
  98.     bra     return
  99. |
  100. |    v is special
  101. |
  102. 1:    tstl    d4
  103.     bne    retnan
  104.     movel    a0@,d0
  105.     bra    return
  106. |
  107. |    u and v are both special
  108. |
  109. bothspec:
  110.     movel    d5,d0
  111.     orl    d4,d0
  112.     beq    bothinf
  113.     bra    retnan    
  114. |
  115. | Both are infinities Test if cancellation
  116. | 
  117. bothinf:
  118.     tstw    d2
  119.     bpl    retinf    
  120. |
  121. | return a quiet NaN
  122. |
  123. retnan:    movel    #0x7fffffff,d0
  124.     bra    return
  125.  
  126. retinf: movel   #0x7f800000,d0
  127.     tstl    d2
  128.     bpl    return
  129.     bchg    #31,d0
  130. return:    moveml    sp@+,d2-d5
  131.     rts
  132. |    
  133. | Ok, no inifinty or Nan involved..
  134. |
  135. nospec:    tstw    d0        | check for zero exponent - no leading "1"
  136.     beq    0f
  137.     orl    #0x800000,d5    | restore implied leading "1"
  138.     bra    1f
  139. 0:    addw    #1,d0        | "normalize" exponent
  140. 1:
  141.     tstw    d1        | check for zero exponent - no leading "1"
  142.     beq    0f
  143.     orl    #0x800000,d4    | restore implied leading "1"
  144.     bra    1f
  145. 0:    addw    #1,d1        | "normalize" exponent
  146. 1:
  147.     clrl    d3        | (put initial zero rounding bits in d3)
  148.     negw    d1        | d1 = u.exp - v.exp
  149.     addw    d0,d1
  150.     beq    5f        | exponents are equal - no shifting neccessary
  151.     bgt    1f        | not equal but no exchange neccessary
  152.     exg    d4,d5        | exchange u and v
  153.     subw    d1,d0        | d0 = u.exp - (u.exp - v.exp) = v.exp
  154.     negw    d1
  155.     tstw    d2        | d2.h = u.sign ^ (u.sign ^ v.sign) = v.sign
  156.     bpl    1f
  157.     bchg    #31,d2
  158. 1:
  159.     cmpw    #26,d1        | is u so much bigger that v is not
  160.     bge    7f        | significant ?
  161. |
  162. | shift mantissa left two digits, to allow cancellation of
  163. | most significant digit, while gaining an additional digit for
  164. | rounding.
  165. |
  166.     moveql    #1,d3    
  167. 2:    addl    d5,d5
  168.     subw    #1,d0        | decrement exponent
  169.     subw    #1,d1        | done shifting altogether ?
  170.     dbeq    d3,2b        | loop if still can shift u.mant more
  171.     clrl    d3
  172.  
  173.     cmpw    #16,d1        | see if fast rotate possible
  174.     blt    4f
  175.     orw    d4,d3        | set rounding bits
  176.     clrw    d4
  177.     swap    d4
  178.     subw    #16,d1
  179.         bra     4f
  180.  
  181. 0:    moveb   d4,d2
  182.     andb    #1,d2
  183.     orb    d2,d3
  184.     lsrl    #1,d4        | shift v.mant right the rest of the way
  185. 4:    dbra    d1,0b        | loop
  186.  
  187. 5:
  188.     tstw    d2        | are the signs equal ?
  189.     bpl    6f        | yes, no negate necessary
  190.  
  191.  
  192.     tstw    d3        | negate rounding bits and v.mant
  193.     beq    9f
  194.     addql    #1,d4
  195. 9:    negl    d4
  196.  
  197. 6:
  198.     addl    d4,d5        | u.mant = u.mant + v.mant
  199.     bcs    7f        | needn not negate
  200.     tstw    d2        | opposite signs ?
  201.     bpl    7f        | do not need to negate result
  202.  
  203.     negl    d5
  204.     notl    d2        | switch sign
  205. 7:
  206.     movel    d5,d4        | move result for normalization
  207.     clrl    d1
  208.     tstl    d3
  209.     beq    8f
  210.     moveql    #-1,d1
  211. 8:    swap    d2        | put sign into d2 (exponent is in d0)
  212.     jmp    norm_sf        | leave registers on stack for norm_sf
  213.  
  214. # else    sfp004
  215.  
  216. | single precision floating point stuff for Atari-gcc using the SFP004
  217. | developed with gas
  218. |
  219. |  single floating point add/subtract routine
  220. |
  221. | M. Ritzert (mjr at dmzrzu71)
  222. |
  223. | 4.10.1990
  224. |
  225. | no NAN checking implemented since the 68881 treats this situation "correct",
  226. | i.e. according to IEEE
  227.  
  228. | addresses of the 68881 data port. This choice is fastest when much data is
  229. | transferred between the two processors.
  230.  
  231. comm =     -6
  232. resp =    -16
  233. zahl =      0
  234.  
  235. | waiting loop ...
  236. |
  237. | wait:
  238. | ww:    cmpiw    #0x8900,a0@(resp)
  239. |     beq    ww
  240. | is coded directly by
  241. |    .long    0x0c688900, 0xfff067f8
  242.  
  243. __subsf3:
  244. ___subsf3:
  245.     lea    0xfffffa50:w,a0
  246.     movew    #0x4400,a0@(comm)    | load first argument to fp0
  247.     cmpiw    #0x8900,a0@(resp)    | check
  248.     movel    a7@(4),a0@
  249.     movew    #0x4428,a0@(comm)
  250.     .long    0x0c688900, 0xfff067f8
  251.     movel    a7@(8),a0@
  252.     movew    #0x6400,a0@(comm)    | result to d0
  253.     .long    0x0c688900, 0xfff067f8
  254.     movel    a0@,d0
  255.      rts
  256.  
  257. __addsf3:
  258. ___addsf3:
  259.     lea    0xfffffa50:w,a0
  260.     movew    #0x4400,a0@(comm)        | load fp0
  261.     cmpiw    #0x8900,a0@(resp)        | got it?
  262.     movel    a7@(4),a0@            | take a from stack to FPU
  263.     movew    #0x4422,a0@(comm)        | add second arg to fp0
  264.     .long    0x0c688900, 0xfff067f8
  265.     movel    a7@(8),a0@            | move b from stack to FPU
  266.     movew    #0x6400,a0@(comm)        | result to d0
  267.     .long    0x0c688900, 0xfff067f8
  268.     movel    a0@,d0                | download result
  269.      rts
  270.  
  271. # endif    sfp004
  272. #endif    __M68881__
  273.