home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
The Pier Shareware 6
/
The_Pier_Shareware_Number_6_(The_Pier_Exchange)_(1995).iso
/
030
/
cstnet12.zip
/
QMODEM.SCR
< prev
next >
Wrap
Text File
|
1994-11-10
|
8KB
|
326 lines
; Script Date: 3/10/93
; WILDCAT!/QMODEM SCRIPT From MSI By: Robert Cole
; -----------------------------------------------
; Modified For COASTNET! On November 1st, 1993
; (This Script Good To WC v3.99 ONLY - NOT For v4.x)
TurnON 8_BIT
TurnOFF LINEFEED
TurnOFF NOISE
TurnOFF MUSIC
TurnOFF SCROLL
TurnOFF PRINT
TurnOFF SPLIT
TurnOFF DOORWAY
GRAPHICS ANSI
COLORBG 0
COLORFG 14
CLRSCR
STRING NAME
STRING QWK_PACKET
STRING PHONE
STRING PREFIX
STRING INIT
STRING MAX_REDIAL
STRING LOGIN_NAME
STRING PWORD,ANSWER
ASSIGN 0 1 ; Redial counter.
ASSIGN 1 5 ; Number of Init tries.
ASSIGN 3 "INITIALIZED" ; Fill variable with initial value.
ASSIGN QWK_PACKET LZRCST
EXIST $QWK_PACKET.CFG GO
QUES1:
ATWRITE 1,1,11,"Enter the name of the system you are calling:"
GOTOXY 1 2
DISPLAYLN "[───────────────────────────────]"
GOTOXY 2 3
GETN NAME 30
QUES2:
ATWRITE 1,4,11,"Enter the login name that you call to get mail with (DON'T ADD A ! TO YOUR NAME)"
GOTOXY 1 5
DISPLAYLN "[───────────────────────────────]"
GOTOXY 2 6
GETN LOGIN_NAME 30
QUES3:
ATWRITE 1,7,11,"Enter the password (14 chars max):
GOTOXY 1,8
DISPLAYLN "[──────────────]"
GOTOXY 2 9
GETN PWORD 14
QUES4:
ATWRITE 1,10,11,"Enter The phone number to dial (Default: 1-805-285-3961):
ATWRITE 1,11,11,"MAKE SURE TO ADD THE 1- if you are calling long distance!!"
GOTOXY 1 12
DISPLAYLN "[──────────────]"
GOTOXY 2 13
GETN PHONE 12
IF "$PHONE" = "" LOAD_DEFAULT_NUMBER
QUES5:
ATWRITE 1,14,11,"Enter the max NUMBER of redial attempts to this system (Max 999):
GOTOXY 1 15
DISPLAYLN "[───]"
GOTOXY 2 16
GETN MAX_REDIAL 3
QUES6:
ATWRITE 1,17,11,"Enter your custom initialization string here (Default: ATZ):
GOTOXY 1 18
DISPLAYLN "[────────────────────────────────────────]"
GOTOXY 2 19
GETN INIT 40
IF "$INIT" = "" LOAD_DEFAULT_INIT
QUES7:
COLORFG 11
GOTOXY 1 20
DISPLAY "Do you have [T]one or [P]ulse dialing (Default: Tone)(T/P)? "
GETN PREFIX 1
IF "$PREFIX" = "P" ASSIGN_PULSE
IF "$PREFIX" = "T" ASSIGN_TONE
IF "$PREFIX" = "" ASSIGN_TONE
QUES8:
CLRSCR
ATWRITE 1,1,11,"Do you want this script to pick up the line and"
ATWRITE 1,2,11,"send a message to a use who is trying to call the BBS"
GOTOXY 1 3
DISPLAY "telling them to call back later Y/n? "
GETN ANSWER 1
IF "$ANSWER" = "Y" ASSIGN_Y
IF "$ANSWER" = "N" ASSIGN_N
IF "$ANSWER" = "" ASSIGN_Y
WRITE_INFO:
OPENFILE $QWK_PACKET.CFG REWRITE
WRITEFILE "$NAME"
WRITEFILE "!$LOGIN_NAME"
WRITEFILE "$PWORD"
WRITEFILE "$PHONE"
WRITEFILE "$MAX_REDIAL"
WRITEFILE "$INIT"
WRITEFILE "$PREFIX"
WRITEFILE "$ANSWER"
CLOSEFILE
GOTO GO
LOAD_DEFAULT_NUMBER:
ASSIGN PHONE 1-805-285-3961
GOTO QUES5
LOAD_DEFAULT_INIT:
ASSIGN INIT ATZ
GOTO QUES7
ASSIGN_TONE:
ASSIGN PREFIX T
GOTO QUES8
ASSIGN_PULSE:
ASSIGN PREFIX P
GOTO QUES8
ASSIGN_Y:
ASSIGN ANSWER Y
GOTO WRITE_INFO
ASSIGN_N:
ASSIGN ANSWER N
GOTO WRITE_INFO
SEND_MESSAGE:
WHEN ; Clear WHEN's
TimeOut 10 START
Waitfor "RING"
IF "$ANSWER" = "N" WAIT_4_SILENCE
TimeOut 60 REINIT
Waitfor "RING"
Delay 500
Send "ATA^M"
Waitfor "CONNECT"
Delay 3000
Send "The System Is Currently Attempting To Make An Outgoing Call.^M^J"
Send "Please Hang Up And Try Back Later."
Delay 2000
HANGUP
GOTO REINIT
WAIT_4_SILENCE:
CLRSCR
FLUSH ALL ; Flush the buffers to make sure of no stray RING's
TimeOut 15 INCREMENT
Waitfor "RING" WAIT_4_SILENCE
GO: ; Begin Main body of script
; Fill variables with preferences
OPENFILE $QWK_PACKET.CFG READ
READFILE NAME ; Read System name
READFILE LOGIN_NAME ; Read in login name
READFILE PWORD ; Read in password
READFILE PHONE ; Read phone number
READFILE MAX_REDIAL ; Read max redial attempts
READFILE INIT ; Read init string.
READFILE PREFIX ; Read in dialing prefix
READFILE ANSWER ; Read in call collision preference
CLOSEFILE
LOG $QWK_PACKET.LOG ; Turn on logging.
CAPTURE $QWK_PACKET.CAP ; Turn on session capture.
ASSIGN 6 1 ; Current number of tries
REINIT:
TimeOut 10 REINIT
CLRSCR
COLORFG 0
COLORBG 0
IF "$6" = "$1" NO_MODEM_RESPONSE
ATWRITE 1,1,11,"Modem Init Attempt Number $6 of $1"
GOTOXY 5 5
SEND "$INIT^M"
INCR 6
WAITFOR "OK" ; Get modem response.
PAUSE 3000
SEND "ATX4E0M0^M" ; HST's and HST/DS's needs X4 to run this script!
WAITFOR "OK" ; Get modem response.
TimeOut 60 START
START:
CLRSCR
WHEN
WHEN "RING" SEND_MESSAGE
WHEN "BUSY" INCREMENT
WHEN "NO DIAL" INCREMENT
WHEN "NO CARRIER" INCREMENT
COLOR 30
BOX 10,5,65,15
CLRSCR
GOTOXY 4 1
DISPLAY " Dialing $NAME at $TIME"
GOTOXY 17 3
DISPLAY "Try Number $0 of $MAX_REDIAL"
GOTOXY 12 5
DISPLAY "Message From Modem: "
WINDOW 42 10 55 12
COLORFG 11
TIMEOUT 30 START ; Increase/Decrease as needed to match S7 register in modem.
DELAY 3000
SEND "ATD$PREFIX$PHONE^M"
GOTOXY 1 1
WAITFOR "CONNECT"
DELAY 1000
IF $ONLINE SKIP
INCREMENT:
IF "$0" = "$MAX_REDIAL" END
INCR 0
Delay 9000 ; Delay for 9 seconds before next attempt.
GOTO START
SKIP:
COLORBG 0
TimeOut 30 FIRST_NAME
WINDOW 1,1,80,24
CLRSCR
WHEN ; Clear Above WHEN "BUSY" setting
WHEN "[C]ont" "^M" ; Watch for long prelog screen
WHEN "CAUTION!" "^M"
WHEN "[y/N]" "^M"
WHEN "correctly" "^M"
WHEN "first name" SEND_NAME
WHEN "-PAUSE-" "^M"
WHEN "[S]top" "^M"
WHEN "NO CARRIER" START
FIRST_NAME:
Waitfor "your first name"
Delay 100
SEND_NAME:
Send "$LOGIN_NAME^M"
PAUSE 1000
Send "^M"
Waitfor "Password?"
Send "$PWORD"
TimeOut 30 TOMCAT_MENU
WHEN ; Clear above WHEN's
WHEN "first name" SKIP
WHEN "PACKER MENU" SELECT_PACKER
WHEN "PROTOCOL MENU" SELECT_PROTOCOL
WHEN "NO CARRIER" START
GOTO TOMCAT_MENU
SELECT_PACKER:
Send "Z"
GOTO DOWNQWK
SELECT_PROTOCOL:
Send "Z"
GOTO DOWNQWK
TOMCAT_MENU:
Send "^M"
Waitfor "WCMAIL" ; wcMAIL Main Menu Prompt
Delay 300
When "load!" TEST_FOR_REP
Send "D"
DOWNQWK:
TimeOut 900 TOMCAT_MENU
Waitfor "done?"
Delay 100
Send "Y"
Waitfor "now"
Download Z $DLPATH
IF $FAIL TOMCAT_MENU
WHEN
TEST_FOR_REP:
EXIST $ULPATH$QWK_PACKET.REP UPLOAD_REP ; Test for existence of reply Packet
GOTO END
SELECT_PACKER_UPLOAD:
Send "Z"
GOTO CONTINUE_REP_UPLOAD
SELECT_PROTOCOL_UPLOAD:
Send "Z"
GOTO CONTINUE_REP_UPLOAD
UPLOAD_REP: ; Subroutine for uploading reply packet
TimeOut 30 UPLOAD_REP
WHEN
WHEN "PACKER MENU" SELECT_PACKER_UPLOAD
WHEN "PROTOCOL MENU" SELECT_PROTOCOL_UPLOAD
Send "^M"
Waitfor "WCMAIL"
Delay 300 ; Once a reply packet is uploaded successfully
Send "U" ; You may hang up. Tomcat will continue to
CONTINUE_REP_UPLOAD:
Waitfor "now" ; insert your messages and the board will
UPLOAD Z $ULPATH$QWK_PACKET.REP ; recycle when Tomcat is done. This script hangs
Waitfor "ing reply packet" ; up as soon as the reply packet is uploaded.
IF $SUCCESS DELETE_REP_QWK_PACKET
GOTO UPLOAD_REP ; It failed, try upload again.
DELETE_REP_QWK_PACKET:
DOS "DEL $ULPATH$QWK_PACKET.REP"
GOTO END
END:
WHEN
HANGUP
TimeOut 10 END
Send "ATM0H1^M"
Waitfor "OK"
TURNOFF LOG
TURNOFF CAPTURE
SYSTEM X
NO_MODEM_RESPONSE:
OPENFILE $QWK_PACKET.ERR REWRITE
WRITEFILE **********************
WRITEFILE "No Modem Response given on $DATE at $TIME after $6 Tries"
CLOSEFILE
STAMP ********************
STAMP Failed to init the modem on $DATE at $TIME after $6 tries.
GOTO END