home *** CD-ROM | disk | FTP | other *** search
/ NeXTSTEP 3.3.4.17 [SPARC, PA-RISC] / nextstep33_risc.iso / NextLibrary / TeX / mf / inputs / 3test.mf next >
Text File  |  1995-02-07  |  2KB  |  54 lines
  1. % This tries all characters on TEST.MF using three different sets of parameters
  2. % (appropriate for italic styles)
  3. if unknown cmbase: input cmbase fi % omit if CMMF can be assumed
  4. mag=.5;
  5. mode_setup; let mode_setup=\;
  6.  
  7. boolean running;
  8. def abort = hide(scrollmode; running:=false) enddef;
  9. def pause=stop "done with char "&decimal charcode&". " enddef;
  10. let iff=always_iff;
  11. def ligtable text t=enddef;
  12. def charlist text t=enddef;
  13. def extensible text t=enddef;
  14.  
  15. string currenttitle;
  16. let semi=;; let echar=endchar; let endchar=enddef;
  17. def cmchar expr s = currenttitle:=s;
  18.  let;=testchar semi quote def chartext=enddef;
  19. def testchar = semi let;=semi;
  20.  % now `chartext echar' will generate the character to be tested
  21.  running:=true; errorstopmode;
  22.  for k=1 upto 6:
  23.   if running: if known params[k]: scantokens params[k]; font_setup;
  24.     currentwindow:=k;
  25.     currenttitle & ", " & fontname[k];
  26.     chartext echar; fi fi endfor
  27.  pause; enddef;
  28.  
  29. string params[],fontname[];
  30. params[1]="ital_params"; fontname[1]="cmti10";
  31. params[2]="bold_ital_params"; fontname[2]="cmbxti10";
  32. params[3]="tt_params"; fontname[3]="cmmi10";
  33.  
  34. w_rows=floor 1/2 screen_rows; w_cols=floor 1/3 screen_cols;
  35. def open(expr k,i,j)=
  36.  openwindow k from ((i-1)*w_rows,(j-1)*w_cols) to (i*w_rows,j*w_cols)
  37.  at (-10,140) enddef;
  38. def openit =
  39.  open(1,1,1); open(2,1,2); open(3,1,3);
  40.  open(4,2,1); open(5,2,2); open(6,2,3); enddef;
  41.  
  42. begingroup delimiters begintext generate;
  43.  def makedef(expr s)(text t) =
  44.   expandafter def scantokens s = t enddef; flushtext enddef;
  45.  def flushtext suffix t = enddef;
  46.  for k=1 upto 6: if known params[k]:
  47.  makedef(params[k])
  48.   expandafter expandafter expandafter begintext
  49.   scantokens ("input "&fontname[k]); fi endfor
  50. endgroup;
  51.  
  52. input test
  53. end
  54.