Hacker Chronicles 2/HACKER2.BIN/762.LOGQSL.PRG

Text File | 1985-09-22 | 2KB | 73 lines

*LOGQSL VERSION 850922
* CALLED FROM logbook
*LOCAL VARIABLES callflag,callheard,linecount

*INITIALISE EVERYTHING

USE &logbook INDEX &logbook

STORE  T  TO callflag
STORE '-' TO nqslsent
STORE '-' TO nqslrx

*MAIN LOOP
DO WHILE callflag
   GOTO TOP
   ACCEPT "Call/Prefix (* To terminate) ? " to callheard

   IF callheard = "*"
      STORE F TO callflag
      * Clear loop control for exit
   ELSE
      FIND &callheard
      IF # = 0
         ERASE
         @ 5,1 SAY callheard
         @ 5,12 say "does not appear to be in the log"
         ?
         ?
      ELSE
         DO WHILE CALL = callheard .AND. (.NOT.EOF)
            ERASE
            STORE qslsent TO  nqslsent
            STORE qslrx   TO  nqslrx

            @ 12,1 SAY "DATE"
            @ 13,1 SAY "TIME"
            @ 14,1 SAY "CALL"
            @ 15,1 SAY "BAND"
            @ 16,1 SAY "POWER"
            @ 17,1 SAY "MODE"
            @ 18,1 SAY "REPORT (RX)"
            @ 19,1 SAY "REPORT (TX)"
            @ 20,1 SAY "COMMENTS"
            @ 21,1 SAY "QSLSENT"
            @ 22,1 SAY "QSLRX"

            @ 12,13 SAY date
            @ 13,13 SAY time
            @ 14,13 SAY call
            @ 15,13 SAY band
            @ 16,13 SAY power
            @ 17,13 SAY mode
            @ 18,13 SAY rx
            @ 19,13 SAY tx

            @ 21,13 GET nqslsent
            @ 22,13 GET nqslrx
            READ

            *UPDATE ENTRY
            REPLACE qslsent WITH nqslsent
            REPLACE qslrx WITH nqslrx

            SKIP
         ENDDO
      ENDIF
   ENDIF
ENDDO

* GET READY TO EXIT
RELEASE callflag,callheard,linecount
RETURN