home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
64'er 1990 December
/
64er_Magazin_90-12_1990_Markt__Technik_de_Side_A.d64
/
btxkonv
(
.txt
)
< prev
next >
Wrap
Commodore BASIC
|
2022-10-26
|
4KB
|
173 lines
10 ifa=1then100
20 poke53280,12
30 poke53281,12
40 print"[144][147]";
50 print"[184][184][184][184][184][184][184][184][184][184][184][184][184][184][184][184][184][184][184][184][184][184][184][184][184][184][184]"
60 print" [195]odetabellen-[197]ditor [214]1.31"
70 print" [196][210][197][215][211] [197][196][214]+[194]tx [199]mb[200] ([195])'90"
80 print"[185][185][185][185][185][185][185][185][185][185][185][185][185][185][185][185][185][185][185][185][185][185][185][185][185][185][185]"
90 a=1:load"btxparam",8,1
100 clr:x=20000
110 print"[194]edienung mit:"
120 print"[211]pace : [193]lten [215]ert uebernehmen"
130 print"[210]eturn: [206]euen [215]ert eingeben"
140 print"[196]ruckertabelle aendern (j/n) ";
150 geta$:ifa$<>"j"anda$<>"n"then150
160 ifa$="n"thenprint"n":goto900
170 print"j"
180 print"[211]tandardtabelle nehmen (s)"
190 print"[206]eue [215]erte eingeben (n)"
200 geta$:ifa$<>"s"anda$<>"n"then200
210 ifa$="n"thenprint"n":goto810
220 rem standard
230 print"[197]pson-kompatibel (1)"
240 print"[205][208][211]801-kompatibel (2)"
250 print"[205][208][211]802-kompatibel (3)"
260 print"[205][208][211]1xxx-kompatibel (4)"
270 print"nur [199][210][207][211][211] (5)"
280 geta$:ifa$<"1"ora$>"5"then280
290 print
300 ifa$="1"then360
310 ifa$="2"then420
320 ifa$="3"then590
330 ifa$="4"then680
340 ifa$="5"then760
350 rem epson
360 print"[197]pson-[212]abelle initialisiert..."
370 print"[211]ek.adr = 1"
380 fori=0to95:pokex+i,i+32:next
390 pokex+194,1:rem sa 1
400 goto140
410 rem mps801 (crs-down-mode)
420 print"[205][208][211]801-[212]abelle initialisiert..."
430 print"[211]ek.adr = 7"
440 fori=0to32:pokex+i,i+32:next
450 fori=33to58:pokex+i,i+160:next
460 pokex+59,193:rem gr ae
470 pokex+60,207:rem gr oe
480 pokex+61,213:rem gr ue
490 fori=62to64:pokex+i,i+32:next
500 fori=65to90:pokex+i,i:next
510 pokex+91,65:rem ae
520 pokex+92,79:rem oe
530 pokex+93,85:rem ue
540 pokex+94,211:rem sz
550 pokex+95,127
560 pokex+194,7:rem sa 7
570 goto140
580 rem mps802
590 print"[205][208][211]802-[212]abelle initialisiert..."
600 print"[211]ek.adr = 7"
610 fori=0to32:pokex+i,i+32:next
620 fori=33to61:pokex+i,i+32:next
630 fori=62to64:pokex+i,i+32:next
640 fori=65to95:pokex+i,i+128:next
650 pokex+194,7:rem sa 7
660 goto140
670 rem mps1xxx (crs-down-mode)
680 print"[205][208][211]1xxx-[212]abelle initialisiert..."
690 print"[211]ek.adr = 7"
700 fori=0to32:pokex+i,i+32:next
710 fori=33to61:pokex+i,i+160:next
720 fori=62to64:pokex+i,i+32:next
730 fori=65to95:pokex+i,i:next
740 pokex+194,7
750 goto140
760 rem cursor-up-mode
770 fori=0to58:pokex+i,i+32:next
780 print"[199][210][207][211][211]-[212]abelle initialisiert..."
790 goto500:rem wie mps801!
800 rem eingabemodus
810 fori=0to95
820 print" ";i+32;":",peek(x+i),
830 geta$:ifa$=""then830
840 ifa$<>" "andasc(a$)<>13then830
850 ifa$=" "thenprint" ";peek(x+i):goto890
860 b=0:input b
870 ifb=0thenb=peek(x+i):print"[145]",,"";b
880 pokex+i,b
890 nexti
900 print"[193][211][195][201][201]-[212]abelle ? (j/n) ";
910 geta$:ifa$<>"j"anda$<>"n"then910
920 ifa$="n"thenprint"n":goto1030
930 print "j"
940 fori=96to191
950 print" ";i-64;":",peek(x+i),
960 geta$:ifa$=""then960
970 ifa$<>" "andasc(a$)<>13then960
980 ifa$=" "thenprint" ";peek(x+i):goto1020
990 b=0:inputb
1000 ifb=0thenb=peek(x+i):print"[145]",,"";b
1010 pokex+i,b
1020 nexti
1030 print"[196]ruckerparameter? (j/n) ";
1040 geta$:ifa$<>"j"anda$<>"n"then1040
1050 ifa$="n"thenprint"n":goto1540
1060 print"j"
1070 i=192
1080 print" [204]ogische [198]ilenummer ";peek(x+i),
1090 geta$:ifa$=""then1090
1100 ifa$<>" "andasc(a$)<>13then1090
1110 ifa$=" "thenprint" ";peek(x+i):goto1160
1120 b=0:inputb
1130 ifb=0thenb=peek(x+i):print"[145]",,,"";b
1140 pokex+i,b
1150 rem *************************
1160 i=i+1
1170 print" [199]eraeteadresse ";peek(x+i),
1180 geta$:ifa$=""then1180
1190 ifa$<>" "andasc(a$)<>13then1180
1200 ifa$=" "thenprint" ";peek(x+i):goto1250
1210 b=0:inputb
1220 ifb=0thenb=peek(x+i):print"[145]",,,"";b
1230 pokex+i,b
1240 rem *************************
1250 i=i+1
1260 print" [211]ekundaeradresse ";peek(x+i),
1270 geta$:ifa$=""then1270
1280 ifa$<>" "andasc(a$)<>13then1270
1290 ifa$=" "thenprint" ";peek(x+i):goto1340
1300 b=0:inputb
1310 print"[145]",,,"";b
1320 pokex+i,b
1330 rem *************************
1340 i=i+1:a=peek(x+i)
1350 print" [193]uto-[204]inefeed (j/n) ";
1360 ifa=0thenprint"nein";
1370 ifa>0thenprint"ja ";
1380 geta$:ifa$<>"j"anda$<>"n"then1380
1390 ifa$="j"thenprint"[157][157][157][157]ja ":poke(x+i),1:goto1420
1400 print"[157][157][157][157]nein":poke(x+i),0
1410 rem *************************
1420 i=i+1:print" [204]eerzeilen vorher ";peek(x+i),
1430 geta$:ifa$=""then1430
1440 ifa$<>" "andasc(a$)<>13then1430
1450 ifa$=" "thenprint" ";peek(x+i):goto1480
1460 b=0:inputb:print"[145]",,,"";b:pokex+i,b
1470 rem *************************
1480 i=i+1:print" [204]eerzeilen nachher ";peek(x+i),
1490 geta$:ifa$=""then1490
1500 ifa$<>" "andasc(a$)<>13then1490
1510 ifa$=" "thenprint" ";peek(x+i):goto1532
1520 b=0:inputb:print"[145]",,,"";b:pokex+i,b
1530 rem *************************
1532 i=i+1:print" [204]eerzeichen links ";peek(x+i),
1533 geta$:ifa$=""then1533
1534 ifa$<>" "andasc(a$)<>13then1533
1535 ifa$=" "thenprint" ";peek(x+i):goto1540
1536 b=0:inputb:print"[145]",,,"";b:pokex+i,b
1537 rem *************************
1540 print"[215]erte ok (j/n)"
1550 geta$:ifa$<>"j"anda$<>"n"then1550
1560 ifa$="n"then140
1570 print"[212]abellen speichern (j/n)"
1580 geta$:ifa$<>"j"anda$<>"n"then1580
1590 ifa$="n"thenend
1600 poke251,peek(43):poke252,peek(44)
1610 poke253,peek(45):poke254,peek(46)
1620 poke43,32:poke44,78:poke45,232:poke46,78:rem 200 bytes
1630 save"@:btxparam",8,1
1640 poke43,peek(251):poke44,peek(252)
1650 poke45,peek(253):poke46,peek(254)
1660 end