home *** CD-ROM | disk | FTP | other *** search
/ Ahoy 1985 April / Ahoy_Magazine_85-04_1985_Double_L.d64 / rupert (.txt) < prev    next >
Commodore BASIC  |  2022-10-26  |  2KB  |  69 lines
  1. 0 rem << rr16-1 >>
  2. 10 rem - rupert report listing 1 -
  3. 20 rem
  4. 30 rem -- save memory to disk --
  5. 39 rem
  6. 40 rem * * * * * * * * * * * * * * * *
  7. 41 rem *                             *
  8. 42 rem *  note that lines 180 - 400  *
  9. 43 rem *   may be omitted if these   *
  10. 44 rem *   two lines are changed:    *
  11. 45 rem *    200 open 8,8,8,flnam$    *
  12. 46 rem *    520 close 8              *
  13. 47 rem *                             *
  14. 48 rem * * * * * * * * * * * * * * * *
  15. 49 rem
  16. 50 print chr$(147) :rem clear-scrn
  17. 60 def fnh(x)=int(x/256)
  18. 70 def fnl(x)=x-256*fnh(x)
  19. 80 areg=780 : xreg=781 : yreg=782
  20. 90 rem
  21. 100 rem<><><><><><><><><><><><><><><><>
  22. 110 rem put filename, starting address
  23. 120 rem     and ending address below
  24. 130 rem<><><><><><><><><><><><><><><><>
  25. 140 flnam$="dos 5.1" :rem   filename
  26. 150 saddr=52224 :rem $cc00 (start addr)
  27. 160 eaddr=53082 :rem $cf5a (end addr+1)
  28. 170 rem
  29. 180 rem=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-
  30. 190 rem ...kernal routine: setlfs...
  31. 200 rem=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-
  32. 210 slfs=65466  :rem $ffba
  33. 220 flnum=8 : dnum=8 : cmmd=255
  34. 230 poke areg,flnum
  35. 240 poke xreg,dnum : poke yreg,cmmd
  36. 250 sys slfs
  37. 260 print"back from 'setlfs'":print
  38. 270 rem=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-
  39. 280 rem ...kernal routine: setnam...
  40. 290 rem=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-
  41. 300 snam=65469  :rem $ffbd
  42. 310 buff=49155  :rem $c003
  43. 320 lnam=len(flnam$)
  44. 330 for n=1 to lnam
  45. 340 poke buff+n-1,asc(mid$(flnam$,n,1))
  46. 350 next n
  47. 360 poke areg,lnam
  48. 370 poke xreg,fnl(buff)
  49. 380 poke yreg,fnh(buff)
  50. 390 sys snam
  51. 400 print"back from 'setnam'":print
  52. 410 rem=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-
  53. 420 rem ...kernal routine: save...
  54. 430 rem=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-=-
  55. 440 sve=65496   :rem $ffd8
  56. 450 zptr=251    :rem $fb (zero page)
  57. 460 poke zptr,fnl(saddr)
  58. 470 poke zptr+1,fnh(saddr)
  59. 480 poke areg,zptr
  60. 490 poke xreg,fnl(eaddr)
  61. 500 poke yreg,fnh(eaddr)
  62. 510 sys sve
  63. 520 print"back from 'save'":print
  64. 530 print"===memory save routine==="
  65. 540 print"file name:        ";flnam$
  66. 550 print"starting address: ";saddr
  67. 560 print"ending address:   ";eaddr-1
  68. 570 print
  69.