home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
HAM Radio 1
/
HamRadio.cdr
/
packet
/
g0bsx
/
dos.bat
< prev
next >
Wrap
DOS Batch File
|
1989-10-26
|
3KB
|
89 lines
echo off
rem
rem The default directory where all the servers sit is the \MB directory so
rem go there.
rem
cd \MB
rem
rem before we can use thje MAIL or BULLETIN files for mail distribution, we
rem have to "doctor" them since SMTP does not like any text line longer than
rem 128 characters, so we word wrap all lines to 80 characters maximum with
rem the program ROUND.COM
rem
if exist mail.txt goto domail
goto nomail
:domail
round mail.txt mail.tmp
del mail.txt
rem
smtpi mail.tmp smtpmail.lst g0bsx.ampr GB7PLY
rem
rem The parameters for the smtpi.com file are as follows:
rem 1. the filename of the file into which the mailbox ahs exported all the
rem mail to be distributed. Note I use a temp file created by ROUND.COM
rem 2. the filename of the list of host, callsign and selection specs desired
rem for the distribution of MAIL.
rem 3. the host id of the TCP/IP system that interfaces to the mailbox.
rem 4. the CALLSIGN of the mailbox.
rem
rem ONLY do the bulletin export in the early hours and then ONLY once per
rem hour.
rem
:nomail
rem timer -ih 0106
rem if errorlevel 1 goto timeok
rem goto import
:timeok
if exist bulls.txt goto dobulls
goto nobulls
:dobulls
round bulls.txt bulls.tmp
del bulls.txt
rem
smtpi bulls.tmp smtpbull.lst g0bsx.ampr GB7PLY
rem
rem The arguments for the program smtpi.com are as follows:
rem 1. The filename of the file use my the mailbox to put the exported
rem INTO.
rem 2. The filename of the list of calls and hosts and selection parameters
rem pertaining to BULLETINS.
rem 3. the hostid of the SMTP TCPIP system that the mailbox is interfaced to.
rem 4. the CALLSIGN of the mailbox.
rem
rem
:nobulls
:import
smtpx import.txt GB7PLY
rem
rem The parameters of the SMTPX.COM program are the filename of the text file
rem into which will be placed mailbox message for import INTO the mailbox and
rem the Mailbox callsign.
rem
rem Since SMTP don't like long lines, ROUND this output file as well just
rem to be on the safe side!
if exist import.txt goto roundit
goto dodatime
:roundit
round import.txt import.tmp
copy import.tmp import.txt
rem
rem I always leave the .TMP files in case something fails so that I can have
rem a look at them and perhaps re-cycle them if needs be.
rem
:dodatime
rem do datime and update BPQ nodes list every 3 hours.
rem
timer -th 3
if errorlevel = 1 goto datime
goto end
:datime
datime
cd \bpq
bpqnodes
rem
:end
cd \bbs
rem
rem you MUST change back to the BBS directory for SERVER to work another time!
rem
rem *** The END *** ((phew!))