home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
64'er Special 83
/
64er_Magazin_Sonderheft_83_19xx_Markt__Technik_de_Side_B.d64
/
trackwrite
(
.txt
)
< prev
next >
Wrap
Commodore BASIC
|
2022-10-26
|
1KB
|
52 lines
10 t=37 :rem track
20 s=12 :rem sector
30 w=144 :rem schreiben eines blocks
40 r=128 :rem lesen eines blocks
70 v=1 :rem verzoegerung bei compilierten programmen (>=10)
72 poke53280,1:poke53281,1:poke646,0
74 print"[147] [211][197][203][212][207][210] [211][195][200][210][197][201][194][197][206] [201][206] [211][208][213][210] 36 [194][201][211] 40 "
76 print"[210]ichtige [196]iskette einlegen, dann"
77 print"sechs [194]ildschirmzeilen [212]ext eingeben."
78 print"[202]ede [218]eile mit <[210][197][212][213][210][206]> abschliessen!"
80 tx$="":ax$="":gosub2000:rem texteingabe
100 open1,8,15,"i"
120 :
121 rem eintragen informationen in block
122 :
130 fori=1tolen(tx$)
140 x$=mid$(tx$,i,1)
150 print#1,"m-w"+chr$(i+2)+chr$(3)+chr$(1)+x$
160 nexti
170 :
180 rem schreiben auf diskette
190 :
200 p=0:b=w:gosub1000
380 close1
390 end
400 :
1000 :
1010 rem parameter an diskcontroller
1020 :
1030 rem track und sector fuer puffer 0
1040 :
1050 print#1,"m-w"+chr$(6)+chr$(0)+chr$(2)+chr$(t)+chr$(s)
1060 :
1070 rem befehlscode lesen oder schreiben fuer puffer 0
1080 :
1090 print#1,"m-w"+chr$(0)+chr$(0)+chr$(1)+chr$(b)
1100 :
1110 rem warten
1120 :
1130 fori=1to5000*v:nexti
1140 :
1150 rem returncode
1160 :
1170 print#1,"m-r"+chr$(0)+chr$(0)+chr$(1)
1180 get#1,x$:x=asc(x$+chr$(0))
1190 return
2000 print""
2010 fori=1to6:poke19,64:inputax$:poke19,0:print:ax$=ax$+chr$(13)
2011 tx$=tx$+ax$:next
2020 iflen(tx$)<252thenfori=len(tx$)to252:tx$=tx$+chr$(32):next
2030 return