home *** CD-ROM | disk | FTP | other *** search
/ Encyclopedia of Graphics File Formats Companion / GFF_CD.ISO / software / unix / saoimage / sao1_07.tar / make.com < prev    next >
Text File  |  1991-06-04  |  3KB  |  162 lines
  1. $!-------------------------------------------------------------------------
  2. $!
  3. $! MAKE.COM - Build SAOimage on a VMS system
  4. $!
  5. $!    Parameters:
  6. $!        P1    null    Build everything
  7. $!            LINK    Link SAOIMAGE.EXE
  8. $!            CLEAN    Clean up build residue
  9. $!            xxx    Source module - compile and update library
  10. $!        P2    options    If P1=LINK, VMS Linker option (e.g. /DEBUG)
  11. $!                If P1=source module, CC compiler option
  12. $!
  13. $!-------------------------------------------------------------------------
  14. $
  15. $
  16. $ gosub BUILD_SETUP
  17. $
  18. $ if p1 .eqs. ""     then goto BUILD_ALL
  19. $ if p1 .eqs. "LINK" then goto LINK_ONLY
  20. $ if p1 .eqs. "CLEAN" then goto DISPOSE
  21. $ 
  22. $ gosub COMPILE_MODULE
  23. $ exit
  24. $
  25. $
  26. $BUILD_SETUP:
  27. $
  28. $ set noon
  29. $
  30. $ define/nolog  c$include    [.hfiles],decw$include,sys$library
  31. $ define/nolog  vaxc$include c$include
  32. $ define/nolog  X11          decw$include    ! for #include <X11/...>
  33. $ define/nolog  sys          sys$library    ! for #include <sys/...>
  34. $
  35. $ compile := cc/define=(FITS,OIF,IMTOOL,LSB,XV11R2,PSCRIPT,NODEBUG)/nodebug/optimize
  36. $ libname := libsao.olb
  37. $ makefile:= make.lst
  38. $
  39. $ return
  40. $
  41. $
  42. $COMPILE_MODULE:
  43. $
  44. $ p1 = p1 - ".C"
  45. $ compile 'p1' 'p2' 'make_options'
  46. $ library/log 'libname' 'p1'
  47. $
  48. $ return
  49. $
  50. $
  51. $LINK_ONLY:
  52. $
  53. $ if f$locate("/DEBUG",p2) .eqs. f$length(p2)
  54. $ then
  55. $    outname = "SAOIMAGE"
  56. $ else
  57. $    outname = "D_SAOIMAGE"
  58. $ endif
  59. $
  60. $ link 'p2' /nomap='outname' /exe='outname' -
  61.     []libsao/include=maininit/lib, -
  62.     [.btnlib]libbtn/lib, -
  63.     [.vms]libvms/lib, -
  64.     sys$input/opt
  65. sys$share:decw$xlibshr/share
  66. sys$share:vaxcrtl/share
  67. $
  68. $ exit
  69. $
  70. $
  71. $BUILD_ALL:
  72. $
  73. $
  74. $ write sys$output "----- Building local source modules -----"
  75. $
  76. $ if f$search(libname) .eqs. "" then library/create 'libname'
  77. $
  78. $ open/read make_input 'makefile'
  79. $
  80. $ on control_y then goto CLEANUP
  81. $
  82. $ReadLoop:
  83. $ read/end=ReadEOF/err=CLEANUP make_input line
  84. $ first = f$extract(0,1,line)
  85. $ if first .nes. "!" .and. first .nes. "#"
  86. $ then
  87. $    make_options = f$extract(f$locate("/",line),f$length(line),line)
  88. $
  89. $    p1  = f$edit(line,"UPCASE") - ".C" - make_options
  90. $    p1s = p1 + ".C"
  91. $    p1o = p1 + ".OBJ"
  92. $    if f$search(p1s) .eqs. ""
  93. $    then
  94. $        write sys$output p1s + " not found!"
  95. $        goto ReadLoop
  96. $    endif
  97. $    if f$search(p1o) .eqs. "" then goto Recompile
  98. $
  99. $    srcdate = f$file_attributes(p1s,"RDT")
  100. $    objdate = f$file_attributes(p1o,"RDT")
  101. $    bin_srcdate = f$cvtime(srcdate)
  102. $    bin_objdate = f$cvtime(objdate)
  103. $
  104. $    if bin_srcdate .les. bin_objdate
  105. $    then
  106. $        write sys$output "Up-to-date... " + p1
  107. $        goto ReadLoop
  108. $    endif
  109. $Recompile:
  110. $    write sys$output "Compiling... " + p1
  111. $
  112. $ p1 = p1 - ".C"
  113. $ compile 'p1' 'p2' 'make_options'
  114. $ library/log 'libname' 'p1'
  115. $
  116. $ endif
  117. $ goto ReadLoop
  118. $
  119. $ReadEOF:
  120. $ close make_input
  121. $
  122. $
  123. $ write sys$output "----- Building BTNLIB subdirectory -----"
  124. $
  125. $ set default [.btnlib]
  126. $ @make
  127. $ set default [-]
  128. $
  129. $
  130. $ write sys$output "----- Building VMS subdirectory -----"
  131. $
  132. $ set default [.vms]
  133. $ @make
  134. $ set default [-]
  135. $
  136. $
  137. $ write sys$output "----- Building special-case source modules -----"
  138. $
  139. $ set default [.panel]
  140. $
  141. $ libname := [-]libsao.olb
  142. $
  143. $ p1 := MAKEMENU.C
  144. $ write sys$output "Compiling... " + "[.PANEL]" + p1
  145. $ gosub COMPILE_MODULE
  146. $
  147. $ set default [-]
  148. $
  149. $
  150. $ write sys$output "----- Linking SAOimage -----"
  151. $
  152. $ goto LINK_ONLY
  153. $ exit
  154. $
  155. $DISPOSE:
  156. $ delete [...]*.obj;, [...]*.olb;, spool.log;, saoimage.exe;
  157. $ exit
  158. $
  159. $CLEANUP:
  160. $ if f$logical("MAKE_INPUT") .nes. "" then close make_input
  161. $ exit
  162.