home *** CD-ROM | disk | FTP | other *** search
/ 64'er Special 28 / 64er_Magazin_Sonderheft_28_19xx_Markt__Technik_de_Side_B.d64 / relativ (.txt) < prev    next >
Encoding:
Commodore BASIC  |  1990-01-01  |  1.8 KB  |  83 lines
  1. 100 open 1,8,15: rem befehlskanal oeffnen
  2. 110 open 2,8,2,"infodatei,s,r": rem seq.datei oeffnen
  3. 120 input#1,a: rem fehler aufgetreten?
  4. 130 if a=0 then input#2,ad: rem nein, dann adress-anzahl lesen
  5. 140 close 2: rem sequentielle datei schliessen
  6. 150 :
  7. 160 open 2,8,2,"adressen,l,"+chr$(100): rem rel-datei oeffnen
  8. 170 :
  9. 180 :
  10. 190 rem *** menue ***
  11. 200 print:print "1=eintragen/2=blaettern/3=aendern/4=ende":print
  12. 210 get a$: if a$="" then goto 210
  13. 220 :
  14. 230 if a$<>"4" then on val(a$) gosub 340,430,550: goto 200
  15. 240 :
  16. 250 close 2: rem relative datei schliessen
  17. 260 print#1,"s:infodatei": rem seq.datei loeschen
  18. 270 open 2,8,2,"infodatei,s,w": rem seq.datei oeffnen
  19. 280 print#2,ad: rem adressanzahl speichern
  20. 290 close 2: close 1: rem alle dateien schliesen
  21. 300 end
  22. 310 :
  23. 320 :
  24. 330 rem *** neue adresse eintragen ***
  25. 340 print "*eintragen*"
  26. 350 gosub 650: rem adresse abfragen
  27. 360 ad=ad+1
  28. 370 rec=ad: gosub 880: rem positionieren
  29. 380 gosub 740: rem satz schreiben
  30. 390 return
  31. 400 :
  32. 410 :
  33. 420 rem *** blaettern ***
  34. 430 print "*blaettern*"
  35. 440 get a$: if a$="" then goto 440
  36. 450 if a$<>chr$(29) and a$<>chr$(157) then return
  37. 460 if a$=chr$(29) and rec<ad then rec=rec+1
  38. 470 if a$=chr$(157) and rec>1 then rec=rec-1
  39. 480 gosub 880: rem positionieren
  40. 490 gosub 810: rem adresse lesen
  41. 500 print: print n$: print w$: print t$: print
  42. 510 goto 440
  43. 520 :
  44. 530 :
  45. 540 rem *** aendern ***
  46. 550 print "*aendern*"
  47. 560 gosub 650: rem adresse abfragen
  48. 570 gosub 880: rem positionieren
  49. 580 gosub 730: rem satz schreiben
  50. 590 return
  51. 600 :
  52. 610 :
  53. 640 rem *** adresse abfragen ***
  54. 650 n$="": w$="": t$=""
  55. 660 input "name";n$
  56. 670 input "wohnort";w$
  57. 680 input "telefon";t$
  58. 690 return
  59. 700 :
  60. 710 :
  61. 720 rem *** datensatz schreiben ***
  62. 730 if n$="" then n$="*": rem achtung: das schreiben von
  63. 740 if w$="" then w$="*": rem 'leerstrings' muss ver-
  64. 750 if t$="" then t$="*": rem mieden werden !!!
  65. 760 print#2,n$ chr$(13) w$ chr$(13) t$: rem 1 print#-befehl !!!
  66. 770 return
  67. 780 :
  68. 790 :
  69. 800 rem *** datensatz lesen ***
  70. 810 input#2,n$: if n$="*" then n$=""
  71. 820 input#2,w$: if w$="*" then w$=""
  72. 830 input#2,t$: if t$="*" then t$=""
  73. 840 return
  74. 850 :
  75. 860 :
  76. 870 rem *** positionieren ***
  77. 880 hb=int(rec/256)
  78. 890 lb=rec-hb*256
  79. 900 print#1,"p"+chr$(2)+chr$(lb)+chr$(hb)+chr$(1)
  80. 910 return
  81. 920 :
  82. 930 :
  83.