home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
64'er Special 40
/
64er_Magazin_Sonderheft_40_19xx_Markt__Technik_de.d64
/
floppyfehler
(
.txt
)
< prev
next >
Wrap
Commodore BASIC
|
2022-10-26
|
2KB
|
112 lines
1000 rem *** teil a
1001 :
1010 af=6
1020 dim en(af)
1100 data 26
1110 data 72
1120 data 74
1130 data 64
1140 data 62
1150 data 63
1500 for i=1 to af
1510 read en(i)
1520 next i
1530 open 14,8,15
1540 :
1600 rem *** teil b
1601 :
1610 dim n$(300),s$(300),o$(100),t$(100)
2000 aa=0
2100 print chr$(147)
2110 input "dateiname: ";dn$
2120 print
2130 open 1,8,8,dn$+",s,r"
2140 gosub 9000
2150 if a=62 then 2300
2160 if a=0 then 2200
2170 close 1
2180 goto 2100
2190 :
2200 rem *** teil 3
2210 input#1,aa
2220 for i=1 to aa
2230 input#1,n$(i),s$(i),o$(i),t$(i)
2240 print n$(i) : print s$(i)
2250 print o$(i) : print t$(i)
2260 print
2270 next i
2300 close 1
2310 aa=aa+1
2320 input "name: ";n$(aa)
2330 input "strasse: ";s$(aa)
2340 input "ort: ";o$(aa)
2350 input "telefon: ";t$(aa)
2360 print
2370 input "weiter machen (j/n)";e$
2380 if e$="j" then goto 2310
2390 :
2400 rem *** teil d
2401 :
2410 open 1,8,8,dn$+",s,w"
2420 gosub 9000
2430 if a=0 then 2600
2440 close 1
2450 if a<>63 goto 2400
2500 print#14,"s:"+dn$+".bak"
2510 print#14,"r:"+dn$+".bak="+dn$
2520 goto 2400
2600 print#1,aa
2610 for i=1 to aa
2620 print#1,n$(i):print#1,s$(i)
2630 print#1,o$(i):print#1,t$(i)
2640 next i
2650 close 1 : close 14
2660 print "programm beendet"
3000 end
3010 :
9000 rem *** teil e
9001 :
9010 input#14,a,b$,c,d
9020 if a=0 then return
9030 print
9040 i9=1
9050 if en(i9)=a then 9100
9060 i9=i9+1
9070 if i9<=af then 9050
9080 print a;" ";b$;" ";"spur:";c;" sektor:";d
9090 stop : rem programmabbruch
9100 on i9 goto 9200,9300,9400,9500
9110 return
9120 :
9200 rem *** fehlermeldung 1
9210 print "die diskette ist schreibgeschuetzt" : print
9220 print "wenn sie mit der diskette arbeiten wollen"
9230 print " dann entfernen sie den schutz"
9240 gosub 9900
9250 return
9260 :
9300 rem *** fehlermeldung 2
9310 print "die diskette oder das inhaltsverzeichnis sind voll"
9320 print " legen sie eine andere diskette ein"
9330 gosub 9900
9340 return
9350 :
9400 rem *** fehlermeldung 3
9410 print "es befindet sich keine formattierte"
9420 print " diskette im laufwerk"
9430 gosub 9900
9440 return
9450 :
9500 rem *** fehlermeldung 4
9510 print "diese datei existiert bereits als programmdatei"
9520 print " auf der diskette"
9530 print "waehlen sie einen anderen namen"
9540 gosub 9900
9550 return
9560 :
9900 rem *** taste abwarten
9910 print : print "wenn fertig - taste druecken"
9920 get e$ : if e$="" then 9920
9930 return
9940 :