home *** CD-ROM | disk | FTP | other *** search
/ 64'er 1993 July / 64er_Magazin_93-07_1993_Markt__Technik_de_Side_A.d64 / listing1 (.txt) < prev    next >
Commodore BASIC  |  2022-10-26  |  1KB  |  39 lines
  1. 0 s=54272:pokes+24,15   :rem volle lautstaerke
  2. 1 pokes+5,0:pokes+6,255 :rem adsr poken
  3. 8 goto50 :rem zur hauptschleife
  4. 9 :
  5. 10 rem **  vibrato init  **
  6. 11 :
  7. 12 : d=50    :rem verzoegerung (delay)
  8. 13 : l=5     :rem schwingweite (level)
  9. 14 : g=20    :rem geschw.      (speed)
  10. 15 : h=3500  :rem tonhoehe
  11. 16 :
  12. 17 ri=1:za=int(l/2) :rem startrichtung und startzaehler setzen
  13. 18 w=d:t=1 :rem wartezeit auf delay setzen und ton neu anschlagen (t=1)
  14. 19 return
  15. 29 :
  16. 30 rem ** virbato effekt **
  17. 31 :
  18. 32 w=w-1 :rem wartezeit vermindern
  19. 33 if w>0 then return :rem noch laenger warten: return, sonst delay-zeit vorbei
  20. 34 za=za+1 : rem zaehler erhoehen
  21. 36 if za=l then ri=-ri:za=0 :rem ist zaehler gleich level ? nein -> weiter
  22. 37 rem ja -> richtung wechseln und zaehler loeschen
  23. 38 h=h+ri*g :rem je nach richtung g addieren oder subtrahieren
  24. 40 return
  25. 41 :
  26. 42 rem **   sid  poken   **
  27. 43 :
  28. 44 if t=1 thent=0:pokes+4,33:fori=1to10:next:pokes+4,32:rem ton neu anschlagen?
  29. 45 rem ja -> sid poken und anforderung loeschen. nein -> weiter
  30. 46 pokes,hand255:pokes+1,h/256 : rem tonhoehe h in sid poken
  31. 48 return
  32. 49 :
  33. 50 rem **  hauptschleife **
  34. 51 :
  35. 52 geta$:ifa$=" "thengosub10 :rem ton mit space neu starten
  36. 54 gosub 32 :rem vibrato aufrufen
  37. 56 gosub 44 :rem sid-register poken
  38. 58 goto  52 :rem hauptschleife ende
  39.