home *** CD-ROM | disk | FTP | other *** search
/ linuxmafia.com 2016 / linuxmafia.com.tar / linuxmafia.com / pub / linux / network / domain-check-3.7 < prev    next >
Text File  |  2008-08-27  |  19KB  |  515 lines
  1. #!/usr/bin/perl -ws
  2. # Created by Ben Okopnik on Thu Jun 28 09:11:52 EDT 2007
  3. #
  4. # Copyright (C) 2007 Ben Okopnik <ben@okopnik.com>
  5. # This program is free software; you can redistribute it and/or modify
  6. # it under the terms of the GNU General Public License as published by
  7. # the Free Software Foundation; either version 2 of the License, or
  8. # (at your option) any later version.
  9. #
  10. # This program is distributed in the hope that it will be useful,
  11. # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12. # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  13. # GNU General Public License for more details.
  14.  
  15. =pod
  16. ################################## Changelog ##############################
  17. 08/27/08 19:55 v3.7
  18. * Tweaked for the PairNIC date format. Thanks to Janek Hellqvist for the heads-up!
  19.  
  20. 07/27/08 22:33 v3.6
  21. * Added a .ca "special": 'Renewal date:'
  22.  
  23. 11/05/07 21:01 v3.5
  24. * Tweaked to resolve .cz ("expire:" along with "expires:")
  25.  
  26. 09/25/07 12:27 v3.4
  27. * Tweaked regexes to include the ".name" date syntax.
  28.  
  29. 08/15/07  1:06 v3.3
  30. * Added a bit more CLI error checking (trips off on '-d foo.com', etc.)
  31.  
  32. 08/14/07 23:03 v3.2
  33. * Polished the regexen based on Rick Moen's list of 270 TLDs
  34. * Wrapped the date-calc section in an eval for cases where the date is past
  35.     the Unix "death boundary" (18-Jan-2038)
  36.  
  37. 08/08/07 23:26 v3.1
  38. * Added another regex to parse the weird structure of 'extragalactic.net';
  39.     modified another regex slightly to accomodate 'expire date' for 'nic.it'.
  40.  
  41. 07/29/07  1:26 v3.0
  42. * MAJOR REVISION:
  43.     o The format of the 'domain-list' file has been changed, although the
  44.       old format is still valid. You can now add the name of the host for
  45.       'whois' to use as the second argument on the line; however, using the
  46.       '-s' command line argument will force all lookups to be done via the
  47.       specified host.
  48.     o Fixed up a number of regexen for the 'jwhois' differences
  49.  
  50. 07/28/07  0:41 - v2.2
  51. * Added 'jwhois' as the preferred option, with a warning if it's not
  52.     installed. Caching for 'jwhois' is disabled when '-X' is in effect;
  53.     '-H' is no longer a hard-wired argument to 'whois' ('jwhois' doesn't
  54.     support it), but is still appended if 'whois' is used.
  55. * Tweaked a couple of the regexen to process new TLDs (.fi, .ly, etc.)
  56. * Giving serious thought to modifying the format of the -F files; it would
  57.     be nice to be able to specify the whois server for individual domains.
  58.  
  59. 07/20/07  9:36 - v2.1
  60. * Added a bunch of tracing/debugging statements to the date parser, making
  61.     the '-X' option much more useful
  62. * Built a 'switch-case' structure around the parser so that only one regex
  63.     would apply to any given host
  64. * Added a '-H' argument to 'whois' ("elide legal disclaimer") to make
  65.     debugging output less annoying (and maybe speed things up fractionally)
  66. * Made the 'no expiration date found' error into a non-fatal warning (used
  67.     to break list processing)
  68. * Modified the output format slightly (warnings now appear on the same line
  69.     as the domain name)
  70. * Domains without a registrar will no longer be omitted from the mailed
  71.     notifications
  72.  
  73. 07/19/07 22:28 - v2.0
  74. * Now parsing .ci domains as well (millions of people cheer, world peace
  75.     can't be far away now...)
  76.  
  77. 07/19/07 20:54 - v1.9
  78. * Added a little regex-fu to accept lines that have whitespace at the end
  79. * Added a Big Sekrit Option ('-X' - shhh, don't tell anybody!) for debugging
  80.  
  81. 07/19/07 11:56 - v1.8
  82. * Lots and lots of fixes for many different TLDs; much mangling of regexen.
  83.     Now handles many more expiration date types than before. Most
  84.     importantly, domains that don't list a registrar will now be displayed
  85.     anyway; people probably know where to send their money, but not
  86.     necessarily _when._
  87.  
  88. 07/04/07 12:28 - v1.7
  89. * Scrapped previous approach to the .org delay; the .orgs are now sorted to
  90.     the end of the domain list and all except the first one wait 20 seconds.
  91. * Added a cute little time ticker to the delay routine, just because. :)
  92.  
  93. 07/03/07  1:27 - v1.6
  94. * Added a rate limiter (3/minute) for .org domains
  95.  
  96. 06/30/07 18:34 - v1.5
  97. * Added a "domain not parseable; please report" warning
  98. * Added an "Unable to read 'whois' info" warning for the 'fgets: connection
  99.     reset by peer' error.
  100. * All expiration warnings are now sent as one email instead of one per
  101.     domain; ditto the expired domains notifications.
  102. * The 'printf' for the 'SKIPPED' error was ignoring the '-q' option; fixed
  103.  
  104. 06/30/07  8:19 - v1.4
  105. * Removed dependency on File::Find; searching PATH 'manually'
  106. * Added an 'exit 1' to the silent failure mode of 'croak'
  107.  
  108. 06/30/07  7:06 - v1.3
  109. * Improved the date-parsing regexes (the numerical months part can now only
  110.     match '01-12' instead of 'any two digits'); this should increase the
  111.     reliability of resolving 'dd-mm-yyyy' vs. 'mm-dd-yyyy' somewhat.
  112. * More accurate reporting for the 'SKIPPED' error (now shows exact reason)
  113. * Fixed the regexes that I screwed up while adding the Dotster extension
  114. * Added a '-v' option
  115.  
  116. 06/29/07 18:54 - v1.2
  117. * Got rid of an unnecessary system dependency ('which') - 'File::Find' is a
  118.     bit clunky, but better than depending on unknowns...
  119. * Another date-processing regex (ISOC-IL: 'validity: 29-06-2007')
  120.  
  121. 06/29/07 17:07 - v1.1
  122. * Modified output format to include both exp. date and days remaining
  123. * Added another date-processing regex (DOTSTER: 'Expires on: 29-Jun-07')
  124.  
  125. 06/29/07 15:06 - v1.0
  126. I'm finally willing to admit that this script is usable. :) Recent changes
  127. include:
  128.  
  129. * Parsing routine for "2007/08/12" date format
  130. * 'croak' notifies admin of problems encountered in silent mode
  131. * Added a fallback email address for 'croak'
  132. * Fixed GMT parsing routine miscalc (thanks to Rick Moen for the heads up)
  133.  
  134. For Nosy Nellies only: *Yes*, I'm aware of the various '*Whois.pm' modules
  135. on CPAN. None of them do what I want; the one that comes closest
  136. (Net::XWhois) hasn't been maintained since 2001 and only covers a smallish
  137. subset of what I want. No, I'm not interested in taking it over and
  138. maintaining it; I've got enough to do as it is.
  139.  
  140. ###########################################################################
  141. =cut
  142.  
  143. use strict;
  144. use Time::Local;
  145. $|++;
  146.  
  147. # Command-line variables
  148. our ($d, $e, $F, $h, $q, $s, $v, $x, $X);
  149.  
  150. ### FALLBACK ADDRESS FOR NOTIFICATION ############
  151. my $address = 'root@localhost';
  152. ##################################################
  153.  
  154. my ($name) = $0 =~ /([^\/]+)$/;
  155.  
  156. my $usage =<<"+EoT+";
  157. Usage: $name [-e=email] [-x=expir_days] [-q] [-h] <-d=domain_name|-F=domainfile>
  158.  
  159.   -d=domain        : Domain to analyze
  160.   -e=email_address : Send a warning message by email
  161.   -F=domain_list   : File with a list of domains, one per line
  162.   -h               : Print this message
  163.   -q               : Don't print to the console (REQUIRES '-e' OPTION)
  164.   -s=whois server  : Use alternate whois server
  165.   -v               : Display current version of this script
  166.   -x=days          : Change default (30d) expiration interval (REQUIRES '-e' OPTION)
  167.  
  168. +EoT+
  169.  
  170. # Locate 'whois' or (preferred) 'jwhois'
  171. my ($whois) = grep -e, map "$_/jwhois", split /:/, $ENV{PATH};
  172. ($whois) = grep -e, map "$_/whois", split /:/, $ENV{PATH} unless $whois;
  173. die "'whois'|'jwhois' not found in path.\n" unless $whois;
  174. if ($whois =~ m#/whois$#){
  175.     # $q || print "You really should install 'jwhois'; it gives better results.\n";
  176.     # Turn down the noise (minimal output option - only works with 'whois')
  177.     $whois .= " -H";
  178. }
  179. else {
  180.     # Turn off caching for 'jwhois' if the debug option is on
  181.     $whois .= " -f" if $X;
  182. }
  183.  
  184. # $whois = "/usr/bin/whois";
  185.  
  186. # Find a mail client (mutt or mailx)
  187. my ($mail) = grep -e, map "$_/mutt", split /:/, $ENV{PATH};
  188. # Switch Mutt into 'mailx' mode if found
  189. if ($mail){
  190.     $mail .= " -x";
  191. }
  192. else {
  193.     ($mail) = grep -e, map "$_/mailx", split /:/, $ENV{PATH};
  194. }
  195. die "No 'mailx' or 'mutt' (mail client) found in path.\n" unless $mail;
  196.  
  197. # Read the version number at the top of the changelog
  198. if ($v){
  199.     seek DATA, 0, 0;
  200.     while (<DATA>){
  201.         if (m[^\d+/\d+/\d+[^v]+v([0-9.]+)]){
  202.             print "Version: $1\nCopyright (C) 2007 Ben Okopnik <ben\@okopnik.com>\n\n";
  203.             exit 0;
  204.         }
  205.     }
  206. }
  207.  
  208. # Email admin if '-q' is on; otherwise, just exit with the error
  209. sub croak {
  210.     if ($q){
  211.         # If '-e' wasn't specified, use the fallback address
  212.         $e ||= $address;
  213.  
  214.         # No place to send an error if this fails... :)
  215.         open Mail, "|$mail -s 'WARNING: $name script error' $e";
  216.         print Mail "$name [" . localtime() . "]: ", $_[0];
  217.         close Mail;
  218.  
  219.         exit 1;
  220.     }
  221.     else {
  222.         die $_[0];
  223.     }
  224. }
  225.  
  226. # Display the help output if requested or in case of incorrect usage
  227. die "$usage\n" if $h;
  228. die "\n*ERROR: '$name' requires an email address with the '-q' and the '-x' options*\n\n$usage" if ($q || $x) && ! $e;
  229. die "\n*ERROR: '$name' requires either a domain name or a domain list as an argument*\n\n$usage" if ! $d && ! $F;
  230. die "\n*ERROR: Please make sure you're using correct syntax (i.e., '-d=domain_name')*\n\n$usage" if (defined $d && $d =~ /^1$/) || (defined $F && $F =~ /^1$/) || (defined $s && $s =~ /^1$/);
  231.  
  232. # Set default notification interval to 30 days
  233. if ($x){
  234.     croak "Expiration interval must be specified in days (0-9999).\n"
  235.         unless $x =~ /^\d{1,4}$/;
  236. }
  237. else {
  238.     $x = 30;
  239. }
  240.  
  241. # Read the domain list file
  242. my @domains;
  243. if ($F){
  244.     croak "$F is not a regular file\n" unless -f $F;
  245.     croak "Can't read $F\n" unless -r _;
  246.     # Open the file if it exists
  247.     open F or croak "$F: $!\n";
  248.     while (<F>){
  249.         # Skip blank lines; ignore comments
  250.         next if /^\s*(?:#|$)/;
  251.         # Strip preceding and following blanks
  252.         s/^\s*(.*?)\s*$/$1/;
  253.  
  254.         # Separate domain and server if they exist
  255.         my (@line) = split;
  256.         for (@line){
  257.             # Strip URI method and any terminal '/'s
  258.             s#^.*://##;
  259.             s#/$##;
  260.         }
  261.         push @domains, [ @line ];
  262.     }
  263.     close F;
  264. }
  265.  
  266. # Having a '-F' AND a '-d' is explicitly not excluded
  267. if ($d){
  268.     # Strip URI method and any terminal '/'s
  269.     $d =~ s#^.*://##;
  270.     $d =~ s#/$##;
  271.     push @domains, [ $d ];
  272. }
  273.  
  274. # Set the server if it's been specified (this REPLACES any servers defined
  275. # in the domain-list file)
  276. if ($s){
  277.     $_ -> [1] = $s for @domains;
  278. }
  279.  
  280. # Sort list to push .orgs to the end; ASCIIbetical sort otherwise
  281. @domains = sort { ($a->[0] =~ /\.org$/i) <=> ($b->[0] =~ /\.org$/i) || $a->[0] cmp $b->[0] } @domains;
  282.  
  283. # Trim strings to specified length; return '**UNKNOWN**' if undef
  284. sub trim {
  285.     defined $_[0] || return "**UNKNOWN**";
  286.     substr($_[0], 0, $_[1]);
  287. }
  288.  
  289. # Lookup list for month number->name conversion
  290. my (%mth,%mlookup);
  291. @mth{map sprintf("%02d", $_), 1..12} = qw/jan feb mar apr may jun jul aug sep oct nov dec/;
  292. # Lookup list for month name->abbrev conversion
  293. @mlookup{qw/january february march april may june july august september october november december/} =
  294.     (qw/jan feb mar apr may jun jul aug sep oct nov dec/) x 2;
  295.  
  296. ########################## DATA COLLECTION SECTION #############################
  297.  
  298. # Process the domain list
  299. my ($seen, %list);
  300. for my $line (@domains){
  301.     my ($host, $server) = @{$line};
  302.  
  303.     my $opt = $server ? "-h $server" : "";
  304.  
  305.     $q || print "\b\nProcessing $host... ";
  306.  
  307.     # Delay to avoid triggering rate limiter
  308.     if ($host =~ /\.org$/i){
  309.         $q || print "(NOTE: Subsequent ORG queries will be delayed by 20 seconds each due to rate limiting) "
  310.             unless $seen;
  311.         # Show the cute little time ticker :)
  312.         if ($seen++){
  313.             my @chars = split //, '|/-\\';
  314.             for (0 .. 19){
  315.                 $q || print $chars[$_ % 4], "\b";
  316.                 sleep 1;
  317.             }
  318.             print " \b";
  319.         }
  320.     }
  321.  
  322.     # Execute the query
  323.     my $out;
  324.     open Who, "$whois $opt $host|" or croak "Error executing $whois: $!\n";
  325.     {
  326.         # Read in the entire output of 'whois' as a single string
  327.         local $/;
  328.         $out = <Who>;
  329.     }
  330.     close Who;
  331.  
  332.     # Make sure it's not DOS formatted
  333.     $out =~ tr/\cM//d;
  334.  
  335.     # 'fgets: connection reset by peer' - bloody annoying response!
  336.     if (!$out || $out !~ /domain/i){
  337.         $q || print "Unable to read 'whois' info for $host. Skipping... ";
  338.         next;
  339.     }
  340.  
  341.     # Freak out and run away if there's no match
  342.     if ($out =~ /no match/i){
  343.         $q || print "No match for $host!\n";
  344.         next;
  345.     }
  346.     # Ditto for bad hostnames
  347.     if ($out =~ /No whois server is known for this kind of object/i){
  348.         $q || print "'whois' doesn't recognize this kind of object. ";
  349.         next;
  350.     }
  351.  
  352.     # Convert multi-line 'labeled block' output to 'Label: value'
  353.     my $debug;
  354.     if ($out =~ /registrar:\n/i){
  355.         $out =~ s/:\n(?!\n)/: /gsm;
  356.         $debug .= "matched on line " . (__LINE__ - 1) . ": Multi-line 'labeled block'\n";
  357.     }
  358.  
  359.     # Date preprocessing. Desired date format is '29-jun-2007'
  360.     # 'Fri Jun 29 15:16:00 EDT 2007'
  361.     if ($out =~ s/(date:\s*| on:\s*)[A-Z][a-z]+\s+([a-zA-Z]{3})\s+(\d+).*?(\d+)\s*$/$1$3-$2-$4/igsm){
  362.         $debug .= "matched on line " . (__LINE__ - 1) . ": 'Fri Jun 29 15:16:00 EDT 2007'\n";
  363.     }
  364.     # '29-Jun-07'
  365.     elsif ($out =~ s/(date:\s*| on:\s*)(\d{2})[\/ -](...)[\/ -](\d{2})\s*$/$1$2-$3-20$4/igsm){
  366.         $debug .= "matched on line " . (__LINE__ - 1) . ": '29-Jun-07'\n";
  367.     }
  368.     # '2007-Jun-29'
  369.     elsif ($out =~ s/[^\n]*(?:date| on|expires on\.+):\s*(\d{4})[\/-](...)[\/-](\d{2})\.?\s*$/Expiration date: $3-$2-$1/igsm){
  370.         $debug .= "matched on line " . (__LINE__ - 1) . ": '2007-Jun-29'\n";
  371.     }
  372.     # '2007/06/29'
  373.     elsif ($out =~ s/(?:renewal-|expir(?:e|es|y|ation)\s*)(?:date|on)?[ \t.:]*\s*(\d{4})(?:[\/-]|\. )(0[1-9]|1[0-2])(?:[\/-]|\. )(\d{2})(?:\.?\s*[0-9:.]*\s*\w*\s*|\s+\([-A-Z]+\)?)$/Expiration date: $3-$mth{$2}-$1/igsm){
  374.         $debug .= "matched on line " . (__LINE__ - 1) . ": '2007/06/29'\n";
  375.     }
  376.     # '29-06-2007'
  377.     elsif ($out =~ s/(?:validity:|expir(?:y|ation) date:|expire:|expires? (?:on:?|on \([dmy\/]+\):|at:))\s*(\d{2})[\/.-](0[1-9]|1[0-2])[\/.-](\d{4})\s*[0-9:.]*\s*\w*\s*$/Expiration date: $1-$mth{$2}-$3/igsm){
  378.         $debug .= "matched on line " . (__LINE__ - 1) . ": '29-06-2007'\n";
  379.     }
  380.     # '[Expires on]     2007-06-29' (.jp, .ru, .ca)
  381.     elsif ($out =~ s/(?:valid-date|(?:renewal|expiration) date:|paid-till:|\[expires on\]|expires on ?:|expired:)\s*(\d{4})[\/.-](0[1-9]|1[0-2])[\/.-](\d{2})(?:\s*[0-9:.]*\s*\w*\s*|T[0-9:]+Z)$/Expiration date: $3-$mth{$2}-$1/igsm){
  382.         $debug .= "matched on line " . (__LINE__ - 1) . ": '[Expires on]     2007-06-29' (.jp, .ru)\n";
  383.     }
  384.     # 'expires:     June  29[, ]+2007' (.is, PairNIC)
  385.     elsif ($out =~ s/expires:\s*([A-Z][a-z]+)\s+(\d{1,2})(?:\s|,)+(\d{4})\s*$/"Expiration date: " . sprintf("%02d", $2) . "-" . $mlookup{"\L$1\E"} . "-$3"/igsme){
  386.         $debug .= "matched on line " . (__LINE__ - 1) . ": 'expires:     June  29 2007' (.is)\n";
  387.     }
  388.     # 'renewal: 29-June-2007'
  389.     elsif ($out =~ s/renewal:\s*(\d{1,2})[\/ -]([A-Z][a-z]+)[\/ -](\d{4})\s*$/"Expiration date: $1-" . $mlookup{"\L$2\E"} . "-$3"/igsme){
  390.         $debug .= "matched on line " . (__LINE__ - 1) . ": 'renewal: 29-June-2007' (.ie)\n";
  391.     }
  392.     # 'expire:         20080315' (.cz, .ke)
  393.     elsif ($out =~ s/expir[ey]:\s*(\d{4})(\d{2})(\d{2})\s*$/Expiration date: $3-$mth{$2}-$1/igsm){
  394.         $debug .= "matched on line " . (__LINE__ - 1) . ": 'expire:         20080315' (.cz, .ke)\n";
  395.     }
  396.     # 'domain_datebilleduntil: 2007-06-29T00:00:00+12:00' (.nz)
  397.     elsif ($out =~ s/domain_datebilleduntil:\s*(\d{4})[-\/](\d{2})[-\/](\d{2})T[0-9:.+-]+\s*$/Expiration date: $3-$mth{$2}-$1/igsm){
  398.         $debug .= "matched on line " . (__LINE__ - 1) . ": 'domain_datebilleduntil: 2007-06-29T00:00:00+12:00' (.nz)\n";
  399.     }
  400.     # '29 Jun 2007 11:58:42 UTC' (.coop)
  401.     elsif ($out =~ s/(?:expir(?:ation|y) date|expire[sd](?: on)?)[:\] ]\s*(\d{2})[\/ -](...)[\/ -](\d{4})\s*[0-9:.]*\s*\w*\s*$/Expiration date: $1-\L$2\E-$3/igsm){
  402.         $debug .= "matched on line " . (__LINE__ - 1) . ": '29 Jun 2007 11:58:42 UTC' (.coop)\n";
  403.     }
  404.     # 'Record expires on 17/8/2100' (.hm, fi)
  405.     elsif ($out =~ s/(?:expires(?: on|:))\s*(\d{2})[\/.-]([1-9]|0[1-9]|1[0-2])[\/.-](\d{4})\s*[0-9:.]*\s*\w*\s*$/"Expiration date: $1-".$mth{sprintf "%02d", $2} . "-$3"/iegsm){
  406.         $debug .= "matched on line " . (__LINE__ - 1) . ": 'Record expires on 17/8/2100' (.hm)\n";
  407.     }
  408.     # 'Expires on..............: Sat, Mar 29, 2008'
  409.     elsif ($out =~ s/expires on\.*:\s*(?:[SMTWF][uoehra][neduit]),\s+([A-Z][a-z]+)\s+(\d{1,2}),\s+(\d{4})\s*$/"Expiration date: " . sprintf("%02d", $2) . "-\L$1-$3"/iegsm){
  410.         $debug .= "matched on line " . (__LINE__ - 1) . ": 'Expires on..............: Sat, Mar 29, 2008'\n";
  411.     }
  412.     else {
  413.         $debug = "No regexes matched.\n";
  414.     }
  415.  
  416.     # Collect the data from each query
  417.     for (split /\n/, $out){
  418.         # Clip pre- and post- blanks
  419.         s/^\s*(.*?)\s*$/$1/;
  420.         # Squash repeated tabs and spaces
  421.         tr/ \t//s;
  422.  
  423.         # This is where it all happens - regexes to capture registrar and expiration
  424.         $list{$host}{Registrar} ||= $1 if /(?:maintained by|registration [^:]*by|authorized agency|registrar)(?:\s*|_)(?:name|id|of record)?:\s*(.*)$/i;
  425.         $list{$host}{Expires} ||= $1 if /(?:expires(?: on)?|expir(?:e|y|ation) date\s*|renewal(?:[- ]date)?)[:\] ]\s*(\d{2}-[a-z]{3}-\d{4})/i;
  426.         # print "Registrar: $list{$host}{Registrar}\nExpires: $list{$host}{Expires}\n";
  427.     }
  428.  
  429.     # Assign default message if no registrar was found
  430.     $list{$host}{Registrar} ||= "[[[ No registrar found ]]]";
  431.     
  432.     $q || print "No expiration date found in 'whois' output. Please report this domain to the author!"
  433.         unless defined $list{$host}{Expires};
  434.  
  435.     # Debug option (activated by '-X'); exits here with parsed 'whois' output
  436.     $debug .= "Registrar: $list{$host}{Registrar}\n" if defined $list{$host}{Registrar};
  437.     $debug .= "Expires: $list{$host}{Expires}\n" if defined $list{$host}{Expires};
  438.     die "\n", "=" x 70, "\n$out", "=" x 70, "\n$debug", "=" x 70, "\n" if $X;
  439. }
  440.  
  441. $q || print "\n";
  442.  
  443. ########################## DATA ANALYSIS SECTION #############################
  444.  
  445. # Get current time snapshot in UTC
  446. my $now = timegm(gmtime);
  447.  
  448. # Convert dates to UTC epoch seconds; *will* fail on 19 Jan 2038. :)
  449. my %months;
  450. @months{qw/jan feb mar apr may jun jul aug sep oct nov dec/} = 0..11;
  451.  
  452. # Print the header if '$q' is off and there's content in %list
  453. $q || %list && printf "\n\n%-24s%-36s%s\n%s\n", "Host", "Registrar", "Exp.date/Days left", "=" x 78;
  454.  
  455. # Process the collected data
  456. my (%exp, %end);
  457. for my $k (sort keys %list){
  458.     unless (defined $list{$k}{Expires}){
  459.         $q || printf "%-32s%s\n", trim($k, 31), "*** SKIPPED (missing exp. date) ***";
  460.         delete $list{$k};
  461.         next;
  462.     }
  463.     my @chunks = split /-/, $list{$k}{Expires};
  464.     my $epoch;
  465.     eval { $epoch = timegm(0, 0, 0, $chunks[0], $months{lc $chunks[1]}, $chunks[2] - 1900) };
  466.     if ($@ =~ /too big/){
  467.         $q || print "**** NOTE: Date past 19-Jan-2038 - date will NOT be calculated correctly! ****\n";
  468.         # Set date to EPOCH_MAX
  469.         $epoch = 2147212800;
  470.     }
  471.     elsif ($@){
  472.         $q || print "$@\n";
  473.         # Set date to EPOCH_MAX
  474.         $epoch = 2147212800;
  475.     }
  476.     my $diff = int(($epoch - $now) / 86400);
  477.     $q || printf "%-24s%-36s%-12s/%5s\n", trim($k, 23), trim($list{$k}{Registrar}, 35),
  478.         $list{$k}{Expires}, $diff;
  479.  
  480.     # Prepare alerts if domain is expired or the expiration date is <= $x days
  481.     if ($e && ($diff <= $x)){
  482.         if ($diff <= 0){
  483.             $exp{$k} = -$diff;
  484.         }
  485.         else {
  486.             $end{$k} = $diff;
  487.         }
  488.     }
  489. }
  490.  
  491. # Report expired domains
  492. if (%exp){
  493.     open Mail, "|$mail -s '$name: Expired domains' $e" or croak "$mail: $!\n";
  494.     print Mail "According to 'whois', the following domains have expired:\n\n";
  495.     for my $x (sort { $exp{$a} <=> $exp{$b} } keys %exp){
  496.         my $s = $exp{$x} == 1 ? "" : "s";
  497.         print Mail "$x ($exp{$x} day$s ago)\n";
  498.     }
  499.     close Mail;
  500. }
  501.  
  502. # Report domains that will expire within the '-x' period
  503. if (%end){
  504.     open Mail, "|$mail -s '$name: Domain expiration warning ($x day cutoff)' $e" or croak "$mail: $!\n";
  505.     print Mail "According to 'whois', these domains will expire soon:\n\n";
  506.     for my $d (sort { $end{$a} <=> $end{$b} } keys %end){
  507.         my $s = $end{$d} == 1 ? "" : "s";
  508.         print Mail "$d (in $end{$d} day$s)\n";
  509.     }
  510.     close Mail;
  511. }
  512.  
  513. __END__
  514.  
  515.