home *** CD-ROM | disk | FTP | other *** search
/ 64'er 1995 June / 64er_Magazin_95-06_1995_Markt__Technik_de_Side_A.d64 / heapsort (.txt) < prev    next >
Commodore BASIC  |  2022-10-26  |  2KB  |  88 lines
  1. 10 rem erstellen eines feldes zum
  2. 20 rem sortieren.
  3. 30 rem das erstellen kann zufaellig
  4. 40 rem oder geziehlt (durch eingabe)
  5. 50 rem erfolgen.
  6. 60 rem
  7. 70 rem sortieralgorithmen erhalten die
  8. 80 rem zeilennummern von 10000 bis 50000
  9. 90 rem sie benoetigen jeweils diesen
  10. 99 rem vorspann zur ausfuehrung.
  11. 100 rem herstellung eines arrays:
  12. 110 rem arrayvariable      - a$
  13. 120 rem schleifenvariablen - x, y, z
  14. 130 rem hilfsvariablen     - b$, c$, d$
  15. 140 rem dreiecktausch mit  - s$
  16. 150 print"[147]":clr
  17. 160 print"soll von h[146]and oder z[146]ufaellig erstellt":print
  18. 170 input"werden ";x$
  19. 180 ifx$<>"h"andx$<>"z"then150
  20. 190 ifx$="h"thengosub220:gosub1000:goto210
  21. 200 gosub220:gosub2000
  22. 210 goto4000: rem weitermachen
  23. 220 rem anzahl der elemente bestimmen
  24. 230 print:input"anzahl der elemente ";a
  25. 240 if a>10000thenprint:print"zu viele elemente":goto230
  26. 250 ifa<10thenprint:print"zu wenige elemente":goto230
  27. 255 dim a$(a)
  28. 260 input"d[146]rucker oder b[146]ildschirm ";y$
  29. 270 ify$<>"d"andy$<>"b"then260
  30. 280 ify$="d"thend=4:goto300
  31. 290 d=3
  32. 300 return
  33. 1000 rem eingabe von hand
  34. 1010 print"[147]"
  35. 1020 print:print"sie muessen jetzt"a" elemente eingeben!":print:print
  36. 1030 print"jedes element besteht aus 3 zeichen.":print:print
  37. 1040 forx=1toa
  38. 1050 printx". ";:input"element";a$(x)
  39. 1060 iflen(a$(x))<>3then1050
  40. 1070 nextx
  41. 1080 return
  42. 2000 rem zufaellige eingabe
  43. 2010 print"[147]"
  44. 2020 print:print"es werden jetzt"a" elemente zufaellig":print:print"ausgewaehlt"
  45. 2030 print:print"jedes element besteht aus 3 zeichen.":print:print
  46. 2040 forx=1toa
  47. 2050 a$(x)=""
  48. 2060 fory=1to3:a$(x)=a$(x)+chr$(int(rnd(ti)*25)+65):nexty
  49. 2070 nextx
  50. 2080 return
  51. 3000 rem zwischenausgabe der elemente
  52. 3010 for i=1toa-9step10
  53. 3020 for j=itoi+9:print#1,a$(j)" ";:nextj
  54. 3030 print#1:nexti
  55. 3040 return
  56. 4000 rem weitermachen
  57. 4005 open1,d
  58. 4010 print"[147]ausgabe des erstellten feldes"
  59. 4020 print
  60. 4030 gosub3000
  61. 4040 rem sortierung startet
  62. 4050 rem
  63. 10040 lg=int(a/2)+1:rg=a
  64. 10050 ifrg<=1then50000
  65. 10060 iflg<=1then10110
  66. 10080 lg=lg-1
  67. 10090 i=lg:goto10140
  68. 10110 s$=a$(1):a$(1)=a$(rg):a$(rg)=s$
  69. 10120 rg=rg-1
  70. 10130 i=1
  71. 10140 x$=a$(i)
  72. 10150 p=0
  73. 10160 if2*i<=rgandp=0then10210
  74. 10170 a$(i)=x$
  75. 10180 goto10050
  76. 10210 j=2*i
  77. 10220 ifj<rgthenifa$(j)<a$(j+1)thenj=j+1
  78. 10230 ifx$>=a$(j)then10260
  79. 10240 a$(i)=a$(j)
  80. 10250 i=j:goto10160
  81. 10260 p=1:goto10160
  82. 50000 rem endebehandlung
  83. 50010 print#1
  84. 50020 gosub 3000
  85. 50030 print#1,a;" elemente"
  86. 50040 print#1:print#1:close1
  87. 50050 end
  88.