home *** CD-ROM | disk | FTP | other *** search
/ Hacker Chronicles 2 / HACKER2.BIN / 854.OP42.CIR < prev    next >
Text File  |  1989-07-12  |  4KB  |  154 lines
  1. * OP-42 SPICE Macro-model
  2. *
  3. * Copyright 1989 by Precision Monolithics, Inc.
  4. *
  5. * Precision Monolithics, Inc. hereby grants users of this
  6. * OP-42 macro-model hereto referred to as licensee, a
  7. * nonexclusive, nontransferable license to use this macro-
  8. * model as long the licensee agrees to treat this macro-
  9. * model just like a book, except that the licensee may not
  10. * loan, rent, lease, or license the macro-model, in whole,
  11. * in part, or in modified form, to anyone outside the
  12. * licensee's company.
  13. *
  14. * The OP-42 macro-model is provided "as is."  PMI makes no
  15. * warranty, either express or implied, including but not
  16. * limited to any implied warranties or merchantability and
  17. * fitness for a particular purpose using this macro-model.
  18. * In no event will PMI be liable for special, collateral,
  19. * incidental, or consequential damages in connection with or
  20. * arising out of the use of this macro-model.  PMI reserves
  21. * the right to make changes to the product and the macro-
  22. * model without prior notice.
  23. *
  24. *
  25. * Node assignments
  26. *             non-inverting input
  27. *             | inverting input
  28. *             | | output
  29. *             | | |  positive supply
  30. *             | | |  |  negative supply
  31. *             | | |  |  |
  32. .subckt OP-42 1 2 32 99 50
  33. *
  34. * INPUT STAGE & POLE AT 15.9 MHz
  35. *
  36. r1   1  3     5E11
  37. r2   2  3     5E11
  38. r3   5 50     707.36
  39. r4   6 50     707.36
  40. cin  1  2     5E-12
  41. c2   5  6     7.08E-12
  42. i1  99  4     1E-3
  43. ios  1  2     4E-12
  44. Eos  7  1     POLY(1)  20 26  1E-3  1
  45. j1   5  2  4  jx
  46. j2   6  7  4  jx
  47. *
  48. * SECOND STAGE & POLE AT 45 Hz
  49. *
  50. r5   9 99     176.84E6
  51. r6   9 50     176.84E6
  52. c3   9 99     20E-12
  53. c4   9 50     20E-12
  54. g1  99  9     poly(1)  5  6  3.96E-3  1.4137E-3
  55. g2   9 50     poly(1)  6  5  3.96E-3  1.4137E-3
  56. v2  99  8     2.5
  57. v3  10 50     3.1
  58. d1   9  8     dx
  59. d2  10  9     dx
  60. *
  61. * POLE-ZERO PAIR AT 1.80 MHz / 2.20 MHz
  62. *
  63. r7  11 99     1E6
  64. r8  11 50     1E6
  65. r9  11 12     4.5E6
  66. r10 11 13     4.5E6
  67. c5  12 99     16.1E-15
  68. c6  13 50     16.1E-15
  69. g3  99 11     9  26  1E-6
  70. g4  11 50     26  9  1E-6
  71. *
  72. * POLE-ZERO PAIR AT 1.80 MHz / 2.20 MHz
  73. *
  74. r11 14 99     1E6
  75. r12 14 50     1E6
  76. r13 14 15     4.5E6
  77. r14 14 16     4.5E6
  78. c7  15 99     16.1E-15
  79. c8  16 50     16.1E-15
  80. g5  99 14     11 26  1E-6
  81. g6  14 50     26 11  1E-6
  82. *
  83. * POLE AT 53 MHz
  84. *
  85. r15 17 99     1E6
  86. r16 17 50     1E6
  87. c9  17 99     3E-15
  88. c10 17 50     3E-15
  89. g7  99 17     14 26  1E-6
  90. g8  17 50     26 14  1E-6
  91. *
  92. * POLE AT 53 MHz
  93. *
  94. r17 18 99     1E6
  95. r18 18 50     1E6
  96. c11 18 99     3E-15
  97. c12 18 50     3E-15
  98. g9  99 18     17 26  1E-6
  99. g10 18 50     26 17  1E-6
  100. *
  101. * POLE AT 53 MHz
  102. *
  103. r19 19 99     1E6
  104. r20 19 50     1E6
  105. c13 19 99     3E-15
  106. c14 19 50     3E-15
  107. g11 99 19     18 26  1E-6
  108. g12 19 50     26 18  1E-6
  109. *
  110. * COMMON-MODE GAIN NETWORK WITH ZERO AT 100 kHz
  111. *
  112. r21 20 21     1E6
  113. r22 20 23     1E6
  114. l1  21 99     1.5915
  115. l2  23 50     1.5915
  116. g13 99 20     3  26  1.58E-11
  117. g14 20 50     26  3  1.58E-11
  118. *
  119. * POLE AT 79.6 MHz
  120. *
  121. r24 25 99     1E6
  122. r25 25 50     1E6
  123. c15 25 99     2E-15
  124. c16 25 50     2E-15
  125. g15 99 25     19 26  1E-6
  126. g16 25 50     26 19  1E-6
  127. *
  128. * OUTPUT STAGE
  129. *
  130. r26 26 99     111.1E3
  131. r27 26 50     111.1E3
  132. r28 27 99     90
  133. r29 27 50     90
  134. l3  27 32     2.5E-7
  135. g17 30 50     25 27  11.1111E-3
  136. g18 31 50     27 25  11.1111E-3
  137. g19 27 99     99 25  11.1111E-3
  138. g20 50 27     25 50  11.1111E-3
  139. v6  28 27     0.7
  140. v7  27 29     0.7
  141. d5  25 28     dx
  142. d6  29 25     dx
  143. d7  99 30     dx
  144. d8  99 31     dx
  145. d9  50 30     dy
  146. d10 50 31     dy
  147. *
  148. * MODELS USED
  149. *
  150. .model jx PJF(BETA=999.3E-6  VTO=-2.000  IS=4E-11)
  151. .model dx   D(IS=1E-15)
  152. .model dy   D(IS=1E-15 BV=50)
  153. .ends OP-42
  154.