home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
64'er Special 19
/
64er_Magazin_Sonderheft_19_19xx_Markt__Technik_de.d64
/
literatur-datei
(
.txt
)
< prev
next >
Wrap
Commodore BASIC
|
2022-10-26
|
1KB
|
74 lines
2 rem++++++++ literatur datei +++++++++
3 :
4 :
5 rem--------- menue ----------------
7 :
10 printchr$(147)
15 print spc(90)"waehlen sie bitte aus"
20 print tab(202)"(1) datei laden"
25 print spc(82) "(2) datensaetze suchen"
30 print spc(82) "(3) neuen text eingeben"
35 print spc(82) "(4) datei abspeichern"
40 print spc(82) "(5) ende"
45 :
50 print
55 input a
60 on a gosub 100,200,400,500,600
65 goto 10
90 :
100 rem-------- datei laden ----------
105 :
110 dim a$(100,6)
115 open 1,8,3,"literatur,s,r"
120 d=d+1
130 for k=1 to 6
140 input#1,a$(d,k)
150 if a$(d,k)="@"then k=6:next k:goto 180
160 next k
170 goto 120
180 close 1
190 return
195 :
200 rem------ datensaetze suchen ------
205 :
210 input"stichwort";s$
220 for s=1 to d
230 for k=1 to 6
240 if a$(s,k)=s$ then for z=1 to 6:printa$(s,z):next z
250 next k
260 print
270 next s
280 print"ende der suche"
290 print
300 :
310 print"noch einmal (j/n)?"
320 get v$:if v$="" then 320
330 if v$="j" then 210
340 return
390 :
400 rem----- neuen text eingeben ------
405 :
420 k=1
430 print k".kategorie":input a$(d,k)
440 if k<6 then k=k+1:goto 430
445 :
450 print:print"noch eine eingabe (j/n) ?"
460 get v$:if v$="" then 460
470 if v$="j" then d=d+1:goto 420
480 goto 500
490 :
500 rem------- datei abspeichern ------
505 :
510 open 1,8,4,"@:literatur,s,w"
520 for s=1 to d
530 for k=1 to 6
540 print#1,a$(s,k)
550 next k:next s
560 print#1,"@"
570 close 1
580 return
599 :
600 rem----------- ende --------------
605 :
610 end