home *** CD-ROM | disk | FTP | other *** search
/ linuxmafia.com 2016 / linuxmafia.com.tar / linuxmafia.com / pub / linux / network / domain-check-3.6 < prev    next >
Text File  |  2008-07-27  |  19KB  |  512 lines
  1. #!/usr/bin/perl -ws
  2. # Created by Ben Okopnik on Thu Jun 28 09:11:52 EDT 2007
  3. #
  4. # Copyright (C) 2007 Ben Okopnik <ben@okopnik.com>
  5. # This program is free software; you can redistribute it and/or modify
  6. # it under the terms of the GNU General Public License as published by
  7. # the Free Software Foundation; either version 2 of the License, or
  8. # (at your option) any later version.
  9. #
  10. # This program is distributed in the hope that it will be useful,
  11. # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12. # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  13. # GNU General Public License for more details.
  14.  
  15. =pod
  16. ################################## Changelog ##############################
  17. 07/27/08 22:33 v3.6
  18. * Added a .ca "special": 'Renewal date:'
  19.  
  20. 11/05/07 21:01 v3.5
  21. * Tweaked to resolve .cz ("expire:" along with "expires:")
  22.  
  23. 09/25/07 12:27 v3.4
  24. * Tweaked regexes to include the ".name" date syntax.
  25.  
  26. 08/15/07  1:06 v3.3
  27. * Added a bit more CLI error checking (trips off on '-d foo.com', etc.)
  28.  
  29. 08/14/07 23:03 v3.2
  30. * Polished the regexen based on Rick Moen's list of 270 TLDs
  31. * Wrapped the date-calc section in an eval for cases where the date is past
  32.     the Unix "death boundary" (18-Jan-2038)
  33.  
  34. 08/08/07 23:26 v3.1
  35. * Added another regex to parse the weird structure of 'extragalactic.net';
  36.     modified another regex slightly to accomodate 'expire date' for 'nic.it'.
  37.  
  38. 07/29/07  1:26 v3.0
  39. * MAJOR REVISION:
  40.     o The format of the 'domain-list' file has been changed, although the
  41.       old format is still valid. You can now add the name of the host for
  42.       'whois' to use as the second argument on the line; however, using the
  43.       '-s' command line argument will force all lookups to be done via the
  44.       specified host.
  45.     o Fixed up a number of regexen for the 'jwhois' differences
  46.  
  47. 07/28/07  0:41 - v2.2
  48. * Added 'jwhois' as the preferred option, with a warning if it's not
  49.     installed. Caching for 'jwhois' is disabled when '-X' is in effect;
  50.     '-H' is no longer a hard-wired argument to 'whois' ('jwhois' doesn't
  51.     support it), but is still appended if 'whois' is used.
  52. * Tweaked a couple of the regexen to process new TLDs (.fi, .ly, etc.)
  53. * Giving serious thought to modifying the format of the -F files; it would
  54.     be nice to be able to specify the whois server for individual domains.
  55.  
  56. 07/20/07  9:36 - v2.1
  57. * Added a bunch of tracing/debugging statements to the date parser, making
  58.     the '-X' option much more useful
  59. * Built a 'switch-case' structure around the parser so that only one regex
  60.     would apply to any given host
  61. * Added a '-H' argument to 'whois' ("elide legal disclaimer") to make
  62.     debugging output less annoying (and maybe speed things up fractionally)
  63. * Made the 'no expiration date found' error into a non-fatal warning (used
  64.     to break list processing)
  65. * Modified the output format slightly (warnings now appear on the same line
  66.     as the domain name)
  67. * Domains without a registrar will no longer be omitted from the mailed
  68.     notifications
  69.  
  70. 07/19/07 22:28 - v2.0
  71. * Now parsing .ci domains as well (millions of people cheer, world peace
  72.     can't be far away now...)
  73.  
  74. 07/19/07 20:54 - v1.9
  75. * Added a little regex-fu to accept lines that have whitespace at the end
  76. * Added a Big Sekrit Option ('-X' - shhh, don't tell anybody!) for debugging
  77.  
  78. 07/19/07 11:56 - v1.8
  79. * Lots and lots of fixes for many different TLDs; much mangling of regexen.
  80.     Now handles many more expiration date types than before. Most
  81.     importantly, domains that don't list a registrar will now be displayed
  82.     anyway; people probably know where to send their money, but not
  83.     necessarily _when._
  84.  
  85. 07/04/07 12:28 - v1.7
  86. * Scrapped previous approach to the .org delay; the .orgs are now sorted to
  87.     the end of the domain list and all except the first one wait 20 seconds.
  88. * Added a cute little time ticker to the delay routine, just because. :)
  89.  
  90. 07/03/07  1:27 - v1.6
  91. * Added a rate limiter (3/minute) for .org domains
  92.  
  93. 06/30/07 18:34 - v1.5
  94. * Added a "domain not parseable; please report" warning
  95. * Added an "Unable to read 'whois' info" warning for the 'fgets: connection
  96.     reset by peer' error.
  97. * All expiration warnings are now sent as one email instead of one per
  98.     domain; ditto the expired domains notifications.
  99. * The 'printf' for the 'SKIPPED' error was ignoring the '-q' option; fixed
  100.  
  101. 06/30/07  8:19 - v1.4
  102. * Removed dependency on File::Find; searching PATH 'manually'
  103. * Added an 'exit 1' to the silent failure mode of 'croak'
  104.  
  105. 06/30/07  7:06 - v1.3
  106. * Improved the date-parsing regexes (the numerical months part can now only
  107.     match '01-12' instead of 'any two digits'); this should increase the
  108.     reliability of resolving 'dd-mm-yyyy' vs. 'mm-dd-yyyy' somewhat.
  109. * More accurate reporting for the 'SKIPPED' error (now shows exact reason)
  110. * Fixed the regexes that I screwed up while adding the Dotster extension
  111. * Added a '-v' option
  112.  
  113. 06/29/07 18:54 - v1.2
  114. * Got rid of an unnecessary system dependency ('which') - 'File::Find' is a
  115.     bit clunky, but better than depending on unknowns...
  116. * Another date-processing regex (ISOC-IL: 'validity: 29-06-2007')
  117.  
  118. 06/29/07 17:07 - v1.1
  119. * Modified output format to include both exp. date and days remaining
  120. * Added another date-processing regex (DOTSTER: 'Expires on: 29-Jun-07')
  121.  
  122. 06/29/07 15:06 - v1.0
  123. I'm finally willing to admit that this script is usable. :) Recent changes
  124. include:
  125.  
  126. * Parsing routine for "2007/08/12" date format
  127. * 'croak' notifies admin of problems encountered in silent mode
  128. * Added a fallback email address for 'croak'
  129. * Fixed GMT parsing routine miscalc (thanks to Rick Moen for the heads up)
  130.  
  131. For Nosy Nellies only: *Yes*, I'm aware of the various '*Whois.pm' modules
  132. on CPAN. None of them do what I want; the one that comes closest
  133. (Net::XWhois) hasn't been maintained since 2001 and only covers a smallish
  134. subset of what I want. No, I'm not interested in taking it over and
  135. maintaining it; I've got enough to do as it is.
  136.  
  137. ###########################################################################
  138. =cut
  139.  
  140. use strict;
  141. use Time::Local;
  142. $|++;
  143.  
  144. # Command-line variables
  145. our ($d, $e, $F, $h, $q, $s, $v, $x, $X);
  146.  
  147. ### FALLBACK ADDRESS FOR NOTIFICATION ############
  148. my $address = 'root@localhost';
  149. ##################################################
  150.  
  151. my ($name) = $0 =~ /([^\/]+)$/;
  152.  
  153. my $usage =<<"+EoT+";
  154. Usage: $name [-e=email] [-x=expir_days] [-q] [-h] <-d=domain_name|-F=domainfile>
  155.  
  156.   -d=domain        : Domain to analyze
  157.   -e=email_address : Send a warning message by email
  158.   -F=domain_list   : File with a list of domains, one per line
  159.   -h               : Print this message
  160.   -q               : Don't print to the console (REQUIRES '-e' OPTION)
  161.   -s=whois server  : Use alternate whois server
  162.   -v               : Display current version of this script
  163.   -x=days          : Change default (30d) expiration interval (REQUIRES '-e' OPTION)
  164.  
  165. +EoT+
  166.  
  167. # Locate 'whois' or (preferred) 'jwhois'
  168. my ($whois) = grep -e, map "$_/jwhois", split /:/, $ENV{PATH};
  169. ($whois) = grep -e, map "$_/whois", split /:/, $ENV{PATH} unless $whois;
  170. die "'whois'|'jwhois' not found in path.\n" unless $whois;
  171. if ($whois =~ m#/whois$#){
  172.     # $q || print "You really should install 'jwhois'; it gives better results.\n";
  173.     # Turn down the noise (minimal output option - only works with 'whois')
  174.     $whois .= " -H";
  175. }
  176. else {
  177.     # Turn off caching for 'jwhois' if the debug option is on
  178.     $whois .= " -f" if $X;
  179. }
  180.  
  181. # $whois = "/usr/bin/whois";
  182.  
  183. # Find a mail client (mutt or mailx)
  184. my ($mail) = grep -e, map "$_/mutt", split /:/, $ENV{PATH};
  185. # Switch Mutt into 'mailx' mode if found
  186. if ($mail){
  187.     $mail .= " -x";
  188. }
  189. else {
  190.     ($mail) = grep -e, map "$_/mailx", split /:/, $ENV{PATH};
  191. }
  192. die "No 'mailx' or 'mutt' (mail client) found in path.\n" unless $mail;
  193.  
  194. # Read the version number at the top of the changelog
  195. if ($v){
  196.     seek DATA, 0, 0;
  197.     while (<DATA>){
  198.         if (m[^\d+/\d+/\d+[^v]+v([0-9.]+)]){
  199.             print "Version: $1\nCopyright (C) 2007 Ben Okopnik <ben\@okopnik.com>\n\n";
  200.             exit 0;
  201.         }
  202.     }
  203. }
  204.  
  205. # Email admin if '-q' is on; otherwise, just exit with the error
  206. sub croak {
  207.     if ($q){
  208.         # If '-e' wasn't specified, use the fallback address
  209.         $e ||= $address;
  210.  
  211.         # No place to send an error if this fails... :)
  212.         open Mail, "|$mail -s 'WARNING: $name script error' $e";
  213.         print Mail "$name [" . localtime() . "]: ", $_[0];
  214.         close Mail;
  215.  
  216.         exit 1;
  217.     }
  218.     else {
  219.         die $_[0];
  220.     }
  221. }
  222.  
  223. # Display the help output if requested or in case of incorrect usage
  224. die "$usage\n" if $h;
  225. die "\n*ERROR: '$name' requires an email address with the '-q' and the '-x' options*\n\n$usage" if ($q || $x) && ! $e;
  226. die "\n*ERROR: '$name' requires either a domain name or a domain list as an argument*\n\n$usage" if ! $d && ! $F;
  227. die "\n*ERROR: Please make sure you're using correct syntax (i.e., '-d=domain_name')*\n\n$usage" if (defined $d && $d =~ /^1$/) || (defined $F && $F =~ /^1$/) || (defined $s && $s =~ /^1$/);
  228.  
  229. # Set default notification interval to 30 days
  230. if ($x){
  231.     croak "Expiration interval must be specified in days (0-9999).\n"
  232.         unless $x =~ /^\d{1,4}$/;
  233. }
  234. else {
  235.     $x = 30;
  236. }
  237.  
  238. # Read the domain list file
  239. my @domains;
  240. if ($F){
  241.     croak "$F is not a regular file\n" unless -f $F;
  242.     croak "Can't read $F\n" unless -r _;
  243.     # Open the file if it exists
  244.     open F or croak "$F: $!\n";
  245.     while (<F>){
  246.         # Skip blank lines; ignore comments
  247.         next if /^\s*(?:#|$)/;
  248.         # Strip preceding and following blanks
  249.         s/^\s*(.*?)\s*$/$1/;
  250.  
  251.         # Separate domain and server if they exist
  252.         my (@line) = split;
  253.         for (@line){
  254.             # Strip URI method and any terminal '/'s
  255.             s#^.*://##;
  256.             s#/$##;
  257.         }
  258.         push @domains, [ @line ];
  259.     }
  260.     close F;
  261. }
  262.  
  263. # Having a '-F' AND a '-d' is explicitly not excluded
  264. if ($d){
  265.     # Strip URI method and any terminal '/'s
  266.     $d =~ s#^.*://##;
  267.     $d =~ s#/$##;
  268.     push @domains, [ $d ];
  269. }
  270.  
  271. # Set the server if it's been specified (this REPLACES any servers defined
  272. # in the domain-list file)
  273. if ($s){
  274.     $_ -> [1] = $s for @domains;
  275. }
  276.  
  277. # Sort list to push .orgs to the end; ASCIIbetical sort otherwise
  278. @domains = sort { ($a->[0] =~ /\.org$/i) <=> ($b->[0] =~ /\.org$/i) || $a->[0] cmp $b->[0] } @domains;
  279.  
  280. # Trim strings to specified length; return '**UNKNOWN**' if undef
  281. sub trim {
  282.     defined $_[0] || return "**UNKNOWN**";
  283.     substr($_[0], 0, $_[1]);
  284. }
  285.  
  286. # Lookup list for month number->name conversion
  287. my (%mth,%mlookup);
  288. @mth{map sprintf("%02d", $_), 1..12} = qw/jan feb mar apr may jun jul aug sep oct nov dec/;
  289. # Lookup list for month name->abbrev conversion
  290. @mlookup{qw/january february march april may june july august september october november december/} =
  291.     (qw/jan feb mar apr may jun jul aug sep oct nov dec/) x 2;
  292.  
  293. ########################## DATA COLLECTION SECTION #############################
  294.  
  295. # Process the domain list
  296. my ($seen, %list);
  297. for my $line (@domains){
  298.     my ($host, $server) = @{$line};
  299.  
  300.     my $opt = $server ? "-h $server" : "";
  301.  
  302.     $q || print "\b\nProcessing $host... ";
  303.  
  304.     # Delay to avoid triggering rate limiter
  305.     if ($host =~ /\.org$/i){
  306.         $q || print "(NOTE: Subsequent ORG queries will be delayed by 20 seconds each due to rate limiting) "
  307.             unless $seen;
  308.         # Show the cute little time ticker :)
  309.         if ($seen++){
  310.             my @chars = split //, '|/-\\';
  311.             for (0 .. 19){
  312.                 $q || print $chars[$_ % 4], "\b";
  313.                 sleep 1;
  314.             }
  315.             print " \b";
  316.         }
  317.     }
  318.  
  319.     # Execute the query
  320.     my $out;
  321.     open Who, "$whois $opt $host|" or croak "Error executing $whois: $!\n";
  322.     {
  323.         # Read in the entire output of 'whois' as a single string
  324.         local $/;
  325.         $out = <Who>;
  326.     }
  327.     close Who;
  328.  
  329.     # Make sure it's not DOS formatted
  330.     $out =~ tr/\cM//d;
  331.  
  332.     # 'fgets: connection reset by peer' - bloody annoying response!
  333.     if (!$out || $out !~ /domain/i){
  334.         $q || print "Unable to read 'whois' info for $host. Skipping... ";
  335.         next;
  336.     }
  337.  
  338.     # Freak out and run away if there's no match
  339.     if ($out =~ /no match/i){
  340.         $q || print "No match for $host!\n";
  341.         next;
  342.     }
  343.     # Ditto for bad hostnames
  344.     if ($out =~ /No whois server is known for this kind of object/i){
  345.         $q || print "'whois' doesn't recognize this kind of object. ";
  346.         next;
  347.     }
  348.  
  349.     # Convert multi-line 'labeled block' output to 'Label: value'
  350.     my $debug;
  351.     if ($out =~ /registrar:\n/i){
  352.         $out =~ s/:\n(?!\n)/: /gsm;
  353.         $debug .= "matched on line " . (__LINE__ - 1) . ": Multi-line 'labeled block'\n";
  354.     }
  355.  
  356.     # Date preprocessing. Desired date format is '29-jun-2007'
  357.     # 'Fri Jun 29 15:16:00 EDT 2007'
  358.     if ($out =~ s/(date:\s*| on:\s*)[A-Z][a-z]+\s+([a-zA-Z]{3})\s+(\d+).*?(\d+)\s*$/$1$3-$2-$4/igsm){
  359.         $debug .= "matched on line " . (__LINE__ - 1) . ": 'Fri Jun 29 15:16:00 EDT 2007'\n";
  360.     }
  361.     # '29-Jun-07'
  362.     elsif ($out =~ s/(date:\s*| on:\s*)(\d{2})[\/ -](...)[\/ -](\d{2})\s*$/$1$2-$3-20$4/igsm){
  363.         $debug .= "matched on line " . (__LINE__ - 1) . ": '29-Jun-07'\n";
  364.     }
  365.     # '2007-Jun-29'
  366.     elsif ($out =~ s/[^\n]*(?:date| on|expires on\.+):\s*(\d{4})[\/-](...)[\/-](\d{2})\.?\s*$/Expiration date: $3-$2-$1/igsm){
  367.         $debug .= "matched on line " . (__LINE__ - 1) . ": '2007-Jun-29'\n";
  368.     }
  369.     # '2007/06/29'
  370.     elsif ($out =~ s/(?:renewal-|expir(?:e|es|y|ation)\s*)(?:date|on)?[ \t.:]*\s*(\d{4})(?:[\/-]|\. )(0[1-9]|1[0-2])(?:[\/-]|\. )(\d{2})(?:\.?\s*[0-9:.]*\s*\w*\s*|\s+\([-A-Z]+\)?)$/Expiration date: $3-$mth{$2}-$1/igsm){
  371.         $debug .= "matched on line " . (__LINE__ - 1) . ": '2007/06/29'\n";
  372.     }
  373.     # '29-06-2007'
  374.     elsif ($out =~ s/(?:validity:|expir(?:y|ation) date:|expire:|expires? (?:on:?|on \([dmy\/]+\):|at:))\s*(\d{2})[\/.-](0[1-9]|1[0-2])[\/.-](\d{4})\s*[0-9:.]*\s*\w*\s*$/Expiration date: $1-$mth{$2}-$3/igsm){
  375.         $debug .= "matched on line " . (__LINE__ - 1) . ": '29-06-2007'\n";
  376.     }
  377.     # '[Expires on]     2007-06-29' (.jp, .ru, .ca)
  378.     elsif ($out =~ s/(?:valid-date|(?:renewal|expiration) date:|paid-till:|\[expires on\]|expires on ?:|expired:)\s*(\d{4})[\/.-](0[1-9]|1[0-2])[\/.-](\d{2})(?:\s*[0-9:.]*\s*\w*\s*|T[0-9:]+Z)$/Expiration date: $3-$mth{$2}-$1/igsm){
  379.         $debug .= "matched on line " . (__LINE__ - 1) . ": '[Expires on]     2007-06-29' (.jp, .ru)\n";
  380.     }
  381.     # 'expires:     June  29 2007' (.is)
  382.     elsif ($out =~ s/expires:\s*([A-Z][a-z]+)\s+(\d{1,2})\s+(\d{4})\s*$/"Expiration date: " . sprintf("%02d", $2) . "-" . $mlookup{"\L$1\E"} . "-$3"/igsme){
  383.         $debug .= "matched on line " . (__LINE__ - 1) . ": 'expires:     June  29 2007' (.is)\n";
  384.     }
  385.     # 'renewal: 29-June-2007'
  386.     elsif ($out =~ s/renewal:\s*(\d{1,2})[\/ -]([A-Z][a-z]+)[\/ -](\d{4})\s*$/"Expiration date: $1-" . $mlookup{"\L$2\E"} . "-$3"/igsme){
  387.         $debug .= "matched on line " . (__LINE__ - 1) . ": 'renewal: 29-June-2007' (.ie)\n";
  388.     }
  389.     # 'expire:         20080315' (.cz, .ke)
  390.     elsif ($out =~ s/expir[ey]:\s*(\d{4})(\d{2})(\d{2})\s*$/Expiration date: $3-$mth{$2}-$1/igsm){
  391.         $debug .= "matched on line " . (__LINE__ - 1) . ": 'expire:         20080315' (.cz, .ke)\n";
  392.     }
  393.     # 'domain_datebilleduntil: 2007-06-29T00:00:00+12:00' (.nz)
  394.     elsif ($out =~ s/domain_datebilleduntil:\s*(\d{4})[-\/](\d{2})[-\/](\d{2})T[0-9:.+-]+\s*$/Expiration date: $3-$mth{$2}-$1/igsm){
  395.         $debug .= "matched on line " . (__LINE__ - 1) . ": 'domain_datebilleduntil: 2007-06-29T00:00:00+12:00' (.nz)\n";
  396.     }
  397.     # '29 Jun 2007 11:58:42 UTC' (.coop)
  398.     elsif ($out =~ s/(?:expir(?:ation|y) date|expire[sd](?: on)?)[:\] ]\s*(\d{2})[\/ -](...)[\/ -](\d{4})\s*[0-9:.]*\s*\w*\s*$/Expiration date: $1-\L$2\E-$3/igsm){
  399.         $debug .= "matched on line " . (__LINE__ - 1) . ": '29 Jun 2007 11:58:42 UTC' (.coop)\n";
  400.     }
  401.     # 'Record expires on 17/8/2100' (.hm, fi)
  402.     elsif ($out =~ s/(?:expires(?: on|:))\s*(\d{2})[\/.-]([1-9]|0[1-9]|1[0-2])[\/.-](\d{4})\s*[0-9:.]*\s*\w*\s*$/"Expiration date: $1-".$mth{sprintf "%02d", $2} . "-$3"/iegsm){
  403.         $debug .= "matched on line " . (__LINE__ - 1) . ": 'Record expires on 17/8/2100' (.hm)\n";
  404.     }
  405.     # 'Expires on..............: Sat, Mar 29, 2008'
  406.     elsif ($out =~ s/expires on\.*:\s*(?:[SMTWF][uoehra][neduit]),\s+([A-Z][a-z]+)\s+(\d{1,2}),\s+(\d{4})\s*$/"Expiration date: " . sprintf("%02d", $2) . "-\L$1-$3"/iegsm){
  407.         $debug .= "matched on line " . (__LINE__ - 1) . ": 'Expires on..............: Sat, Mar 29, 2008'\n";
  408.     }
  409.     else {
  410.         $debug = "No regexes matched.\n";
  411.     }
  412.  
  413.     # Collect the data from each query
  414.     for (split /\n/, $out){
  415.         # Clip pre- and post- blanks
  416.         s/^\s*(.*?)\s*$/$1/;
  417.         # Squash repeated tabs and spaces
  418.         tr/ \t//s;
  419.  
  420.         # This is where it all happens - regexes to capture registrar and expiration
  421.         $list{$host}{Registrar} ||= $1 if /(?:maintained by|registration [^:]*by|authorized agency|registrar)(?:\s*|_)(?:name|id|of record)?:\s*(.*)$/i;
  422.         $list{$host}{Expires} ||= $1 if /(?:expires(?: on)?|expir(?:e|y|ation) date\s*|renewal(?:[- ]date)?)[:\] ]\s*(\d{2}-[a-z]{3}-\d{4})/i;
  423.         # print "Registrar: $list{$host}{Registrar}\nExpires: $list{$host}{Expires}\n";
  424.     }
  425.  
  426.     # Assign default message if no registrar was found
  427.     $list{$host}{Registrar} ||= "[[[ No registrar found ]]]";
  428.     
  429.     $q || print "No expiration date found in 'whois' output. Please report this domain to the author!"
  430.         unless defined $list{$host}{Expires};
  431.  
  432.     # Debug option (activated by '-X'); exits here with parsed 'whois' output
  433.     $debug .= "Registrar: $list{$host}{Registrar}\n" if defined $list{$host}{Registrar};
  434.     $debug .= "Expires: $list{$host}{Expires}\n" if defined $list{$host}{Expires};
  435.     die "\n", "=" x 70, "\n$out", "=" x 70, "\n$debug", "=" x 70, "\n" if $X;
  436. }
  437.  
  438. $q || print "\n";
  439.  
  440. ########################## DATA ANALYSIS SECTION #############################
  441.  
  442. # Get current time snapshot in UTC
  443. my $now = timegm(gmtime);
  444.  
  445. # Convert dates to UTC epoch seconds; *will* fail on 19 Jan 2038. :)
  446. my %months;
  447. @months{qw/jan feb mar apr may jun jul aug sep oct nov dec/} = 0..11;
  448.  
  449. # Print the header if '$q' is off and there's content in %list
  450. $q || %list && printf "\n\n%-24s%-36s%s\n%s\n", "Host", "Registrar", "Exp.date/Days left", "=" x 78;
  451.  
  452. # Process the collected data
  453. my (%exp, %end);
  454. for my $k (sort keys %list){
  455.     unless (defined $list{$k}{Expires}){
  456.         $q || printf "%-32s%s\n", trim($k, 31), "*** SKIPPED (missing exp. date) ***";
  457.         delete $list{$k};
  458.         next;
  459.     }
  460.     my @chunks = split /-/, $list{$k}{Expires};
  461.     my $epoch;
  462.     eval { $epoch = timegm(0, 0, 0, $chunks[0], $months{lc $chunks[1]}, $chunks[2] - 1900) };
  463.     if ($@ =~ /too big/){
  464.         $q || print "**** NOTE: Date past 19-Jan-2038 - date will NOT be calculated correctly! ****\n";
  465.         # Set date to EPOCH_MAX
  466.         $epoch = 2147212800;
  467.     }
  468.     elsif ($@){
  469.         $q || print "$@\n";
  470.         # Set date to EPOCH_MAX
  471.         $epoch = 2147212800;
  472.     }
  473.     my $diff = int(($epoch - $now) / 86400);
  474.     $q || printf "%-24s%-36s%-12s/%5s\n", trim($k, 23), trim($list{$k}{Registrar}, 35),
  475.         $list{$k}{Expires}, $diff;
  476.  
  477.     # Prepare alerts if domain is expired or the expiration date is <= $x days
  478.     if ($e && ($diff <= $x)){
  479.         if ($diff <= 0){
  480.             $exp{$k} = -$diff;
  481.         }
  482.         else {
  483.             $end{$k} = $diff;
  484.         }
  485.     }
  486. }
  487.  
  488. # Report expired domains
  489. if (%exp){
  490.     open Mail, "|$mail -s '$name: Expired domains' $e" or croak "$mail: $!\n";
  491.     print Mail "According to 'whois', the following domains have expired:\n\n";
  492.     for my $x (sort { $exp{$a} <=> $exp{$b} } keys %exp){
  493.         my $s = $exp{$x} == 1 ? "" : "s";
  494.         print Mail "$x ($exp{$x} day$s ago)\n";
  495.     }
  496.     close Mail;
  497. }
  498.  
  499. # Report domains that will expire within the '-x' period
  500. if (%end){
  501.     open Mail, "|$mail -s '$name: Domain expiration warning ($x day cutoff)' $e" or croak "$mail: $!\n";
  502.     print Mail "According to 'whois', these domains will expire soon:\n\n";
  503.     for my $d (sort { $end{$a} <=> $end{$b} } keys %end){
  504.         my $s = $end{$d} == 1 ? "" : "s";
  505.         print Mail "$d (in $end{$d} day$s)\n";
  506.     }
  507.     close Mail;
  508. }
  509.  
  510. __END__
  511.  
  512.