home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Shareware Gold 1
/
The_Golden_ROM_Series_-_Shareware_Gold_Volume_1_Number_11_-_SK_89-301_-_1989.iso
/
BBS
/
LIB022.ARC
/
UPPCB1.SCR
< prev
next >
Wrap
Text File
|
1988-01-01
|
5KB
|
284 lines
; JTL 09-17-87 23:45
; Forbin 01-09-88 13:40
GetScr
ClrScr
ColorFG 15
Box 6 1 75 13
ColorFG 14
Note
Display ' ****-'
ColorFG 13
ColorBG 1
Display 'Multiple'
ColorFG 14
ColorBG 0
Display '-File Upload/Logoff PCBoard V11/12.x Qmodem3.1-****'
ColorFG 15
Note
Note Instructions:
ColorFG 6
Note Enter a filename to be uploaded after each prompt.
Note Maximum of TEN (10) filenames can be entered.
Note A blank <CR> entry starts the transfers.
ColorFG 7
Note Invalid or Existing Filenames will be Automatically bypassed.
Note
String login transfer logend dirpath correct cnt file cownt count cwnt kount
String desc
getlog:
ColorFG 6
Display " Select Auto-Logoff after File Transfers [Y]es or [N]o ? > "
ColorFG 15
Inkey login
DisplayLN '$login'
If '$login' = 'N' nlog
If '$login' = 'Y' ylog
Goto getlog
nlog:
Assign logend "done"
Goto home
ylog:
Assign logend "logoff"
home:
ColorFG 6
Display ' Select Upload Protocol [X,C,I,Y,G,Z <Q>=Quit] > '
ColorFG 15
Inkey 9
DisplayLN '$9'
If '$9' = 'X' selpath
If '$9' = 'C' selpath
If '$9' = 'I' selpath
If '$9' = 'Y' selpath
If '$9' = 'G' selpath
If '$9' = 'Z' selpath
If '$9' = 'Q' done
Goto home
selpath:
ColorFG 3
Note Enter Upload Drive:\Path DO NOT use a "\" to end the Path.
ColorFG 6
Display ' Drive:\Path > '
ColorFG 15
Get dirpath 45
If '$dirpath' = '' selpath
Chdir $dirpath\
If $SUCCESS valid
Chdir $dirpath
If $SUCCESS valid
ColorFG 12
DisplayLN " Path is Invalid, Re-enter."
ColorFG 6
Goto selpath
valid:
ColorFG 2
Display " Path is Valid."
ColorFG 6
Display ' Is Path Correct [Y]es or [N]o ? <CR>=Yes] > '
ColorFG 15
Inkey correct
DisplayLN '$correct'
If '$correct' = 'Y' getone
If '$correct' = 'N' selpath
getone:
ColorFG 2
Assign cwnt 0 ;actual file counter
Assign cnt 1 ;visual file counter
ColorFG 2
Display ' File # $cnt > '
ColorFG 3
Get file 12
If '$file' = '' $logend
Goto okfile
nextone:
ColorFG 2
Display ' File # $cnt > '
ColorFG 3
Get file 12
okfile:
Exist $dirpath\$file desc1
ColorFG 4
If '$file' = '' go
Note File Not Found, enter another name or <CR> to Abort.
Goto nextone
desc1:
ColorFG 4
Display 'Desc. 45 Char Max. > '
ColorFG 5
Get desc 45
If '$desc' = '' desc1
push '$file'
push '$desc'
Incr cnt
Incr cwnt
If '$cnt' = '11' go
Goto nextone
go:
ColorFG 7
GotoXY 1 13
Note
Display ' Online with: '
ColorBG 2
ColorFG 15
Display ' $board '
ColorBG 0
ColorFG 7
Display ' '
ColorBG 4
ColorFG 15
Display '[$9]'
ColorBG 0
ColorFG 7
DisplayLN ' Protocol '
ColorFG 10
Display ' $cwnt'
ColorFG 7
If '$cwnt' = '0' alldone
If '$cwnt' = '1' one
Display ' Files will be Uploaded in Reverse order from: '
Goto skip
one:
Display ' File will be Uploaded '
Goto cont
skip:
ColorBG 2
ColorFG 15
Display ' $cwnt to 1 '
ColorBG 0
ColorFG 7
cont:
ColorBG 0
DisplayLN ' '
Display ' '
ColorFG 0
ColorBG 6
Display "====================[ Online Text Area Below ]===================="
ColorBG 0
ColorFG 12
Box 1,14,80,$last_row ;window can be used instead
ClrScr
ColorFG 3
Timeout 60 $logend
Assign cownt $cnt
start:
Assign kount $cnt ;upload file counter in window
next:
Send "{"
ColorFG 3
Waitfor "Command?"
next1:
Pause 1000
Decr kount
When
Pop desc
Pop file
If '$file' = '' $logend
When "board file" next1
When "Not Accepted" start
Send "u $file $9{"
Waitfor "description"
Pause 1000
Send "$desc{"
Pause 5500
ColorFG 6
Note Wait Several Seconds for Upload to Begin
ColorFG 3
Pause 500
GotoXY 1 40
DisplayLN ' '
Display ' '
ColorBG 2
ColorFG 15
Display 'File # $kount'
ColorBG 0
ColorFG 3
DisplayLN ' '
If $offline discon ;use semicolon in front for offline testing
Upld $dirpath\$file $9
If $offline discon ;use semicolon in front for offline testing
Pause 5000 ;for zmodem only so 00 is not accepted
Decr cownt
When
If '$9' = 'z' tones
Goto next
tones:
Beep 800
Beep 600
Beep 400
Goto next
discon:
ColorFG 10
PutScr
GotoXY 25 12
DisplayLN 'Line Disconnect has Occurred......'
Exit
done:
Send "{"
ColorFG 10
PutScr
Exit
logoff:
PutScr
ClrScr
When
When "Command?" logout
Send "{"
Waitfor "Command?"
logout:
Pause 4500
ClrScr
ColorFG 6
Note
Note Auto Logoff was Previously Selected.
ColorFG 15
Note
Note PRESS [Esc] then [Y] to Abort the Logoff.
ColorFG 10
Assign 0 $wherex
Assign 1 $wherey
Assign cnt 9
tmout:
GotoXY $0 $1
Display ' $cnt Seconds to Auto Logoff.
Pause 200
If '$cnt' = '2' bye
Decr cnt
Goto tmout
bye:
Gotoxy $0 $1
Display ' 1 Second to Auto Logoff.
Pause 200
ColorFG 15
Note Auto-Logoff Completed.
ColorFG 10
Send "g{"
Pause 5000
Hangup
Exit
AllDone:
Exit