home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
HAM Radio 1
/
HamRadio.cdr
/
tech
/
palsum5
/
dcoder.pds
< prev
next >
Wrap
Text File
|
1987-08-26
|
3KB
|
77 lines
; THIS PAL IS PART OF THE QIC-02 COMMAND SQUENCER DESIGN.
; THE PRIMARY PURPOSE OF THIS PAL IS TO ENCODE 8 BIT COMMANDS
; INTO 4 BIT COMMAND CODES. THIS PAL IS ALSO USED TO ENCODE
; TAPE DRIVE STATUS SIGNALS AND TO SELECT THE DRIVE NUMBER.
TITLE QIC-02 COMMAND DECODER PAL
PATTERN
REVISION B
AUTHOR KEN WON
COMPANY MONOLITHIC MEMORIES
DATE JANUARY 26, 1987
CHIP QIC_02_CMD_PAL PAL20L8
D7 D6 D5 D4 D3 D2 D1 D0 DS0 DS1 FM GND
BOT EOT NC /DSELD /CC2A /STATUS CC3 CC2 CC1 CC0 NC VCC
EQUATIONS
STATUS = /EOT*/BOT*/FM ;ASSERT STATUS TO PMS14R21
/CC0 = D7*D6*/D5*D4*D3*D2*D1*/D0 ; BOT COMMAND
+ D7*D6*/D5*D4*D3*/D2*D1*D0 ; INITIALIZE
+ D7*/D6*/D5*D4*D3*D2*D1*D0 ; WRITE FILE MARK
+ /D7*D6*D5*D4*D3*D2*D1*D0 ; READ
+ D7*D6*D5*D4*DSELD ; SELECT DRIVE
/CC1 = D7*D6*/D5*D4*D3*D2*/D1*D0 ; ERASE
+ D7*D6*/D5*D4*D3*/D2*D1*D0 ; INITIALIZE
+ D7*/D6*/D5*D4*D3*D2*D1*D0 ; WRITE FILE MARK
+ /D7*D6*/D5*D4*D3*D2*D1*D0 ; READ FILE MARK
+ D7*D6*D5*D4*/DSELD ; UNSELECT DRIVE
/CC2 = D7*D6*/D5*D4*D3*D2*D1*/D0 ; BOT COMMAND
+ D7*D6*/D5*D4*D3*D2*/D1*D0 ; ERASE
+ D7*D6*/D5*D4*D3*/D2*D1*D0 ; INITIALIZE
+ D7*/D6*D5*D4*D3*D2*D1*D0 ; WRITE
+ D7*/D6*/D5*D4*D3*D2*D1*D0 ; WRITE FILE MARK
+ /D7*D6*/D5*D4*D3*D2*D1*D0 ; READ FILE MARK
+ CC2A ; READ AND READ STATUS
CC2A = /D7*D6*D5*D4*D3*D2*D1*D0 ; READ
+ /D7*/D6*D5*D4*D3*D2*D1*D0 ; READ STATUS
/CC3 = D7*/D6*D5*D4*D3*D2*D1*D0 ; WRITE
+ D7*/D6*/D5*D4*D3*D2*D1*D0 ; WRITE FILE MARK
+ /D7*D6*D5*D4*D3*D2*D1*D0 ; READ
+ /D7*D6*/D5*D4*D3*D2*D1*D0 ; READ FILE MARK
DSELD = /D0*/DS1*/DS0*D1*D2*D3 ; DRIVE 1 SELECT
+ /D1*/DS1*DS0*D0*D2*D3 ; DRIVE 2 SELECT
+ /D2*DS1*/DS0*D0*D1*D3 ; DRIVE 3 SELECT
+ /D3*DS1*DS0*D0*D1*D2 ; DRIVE 4 SELECT
SIMULATION
; THIS SIMULATION FILE TESTS THE OUTPUT FOR ALL VALID AND ONE INVALID
; COMMAND INPUT
TRACE_ON D7 D6 D5 D4 D3 D2 D1 D0 FM EOT BOT CC0 CC1 CC2 CC3 /STATUS /DSELD
SETF D7 D6 /D5 D4 D3 D2 D1 /D0 ;BEGINNING OF TAPE
SETF D7 D6 /D5 D4 D3 D2 /D1 D0 ;ERASE
SETF D7 D6 /D5 D4 D3 /D2 D1 D0 ;INITIALIZE
SETF D7 /D6 D5 D4 D3 D2 D1 D0 ;WRITE
SETF D7 /D6 /D5 D4 D3 D2 D1 D0 ;WRITE FILE MARK
SETF /D7 D6 D5 D4 D3 D2 D1 D0 ;READ
SETF /D7 D6 /D5 D4 D3 D2 D1 D0 ;READ FILE MARK
SETF /D7 /D6 D5 D4 D3 D2 D1 D0 ;READ STATUS
SETF /D7 D6 D5 D4 /D3 /D2 D1 D0 ;INVALID COMMAND
SETF EOT ;ASSERT EOT
SETF /EOT ;NEGATE EOT
SETF BOT ;ASSERT BOT
SETF /BOT ;NEGATE BOT
SETF FM ;ASSERT FM
SETF /FM ;NEGATE FM
SETF DS1 /DS0 ;SET DRIVE NUMBER TO 3
SETF D7 D6 D5 D4 D3 /D2 D1 D0 ;SELECT DRIVE 3
SETF D7 D6 D5 D4 D3 D2 /D1 D0 ;UNSELECT DRIVE 3
TRACE_OFF