home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
64'er 1987 October
/
64er_Magazin_87-10_1987_Markt__Technik_de.d64
/
fr.baeume
(
.txt
)
< prev
next >
Wrap
Commodore BASIC
|
2022-10-26
|
2KB
|
58 lines
10 rem ****************************
20 rem * fraktale baeume *
30 rem * 1987 by stefan vilsmeier *
40 rem ****************************
50 :
60 if a=0 then a=1:load "fractal.obj",8,1
70 open 1,8,15,"u9":close 1: rem diese zeeile kann bei problemen mit dem
80 rem floppyspeeder weggelassen werden!
90 poke53280,0:poke53281,0
100 input "[147]grad ";gr
110 input "winkel,faktor ";wi,f
120 se=40:xp=160:yp=150:w=-90
130 sys 50176,14,0:sys 50179,1:sys 50194:rem grafik ein
140 :
150 gosub 300: rem 'baum' aufrufen
160 sys 50185,0,0,319,0,1:sys 50185,319,0,319,199,1
170 sys 50185,319,199,0,199,1:sys 50185,0,199,0,0,1
180 get a$:if a$="" goto 180
190 sys 50179,0:if a$="s" then gosub 700: rem 'grafik speichern'
200 goto 70: rem neustart
260 :
270 :
280 rem ***************************
290 rem * 'baum' *
300 rem ***************************
310 :
320 t=t+1:if gr<=0 goto 420
330 w=w-wi/2: rem 'drehe'
340 s=se:gosub 500: rem 'schreite'
350 g(t)=gr:gr=gr-1:se=se/f:gosub300:se=se*f:rem 'baum'
360 s=-se:gosub 500: rem 'schreite'
370 w=w+wi: rem 'drehe'
380 s=se:gosub 500: rem 'schreite'
390 g(t)=gr:gr=gr-1:se=se/f:gosub300:se=se*f:rem 'baum'
400 s=-se:gosub 500: rem 'schreite'
410 w=w-wi/2: rem 'drehe'
420 t=t-1:gr=g(t):return
450 :
460 :
470 rem ***************************
480 rem * 'schreite' *
490 rem ***************************
500 :
510 xs=s*cos(w*(NULL)/180)
520 ys=s*sin(w*(NULL)/180)
530 xp=xp+xs:yp=yp+ys
540 sys 50185,xp-xs,yp-ys,xp,yp,1:rem linie
550 return
650 :
660 :
670 rem ***************************
680 rem * 'grafik speichern' *
690 rem ***************************
700 :
710 input "grafik-name ";n$
720 open 2,8,2,"pi."+n$+",p,w":sys 50191:close 2
730 return