home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Commodore Disk User Volume 3 #9
/
Commodore_Disk_User_Vol.3_9_1990_-.d64
/
.dir.41000
< prev
next >
Wrap
Text File
|
2022-10-26
|
827b
|
35 lines
41000 rem" Display directory, supply file spec in a$. (C) A.Millett.
41020 print
41040 open 15,8,15
41060 qe=0
41080 open 1,8,0,"$"+a$
41100 gosub 41500:if qe then 41300 :rem" Disk error?
41120 get#1,a$,a$
41140 : get#1,a$,a$,a$,b$
41160 : if st then qe=99:goto 41300
41180 : get c$:if c$="" then 41300
41200 : print asc(a$+chr$(0))+asc(b$+chr$(0))*256;
41220 : get#1,a$:if st then qe=99:goto 41300
41240 : print a$;:if a$>"" then 41220
41260 : print
41280 goto 41140
41300 close 1:close 15
41320 return
41499 :
41500 rem" Check error channel , return (qe) error #
41520 input#15,qe,qe$,qt,qs
41540 if qe=0 then return
41560 print
41580 print "DISK ERROR - ";qe;",";qe$;",";qt;",";qs
41600 for x=1 to 15:close x:next
41620 print"Hit SPACE to continue."
41640 get a$
41660 if a$<>" " then 41640
41680 return
41999 :
ready.