home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Amiga Format CD 28
/
amigaformatcd28.iso
/
-seriously_amiga-
/
archivers
/
xfx
/
install
< prev
next >
Wrap
Text File
|
1998-04-27
|
5KB
|
237 lines
; *******************************************
; **** ****
; **** xFX ****
; **** Multilanguage Installation Script ****
; **** © 1997-98, Alessandro Pedretti ****
; **** ****
; *******************************************
; $VER:xFX_Install 1.2 (3.2.98) Alessandro Pedretti
;
; Language selector (default: english)
;
(set #DefLang 0)
(set #DefDoc 0)
(if (= @language "italiano")
(set #DefLang 1)
)
(if (= @language "deutsch")
(set #DefLang 2)
)
(if (= @language "dansk")
(set #DefLang 3)
)
(if (= @language "français")
(set #DefLang 4)
)
(select #DefLang
; English
((set #DefDoc 0)
(set #ARexxTxt "Do you want install ARexx scripts ?")
(set #DirTxt "Select the directory where the xFX drawer will be created.")
(set #LangDocTxt "Please select your preferred language documentation")
(set #LangHelpTxt "You must specify your language.")
(set #LangLocTxt "Please select the language for localization")
(set #LangLocTxt "Please select the language for localization")
(set #StartupTxt1 "The line \"Assign xFX: ")
(set #StartupTxt2 "\" will be added to your \"S:User-Startup\" file")
)
; Italiano
((set #DefDoc 1)
(set #ARexxTxt "Vuoi installare gli scripts ARexx ?")
(set #DirTxt "Selezionare la directory dove verrà creato il cassetto xFX.")
(set #LangDocTxt "Selezionare il linguaggio per la documentazione")
(set #LangHelpTxt "E' necessario specificare un linguaggio.")
(set #LangLocTxt "Selezionare il linguaggio per la localizzazione")
(set #StartupTxt1 "La linea \"Assign xFX: ")
(set #StartupTxt2 "\" deve essere aggiunta al file \"S:User-Startup\"")
)
; Deutsch
((set #DefDoc 0)
(set #ARexxTxt "Wollen Sie die ARexx Scripts installiren ?")
(set #DirTxt "Bitte wählen Sie einen Platz für xFX. Ein Verzeichnis namens 'xFX' wird dort automatisch erzeugt.")
(set #LangDocTxt "Bitte wählen Sie die Sprache für die Dokumentation aus.")
(set #LangHelpTxt "Sie wählen die Sprache aus.")
(set #LangLocTxt "Bitte wählen Sie die Sprache für die Programmen aus.")
(set #StartupTxt1 "\"Assign xFX: ")
(set #StartupTxt2 "\" wird nach \"S:User-Startup\" kopiert")
)
; Dansk
((set #DefDoc 0)
(set #ARexxTxt "Ønsker du at installere ARexx eksempler ?")
(set #DirTxt "Vælg stien hvor xFX skuffen skal oprettes.")
(set #LangDocTxt "Vælg venligst dit foretrukne sprog for dokumentationen")
(set #LangHelpTxt "Specificer hvilken dokumentation du ønsker at installere")
(set #LangLocTxt "Vælg venligst sprog til brug i programmet")
(set #StartupTxt1 "The line \"Assign xFX: ")
(set #StartupTxt2 "\" will be added to your \"S:User-Startup\" file")
)
; Français
((set #DefDoc 0)
(set #ARexxTxt "Voulez vous installer le ARexx scripts ?")
(set #DirTxt "Sélectionnez le répertoire dans lequel vous voulez installer le répertoire de xFX.")
(set #LangDocTxt "Sélectionnez le langage de la documentation")
(set #LangHelpTxt "Sélectionnez le langage.")
(set #LangLocTxt "Sélectionnez le langage pour la localizzazione")
(set #StartupTxt1 "La ligne \"Assign xFX: ")
(set #StartupTxt2 "\" doit etre adjointe' au fiche \"S:User-Startup\"")
)
)
;
; Default xFX directory
;
(complete 20)
(set xFXDir
(askdir
(prompt #DirTxt)
(help @askdir-help)
(default @default-dest)
(newpath)
)
)
(set xFXDir(tackon xFXDir "xFX"))
(set @default-dest xFXDir)
;
; Documentation language
;
(complete 30)
(set DocLang
(select
(askchoice
(prompt #LangDocTxt)
(help #LangHelpTxt)
(choices "English" "Italiano")
(default #DefDoc)
)
"xFX-Eng.guide" "xFX-Ita.guide"
)
)
(set DocLang (cat "Docs/" DocLang))
;
; Catalogs
;
(complete 40)
(set CatLang
(askoptions
(prompt #LangLocTxt)
(help #LangHelpTxt)
(default 1)
(choices "English (Built-In)"
"Italiano"
; "Dansk"
)
)
)
;
; File copy
;
(complete 50)
(copyfiles
(source "")
(help @copyfiles-help)
(infos)
(noposition)
(dest @default-dest)
(choices "xFX"
"GuiX"
"zFX"
"SCSI_Errors.dat"
)
)
(complete 60)
(copyfiles
(source DocLang)
(help @copyfiles-help)
(infos)
(noposition)
(dest @default-dest)
(newname "xFX.guide")
)
;
; ARexx Scripts
;
(complete 70)
(if (askbool (prompt #ARexxTxt) (help @askbool-help))
(copyfiles
(source "")
(help @copyfiles-help)
(infos)
(dest @default-dest)
(choices "ARexx")
)
)
(complete 80)
(set @default-dest (tackon @default-dest "Catalogs"))
(copyfiles
(source "Catalogs")
(help @copyfiles-help)
(dest @default-dest)
(choices "xFX.cd"
"GuiX.cd"
)
)
(complete 90)
(if (IN CatLang 1)
(copyfiles
(source "Catalogs")
(help @copyfiles-help)
(dest @default-dest )
(choices "Italiano")
)
)
(if (IN CatLang 2)
(copyfiles
(source "Catalogs")
(help @copyfiles-help)
(dest @default-dest )
(choices "Dansk")
)
)
; Startup-sequence (User-Startup):
(complete 95)
(startup "xFX"
(prompt #StartupTxt1 xFXDir #StartupTxt2)
(help @startup-help)
(command "Assign xFX: \"" xFXDir "\"\n")
)
(set @default-dest xFXDir)
(complete 100)