home *** CD-ROM | disk | FTP | other *** search
/ Commodore Disc 30 / Commodore_Disc_30_19xx_-_de.d64 / datawandler.uni (.txt) < prev    next >
Commodore BASIC  |  2022-10-26  |  2KB  |  53 lines
  1. 10 rem datawandler=universal===========
  2. 20 rem
  3. 30 rem by alfons mittelmeyer
  4. 40 rem
  5. 50 rem fuer c64/c128/c16/c116/plus4
  6. 60 rem floppy wird benoetigt
  7. 70 rem ================================
  8. 80 printchr$(147):input"zeilennummer";zn
  9. 90 input"schrittweite";sw
  10. 100 input"datas pro zeile";dz
  11. 110 print:input"adressangabe hex oder dezimal h/d";hx$
  12. 120 zs$="dezimal":ifhx$="h"thenzs$="hex"
  13. 130 print:print"adressen "zs$" eingeben !"
  14. 140 input"anfangsadresse";x$
  15. 150 input"endadresse    ";y$
  16. 160 ifhx$<>"h"thenx=val(x$):y=val(y$):goto200
  17. 170 a$=x$:gosub180:x=a:a$=y$:gosub180:y=a:goto200
  18. 180 a=0:fori=1tolen(a$):b=asc(mid$(a$,i,1))-48
  19. 190 a=16*a+b+7*(b>9):next:return
  20. 200 print:print"kontrolle:"
  21. 210 print"anfang="x" ende="y"  richtig j/n";:inputr$
  22. 220 ifr$<>"j"then110
  23. 230 print:input"datas in programm mergen j/n";mg$
  24. 240 ifmg$="j"theninput"filename";fi$
  25. 250 l$="":ifmg$="j"thenl$="l[207]"+chr$(34)+fi$+chr$(34)+",8"
  26. 260 print:print"datawandlung beginnt..."
  27. 270 open8,8,8,"datas,s,w":cmd8
  28. 280 x$=str$(x):y$=str$(y)
  29. 290 x$=right$(x$,len(x$)-1)
  30. 300 y$=right$(y$,len(y$)-1)
  31. 310 gosub430:print" fori="x$"to"y$:zn=zn+sw
  32. 320 gosub430:print" reada:pokei,a:next"
  33. 330 zn=zn+sw
  34. 340 l=int((y-x+1)/dz)+1:k=(y-x+1)-(l-1)*dz
  35. 350 ifk=0thenl=l-1:k=dz
  36. 360 forj=1tol:n=dz:ifj=lthenn=k
  37. 370 gosub430:print" data ";:k$=","
  38. 380 for i=0 to n-1:a=peek(x+i)
  39. 390 a$=str$(a):a$=right$(a$,len(a$)-1)
  40. 400 a$=right$("00"+a$,3):ifi=n-1thenk$=chr$(13)
  41. 410 print a$k$;:next
  42. 420 x=x+dz:zn=zn+sw:next:goto450
  43. 430 printright$(str$(zn),len(str$(zn))-1);
  44. 440 return
  45. 450 p=peek(772):ifp=124then re$="812,46:poke781":tp=631:tn=198:goto480
  46. 460 ifp= 13then re$="812,33:poke7":tp=842:tn=208:goto480
  47. 470 re$="810,7:poke2035":tp=1319:tn=239
  48. 480 print#8,"sys65484:close8:open8,8,15,"chr$(34)"s:datas"chr$(34)":close8"
  49. 490 close8:print"[147]open8,8,8,"chr$(34)"datas,s,r"chr$(34)":poke"re$",8:sys65478"
  50. 500 printl$;:poketp,145:poketp+1,145:poketp+2,13:poketp+3,19:poketp+4,13
  51. 510 poketn,5:new:end
  52. 520 rem ==programmende=================
  53.