home *** CD-ROM | disk | FTP | other *** search
/ HAM Radio 1 / HamRadio.cdr / satel / geosatts / satloctr.bas < prev    next >
BASIC Source File  |  1986-02-23  |  6KB  |  143 lines
  1. 10  '***************************************************************************
  2. 20  '*                                                                         *
  3. 30  '*                       GEO-SYNCHRONOUS SATELLITE                         *
  4. 40  '*                    EARTH STATION  ANTENNA LOCATOR                       *
  5. 50  '*                            Version  1.0                                 *
  6. 60  '*                 Last satellite  list update 09/22/85                    *
  7. 70  '*                                                                         *
  8. 80  '*                                 BY                                      *
  9. 90  '*                         Thomas R. Thornton                              *
  10. 100  '*                          7228 Dieppe Way.                               *
  11. 110  '*                      Sacramento, Calif. 95842                           *
  12. 120 '*                        (916) 334-2005 voice                             *
  13. 130 '*                        (916) 334-2006 data                              *
  14. 140 '*                                                                         *
  15. 150 '***************************************************************************
  16. 160 PCLS$=CHR$(12): FF$=CHR$(12)     ' CLEAR SCREEN & FORM FEED CODES
  17. 170 PRINT PCLS$
  18. 180 PRINT "SATLOCTR.BAS is the copyrighted property of Thomas R. Thornton. You"
  19. 190 PRINT "are granted a limited license to use, copy and distribute it, provided"
  20. 200 PRINT "that the following conditions are met:"
  21. 210 PRINT
  22. 220 PRINT "1)  No fee may be charged for such copying and distribution.
  23. 230 PRINT
  24. 240 PRINT "2)  SATLOCTR.BAS may ONLY be distributed in its original, unmodified state.
  25. 250 PRINT "    (except for 'SATELLITE LOCATION DATA', which requires periodic updating.)"
  26. 260 PRINT
  27. 270 PRINT "3)  The notice displayed at program start-up is not to be bypassed altered"
  28. 280 PRINT "    or removed."
  29. 290 PRINT
  30. 300 PRINT "4)  This program may be used for comercial use provided that a fee of $20.00 is"
  31. 310 PRINT "    sent to the copyright owner.
  32. 320 PRINT
  33. 330 PRINT "Voluntary contributions of $10 for the use of this program will help to update"
  34. 340 PRINT "the program and satellite location data."
  35. 350 PRINT
  36. 360 PRINT "Contributions should be sent to:  Thomas R. Thornton"
  37. 370 PRINT "                                  7228 Dieppe Way"
  38. 380 PRINT "                                  Sacramento, Calif. 95842-1702
  39. 390 PRINT
  40. 400 J=66.5     ' INITIAL SATELLITE POSITION MINUS .5 DEGREES
  41. 410 DEF FNACS(X)=-ATN(X/SQR(-X*X+1))+1.570796   'ARC COSINE FUNCTION DEFINITION
  42. 420 DEF FNRAD(X)=X/360*6.283185307#     ' DEGREES TO RADIANS CONVERSION
  43. 430 DEF FNDEG(X)=X/6.283185307#*360     ' RADIANS TO DEGREES CONVERSION
  44. 440 A$=INPUT$(1)
  45. 450 PRINT PCLS$
  46. 460 PRINT: PRINT: PRINT
  47. 470 PRINT TAB(28);"GEO-SYNCHRONUS SATELLITE"
  48. 480 PRINT TAB(27);"LOCATOR FOR EARTH STATIONS"
  49. 490 PRINT TAB(30);"NORTH OF THE EQUATOR"
  50. 500 PRINT TAB(22);"EAST OF THE  INTERNATIONAL DATE LINE"
  51. 510 PRINT: PRINT: PRINT
  52. 520 LINE INPUT "Location of earth station: ",ESNM$
  53. 530 PRINT
  54. 540 INPUT "Earth station latitude (DEGREES): ",LATDEG$
  55. 550 INPUT "                       (MINUTES): ",LATMIN$
  56. 560 INPUT "                       (SECONDS): ",LATSEC$
  57. 570 PRINT: PRINT
  58. 580 DLAT=VAL(LATDEG$)+(VAL(LATMIN$)/60)+(VAL(LATSEC$)/3600)  'LAT DMS -> DECIMAL
  59. 590 RLAT=FNRAD(DLAT)
  60. 600 INPUT "Earth station longitude (DEGREES): ",LONDEG$
  61. 610 INPUT "                        (MINUTES): ",LONMIN$
  62. 620 INPUT "                        (SECONDS): ",LONSEC$
  63. 630 DLON=VAL(LONDEG$)+(VAL(LONMIN$)/60)+(VAL(LONSEC$)/3600)  'LON DMS -> DECIMAL
  64. 640 RLON=FNRAD(DLON)
  65. 650 FOR PAGE=1 TO 2
  66. 660 LPRINT FF$;STRING$(80,"*")
  67. 670 LPRINT TAB(29);"GEO-SYNCHRONOUS SATELLITE"
  68. 680 LPRINT TAB(36);"LOCATOR"
  69. 690 TB=(80-19-LEN(ESNM$))/2
  70. 700 LPRINT TAB(TB);"TERMINAL LOCATION: ";ESNM$
  71. 710 TB=(80-40-LEN(LATDEG$)-LEN(LONDEG$))/2
  72. 720 LPRINT TAB(TB);"LAT = ";LATDEG$;" . ";LATMIN$;" . ";LATSEC$;
  73. 730 LPRINT TAB(TB+26);"LON = ";LONDEG$;" . ";LONMIN$;" . ";LONSEC$
  74. 740 LPRINT
  75. 750 LPRINT STRING$(80,"*")
  76. 760 LPRINT "SATELLITE     C/K  LON    AZIM   ELEV  I SATELLITE     C/K  LON    AZIM   ELEV"
  77. 770 LPRINT STRING$(39,"=");"I";STRING$(39,"=")
  78. 780 FOR I=J+.5 TO J+24 STEP .5
  79. 790 J=I+24
  80. 800 SATLOC=I
  81. 810 GOSUB 1020    ' GO GET SATELLITE NAME IF APLICABLE
  82. 820 GOSUB 930    ' GO COMPUTE LEFT COLUMN AZIMUTH & ELEVATION
  83. 830 LPRINT USING "\           \ \ \####.# ####.## ###.##";SATNM$;CK$;SATLOC;AZIM;ELEV;
  84. 840 LPRINT " I ";
  85. 850 SATLOC=J
  86. 860 GOSUB 1020    ' GO GET SATELLITE NAME IF APLICABLE
  87. 870 GOSUB 930    ' GO COMPUTE RIGHT COLUMN AZIMUTH & ELEVATION
  88. 880 LPRINT USING "\           \ \ \####.# ####.## ###.##";SATNM$;CK$;SATLOC;AZIM;ELEV
  89. 890 NEXT I
  90. 900 NEXT PAGE
  91. 910 END
  92. 920 ' * * *  AZIMUTH AND ELEVATION COMPUTATIONS  * * *
  93. 930 RSATLOC=FNRAD(SATLOC)
  94. 940 C=FNACS(COS(-RLON--RSATLOC)*COS(RLAT))
  95. 950 RAZIM=3.141592654#+ATN(TAN(-RLON--RSATLOC)/SIN(RLAT))
  96. 960 S=SQR(3957^2+(3957+22245)^2-2*3957*(3957+22245)*COS(C))
  97. 970 RELEV=FNACS((S^2+3957^2-(3957+22245)^2)/(2*3957*S))-1.570796
  98. 980 AZIM=FNDEG(RAZIM)
  99. 990 ELEV=FNDEG(RELEV)
  100. 1000 RETURN
  101. 1010 ' * * *  FIND A SATELLITE NAME IF IT EXISTS  * * *
  102. 1020 READ STLC,SAT$,CK1$
  103. 1030 IF STLC=0 THEN SATNM$="": CK$="": RESTORE: RETURN
  104. 1040 IF STLC=SATLOC THEN SATNM$=SAT$: CK$=CK1$: RESTORE: RETURN
  105. 1050 GOTO 1020
  106. 1060 ' * * *  SATELLITE LOCATION DATA  * * *
  107. 1070 ' UPDATE DATA MAY BE ADDED IN ANY ORDER. HOWEVER,
  108. 1080 ' NUMERICAL ORDER BY LONGITUDE IS EASER TO READ.
  109. 1090 ' LAST UPDATED SEPT. 22, 1985. NOT ALL KU BAND
  110. 1100 ' BIRDS LISTED.
  111. 1110 DATA 67,SATCOM F6,C
  112. 1120 DATA 69,SPACENET 2,C/K
  113. 1130 DATA 70,SBTS-1,C
  114. 1140 DATA 72,SATCOM 2R,C
  115. 1150 DATA 74,GALAXY 2,C
  116. 1160 DATA 75,RAINBOW 3,K
  117. 1170 DATA 76,COMSTAR D3&4,C
  118. 1180 DATA 77,SATCOM K3,K
  119. 1190 DATA 79,WESTAR 2,C
  120. 1200 DATA 83,SATCOM 4,C
  121. 1210 DATA 87.5,TELSTAR 302,C
  122. 1220 DATA 91,WESTAR 3,C
  123. 1230 DATA 93.5,GALAXY 3,C
  124. 1240 DATA 95,SBS-3,K
  125. 1250 DATA 96,TELSTAR 301,C
  126. 1260 DATA 97,SBS-2,K
  127. 1270 DATA 99,WESTAR 4,C
  128. 1280 DATA 100,SBS-1,K
  129. 1290 DATA 103,G-STAR-1,K
  130. 1300 DATA 104.5,ANIK D1,C
  131. 1310 DATA 105,ANIK C2,K
  132. 1320 DATA 109,ANIK B,C/K
  133. 1330 DATA 110,ANIK D2,C
  134. 1340 DATA 113.5,MORELOS 1,C
  135. 1350 DATA 120,SPACENET 1,C
  136. 1360 DATA 123,WESTAR 5,C
  137. 1370 DATA 125,TELSTAR 303,C
  138. 1380 DATA 131,SATCOM F3R,C
  139. 1390 DATA 134,GALAXY 1,C
  140. 1400 DATA 139,SATCOM F1R,C
  141. 1410 DATA 143,SATCOM F5,C
  142. 1420 DATA 0,0,0
  143.