home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Commodore Disc 32
/
Commodore_Disc_32_19xx_-_de.d64
/
startmenue.c64
(
.txt
)
< prev
next >
Wrap
Commodore BASIC
|
2022-10-26
|
1KB
|
61 lines
10 rem startmenue.bas==========c64
20 rem (p) commodore disc team
30 rem ===========================
40 rem (c) by r. engelhardt v3.5
50 rem (v) alfons mittelmeyer v2.0
60 rem
70 rem basic v2.0
80 rem c64
90 rem ===========================
100 goto200
110 b$="":fori=1to4:get#1,c$:next
120 get#1,c$:ifc$=chr$(199)thenreturn
130 ifc$<>chr$(34)then120
140 get#1,c$:ifc$<>chr$(34)thenb$=b$+c$:goto140
150 return
160 a$=""
170 get#1,c$:ifc$=chr$(32)then170
180 ifc$<>chr$(32)thena$=a$+c$:get#1,c$:goto180
185 get#1,c$:ifc$<>""then185
190 return
200 dimv$(207):dimy$(15)
210 open1,8,0,"$0"
220 gosub110
230 gosub110:ifc$=chr$(199)then260
240 gosub160
250 ifa$="prg"thenv$(x)=b$:x=x+1
255 goto230
260 close1
270 re$=chr$(0):rn$=chr$(18)
280 fl$=chr$(15):fo$=chr$(143)
290 bk$=chr$(0):rf$=chr$(146)
300 b$=chr$(32)
310 b2$=b$+b$:b4$=b2$+b2$
320 b5$=b4$+b$:b$=b5$+b5$
330 forx=0to15:y$(x)=chr$(65+x):nextx
340 printchr$(147)
350 printtab(10)rn$re$b$b$rf$bk$
360 printtab(10)rn$re$b5$"start-menue"b4$
370 printtab(10)rn$re$b$b$rf$bk$
380 print
390 forx=0to15step2:printrn$re$" "y$(x)" "rf$bk$" "v$(x+y);
400 printtab(20)rn$re$" "y$(x+1)" "rf$bk$" "v$(x+y+1)
401 iflen(v$(x+y+1))<>16thenprint
402 next
410 printtab(12)rn$re$fl$b$b5$rf$bk$fo$
420 printtab(12)rn$re$fl$b2$"waehle file"b2$rf$fo$bk$
430 printtab(12)rn$re$fl$b$b5$rf$bk$fo$
440 geta$:ifa$=""then440
445 ify>170then460
450 ifa$=chr$(13)ora$=chr$(17)theny=y+16:goto340
460 ify<16then480
470 ifa$="^"ora$=chr$(145)theny=y-16:goto340
480 ifa$<"a"ora$>"p"then440
490 a=asc(a$)-65
500 printchr$(147);:print"run"
510 print"l[207]"chr$(34)v$(a+y)chr$(34)",8"
520 poke631,19:poke632,17:poke633,13:poke634,19:poke635,13:poke198,5
530 rem ==========================
540 rem p r o g r a m m e n d e
550 rem ==========================