home *** CD-ROM | disk | FTP | other *** search
/ Commodore Disc 49 / Commodore_Disc_49_19xx_-_de.d64 / wunderland (.txt) < prev   
Commodore BASIC  |  2022-10-26  |  29KB  |  745 lines
  1. 10 rem reise ins wunderland =====64
  2. 20 rem (p) commodore disc         =
  3. 30 rem ============================
  4. 40 rem (c) by                     =
  5. 50 rem juergen gerstenberg        =
  6. 60 rem                            =
  7. 70 rem version 2.0                =
  8. 80 rem c-64 + 1530/1541           =
  9. 90 rem ============================
  10. 100 av=9:ao=115:ar=50:am=49
  11. 110 wl=4:sp=1:af=7
  12. 120 dimdu(ar,6),ob(ao),fl(7)
  13. 130 dimob$(ao),rn$(ao),ra$(ar),ms$(am)
  14. 140 fl(1)=-1:fl(2)=-1:fl(3)=-1:fl(4)=-1
  15. 150 fl(5)=-1:fl(6)=-1:fl(7)=-1
  16. 160 rem ****************** verben *
  17. 170 data untersuche
  18. 180 data nimm
  19. 190 data lege
  20. 200 data oeffne
  21. 210 data betrete
  22. 220 data benutze
  23. 230 data esse
  24. 240 data reibe
  25. 250 data drehe
  26. 260 rem ***************** objekte *
  27. 270 data viele baeume, baeume, 1
  28. 280 data einen grossen felsbrocken, felsen, 2
  29. 290 data eine treppe, treppe, 0
  30. 300 data leere konservendosen, dosen, 0
  31. 310 data ein paket zucker, zucker, 0
  32. 320 data leere flaschen, flaschen, 0
  33. 330 data nichts besonderes, nichts, 7
  34. 340 data baeume, baeume, 4
  35. 350 data viele seen,seen,5
  36. 360 data darin sind viele fische, fische, 0
  37. 370 data "eine hohe, lange mauer",mauer,6
  38. 380 data ein tor, tor, 0
  39. 390 data eine nische, nische,8
  40. 400 data "eine holzkiste, nicht verschlossen", kiste,0
  41. 410 data einen hinterhalt, hinte, 0
  42. 420 data ein brett, brett, 9
  43. 430 data eine eisentruhe, truhe,0
  44. 440 data einen schluessel, schluessel,0
  45. 450 data eine falltuer,fall,10
  46. 460 data tropfsteine,trop,11
  47. 470 data ein reissendes gewaesser,gewaesser,12
  48. 480 data werkzeuge,werk,13
  49. 490 data einen hammer, hammer,0
  50. 500 data eine brechstange, brech,0
  51. 510 data einen meissel,meissel,0
  52. 520 data nichts besonderes, nichts, 14
  53. 530 data nichts besonderes, nichts, 15
  54. 540 data einen hungrig brummenden baeren, baer,0
  55. 550 data eine lichtung,lichtung,3
  56. 560 data nichts besonderes,nichts,9
  57. 570 data nichts besonderes,nichts,13
  58. 580 data fische,fische,0
  59. 590 data eine grosse ebene,ebene,16
  60. 600 data einen riesigen wald,wald,16
  61. 610 data ein stark zerklueftetes gebirge,gebirge,16
  62. 620 data eine merkwuerdige huette,huette,17
  63. 630 data einen wackeligen tisch,tisch,0
  64. 640 data ein messer,messer,0
  65. 650 data eine kutsche,kutsche,18
  66. 660 data ein zerbrochenes rad,rad,0
  67. 670 data einen ring,ring,0
  68. 680 data einen lichtschimmer,schimmer,19
  69. 690 data ein stabiles holztor,holztor,0
  70. 700 data eine strasse,strasse,20
  71. 710 data einen rastplatz,rastplatz,20
  72. 720 data eine quelle,quelle,0
  73. 730 data sauberes wasser,wasser,0
  74. 740 data einen teppich,teppich,21
  75. 750 data eine zugbruecke,zugbruecke,22
  76. 760 data nichts besonderes,nichts,23
  77. 770 data viele grosse toepfe,toepfe,24
  78. 780 data in ihnen spinnweben,weben,0
  79. 790 data mehrere leere gefaesse,gefaesse,24
  80. 800 data einen riesigen eichentisch,eichentisch,25
  81. 810 data eine alte vergammelte lampe,lampe,0
  82. 820 data viele dunkele ecken,ecken,26
  83. 830 data eine wendeltreppe,wendeltreppe,26
  84. 840 data eine stiege nach unten,stiege,26
  85. 850 data ein kaestchen,kaestchen,27
  86. 860 data eine glaeserne glocke,glocke,27
  87. 870 data verschlossene kellertueren,kellertueren,28
  88. 880 data ein skelett,skelett,0
  89. 890 data eingefallene waende,waende,29
  90. 900 data tiegel und toepfe,tiegel,30
  91. 910 data ein himmelbett,himmelbett,30
  92. 920 data eine spinne,spinne,0
  93. 930 data zauberpulver,zauberpulver,0
  94. 940 data einen guertel,guertel,0
  95. 950 data einen bach,bach,31
  96. 960 data einen bach,bach,32
  97. 970 data einen taleingang,taleingang,33
  98. 980 data einen feuerspeienden drachen,drachen,0
  99. 990 data steile felshaenge,haenge,34
  100. 1000 data einen hoehleneingang,eingang,0
  101. 1010 data einen pfad nach oben,pfad,0
  102. 1020 data kein weiterkommen,weiter,35
  103. 1030 data ein hindernis,hindernis,35
  104. 1040 data einen riesen,riese,0
  105. 1050 data eine verborgene huette,verborgene huette,0
  106. 1060 data blumen,blumen,0
  107. 1070 data tiere,tiere,36
  108. 1080 data ein haeuschen,haeuschen,36
  109. 1090 data einen schemel,schemel,0
  110. 1100 data einen zettel,zettel,0
  111. 1110 data einen zauberspruch,spruch,0
  112. 1120 data blumen,blumen,37
  113. 1130 data tiere,tiere,37
  114. 1140 data einen bruechigen weg,weg,38
  115. 1150 data allerlei sachen,sachen,39
  116. 1160 data eine steintafel,tafel,40
  117. 1170 data einen text,text,0
  118. 1180 data blumen,blumen,41
  119. 1190 data tiere,tiere,41
  120. 1200 data blumen,blumen,42
  121. 1210 data tiere,tiere,42
  122. 1220 data eine merkwuerdige stelle,stelle,43
  123. 1230 data ein schwert,schwert,0
  124. 1240 data einen spaten,spaten,0
  125. 1250 data einen dunklen gegenstand,gegenstand,40
  126. 1260 data in der ferne eine grosse mulde,mulde,44
  127. 1270 data giftige schlangen,giftige schlangen,45
  128. 1280 data nichts besonderes,besonderes,46
  129. 1290 data eine ruine,ruine,47
  130. 1300 data truemmer,truemmer,48
  131. 1310 data eine leiter,leiter,0
  132. 1320 data absolute dunkelheit,dunkelheit,49
  133. 1330 data eine geldboerse,geldboerse,0
  134. 1340 data eine wunderblume,wunderblume,0
  135. 1350 data eine ungeheuer als waechter,waechter,50
  136. 1360 data eine kerze,kerze,0
  137. 1370 data ein feuerzeug,feuerzeug,0
  138. 1380 data ein totes ungeheuer,ungeh,0
  139. 1390 data eine tuer,tuer,0
  140. 1400 data nichts besonderes,nichts,0
  141. 1410 data getoetete schlangen,getoetet,0
  142. 1420 rem ***************** raeume *
  143. 1430 data im wald.,1,1,4,3,0,0
  144. 1440 data auf einer lichtung.,0,4,0,0,0,0
  145. 1450 data im wald.,0,1,4,5,0,0
  146. 1460 data im wald.,2,6,3,5,0,0
  147. 1470 data auf einer lichtung.,0,0,6,4,0,0
  148. 1480 data an einem taleingang.,4,3,0,5,0,0
  149. 1490 data in einem unterirdischen gang.,0,8,0,0,2,0
  150. 1500 data in einem unterirdischen gang.,7,0,0,9,0,0
  151. 1510 data in einer hoehle.,7,9,8,11,0,0
  152. 1520 data in einem langen gang.,9,10,11,0,0,0
  153. 1530 data in einer tropfsteinhoehle.,11,11,9,10,11,11
  154. 1540 data an einem unterirdischen fluss.,0,0,10,15,0,0
  155. 1550 data in einer alten baustelle.,0,14,0,0,0,0
  156. 1560 data in einem alten gang.,13,14,15,14,0,0
  157. 1570 data in einem alten gang.,0,0,12,14,14,14
  158. 1580 data in einem grossen tal.,16,18,17,15,0,0
  159. 1590 data in einem grossen tal.,17,17,18,16,0,0
  160. 1600 data auf einer grossen ebene.,20,18,18,17,0,0
  161. 1610 data in einem dunkelen raum.,0,0,0,0,0,0
  162. 1620 data auf einer grossen ebene.,21,21,21,21,0,0
  163. 1630 data immer noch auf dem rastplatz.,21,21,21,21,0,0
  164. 1640 data vor einem unbewohnten schloss.,0,0,22,23,0,0
  165. 1650 data im schlosshof.,25,24,22,24,0,0
  166. 1660 data in der kueche.,23,23,23,25,0,0
  167. 1670 data im rittersaal.,26,23,0,0,0,0
  168. 1680 data in einem korridor.,25,23,24,30,27,28
  169. 1690 data in einem verfallenen turm.,0,0,0,0,0,26
  170. 1700 data in einem feuchten kellergang.,0,0,0,0,26,0
  171. 1710 data in einem schaurigen verliess.,28,0,0,0,0,0
  172. 1720 data in einem wundervollen schlafzimmer.,0,0,26,0,0,0
  173. 1730 data in einem wald,21,32,4,31,0,0
  174. 1740 data in einem wald,31,32,32,33,0,0
  175. 1750 data in einem wald,0,0,32,0,0,0
  176. 1760 data in einem tal,0,35,33,0,0,0
  177. 1770 data vor einem felshindernis,34,0,0,0,0,0
  178. 1780 data auf einer riesiegen wiese,37,36,35,36,0,0
  179. 1790 data auf einer riesiegen wiese,31,41,37,37,0,0
  180. 1800 data auf einem schmalen pfad,0,0,0,0,38,34
  181. 1810 data in einer schummrigen hoehle,0,0,34,0,40,0
  182. 1820 data in einer schummrigen hoehle,8,0,0,0,0,39
  183. 1830 data auf einer riesigen wiese,41,41,37,42,0,0
  184. 1840 data auf einer riesigen wiese,41,41,37,43,0,0
  185. 1850 data an einem tuempel,44,37,0,0,0,0
  186. 1860 data immer noch am tuempel,43,45,0,0,0,0
  187. 1870 data an der mulde,0,0,44,0,0,0
  188. 1880 data in der mulde,0,0,45,47,0,0
  189. 1890 data am ausgang der mulde,0,0,48,37,0,0
  190. 1900 data in der ruine,0,0,46,49,0,0
  191. 1910 data in einem dunklen raum,0,0,48,49,0,0
  192. 1920 data im untergeschoss,0,0,0,0,48,0
  193. 1930 rem *********** mitteilungen *
  194. 1940 ms$(1)="ich sehe nichts besonderes."
  195. 1950 ms$(2)="so stark bin ich nicht."
  196. 1960 ms$(3)="warum? "
  197. 1970 ms$(4)="womit? "
  198. 1980 ms$(5)="was soll ich mit dem schutt."
  199. 1990 ms$(6)="unter dem felsen ist eine treppe."
  200. 2000 ms$(7)="hier hat wohl ein picknick"
  201. 2010 ms$(8)="stattgefunden."
  202. 2020 ms$(9)="wenn du meinst."
  203. 2030 ms$(10)="erst muss ich ihn betreten."
  204. 2040 ms$(11)="wie denn?"
  205. 2050 ms$(12)="es ist verschlossen."
  206. 2060 ms$(13)="da ist ein tor."
  207. 2070 ms$(14)="es ist daemmrig."
  208. 2080 ms$(15)="in der kiste war ein zeitzuender."
  209. 2090 ms$(16)="ich bin tod!"
  210. 2100 ms$(17)="sie ist mit einer kette gesichert."
  211. 2110 ms$(18)="da ist ja ein schluessel."
  212. 2120 ms$(19)="ich bin in die falltuer gestuerzt!"
  213. 2130 ms$(20)="ich bin in den fluss gefallen!"
  214. 2140 ms$(21)="sie sieht sehr stabiel aus."
  215. 2150 ms$(22)="er ist sehr stumpf."
  216. 2160 ms$(23)="                                       "
  217. 2170 ms$(24)="dahinter war eine truhe versteckt."
  218. 2180 ms$(25)="ich wuerde erst einmal untersuchen"
  219. 2190 ms$(26)="welches werkzeug zu gebrauchen ist."
  220. 2200 ms$(27)="der weg ins wunderland ist offen."
  221. 2210 ms$(28)="ein rad ist zerbrochen."
  222. 2220 ms$(29)="im gepaeckfach liegt ein ring."
  223. 2230 ms$(30)="hilfe - es ist ein zauberring."
  224. 2240 ms$(31)="ich muss jetzt unbedingt etwas essen."
  225. 2250 ms$(32)="ich bin verhungert!"
  226. 2260 ms$(33)="der geist des getoeteten spukt noch her-um. er hat mich getoetet."
  227. 2270 ms$(34)="haette ich doch den guertel benutzt. derdrachen hat mich getoetet."
  228. 2280 ms$(35)="hier wohnen trolle."
  229. 2290 ms$(36)="sie haben mir die glocke gestohlen."
  230. 2300 ms$(37)="darauf steht:"
  231. 2310 ms$(38)="fuer dein glueck,"
  232. 2320 ms$(39)="hole dir die glocke zurueck."
  233. 2330 ms$(40)="der guertel verleiht mir riesenkraefte. "
  234. 2340 ms$(41)="ich besiege den drachen."
  235. 2350 ms$(42)="haette ich doch den guertel bei mir.der drachen hat mich getoetet."
  236. 2360 ms$(43)="der riese freut sich,laesst mich durch."
  237. 2370 ms$(44)="mit zauber haette ich kaempfen sollen."
  238. 2380 ms$(45)="das schwert erschlaegt die schlangen."
  239. 2390 ms$(46)="die kerze brennt."
  240. 2400 ms$(47)="mehr kann ich nicht tragen."
  241. 2410 ms$(48)="ich bin doch kein packesel!"
  242. 2420 ms$(49)="der geist bringt mich fort."
  243. 2430 printchr$(147)
  244. 2440 printchr$(18)"               wunderland               "chr$(146)
  245. 2450 print"in einem alten buch lasen sie einmal von";
  246. 2460 print"der existenz von wunderland. in wunder-"
  247. 2470 print"land soll es eine geldboerse geben die"
  248. 2480 print"nie leer wird und eine blume die ewige"
  249. 2490 print"gesundheit verleiht. um diese gegen-"
  250. 2500 print"staende zu finden bedarf es der        "
  251. 2510 print"mithilfe eines trolles."
  252. 2520 print
  253. 2530 print"trolle sind kleine wichte die in       "
  254. 2540 print"wunderland leben und ab und zu einmal  "
  255. 2550 print"zu uns herueberkommen. meistens        "
  256. 2560 print"zu leuten die bereits von wunderland   "
  257. 2570 print"wissen. so erscheint auch einmal ein   "
  258. 2580 print"troll bei ihnen und will ihnen helfen. "
  259. 2590 rem ********* daten einlesen *
  260. 2600 fora=1toav
  261. 2610 readve$(a):vv$(a)=left$(ve$(a),wl)
  262. 2620 nexta
  263. 2630 fora=1toao
  264. 2640 readob$(a),rn$(a),ob(a):rn$(a)=left$(rn$(a),wl)
  265. 2650 nexta
  266. 2660 forx=1toar
  267. 2670 readra$(x)
  268. 2680 fory=1to6
  269. 2690 readdu(x,y)
  270. 2700 nexty
  271. 2710 nextx
  272. 2720 data norden, sueden, westen, osten,oben, unten
  273. 2730 fora=1to6
  274. 2740 readri$(a)
  275. 2750 nexta
  276. 2760 printchr$(18);:printchr$(144)spc(9)"...weiter mit spaces...":printchr$(146)
  277. 2770 getz$:ifz$=""then2770
  278. 2780 ifz$<>chr$(32)then2770
  279. 2790 printchr$(147):printchr$(158)
  280. 2800 print"trolle verstehen nur einfache befehle"
  281. 2810 print"wie 'nimm messer' oder 'lege flasche'."
  282. 2820 print"ausserdem kann man mit dem befehl 'vok'"
  283. 2830 print"fragen welche verben er versteht."
  284. 2840 print"mit 'save' kann man den spielstand spei-";
  285. 2850 print"chern und mit 'load' wieder laden."
  286. 2860 print"mit 'end' kann man das spiel vorzeitig"
  287. 2870 print"beenden."
  288. 2880 print"auf help gibt er nicht immer hilfreiche"
  289. 2890 print"antworten."
  290. 2900 print"mit 'inv' erzaehlt der troll was er"
  291. 2910 print"bei sich hat."
  292. 2920 print
  293. 2930 print"wenn sie wunderland erreicht haben,"
  294. 2940 print"duerfen sie sich nicht wundern,"
  295. 2950 print"wenn sie manchmal nicht dahinkommen"
  296. 2960 print"wo sie hin wollen. dann hat naemlich"
  297. 2970 print"ein troll ihnen einen schabernack"
  298. 2980 print"gespielt und sie irgendwohin gezaubert."
  299. 2990 printchr$(18);:printchr$(144)spc(9)"...weiter mit spaces...":printchr$(146)
  300. 3000 getz$:ifz$=""then3000
  301. 3010 ifz$<>chr$(32)then3000
  302. 3020 printchr$(147):poke53280,6:poke53281,6:printchr$(5)
  303. 3030 printchr$(158):z=z+1
  304. 3040 poke211,0:poke214,0:sys58732
  305. 3050 forze=1to10
  306. 3060 printms$(23)
  307. 3070 nextze
  308. 3080 poke211,0:poke214,0:sys58732
  309. 3090 print"ich bin ";
  310. 3100 printra$(sp)
  311. 3110 print"ich sehe ";
  312. 3120 fora=1toao
  313. 3130 ifob(a)<>spthen3160
  314. 3140 ifpos(0)+len(ob$(a))+2<39thenprintob$(a);", ";:fl(1)=-1:goto3160
  315. 3150 ifpos(0)+len(ob$(a))+2>39thenprint:goto3140
  316. 3160 nexta
  317. 3170 printchr$(157);:printchr$(157)"."
  318. 3180 printms$(23)
  319. 3190 printchr$(154)"ich kann nach ";
  320. 3200 forx=1to6
  321. 3210 ifdu(sp,x)=0then3260
  322. 3220 ifpos(0)=14thenprintri$(x);:goto3260
  323. 3230 ifpos(0)+len(ri$(x))<37thenprint", ";ri$(x);:goto3260
  324. 3240 ifpos(0)+len(ri$(x))>=37thenprint",":printri$(x);:goto3260
  325. 3250 ifpos(0)<16andpos(0)>2thenprint", ";ri$(x);:goto3260
  326. 3260 nextx
  327. 3270 print"."
  328. 3280 forx=1to39:printchr$(5);chr$(166);:nextx
  329. 3290 poke211,0:poke214,24:sys58732:printchr$(144);:input"was soll ich tun";ei$
  330. 3300 iffl(2)=0thenprint"ach du schreck!!!":forx=1to1000:nextx:goto4410
  331. 3310 iflen(ei$)>2then3430
  332. 3320 ifob(32)<>-2andsp=20thenprint"ohne essen gehe ich nicht weiter!":goto3030
  333. 3340 ifei$="n"anddu(sp,1)<>0thensp=du(sp,1):print"o.k.":goto3030
  334. 3350 ifei$="s"anddu(sp,2)<>0thensp=du(sp,2):print"o.k.":goto3030
  335. 3360 ifei$="w"anddu(sp,3)<>0thensp=du(sp,3):print"o.k.":goto3030
  336. 3370 ifei$="o"anddu(sp,4)<>0thensp=du(sp,4):print"o.k.":goto3030
  337. 3380 ifei$="ob"anddu(sp,5)<>0thensp=du(sp,5):print"o.k.":goto3030
  338. 3390 ifei$="u"anddu(sp,6)<>0thensp=du(sp,6):print"o.k.":goto3030
  339. 3400 ifob(32)<>-2andsp=20thenprint"ohne essen gehe ich nicht weiter!":goto3030
  340. 3420 print"dahin fuehrt kein weg!":goto3030
  341. 3430 ifleft$(ei$,3)<>"inv"then3490
  342. 3440 print"ich habe folgende gegenstaende bei mir:"
  343. 3450 forx=1toao
  344. 3460 ifob(x)=-1thenprintob$(x)
  345. 3470 nextx
  346. 3480 goto3030
  347. 3490 ifleft$(ei$,4)<>"save"then3730
  348. 3500 printchr$(147)spc(10)"spielstand speichern":printchr$(17):printchr$(17)
  349. 3510 input"welcher spieler";ei$
  350. 3520 iflen(ei$)>16then3500
  351. 3530 print"das spiel von ";ei$;" wird gespeichert."
  352. 3540 open2,8,2,"@:"+ei$+",s,w"
  353. 3550 print#2,sp
  354. 3560 print#2,z
  355. 3570 forx=1toao
  356. 3580 print#2,ob(x)
  357. 3590 nextx
  358. 3600 print"* ";
  359. 3610 forx=1toar
  360. 3620 fory=1to6
  361. 3630 print#2,du(x,y)
  362. 3640 nexty
  363. 3650 nextx
  364. 3660 print"* ";
  365. 3670 forx=1toaf
  366. 3680 print#2,fl(x)
  367. 3690 nextx
  368. 3700 print"* ";
  369. 3710 close2
  370. 3720 goto3030
  371. 3730 if left$(ei$,4)<>"load" then 3980
  372. 3740 printchr$(147)spc(10)"altes spiel laden":printchr$(17):printchr$(17)
  373. 3750 input"welchen spieler laden";ei$
  374. 3760 if len(ei$)>16 then3740
  375. 3770 printchr$(17):printchr$(17)
  376. 3780 print"spiel von ";ei$;" wird geladen."
  377. 3790 open 2,8,2,ei$+",s,r"
  378. 3800 input#2,sp
  379. 3810 print"* ";
  380. 3820 input#2,z
  381. 3830 forx=1toao
  382. 3840 input#2,ob(x)
  383. 3850 nextx
  384. 3860 print"* ";
  385. 3870 forx=1toar
  386. 3880 fory=1to6
  387. 3890 input#2,du(x,y)
  388. 3900 nexty
  389. 3910 nextx
  390. 3920 print"* ";
  391. 3930 forx=1toaf
  392. 3940 input#2,fl(x)
  393. 3950 print"* "
  394. 3960 close2
  395. 3970 printchr$(147):goto3030
  396. 3980 ifleft$(ei$,3)<>"vok"then4080
  397. 3990 printchr$(147):printchr$(158)"ich verstehe folgende verben:"
  398. 4000 printchr$(17):printchr$(17)
  399. 4010 forx=1toav
  400. 4020 printve$(x)
  401. 4030 nextx
  402. 4040 printspc(19)"weiter '*' druecken"
  403. 4050 getei$:ifei$=""then4050
  404. 4060 ifei$="*"thenprintchr$(147):goto3030
  405. 4070 ifei$<>"*"then4050
  406. 4080 if left$(ei$,3)<>"end"then 4110
  407. 4090 printchr$(147)"schade das sie nicht zuende spielen"
  408. 4100 print:print"koennen.":end
  409. 4110 if left$(ei$,4)<>"help" then goto 4170
  410. 4120 ifsp=20andob(32)<>-2thenprint"ein guetiger troll zeigt das essen.":sp=5:goto3030
  411. 4140 print"sie moechten wohl, dass ich ihnen      "
  412. 4150 print"jetzt helfe. ha! ha! haaaa!"
  413. 4160 goto3030
  414. 4170 ln=len(ei$)
  415. 4180 el=ln+1:fornn=1toln
  416. 4190 test$=mid$(ei$,nn,1)
  417. 4200 iftest$=" "thenel=nn:nn=ln
  418. 4205 next
  419. 4210 ev$=left$(ei$,wl)
  420. 4220 rl=ln-el
  421. 4230 ifrl<0then4260
  422. 4240 eo$=right$(ei$,rl)
  423. 4250 eo$=left$(eo$,wl)
  424. 4260 vn=0:fornn=1toav
  425. 4270 ifev$=vv$(nn)thenvn=nn:nn=av
  426. 4280 next
  427. 4290 ifvn=0thenprint"das verb kenne ich nicht!":goto3030
  428. 4300 n=0:fornn=1toao
  429. 4310 ifeo$=rn$(nn)thenn=nn:nn=ao
  430. 4320 next
  431. 4330 ifn=0thenprint"das objekt kenne ich nicht!":goto3030
  432. 4340 onvngoto4560,4350,6800,6900,7150,7350,7700,7790,7840
  433. 4350 an=0
  434. 4360 nn=0:forx=1toao
  435. 4370 ifob(x)=-1thenan=an+1
  436. 4380 ifan=4thenx=ao:nn=1
  437. 4390 nextx
  438. 4395 ifnn=1thenprintms$(47):printms$(48):goto3030
  439. 4400 goto5790
  440. 4410 printchr$(147)
  441. 4420 print:print:printms$(16):print:printms$(0)
  442. 4430 print:print"noch einmal";:inputei$
  443. 4440 ifei$="n"thenend
  444. 4450 ifei$="j"thenrun
  445. 4460 goto4410
  446. 4470 printchr$(147)
  447. 4480 print:print"sie wachen auf und stellen fest"
  448. 4490 print:print"das sie dieses abenteur nur"
  449. 4500 print:print"getraeumt haben. so einen"
  450. 4510 print:print"geldbeutel und die wunder-"
  451. 4520 print:print"blume gibt es gar nicht."
  452. 4530 print:print"trotzdem haben sie sich gut"
  453. 4540 print:print"geschlagen. herzlichen gluckwuensche!"
  454. 4550 end
  455. 4560 rem ************ untersuchen *
  456. 4570 ifn=1andsp=1thenprintms$(1):goto3030
  457. 4580 ifn=2andob(3)=0andsp=2thenprintms$(6):ob(3)=sp:du(2,6)=7:goto3030
  458. 4590 ifn=3andob(3)=2andsp=2thenprint"sie ist sehr steil.":goto3030
  459. 4600 ifn=29andsp=3thenprintms$(7):printms$(8):ob(4)=3:ob(5)=3:ob(6)=3:goto3030
  460. 4610 ifn=4andob(n)=spthenprint"sie sind sehr rostig.":goto3030
  461. 4620 ifn=5andob(n)=spthenprint"er sieht noch brauchbar aus.":goto3030
  462. 4630 ifn=6andob(n)=spthenprint"kein umweltbewusstsein haben die leute.":goto3030
  463. 4650 ifn=9andsp=5thenprint"o.k. ":ob(10)=sp:goto3030
  464. 4660 ifn=10andsp=5thenprintms$(3):goto3030
  465. 4670 ifn=11andsp=6thenprint"o.k. - ich sehe ein tor.":ob(12)=sp:goto3030
  466. 4680 ifob(12)=spandn=12anddu(6,3)=16thenprintms$(27):goto3030
  467. 4690 ifob(12)=0andsp=6thenprint"erst muss ich doch die mauer untersuch.":goto3030
  468. 4710 if n=13andsp=8thenprint"in der ecke steht eine kiste.":ob(14)=sp:goto3030
  469. 4720 ifn=14andsp=8thenfl(2)=0:ob(15)=sp:ms$(0)=ms$(15):print"o.k.":goto3030
  470. 4730 ifn=16andsp=9thenprint"hinter dem brett ist eine eisentruhe.":ob(17)=9:goto3030
  471. 4750 ifn=17andob(n)=spandfl(3)=-1thenprintms$(17):goto3030
  472. 4760 ifn=17andob(n)=spandfl(3)=0thenprintms$(18):ob(18)=9:goto3030
  473. 4770 ifn=18andob(n)=spthenprint"der ist auch nicht aus gold.":goto3030
  474. 4780 if n=19andfl(4)=-1 andsp=10thenms$(0)=ms$(19):goto4410
  475. 4790 ifn=19andfl(4)=0andsp=10thenprint"ich habe das brett gut darueber gelegt.":goto3030
  476. 4810 ifn=20andsp=11thenprint"o.k.":ob(28)=11:goto3030
  477. 4820 ifn=28andob(28)=11thenprint"ich glaube, er will mich fressen.":goto3030
  478. 4830 ifn=21andsp=12thenms$(0)=ms$(20):goto4410
  479. 4840 ifn=22andsp=13thenprint"o.k.":ob(23)=13:ob(24)=13:ob(25)=13:ob(22)=0:goto3030
  480. 4860 ifn=23andsp=13thenprint"o.k. - ";ms$(1):goto3030
  481. 4870 ifn=24andsp=13thenprint"o.k. - ";ms$(21):goto3030
  482. 4880 ifn=25andsp=13thenprint"o.k. - ";ms$(22):goto3030
  483. 4890 ifn=33andsp=16thenprint"sie ist unendlich.":goto3030
  484. 4900 ifn=34andsp=16thenprint"er ist fast undurchdringlich.":goto3030
  485. 4910 ifn=35andsp=16thenprint"sind die berge hoch!":goto3030
  486. 4920 ifn=36andsp=17thenprint"sie ist aus holz,die tuer ist offen.":goto3030
  487. 4930 ifn=37andob(37)=17andsp=17thenprint"darauf liegt ein messer.":ob(38)=17:goto3030
  488. 4950 ifn=38andob(38)=17thenprint"es ist sehr scharf.":goto3030
  489. 4960 ifn=39andsp=18thenprintms$(28):printms$(29):ob(40)=18:ob(41)=18:goto3030
  490. 4970 ifn=40andob(40)=18andsp=18thenprint"es ist nicht mehr zu reparieren.":goto3030
  491. 4990 ifn=41andob(41)=sp thenprintms$(30):ob(41)=-1:sp=19:goto3030
  492. 5000 ifn=42andob(42)=19thenprint"er faellt durch ein holztor.":ob(43)=19:goto3030
  493. 5020 ifn=43andob(43)=spandfl(6)=-1thenprint"ich brauche hammer und meissel.":goto3030
  494. 5040 ifn=43andob(43)=spandfl(6)=0thenprint"es ist offen.":du(19,2)=20:goto3030
  495. 5050 ifn=45andsp=20thenprintms$(31):ob(46)=20:ob(47)=20:goto3030
  496. 5060 if(n=46orn=47)andob(46)=20andob(47)=20andfl(7)=-1thenms$(0)=ms$(32):goto4410
  497. 5080 if(n=46orn=47)andob(46)=20andob(47)=20andfl(7)=0thenprint"das wasser ist gut.":goto3030
  498. 5100 ifn=48andob(48)=21andsp=21thenprint"er scheint fliegen zu koennen.":goto3030
  499. 5120 ifn=49andsp=22thenprint"die zugbruecke ist heruntergelassen.":goto3030
  500. 5130 ifn=51andsp=24thenprint"sind die dreckig!":ob(52)=24:goto3030
  501. 5140 ifn=53andsp=24thenprint"die sind lange nicht benutzt worden.":goto3030
  502. 5150 ifn=52andsp=24andob(52)=24thenprint"davor ekele ich mich!":goto3030
  503. 5160 ifn=54andsp=25thenprint"ohh - eine alte lampe!":ob(55)=25:goto3030
  504. 5170 ifn=55andsp=25andob(55)=25thenprint"sie sieht wie aladins lampe aus.":goto3030
  505. 5190 ifn=56andsp=26thenprint"puh - liegt da dreck.":goto3030
  506. 5200 ifn=57andsp=26thenprint"sehr vertrauenerweckend sieht die nicht":print"aus.":goto3030
  507. 5220 ifn=58andsp=26thenprint"die ist auch sehr klapprig.":goto3030
  508. 5230 ifn=59andsp=27thenprint"es sieht sehr zerbrechlich aus.":goto3030
  509. 5240 ifn=60andsp=27thenprint"sie klingt sehr hell.":goto3030
  510. 5250 ifn=61andsp=28thenprint"eine tuer ist doch offen.":du(28,2)=29:goto3030
  511. 5260 ifn=63andsp=29thenprint"o. k.":ob(62)=29:ob(68)=29:goto3030
  512. 5270 ifn=62andob(62)=29andsp=29thenms$(0)=ms$(33):goto4410
  513. 5280 ifn=68andob(68)=29andsp=29thenprint"er hat zauberkraefte.":goto3030
  514. 5290 ifn=64andsp=30thenprint"o. k.":ob(67)=30:goto3030
  515. 5300 ifn=65andsp=30thenprint"ihhhgitt - eine spinne!":ob(66)=30:goto3030
  516. 5310 ifn=66andob(66)=30andsp=30 thenms$(0)="ich bin gebissen worden.":goto4410
  517. 5320 ifn=67andob(67)=30andsp=30 thenprint"das kann ich bestimmt gebrauchen.":goto3030
  518. 5340 ifn=69 thenprint"er rauscht.":goto3030
  519. 5350 ifn=71andsp=33thenprint"hilf mir - ein drachen!":ob(72)=33:goto3030
  520. 5360 ifn=72andob(72)=spthenms$(0)=ms$(34):goto4410
  521. 5370 ifn=73andsp=34thenprint"o.k.":ob(74)=34:ob(75)=34:du(34,4)=39:du(34,5)=38:goto3030
  522. 5390 ifn=74andsp=34andob(74)=34thenprint"scheint interressant zu sein.":goto3030
  523. 5410 ifn=75andsp=34andob(75)=34thenprint"von oben habe ich einen weiten ausblick.":goto3030
  524. 5430 ifn=76andsp=35thenprint"die welt scheint zuende zu sein.":goto3030
  525. 5440 ifn=78andsp=35andob(78)=35thenprint"er moechte zauberpulver.":goto3030
  526. 5450 ifn=79andsp=35andob(79)=35thenprint"darin wohnt der riese.":goto3030
  527. 5460 ifn=77andsp=35thenprint"die welt scheint zuende zu sein.":goto3030
  528. 5470 ifn=81andsp=36thenprintms$(1):goto3030
  529. 5480 ifn=82andsp=36thenprint"es ist ein hexenhaus.":ob(113)=36:goto3030
  530. 5490 ifn=83andob(83)=spthenprint"darauf liegt ein zettel.":ob(84)=36:goto3030
  531. 5500 ifn=84andob(84)=spthenprint"ich sehe einen zauberspruch.":ob(85)=36:goto3030
  532. 5520 ifn=85andob(85)=spthenprint"den kann ich bestimmt noch brauchen.":goto3030
  533. 5530 ifn=88andsp=38thenms$(0)="ich bin abgestuerzt.":goto4410
  534. 5540 ifn=89andsp=39andob(60)=-1thenprintms$(35):printms$(36):ob(60)=12:goto3030
  535. 5550 ifn=90andsp=40thenprintms$(37):printms$(38):printms$(39):fl(2)=-1:goto3030
  536. 5560 ifn=99andsp=40thenprint"es ist ein spaten.":ob(98)=40:ob(99)=0:goto3030
  537. 5570 ifn=96andsp=43thenprint"hier ist etwas vergraben worden.":goto3030
  538. 5580 ifn=97andsp=43andob(97)=43thenprint"zum kaempfen geeignet.":goto3030
  539. 5590 ifn=101andsp=45thenms$(0)="ich bin gebissen worden.":goto4410
  540. 5600 ifn=103andsp=47thenprint"ganz schoen zerfallen.":goto3030
  541. 5610 ifn=104andsp=48thenprint"hier ist eine leiter.":ob(105)=48:du(48,6)=50:goto3030
  542. 5630 ifn=106andsp=49thenprint"ich kann nichts sehen.":goto3030
  543. 5640 ifn=107andsp=49andob(107)=49thenprint"sie wird nie leer.":goto3030
  544. 5650 ifn=108andsp=49andob(108)=49thenprint"sie gibt ewige gesundheit.":goto3030
  545. 5660 ifn=109andsp=50thenprint"es erwacht und will mich toeten.":goto3030
  546. 5670 ifn=110andob(110)=50andsp=50thenprint"die kann ich gebrauchen.":goto3030
  547. 5680 ifn=111andob(111)=50andsp=50thenprint"es ist voll funktionstuechtig.":goto3030
  548. 5700 ifn=112andob(112)=spthenprint"da liegen ja sachen.":ob(110)=50:ob(111)=50:goto3030
  549. 5720 ifn=48andsp=22andob(48)=22thenprint"mit dem bist du doch gekommen.":goto3030
  550. 5740 ifn=2andob(3)=2andsp=2thenprint"ausser der treppe sehe ich nichts.":goto3030
  551. 5760 if ob(12)=spandn=12thenprint"es ist verschlossen.":goto3030
  552. 5770 ifob(n)<>spandob(n)<>-1thenprint"so etwas sehe ich hier nicht.":goto3030
  553. 5780 printms$(1):goto3030
  554. 5790 rem ******************* nimm *
  555. 5800 if n=1 andsp=1 then printms$(2):goto3030
  556. 5810 if n=2 andsp=2 thenprintms$(3);ms$(2):goto3030
  557. 5820 if n=4 andob(4)=spthenprint"o.k.":ob(4)=-1:goto3030
  558. 5830 if n=5 andob(5)=spthenprint"o.k.":ob(5)=-1:goto3030
  559. 5840 if n=6 andob(6)=spthenprint"o.k.":ob(6)=-1:goto3030
  560. 5850 ifn=1andsp=4 thenprintms$(2):goto3030
  561. 5860 ifn=10andsp=5andob(10)=sp thenprintms$(4):goto3030
  562. 5870 ifn=11andsp=6thenprint"wie soll ich eine mauer nehmen?":goto3030
  563. 5880 ifn=12andsp=6andob(12)=6thenprint"ich soll ein tor nehmen? ha! ha! ha!":goto3030
  564. 5900 if n=17andsp=9andob(17)=0thenprint"ich sehe nur ein brett.":goto3030
  565. 5910 ifn=16andsp=9andob(17)=0thenprintms$(24):ob(17)=sp:ob(16)=-1:goto3030
  566. 5920 ifn=17andob(17)=spthenprint"geht nicht!":printms$(17):goto3030
  567. 5930 ifn=19andsp=10andfl(4)=-1thenms$(0)=ms$(19):goto4410
  568. 5940 ifn=20andsp=11thenprint"als andenken ganz schoen.":ob(20)=-1:ob(31)=11:goto3030
  569. 5960 ifn=28andob(28)=11thenprint"das traue ich mir nicht zu.":goto3030
  570. 5970 ifn=21andsp=12thenms$(0)=ms$(20):goto4410
  571. 5980 ifn=22andsp=13thenprintms$(25):printms$(26):goto3030
  572. 5990 ifn=23andob(23)=spthenprint"o. k.":ob(23)=-1:goto3030
  573. 6000 ifn=24andob(24)=spthenprint"o. k.":ob(24)=-1:goto3030
  574. 6010 ifn=25andob(25)=spthenprint"o. k.":ob(25)=-1:goto3030
  575. 6020 ifn=16andsp=9andob(17)=spthenprint"o.k.":ob(16)=-1:goto3030
  576. 6030 ifn=3andob(3)=spthenprintms$(2):goto3030
  577. 6040 ifn=29andob(29)=spthenprint"so etwas habe ich noch nie gehoert.":goto3030
  578. 6050 ifn=9andob(9)=spthenprint"so einen grossen topf gibt es nicht!":goto3030
  579. 6060 ifn=13andob(13)=spthenprint"es wird ja immer verrueckter!":goto3030
  580. 6070 ifn=19andob(19)=spandfl(4)=0thenms$(0)=ms$(19):goto4410
  581. 6080 ifn=21andob(21)=spthenms$(0)=ms$(20):goto4410
  582. 6090 ifn=18andob(18)=9andsp=9thenprint"o.k.":fl(5)=0:ob(18)=-1:goto3030
  583. 6100 ifn=37andob(37)=17andsp=17thenprintms$(3):goto3030
  584. 6110 ifn=38andob(38)=17andsp=17thenprint"o.k.":ob(38)=-1:goto3030
  585. 6120 ifn=39andsp=18thenprint"viel lieber lasse ich mich ziehen.":goto3030
  586. 6130 ifn=40andob(40)=18andsp=18thenprintms$(3):goto3030
  587. 6140 ifn=43andob(43)=19andsp=19thenprint"es ist fest verankert.":goto3030
  588. 6150 ifn=42andsp=19thenprint"ich bin doch kein schildbuerger.":goto3030
  589. 6160 if(n=46orn=47)andob(46)=20andob(47)=20andfl(7)=-1thenms$(0)=ms$(32):goto4410
  590. 6180 if(n=46orn=47)andob(46)=20andob(47)=20andfl(7)=0thenprint"das wasser ist gut.":goto3030
  591. 6200 ifn=48andsp=21thenprint"das geht nicht.":goto3030
  592. 6210 ifn=51andsp=24thenprint"o. k.":ob(51)=-1:ob(52)=0:goto3030
  593. 6220 ifn=52andob(52)=24andsp=24thenprint"o. k.":ob(52)=-1:goto3030
  594. 6230 ifn=53andob(53)=24andsp=24thenprint"o.k.":ob(53)=-1:ob(114)=24:goto3030
  595. 6240 ifn=54andsp=25thenprint"warum soll ich denn den schleppen?":goto3030
  596. 6250 ifn=55andob(55)=spthenprintms$(49):ob(55)=-1:sp=1:ob(48)=21:goto3030
  597. 6260 ifn=59andsp=27thenprint"o. k.":ob(59)=-1:goto3030
  598. 6270 ifn=60andsp=27thenprint"o. k.":ob(60)=-1:goto3030
  599. 6280 ifn=62andob(62)=29andsp=29thenms$(0)=ms$(33):goto4410
  600. 6290 ifn=68andob(68)=29andsp=29thenprint"das ist auch in ordnung.":ob(68)=-1:goto3030
  601. 6310 ifn=64andob(64)=30andsp=30thenprint"o.k.":ob(64)=-1:ob(67)=-1:goto3030
  602. 6320 ifn=65andsp=30thenprintms$(9):ob(65)=-1:goto3030
  603. 6330 ifn=67andob(67)=30andsp=30thenprint"o.k.":ob(64)=-1:ob(67)=-1:goto3030
  604. 6340 ifn=66andob(66)=30andsp=30thenms$(0)="sie hat mich gebissen.":goto4410
  605. 6350 if n=33andsp=16 thenprint"das mache mir mal vor.":goto3030
  606. 6360 ifn=34andsp=16thenprint"unmoeglich!":goto3030
  607. 6370 ifn=35andsp=16thenprintms$(11):goto3030
  608. 6380 ifn=41andob(41)=18andsp=18thenprintms$(30):sp=19:ob(41)=-1:goto3030
  609. 6390 ifn=49andsp=22thenprintms$(11):goto3030
  610. 6400 ifn=56andsp=26thenprint"soll wohl ein witz sein?":goto3030
  611. 6410 ifn=57andsp=26thenprint"das schaffe noch nicht einmal ich.":goto3030
  612. 6420 ifn=58andsp=26thenprint"die faellt dann ja auseinander.":goto3030
  613. 6430 ifn=61andsp=28thenprint"es sind zuviele.":goto3030
  614. 6440 ifn=63andsp=29thenprintms$(5):goto3030
  615. 6450 ifn=36andsp=17thenprintms$(11):goto3030
  616. 6460 ifn=69thenprint"wie soll ich den transportieren?":goto3030
  617. 6470 ifn=71andsp=33thenprint"noch ein witz":goto3030
  618. 6480 ifn=72andsp=33thenms$(0)="der drache hat mich getoetet.":goto4410
  619. 6490 ifn=73andsp=34thenprint"was du alles verlangst.":goto3030
  620. 6500 ifn=74andsp=34andob(74)=34thenprintms$(3):goto3030
  621. 6510 ifn=75andsp=34andob(75)=34thenprintms$(2):goto3030
  622. 6520 ifn=78andsp=35andob(78)=35thenprint"das halte ich fuer nicht gut.":goto3030
  623. 6540 ifn=79andsp=35andob(79)=35thenprintms$(2):goto3030
  624. 6550 ifn=82andsp=36thenprint"da wird die hexe aber boese.":goto3030
  625. 6560 ifn=88andsp=38thenprintms$(11):goto3030
  626. 6570 ifn=89andsp=39thenms$(0)="die trolle haben mich verzaubert.":goto4410
  627. 6580 ifn=90andsp=40thenprint"lies lieber die tafel.":goto3030
  628. 6590 ifn=96andsp=43thenprint"grabe lieber.":goto3030
  629. 6600 ifn=99andsp=40thenprint"ich weiss nicht was du meinst.":goto3030
  630. 6610 ifn=100andsp=44thenprint"darauf gebe ich keine antwort.":goto3030
  631. 6620 ifn=101andsp=45thenms$(0)="sie haben mich gebissen.":goto4410
  632. 6630 ifn=103andsp=47thenprintms$(5):goto3030
  633. 6640 ifn=104andsp=48thenprintms$(5):goto3030
  634. 6650 ifn=105andsp=48andob(105)=48thenprint"o.k.":ob(105)=-1:du(48,6)=0:goto3030
  635. 6660 ifn=107andsp=49andob(107)=49andob(108)=-1then4470
  636. 6670 ifn=108andsp=49andob(108)=49andob(107)=-1then4470
  637. 6680 ifn=109andsp=50thenms$(0)="der waechter hat mich getoetet.":goto4410
  638. 6690 ifn=112andsp=50andob(112)=50thenprint"der ist jetzt wertlos.":goto3030
  639. 6700 ifn=76andsp=35thenprint"ich fuehle mich auf den arm genommen.":goto3030
  640. 6710 ifn=77andsp=35thenprintms$(2):goto3030
  641. 6720 ifn=14andob(14)=8andsp=8thenprint"ach du schreck!":ms$(0)=ms$(15):goto4410
  642. 6730 ifn=44andob(44)=spthenprint"soll ich sie aufrollen?":goto3030
  643. 6740 ifn=45andob(45)=spthenprint"gib mir lieber was zu essen.":goto3030
  644. 6750 ifn=84andob(84)=spandob(85)=spthenprint"o.k.":ob(84)=0:ob(85)=-1:goto3030
  645. 6760 ifn=85andob(85)=spandob(84)=spthenprint"o.k.":ob(84)=0:ob(85)=-1:goto3030
  646. 6770 ifn=106andob(106)=49andsp=49thenprint"wie denn?":goto3030
  647. 6780 ifob(n)=spthenprint"o.k.":ob(n)=-1:goto3030
  648. 6790 print"so etwas sehe ich hier nicht.":goto3030
  649. 6800 rem ******************* lege *
  650. 6810 if ob(n)<>-1thenprint"so etwas habe ich nicht.":goto3030
  651. 6820 ifn=16andob(16)=-1andsp=10thenprint"o.k.":ob(16)=10:fl(4)=0:du(10,4)=12:goto3030
  652. 6840 ifn=5andob(28)=spthenprint"ich wuerde lieber laufen.":ob(n)=sp:goto3030
  653. 6850 ifn=105andsp=48andob(105)=-1thenprint"o.k.":ob(105)=48:du(48,6)=50:goto3030
  654. 6870 ifn=67andsp=35andob(67)=-1andob(78)=35thenprintms$(43):du(35,2)=36:goto3030
  655. 6890 ob(n)=sp:print"o.k.":goto3030
  656. 6900 rem **************** oeffnen *
  657. 6910 ifn=12andob(12)=spanddu(6,3)=16thenprint"das tor ist bereits offen.":goto3030
  658. 6930 ifn=12andob(12)=spandob(18)=-1andfl(5)=0thenprintms$(27):du(6,3)=16:goto3030
  659. 6950 ifn=17andob(17)=spandfl(3)=-1thenprint"erst muss die kette weg.":goto3030
  660. 6960 ifn=19andob(19)=spthenms$(0)=ms$(19):goto4410
  661. 6970 ifn=4and(ob(4)=sporob(4)=-1)thenprint"sie ist schon lange geoeffnet.":goto3030
  662. 6990 ifn=6and(ob(6)=sporob(6)=-1)thenprint"sie ist leer.":goto3030
  663. 7000 ifn=17andob(17)=spandfl(3)=0thenprint"da liegt ja ein schluessel.":ob(18)=9:goto3030
  664. 7020 ifn=36andsp=17thenprint"die tuer ist schon offen.":goto3030
  665. 7030 ifn=39andsp=18thenprint"die tuer ist verklemmt.":goto3030
  666. 7040 ifn=43andob(43)=spandfl(6)=-1thenprint"dazu brauche ich hammer und meisel.":goto3030
  667. 7060 ifn=43andob(43)=spandfl(6)=0thenprint"o. k.":du(19,2)=20:goto3030
  668. 7070 ifn=49andsp=22thenprint"sie ist schon heruntergelassen.":goto3030
  669. 7080 ifn=61andsp=28thenprint"eine tuer ist doch offen.":du(28,2)=29:goto3030
  670. 7090 ifn=113andsp=36andob(113)=36thenprint"o.k.":ob(83)=sp:goto3030
  671. 7100 ifn=107andob(107)=spthenprint"darin ist sehr viel geld.":goto3030
  672. 7110 ifn=82andsp=36thenprint"was soll ich an der huette oeffnen?":goto3030
  673. 7120 ifn=12andob(12)=spandfl(5)=-1thenprint"ich brauche einen schluessel.":goto3030
  674. 7140 print"hier gibt es nichts zu oeffnen.":goto3030
  675. 7150 rem **************** betrete *
  676. 7160 ifn=16andob(16)=10andsp=10thenprint"o.k.":sp=12:goto3030
  677. 7170 ifn=36andsp=17thenprint"o.k. - da ist ein tisch.":ob(37)=17:goto3030
  678. 7180 ifn=48andsp=21thenprint"o. k.":ob(48)=22:sp=22:goto3030
  679. 7190 ifn=49andsp=22thenprint"o. k.":sp=23:goto3030
  680. 7200 ifn=58andsp=26thenprintms$(9):sp=28:goto3030
  681. 7210 ifn=57andsp=26thenprint"nur unter groessten bedenken.":sp=27:goto3030
  682. 7220 ifn=48andsp=22andob(48)=22thensp=31:ob(48)=21:goto3030
  683. 7230 ifn=71andsp=33andob(72)=33thenms$(0)="der drachen hat mich gefressen.":goto4410
  684. 7250 ifn=71andsp=33andob(72)=0thenprint"da ist ja ein drache.":ob(72)=33:goto3030
  685. 7270 ifn=74andsp=34andob(74)=34thenprint"was sehe ich denn da!":sp=39:goto3030
  686. 7280 ifn=79andsp=35andob(79)=35thenprint"der riese wird boese.":goto3030
  687. 7290 ifn=82andsp=36andob(113)=0thenprint"wie soll ich die huette betreten?":goto3030
  688. 7310 ifn=82andsp=36andob(113)=36thenprint"erst muss die tuer offen sein.":goto3030
  689. 7330 ifn=21andsp=12thenms$(0)="ich bin ertrunken.":goto4410
  690. 7340 print"warum soll ich dies betreten?":goto3030
  691. 7350 if n=24andob(24)=-1andsp=9thenprint"die kette ist weg.":fl(3)=0:goto3030
  692. 7360 if n=25andob(25)=-1andsp=9thenprint"der meissel ist zu stumpf.":goto3030
  693. 7370 ifn=4andob(4)=-1andsp=12thenms$(0)=ms$(20):goto4410
  694. 7380 ifn=6andob(6)=-1andsp=12thenms$(0)=ms$(20):goto4410
  695. 7390 ifn=16andob(16)=-1andsp=10thenprint"wie soll ich es benutzen?":goto3030
  696. 7400 ifn=23andob(23)=-1andsp=9thenprint"mit dem hammer schaffe ich es nicht.":goto3030
  697. 7420 ifn=4andob(4)=-1andsp=5thenprint"ihhh - die sind ja glitschig!":ob(32)=-1:goto3030
  698. 7440 ifn=38andsp=20thenprint"o. k.":goto3030
  699. 7450 ifn=39andsp18thenprint"ohne pferde?":goto3030
  700. 7460 ifn=23andsp=19andob(43)=19andob(23)=-1andob(25)=-1thenprint"o.k.":fl(6)=0:goto3030
  701. 7480 ifn=65andsp=30thenprint"ich bin aber gar nicht muede.":goto3030
  702. 7490 ifn=69andsp=31thenprint"ich will nicht baden.":goto3030
  703. 7500 ifn=68andob(68)=-1andob(72)=spthenprintms$(40):printms$(41):ob(72)=0:du(33,4)=34:goto3030
  704. 7520 ifn=68andob(68)<>-1andob(72)=spthenms$(0)=ms$(42):goto4410
  705. 7530 ifn=60andsp=35andob(60)=-1thenprint"sie klingt hell.":ob(78)=35:ob(79)=35:goto3030
  706. 7550 ifn=98andob(98)=-1andsp=43thenprint"ein schwert - gut zum kampf.":ob(97)=sp:goto3030
  707. 7570 ifn=97andob(97)=-1andsp=45thenms$(0)=ms$(44):goto4410
  708. 7580 ifn=85andsp=45andob(85)=-1thenprintms$(45):ob(101)=0:ob(115)=45:du(45,4)=46:goto3030
  709. 7600 ifn=97andob(97)=-1andsp=50thenprint"er ist tot.":ob(109)=0:ob(112)=50:goto3030
  710. 7620 ifn=111andob(111)=-1andsp=49thenprintms$(46):ob(106)=0:ob(107)=49:ob(108)=49:goto3030
  711. 7640 ifn=48andsp=21andob(48)=21thenprintms$(10):goto3030
  712. 7650 ifn=48andsp=22andob(48)=22thenprintms$(10):goto3030
  713. 7660 ifn=72andsp=33andob(72)=33thenms$(0)=ms$(34):goto4410
  714. 7670 ifn=60andob(60)=27andsp=27thenprint"sie klingt hell.":goto3030
  715. 7680 ifn=60andob(60)<>-1thenprint"die habe ich nicht bei mir.":goto3030
  716. 7690 print"warum soll ich das benutzen?":goto3030
  717. 7700 rem ****************** essen *
  718. 7710 ifn=32andsp=20andob(32)=-1thenprint"wurde auch zeit.":fl(7)=0:ob(32)=-2:goto3030
  719. 7730 ifn=5andob(5)=-1thenprint"schmeckt gut.":ob(5)=0:goto3030
  720. 7740 ifn=5andob(5)<>-1thenprint"ich habe keinen zucker bei mir.":goto3030
  721. 7750 ifn=32andsp<>20andob(32)=-1thenprint"ich habe noch keinen hunger.":goto3030
  722. 7770 ifn=32andob(32)<>-1thenprint"ich habe keine fische bei mir.":goto3030
  723. 7780 print"dies ist ja gar nichts zum essen":goto3030
  724. 7790 rem ****************** reibe *
  725. 7800 ifn=55andob(55)=spthengosub7870:goto3030
  726. 7810 if n=41and ob(41)=-1thenprint"der ist blank genug.":goto3030
  727. 7820 ifn=41andob(41)<>-1thenprint"den ring habe ich abgelegt.":goto3030
  728. 7830 print"ich habe keinen sauberkeitsfimmel.":goto3030
  729. 7840 ifn=41andob(41)=-1andsp=19thenprint"o.k.":sp=13:goto3030
  730. 7850 ifn=41andob(41)=-1andsp=35thenprint"wo bin ich denn jetzt.":sp=12:goto3030
  731. 7860 print"warum soll ich drehen?":goto3030
  732. 7870 printchr$(147):print"  der geist hat mich in einen tiefen"
  733. 7880 print"  schlaf versetzt. bitte warte"
  734. 7890 print"  bis ich aufwache."
  735. 7900 fora=1to20000:nexta
  736. 7910 return
  737. 7920 rem reise ins wunderland ===64
  738. 7930 rem 038911 bytes memory    ===
  739. 7940 rem  029680 bytes program   ===
  740. 7950 rem 000000 bytes variables ===
  741. 7960 rem 000000 bytes arrays    ===
  742. 7970 rem 000000 bytes strings   ===
  743. 7980 rem 009142 bytes free      ===
  744. 7990 rem ==========================
  745.