home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
The Pier Shareware 6
/
The_Pier_Shareware_Number_6_(The_Pier_Exchange)_(1995).iso
/
035
/
cenvi29.zip
/
CENVISET.CMD
< prev
next >
Wrap
OS/2 REXX Batch file
|
1994-03-08
|
2KB
|
44 lines
@echo OFF
REM ***************************************************************************
REM *** CEnviSet.cmd - This is a kludge file to be used with CEnvi for OS/2 ***
REM *** ver.1 when you want to update Environment Variables that ***
REM *** the Cmm code may have changed. This KLUDGE step ***
REM *** will go away whenever Nombas discovers a valid way ***
REM *** for altering environment variables in the command ***
REM *** interpreter. Also, this is not very multitasking ***
REM *** compatible since only one file name is used, and so ***
REM *** different files may be used simultaneaously. ***
REM ***************************************************************************
REM *** SET A VALUE FOR CENVI_ESET COMMAND FILE IF ONE IS NOT ALREADY SET
SET REMEMBER_CENVI_ESET=%CENVI_ESET%
if a%CENVI_ESET%z == az set CENVI_ESET=TempSet.cmd
REM *** BUILD A VARIABLE WITH ENTIRE INPUT PARAMETERS (MAY BE > 9)
SET CENVI_ARGUMENTS=
:NEXT_ARG
IF q%1q == qq GOTO NO_MORE_ARGS
SET CENVI_ARGUMENTS=%CENVI_ARGUMENTS% %1
SHIFT
GOTO NEXT_ARG
:NO_MORE_ARGS
REM *** CALL CENVI, AND LET IT DO ITS STUFF, INCLUDING SET EVAR FILE
CEnvi.exe %CENVI_ARGUMENTS%
REM *** EXECUTE THE TEMPORARY CENVI_ESET FILE TO SET ENVIRONMENT VARS
if exist %CENVI_ESET% CALL %CENVI_ESET%
REM *** DELETE THE %CENVI_ESET% FILE, WHILE AVOIDING UNDELETE TIME
if not exist %CENVI_ESET% GOTO FINI
SETLOCAL
SET DELDIR=
del %CENVI_ESET%
ENDLOCAL
REM *** CLEANUP
:FINI
SET CENVI_ESET=%REMEMBER_CENVI_ESET%
SET REMEMBER_CENVI_ESET=
SET CENVI_ARGUMENTS=