home *** CD-ROM | disk | FTP | other *** search
/ HAM Radio 1 / HamRadio.cdr / tech / palsum5 / memio.pds < prev    next >
Text File  |  1987-08-26  |  3KB  |  89 lines
  1. Title    PC I/O Mapper
  2. Pattern  MemIO.pds
  3. Revision A
  4. Author   A G Gilbert
  5. Company  Monolithic Memories Inc., Santa Clara,CA
  6. Date     1/8/85
  7.   
  8. ;Personal computers which are hardware compatible with the
  9. ;ubiquitous IBM PC share this I/O map.
  10.   
  11. CHIP PC_IO PAL8L14
  12.   
  13. NC NC A9 A8 A7 A6 A5 A4 A3 AEN /CSMONOCHRMAD GND
  14. /CSGAMEIOAD /CSCOLORAD /CSPRINTERAD /CS5FLOPPYAD /CSRS232AD /CSNMIMKRG
  15. /CSDMAPGRG /CSPPICHIP /CSTIMERCHIP /CSINTCCHIP /CSDMACCHIP VCC
  16.   
  17. Equations
  18.   
  19. CSDMACCHIP = /A9*/A8*/A7*/A6*/A5       ;DMA controller
  20.            * /A4*/AEN                  ;Chip select
  21.                                        ;HEX address 000-00F
  22.   
  23. CSINTCCHIP = /A9*/A8*/A7*/A6*A5        ;Interupt controller
  24.            * /A4*/A3*/AEN              ;Chip select
  25.                                        ;HEX address 020-021
  26.   
  27. CSTIMERCHIP = /A9*/A8*/A7*A6*/A5       ;Timer
  28.             * /A4*/A3*/AEN             ;Chip select
  29.                                        ;HEX address 040-043
  30.   
  31. CSPPICHIP = /A9*/A8*/A7*A6*A5          ;Parallel peripheral interface
  32.           * /A4*/A3*/AEN               ;Chip select
  33.                                        ;HEX address 060-063
  34.   
  35. CSDMAPGRG = /A9*/A8*A7*/A6*/A5         ;DMA page register
  36.           * /A4*/A3*/AEN               ;Chip select
  37.                                        ;HEX address 080-083
  38.   
  39. CSNMIMKRG = /A9*/A8*A7*/A6*A5          ;NMI mask register
  40.           * /A4*/AEN                   ;Chip select
  41.                                        ;HEX address 0AX
  42.   
  43. CSRS232AD = A9*A8*A7*A6*A5             ;RS 232 module
  44.           * A4*A3*/AEN                 ;Device select
  45.                                        ;HEX address 3F8-3FF
  46.   
  47. CS5FLOPPYAD = A9*A8*A7*A6*A5           ;5.25 floppy disk module
  48.             * A4*/A3*/AEN              ;Device select
  49.                                        ;HEX address 3F0-3F7
  50.   
  51. CSPRINTERAD = A9*/A8*/A7*A6*A5         ;Parallel printer module
  52.             * A4*A3*/AEN               ;Device select
  53.                                        ;HEX address 378-37F
  54.   
  55. CSCOLORAD = A9*A8*A7*A6*/A5            ;Color graphics video module
  56.           * A4*/AEN                    ;Device select
  57.                                        ;HEX address 3D0-3DF
  58.   
  59. CSGAMEIOAD = A9*/A8*/A7*/A6*/A5        ;Game I/O module
  60.            * /A4*/AEN                  ;Device select
  61.                                        ;HEX address 200-20F
  62.   
  63. CSMONOCHRMAD = A9*A8*A7*/A6*A5         ;Monochrome video module
  64.              * A4*/AEN                 ;Device select
  65.                                        ;HEX address 3B0-3BF
  66.   
  67.   
  68. SIMULATION
  69.   
  70. TRACE_ON  A9 A8 A7 A6 A5 A4 A3 AEN /CSMONOCHRMAD
  71.          /CSGAMEIOAD /CSCOLORAD /CSPRINTERAD /CS5FLOPPYAD
  72.          /CSRS232AD /CSNMIMKRG /CSDMAPGRG /CSPPICHIP
  73.          /CSTIMERCHIP /CSINTCCHIP /CSDMACCHIP
  74. SETF AEN
  75. SETF /A9 /A8 /A7 /A6 /A5 /A4 /A3 /AEN
  76. SETF  A5
  77. SETF  A6
  78. SETF /A5  A7
  79. SETF  A5
  80. SETF  A4 /A6
  81. SETF  A9  A8  A7  A6  A5  A4  A3
  82. SETF /A3
  83. SETF /A5
  84. SETF /A4 /A6 /A7 /A8
  85. SETF  A9  A8  A7 /A6  A5  A4
  86.   
  87. TRACE_OFF
  88.   
  89.